AutoIt Français

Bonjour

Je demande votre aide sur quelque chose qui me tracasse depuis quelques jours.

Je souhaiterai pouvoir envoyer plusieurs pièces-jointes, dans un seul mail, en autoit.

J'utilise déjà la fonction _INetSmtpMailCom ci-dessous.

► Afficher le texte

Code : Tout sélectionner

Func _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject = "", $as_Body = "", $s_AttachFiles = "", $s_CcAddress = "", $s_BccAddress = "", $s_Importance="Normal", $s_Username = "", $s_Password = "", $IPPort = 25, $ssl = 0) ; Envoie e-mail
    Local $objEmail = ObjCreate("CDO.Message")
    $objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
    $objEmail.To = $s_ToAddress
    If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
    If $s_BccAddress <> "" Then $objEmail.Bcc = $s_BccAddress
    $objEmail.Subject = $s_Subject
    If StringInStr($as_Body, "<") And StringInStr($as_Body, ">") Then
        $objEmail.HTMLBody = $as_Body
    Else
        $objEmail.Textbody = $as_Body & @CRLF
    EndIf
    If $s_AttachFiles <> "" Then
        Local $S_Files2Attach = StringSplit($s_AttachFiles, ";")
        For $x = 1 To $S_Files2Attach[0]
            $S_Files2Attach[$x] = _PathFull($S_Files2Attach[$x])
            ConsoleWrite('@@ Debug(62) : $S_Files2Attach = ' & $S_Files2Attach[$x] & @LF & '>Error code: ' & @error & @LF) ;### Debug Console
            If FileExists($S_Files2Attach[$x]) Then
                $objEmail.AddAttachment ($S_Files2Attach[$x])
            Else
                ConsoleWrite('!> File not found to attach: ' & $S_Files2Attach[$x] & @LF)
                SetError(1)
                Return 0
            EndIf
        Next
    EndIf
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $s_SmtpServer
    If Number($IPPort) = 0 then $IPPort = 25
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $IPPort
    If $s_Username <> "" Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") = $s_Username
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $s_Password
    EndIf
    If $ssl Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
    EndIf
    $objEmail.Configuration.Fields.Update
    $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "High"
    $objEmail.Fields.Update
    $objEmail.Send
    $objEmail=""
EndFunc

Je souhaiterai savoir comment joindre plusieurs pièces-jointe dans le même email.

En effet j'ai fais plusieurs recherche (sur le forum ici, le forum anglais, google) et pourtant je n'ai pas tout trouvé, ou tout compris :/.

Les fichiers (n'importe lequel, n'importe quelle extension, tant qu'elle est supportée par gmail) peuvent se trouver n'importe où, ce n'est pas un problème ^^.

Code : Tout sélectionner

_INetSmtpMailCom("smtp.gmail.com", "", $envoie, $recoit, "Mes infos", $touche , $fichiers , "", "", "Normal", $envoie, $mdp , 465 , 1)

Merci de votre aide :p.

Katanati

PS : c'est mon deuxième topic (après ma présentation) si j'ai fais quelque chose de mal présenté, dites le moi pour que j'édite

Merci.

Bonsoir,

J'utilise pas du tout "_INetSmtpMailCom" donc je ne peux que vous orienté vers ceci.

Apparemment il est possible de spécifier "plusieurs" fichier en les séparant par des ";"

C'est n'est pas apparemment, mais surement!
Il suffit de séparer les fichiers par ;

Merci pour vos liens, j'avais déjà vu ce lien et tenter de faire quelque chose avec

Mais je n'y arrive pas du tout

Pourriez vous me faire un exemple avec la façon de faire que ce membre anglais à présenté ?

J'ai tout tenté, et rien compris au final :/.

Code : Tout sélectionner

#include <File.au3>

$list = _FileListToArray(@ScriptDir, "*", 1)
If $list = 0 Then Exit MsgBox(0, "Erreur", "Aucun fichier")

Global $files = ""
For $i = 1 To $list[0]
    $files &= $list[$i] & ";"
Next
$files = StringTrimRight($files, 1) ; enlever le dernier ;
MsgBox(0, "Debug", "Liste des fichiers à envoyer:" & @CRLF & $files)

_INetSmtpMailCom("smtp", "Votre nom", "Votre mail", "EMail destinataire", "Sujet", "Corps du message", $files, "", "", "Normal", "user", "pass", 25, 0)

matwachich a écrit :

Code : Tout sélectionner

#include <File.au3>

$list = _FileListToArray(@ScriptDir, "*", 1)
If $list = 0 Then Exit MsgBox(0, "Erreur", "Aucun fichier")

Global $files = ""
For $i = 1 To $list[0]
    $files &= $list[$i] & ";"
Next
$files = StringTrimRight($files, 1) ; enlever le dernier ;
MsgBox(0, "Debug", "Liste des fichiers à envoyer:" & @CRLF & $files)

_INetSmtpMailCom("smtp", "Votre nom", "Votre mail", "EMail destinataire", "Sujet", "Corps du message", $files, "", "", "Normal", "user", "pass", 25, 0)

Merci de votre réponse !
Je vais voir ça et je vous dirai si j'ai réussi,

J'espère que ce topic pourra aider ceux qui cherchent à faire la même chose que moi, ou ceux qui ne savent pas bien comprendre l'anglais.

Merci à vous !

AutoIt Français

[..] Multi pièce jointe

[..] Multi pièce jointe

Re: [..] Multi pièce jointe

Re: [..] Multi pièce jointe

Re: [..] Multi pièce jointe

Re: [..] Multi pièce jointe

Re: [..] Multi pièce jointe