AutoIt Français

Bonjour,
Voilà, j'ai un petit problème avec une fonction (que j'ai reprise de ce programme: http://autoitscript.fr/forum/viewtopic. ... act#p40472)

Donc, voici la fonction en question:

Code : Tout sélectionner

        Case $ListM ; Lorsqu'on clique sur la liste
            $SelItem = _GUICtrlListBox_GetSelItemsText($ListM) ; On récupère l'item sélectionné dans $SelItem
            If $SelItem[0] <> 0 Then ; Si il y a bien un item de sélectionné alors
                GUICTrlSetData($GroupMemoActif, $IntituleMemo & ">" & $SelItem) ; On modifie l'intitulé du groupe $GroupMemoActif
                If $SelItem = "Credits" Then ; Si l'item sélectionné correspond à la key "Credits" alors
                    GUICtrlSetData($InputTitre, "Crédits") ; On modifie l'input $InputTitre
                    GUICtrlSetData($EditMemo, IniRead($IniFile, $SelItem[1], "Auteur", "")) ; On modifie la zone de saisie $EditMemo
                EndIf
            EndIf

Voila, la fonction est on ne peut plus simple à comprendre, seulement, je ne vois pas d'où peut venir l'erreur :S
Merci de votre aide.

$SelItem est une array

Code : Tout sélectionner

      Case $ListM ; Lorsqu'on clique sur la liste
            $SelItem = _GUICtrlListBox_GetSelItemsText($ListM) ; On récupère l'item sélectionné dans $SelItem
            If $SelItem[0] <> 0 Then ; Si il y a bien un item de sélectionné alors
                GUICTrlSetData($GroupMemoActif, $IntituleMemo & ">" & $SelItem[color=#FF0000][1][/color]) ; [color=#FF0000]ou peut-être $SelItem[0] ?[/color]
                If $SelItem[color=#FF0000][1][/color] = "Credits" Then ; Si l'item sélectionné correspond à la key "Credits" alors
                    GUICtrlSetData($InputTitre, "Crédits") ; On modifie l'input $InputTitre
                    GUICtrlSetData($EditMemo, IniRead($IniFile, $SelItem[1], "Auteur", "")) ; On modifie la zone de saisie $EditMemo
                EndIf
            EndIf

C'est ce que j'avais mis au début ^^
Si ça peut t'aider, le problème vient très certainement de ceci: If $SelItem[0] <> 0 Then
Puisque lorsque je met un MsgBox après, elle ne s'affiche pas.
Merci de ton aide (:

Faudrait vérifier qu'il enregistre bien une sélection d'item si clic sur la liste

Code : Tout sélectionner

Case $ListM
    $sel = _GUICtrlListBox_GetSelCount ($ListM)
    If $sel = -1 Then 
        msgbox(0,"", "aucun item sélectionné")
    Else
        msgbox(0,"", $sel & "  items sélectionnés")
    EndIf

Apparemment il n'enregistre aucune sélection puisque ça me retourne la première condition :/
C'est étrange quand même :d

Alors là faudrait me montrer le code complet (ou presque) histoire de pouvoir faire des essais
Heu à tout hasard, ça marche bien ça ?

Code : Tout sélectionner

Case $ListM
   MsgBox(0,"", "clic sur la liste")

Oui, ça ça marche :p
C'est la sélection qui bug ^^
Le code complet est très simple puisque j'ai simplement reprit l'idée de mémo de silvere.
Je suis juste reparti de 0 pour pouvoir le modifier à ma sauce et mettre les éléments qui me paraissent le plus logique (d'où la liste permettant d'afficher tous les mémos)

Voici:

► Afficher le texte

Code : Tout sélectionner

;===Includes===
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <File.au3>
#Include <GuiListBox.au3>


;===Déclaration des Variables===
Global $IntituleMemo = "Mémo Actif"
Dim $IniFile = @UserProfileDir & "\Memo\Memo.ini"


;===GUI===
#Region ### START Koda GUI section ### Form=C:\Users\Kagami\Desktop\Olympe Mémo.kxf
;=GUI=
$GUI = GUICreate("Olympe Mémo", 362, 288, 483, 246)
;==Groupe ListeView==
$GroupListMemo = GUICtrlCreateGroup("Olympe Mémo", 8, 0, 170, 281)
;=Liste=
$ListM = GUICtrlCreateList("", 16, 16, 154, 254)
GUICtrlCreateGroup("", -99, -99, 1, 1)
;==Groupe Info Mémo actif==
$GroupMemoActif = GUICtrlCreateGroup($IntituleMemo, 184, 0, 170, 281)
;=Titre=
$LabelTitre = GUICtrlCreateLabel("Titre", 192, 16, 25, 17)
$InputTitre = GUICtrlCreateInput("", 192, 32, 153, 21)
;=Detail=
$LabelDetail = GUICtrlCreateLabel("Détail Mémo", 192, 56, 63, 17)
$EditMemo = GUICtrlCreateEdit("", 192, 72, 153, 105, BitOR($ES_AUTOVSCROLL,$ES_WANTRETURN))
;=Heures=
$LabelHeure = GUICtrlCreateLabel("Heure", 192, 184, 33, 17)
$InputHeure = GUICtrlCreateInput("", 192, 200, 41, 21, BitOR($ES_AUTOHSCROLL,$ES_NUMBER,$SS_CENTER))
GUICtrlSetLimit(-1, 2)
$LabelH = GUICtrlCreateLabel("H", 240, 200, 18, 21, BitOR($SS_CENTER,$SS_NOPREFIX,$SS_CENTERIMAGE,$SS_SUNKEN))
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
;=Minutes=
$InputMin = GUICtrlCreateInput("", 264, 200, 41, 21, BitOR($ES_AUTOHSCROLL,$ES_NUMBER,$SS_CENTER))
GUICtrlSetLimit(-1, 2)
$LabelMin = GUICtrlCreateLabel("Min", 312, 200, 34, 21, BitOR($SS_CENTER,$SS_NOPREFIX,$SS_CENTERIMAGE,$SS_SUNKEN))
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
;=Boutons=
$ButtonNouveau = GUICtrlCreateButton("Nouveau", 200, 232, 67, 38, $WS_GROUP)
$ButtonSupprimer = GUICtrlCreateButton("Supprimer", 272, 232, 67, 38, $WS_GROUP)
GUICtrlCreateGroup("", -99, -99, 1, 1)
;=Affichage=
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


;===2nd Déclaration des Variables===
Global $ReadTitre = GUICtrlRead($InputTitre)
Global $ReadDetail = GUICtrlRead($EditMemo)


;===Création du ini & Recherche des contacts===
_VerifFileExist($IniFile)
;=Remplissage de la liste=
$ReadIniTitre = IniReadSectionNames($IniFile)
For $i = 1 To $ReadIniTitre[0]
    _GuiCtrlListBox_AddString($ListM, $ReadIniTitre[$i])
Next


;===Boucle Principale===
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            _VerifFileExist($IniFile)
            Exit

        Case $ListM
            $SelItems = _GUICtrlListBox_GetSelItemsText($ListM)
            MsgBox(0, "", "Vous avez selectionné" & $SelItems[1])
            If $SelItems[0] <> 0 Then
                GUICTrlSetData($GroupMemoActif, $IntituleMemo & ">" & $SelItems[1])
                If $SelItems[1] = "Credits" Then
                    GUICtrlSetData($InputTitre, "Crédits")
                    GUICtrlSetData($EditMemo, IniRead($IniFile, $SelItems[1], "Auteur", ""))
                EndIf
            EndIf

        Case $InputHeure
            _CorrectionHeures($InputHeure, GUICtrlRead($InputHeure))

        Case $InputMin
            _CorrectionMinutes($InputMin, GUICtrlRead($InputMin))

    EndSwitch
WEnd


;===Fonctions===
;===Func _CorrectionMinutes & _CorrectionHeures===
Func _CorrectionMinutes($InputMin, $ReadMin)
    ;=Gestion du dépassement des 59 minutes=
    If $ReadMin > 59 Then
        MsgBox(0, "Erreur", $ReadMin & " n'est pas une minute de la journée!" & @LF & "Les minutes vont de 0 à 59!")
        GUICtrlSetData($InputMin, 0 & 0)
    EndIf
    ;=Caractères maximum
    $StrgSizeMin = StringLen($ReadMin)
    If $StrgSizeMin = 1 Then
        GUICtrlSetData($InputMin, 0 & $ReadMin)
    EndIf
EndFunc

Func _CorrectionHeures($InputHeure, $ReadHeure)
    ;=Gestion du dépassement des 24 heures=
    If $ReadHeure > 23 Then
        MsgBox(0, "Erreur", $ReadHeure & " n'est pas une heure de la journée!" & @LF & "Les heures vont de 0 à 23!")
        GUICtrlSetData($InputHeure, 0 & 0)
    EndIf
    ;=Caractères maximum
    $StrgSizeHeure = StringLen($ReadHeure)
    If $StrgSizeHeure = 1 Then
        GUICtrlSetData($InputHeure, 0 & $ReadHeure)
    EndIf
EndFunc

;===Func _VerifFileExist===
Func _VerifFileExist($IniFile)
    ;=Création du dossier du .ini=
    If Not FileExists(@UserProfileDir & "\Memo") Then
        DirCreate(@UserProfileDir & "\Memo")
    EndIf
    ;=Création du .ini=
    If Not FileExists($IniFile) Then
        _FileCreate($IniFile)
        IniWriteSection($IniFile, "Credits", "Auteur=Kagami Tsuki" & @LF & "Version=011.12" & @LF & "Update=21 Décembre 2011" & @LF & @LF)
        MsgBox(4096, "", "Création du fichier paramètre effectuée avec succès")
    EndIf
EndFunc

Merci de ton aide (:

Ouah ! mets vite un spoiler/code sur ce post !

Le spoiler >.<
Voila, tu peux reprendre la code, je viens tout juste de réapporter une légère modification.

Ouais bon pfff c'est toujours pareil, comment faire simple quand on peut faire compliqué....

Code : Tout sélectionner

Case $ListM
    $txt = ControlCommand ($GUI, "",  $ListM, "GetCurrentSelection", "")
    If $txt<>"" Then
        MsgBox(0, "", $txt)
        GUICTrlSetData($GroupMemoActif, $IntituleMemo & ">" & $txt)
        If $txt = "Credits" Then
            GUICtrlSetData($InputTitre, "Crédits")
            GUICtrlSetData($EditMemo, IniRead($IniFile, $txt, "Auteur", ""))
        EndIf
    EndIf

Ho *-*
Merci, ma fonction me paraissait très simple aussi >.<
En tout cas, merci comme toujours

c'est vrai que je suis un peu maniaque là-dessus
Tu utilises les UDF et tu te rends pas compte que tu rajoutes 500 Ko d'includes ce qui fait plusieurs milliers de lignes que ton script doit gérer
Regarde, en changeant 2 bricoles plus besoin de trucs lourds

► Afficher le texte

Code : Tout sélectionner

;===Includes===
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>


;===Déclaration des Variables===
Global $IntituleMemo = "Mémo Actif"
Dim $IniFile = @scriptDir & "\Memo\Memo.ini"
_VerifFileExist($IniFile)


;===GUI===
#Region ### START Koda GUI section ### Form=C:\Users\Kagami\Desktop\Olympe Mémo.kxf
;=GUI=
$GUI = GUICreate("Olympe Mémo", 362, 288, 483, 246)
;==Groupe Liste==
$GroupListMemo = GUICtrlCreateGroup("Olympe Mémo", 8, 0, 170, 281)
;=Liste=
$ListM = GUICtrlCreateList("", 16, 16, 154, 254)
GUICtrlCreateGroup("", -99, -99, 1, 1)
;==Groupe Info Mémo actif==
$GroupMemoActif = GUICtrlCreateGroup($IntituleMemo, 184, 0, 170, 281)
;=Titre=
$LabelTitre = GUICtrlCreateLabel("Titre", 192, 16, 25, 17)
$InputTitre = GUICtrlCreateInput("", 192, 32, 153, 21)
;=Detail=
$LabelDetail = GUICtrlCreateLabel("Détail Mémo", 192, 56, 63, 17)
$EditMemo = GUICtrlCreateEdit("", 192, 72, 153, 105, BitOR($ES_AUTOVSCROLL,$ES_WANTRETURN))
;=Heures=
$LabelHeure = GUICtrlCreateLabel("Heure", 192, 184, 33, 17)
$InputHeure = GUICtrlCreateInput("", 192, 200, 41, 21, BitOR($ES_AUTOHSCROLL,$ES_NUMBER,$SS_CENTER))
GUICtrlSetLimit(-1, 2)
$LabelH = GUICtrlCreateLabel("H", 240, 200, 18, 21, BitOR($SS_CENTER,$SS_NOPREFIX,$SS_CENTERIMAGE,$SS_SUNKEN))
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
;=Minutes=
$InputMin = GUICtrlCreateInput("", 264, 200, 41, 21, BitOR($ES_AUTOHSCROLL,$ES_NUMBER,$SS_CENTER))
GUICtrlSetLimit(-1, 2)
$LabelMin = GUICtrlCreateLabel("Min", 312, 200, 34, 21, BitOR($SS_CENTER,$SS_NOPREFIX,$SS_CENTERIMAGE,$SS_SUNKEN))
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
;=Boutons=
$ButtonNouveau = GUICtrlCreateButton("Nouveau", 200, 232, 67, 38, $WS_GROUP)
$ButtonSupprimer = GUICtrlCreateButton("Supprimer", 272, 232, 67, 38, $WS_GROUP)
GUICtrlCreateGroup("", -99, -99, 1, 1)
;=Affichage=
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###



;===2nd Déclaration des Variables===
Global $ReadTitre = GUICtrlRead($InputTitre)
Global $ReadDetail = GUICtrlRead($EditMemo)


;===Création du ini & Recherche des contacts===
;_VerifFileExist($IniFile)
;=Remplissage de la liste=
$ReadIniTitre = IniReadSectionNames($IniFile)
For $i = 1 To $ReadIniTitre[0]
GuiCtrlSetData($ListM, $ReadIniTitre[$i] & "|")
;_GuiCtrlListBox_AddString($ListM, $ReadIniTitre[$i])
Next






;===Boucle Principale===
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
;_VerifFileExist($IniFile)
Exit


Case $ListM
    $txt = ControlCommand ($GUI, "",  $ListM, "GetCurrentSelection", "")
    If $txt<>"" Then
    MsgBox(0, "", $txt)
        GUICTrlSetData($GroupMemoActif, $IntituleMemo & ">" & $txt)
        If $txt = "Credits" Then
            GUICtrlSetData($InputTitre, "Crédits")
            GUICtrlSetData($EditMemo, IniRead($IniFile, $txt, "Auteur", ""))
        EndIf
    EndIf

#cs
$SelItems = _GUICtrlListBox_GetSelItemsText(GuiCtrlGetHandle($ListM))
MsgBox(0, "", "Vous avez selectionné" & $SelItems[1])
If $SelItems[0] <> 0 Then
GUICTrlSetData($GroupMemoActif, $IntituleMemo & ">" & $SelItems[1])
If $SelItems[1] = "Credits" Then
GUICtrlSetData($InputTitre, "Crédits")
GUICtrlSetData($EditMemo, IniRead($IniFile, $SelItems[1], "Auteur", ""))
EndIf
EndIf
#ce



Case $InputHeure
$ReadHeure = GUICtrlRead($InputHeure)
If $ReadHeure > 23 Then
MsgBox(0, "Erreur", $ReadHeure & " n'est pas une heure de la journée!" & @LF & "Les heures vont de 0 à 23!")
GUICtrlSetData($InputHeure, 0 & 0)
EndIf
_CorrectionHeures($InputHeure, $ReadHeure)

Case $InputMin
$ReadMin = GUICtrlRead($InputMin)
If $ReadMin > 59 Then
MsgBox(0, "Erreur", $ReadMin & " n'est pas une minute de la journée!" & @LF & "Les minutes vont de 0 à 59!")
GUICtrlSetData($InputMin, 0 & 0)
EndIf
_CorrectionMinutes($InputMin, $ReadMin)

EndSwitch
WEnd

;===Fonctions===
;===Func _CorrectionMinutes & _CorrectionHeures===
Func _CorrectionMinutes($InputMin, $ReadMin)
$StrgSizeMin = StringLen($ReadMin)
If $StrgSizeMin = 1 Then
GUICtrlSetData($InputMin, 0 & $ReadMin)
EndIf
EndFunc

Func _CorrectionHeures($InputHeure, $ReadHeure)
$StrgSizeHeure = StringLen($ReadHeure)
If $StrgSizeHeure = 1 Then
GUICtrlSetData($InputHeure, 0 & $ReadHeure)
EndIf
EndFunc

;===Func _VerifFileExist===
Func _VerifFileExist($IniFile)
;=Création du dossier du .ini=
If Not FileExists(@scriptDir & "\Memo") Then
DirCreate(@scriptDir & "\Memo")
EndIf
;=Création du .ini=
 If Not FileExists($IniFile) Then
; _FileCreate($IniFile)  ; pas besoin : If file does not exist, it is created (l'aide ! )
IniWriteSection($IniFile, "Credits", "Auteur=Kagami Tsuki" & @LF & "Version=011.12" & @LF & "Update=21 Décembre 2011" & @LF & @LF)
MsgBox(4096, "", "Création du fichier paramètre effectuée avec succès")
EndIf
EndFunc

Hum... il me semblait que les fonctions non utilisées d'un include n'étaient pas complées ?

As such a feature is mentioned nowhere in the helpfile, did u notice this on the US forum ? provide the link please !

Au temps pour moi, apres vérification, ca a été demandé il y a plusieurs années, mais ca semble ne pas avoir été implémenté.
Domage, ca permettrait de faire un include de tout, et a la compilation, il ne garderait que le nécéssaire.

AutoIt Français

[R] Problème avec _GUICtrlListBox_GetSelItemsText

[R] Problème avec _GUICtrlListBox_GetSelItemsText

Re: [..] Problème avec _GUICtrlListBox_GetSelItemsText

Re: [..] Problème avec _GUICtrlListBox_GetSelItemsText

Re: [..] Problème avec _GUICtrlListBox_GetSelItemsText

Re: [..] Problème avec _GUICtrlListBox_GetSelItemsText

Re: [..] Problème avec _GUICtrlListBox_GetSelItemsText

Re: [..] Problème avec _GUICtrlListBox_GetSelItemsText

Re: [..] Problème avec _GUICtrlListBox_GetSelItemsText

Re: [..] Problème avec _GUICtrlListBox_GetSelItemsText

Re: [..] Problème avec _GUICtrlListBox_GetSelItemsText

Re: [..] Problème avec _GUICtrlListBox_GetSelItemsText

Re: [R] Problème avec _GUICtrlListBox_GetSelItemsText

Re: [R] Problème avec _GUICtrlListBox_GetSelItemsText

Re: [R] Problème avec _GUICtrlListBox_GetSelItemsText

Re: [R] Problème avec _GUICtrlListBox_GetSelItemsText