AutoIt Français

Bonjour à tous,

Je réalise un programme qui répertorie des logiciels sans licence, pour que les utilisateurs de ma boite puissent les installer simplement eux-mêmes.
Pour ce faire j'ai une listview avec des checkbox à l'intérieur.
Pour plus de facilité au niveau de la maintenance de cet outil, tous est dynamique (les noms et emplacements des exécutables sont renseigné dans des fichiers ini)

Voilà le code du programme :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
;~ #include <ListViewConstants.au3>

Opt('MustDeclareVars', 1)

Global $bt_condition, $check_non, $check_oui, $nMsg, $ini, $arr, $arr2, $cmd, $cmd_timeout, $gw, $radio_oui
Global $i, $i2, $ini, $bt_install, $listview, $output, $pid, $bt_quit, $timer, $var, $var2, $var_site, $var_site2, $Checks


If @OSVersion = "WIN_7" Then
    $ini = @ScriptDir & '\param_7.ini'
ElseIf @OSVersion = "WIN_XP" Then
    $ini = @ScriptDir & '\param_xp.ini'
ElseIf @OSVersion <> "WIN_7" Or "WIN_XP" Then
    MsgBox(0, "Information","OS non supporté")
EndIf


Dim $gw
$gw = _get_default_gateway()


$var_site = IniReadSection(@ScriptDir & "\param_site.ini", "site")
If @error Then
    MsgBox(4096, "", "Error occurred, probably no INI file.")
Else
    For $i = 1 To $var_site[0][0]
        If $gw = $var_site[$i][0] Then
            $var_site2 = $var_site[$i][1]
        EndIf
    Next
EndIf

GUICreate("APLLI", 450, 450)

GUICtrlCreatePic("C:\images.jpg", 10, 10)

GUICtrlCreateLabel("APLLI", 180, 40)
GUICtrlCreateLabel("Outil de téléchargement de logiciels", 180, 60)

$listview = GUICtrlCreateListView("Liste des logiciels| Descriptions des programmes", 10, 165, 400, 150)
_GUICtrlListView_SetExtendedListViewStyle($listview, BitOR($LVS_EX_GRIDLINES, $LVS_EX_CHECKBOXES))

GUICtrlCreateLabel("J'accepte les conditions d'utilisation de ce module", 10, 325)

$check_oui = GUICtrlCreateCheckbox ("J'accepte", 10, 340)

$bt_condition = GUICtrlCreateButton ("Condition général", 290, 320, 110)

$bt_quit = GUICtrlCreateButton("Quitter", 290, 370, 100)
$bt_install = GUICtrlCreateButton("Installer", 185, 370, 100)


$var = IniReadSection($ini, "progs")
$var2 = IniReadSection($ini, "description")
    For $i = 1 To $var[0][0]
    For $i = 1 To $var2[0][0]
GUICtrlCreateListViewItem($var[$i][0] & "|" & $var2[$i][0], $listview)
    Next
    Next

Dim $Checks[$var[0][0] + 1]

;~ -----------------------------------------------------------------------------------------------------------------
GUISetState(@SW_SHOW)

While 1
        $nMsg = GUIGetMsg()
    Switch $nMsg

        Case $nMsg = $check_oui

        Case $nMsg = $bt_install
            If _IsunChecked($check_oui) Then
                MsgBox(8192, "Information", "Il faut accepter les conditions générales avant de lancer l'installation des applications")
            EndIf
                If _IsChecked($check_oui) Then
                    For $x = 1 To $var[0][0]
                        If _IsChecked($Checks[$x]) Then
                            MsgBox(0, "verif3", $var_site2 & $var[$x][1])
;~                          ShellExecuteWait($var_site2 & $var[$x][1])
                            If @error Then
                                MsgBox(8192, "", "Erreur, Installation non complète.")
                            EndIf
                        EndIf
                    Next
                EndIf

        case $nMsg = $bt_condition
            ShellExecute ("C:\Condition général.docx")

        Case $GUI_EVENT_CLOSE
        Exit

        Case $bt_quit
        ExitLoop

    EndSwitch
WEnd

;~ -----------------------------------------------------------------------------------------------------------------
;~ Fonction pour la gateway
;~ -----------------------------------------------------------------------------------------------------------------
Func _get_default_gateway()
    $output = _get_cmd_output("netstat -rn")
    $arr = StringSplit($output, "0.0.0.0", 1)
    $arr2 = StringStripWS($arr[3], 1)
    $arr2 = StringSplit($arr2, " ")
    Return $arr2[1]
EndFunc

Func _get_cmd_output($cmd)
    $cmd_timeout = 2000
    $pid = Run($cmd,@WorkingDir,@SW_HIDE,2)
    $timer = TimerInit()
    while (ProcessExists($pid))
        sleep(50)
        If TimerDiff($timer) > $cmd_timeout Then ProcessClose($pid)
    WEnd
    $output = StdoutRead($pid)
    Return StringStripCR($output)
EndFunc
;~ -----------------------------------------------------------------------------------------------------------------
;~ Fonction checkbox
;~ -----------------------------------------------------------------------------------------------------------------
Func _IsChecked($control)
    Return BitAnd(GUICtrlRead($control),$GUI_CHECKED) = $GUI_CHECKED
EndFunc

Func _IsunChecked($control)
    Return BitAnd(GUICtrlRead($control),$GUI_UNCHECKED) = $GUI_UNCHECKED
EndFunc

Voilà mes fichiers INI :

Fichier param_xp.ini

► Afficher le texte

Fichier param_7.ini
Identique pour le moment

Fichier param_site.ini

► Afficher le texte

Jusque là, j'ai réussi!! (pas sans mal :p) Mon problème est de récupérer le chemin complet de l'exécutable des box qui ont été cochées.
J'arrive à récupérer tous les chemins complets, mais pas uniquement ceux que j'ai cochées…
Mon problème est à la ligne :
If _IsChecked($Checks[$x]) Then
La variable $Checks ne correspond à rien dans ce script mais à une ancienne version .
Ancienne version :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstants.au3>

If @OSVersion = "WIN_7" Then
    $ini = @ScriptDir & '\param_7.ini'
ElseIf @OSVersion = "WIN_XP" Then
    $ini = @ScriptDir & '\param_xp.ini'
ElseIf @OSVersion <> "WIN_7" Or "WIN_XP" Then
    MsgBox(0, "Information","OS non supporté")
EndIf


Dim $gw
$gw = _get_default_gateway()

$var = IniReadSection(@ScriptDir & "\param_site.ini", "site")
If @error Then
    MsgBox(4096, "", "Error occurred, probably no INI file.")
Else
    For $i = 1 To $var[0][0]
        If $gw = $var[$i][0] Then
            $var2 = $var[$i][1]
        EndIf
    Next
EndIf

$var = IniReadSection($ini, "progs")

If @error Then
    MsgBox(4096, "", "Erreur, Fichier ini non trouvé.")
Else
    For $i = 1 To $var[0][0]
    Next
EndIf

Dim $Checks[$var[0][0] + 1]

$Height = ($var[0][0] * 20) + 50

If $Height > @DesktopHeight Then
    MsgBox(0x0,"Erreur", "Il y a trop de logiceil à afficher pour votre ecran", 3)
    $Height = @DesktopHeight - 50
EndIf

GUICreate("Logiciels disponnibles : " & $var[0][0], 300, $Height)

For $i = 1 To $var[0][0]
    $Height = $i * 20
    $Checks[$i] = GUICtrlCreateCheckbox($var[$i][0], 5, $Height, 150, 15)

Next

$btn = GUICtrlCreateButton("Start", 200, 30, 60, 30)

GUISetState()
While 1

    $Msg = GUIGetMsg()
    Select
        Case $Msg = $GUI_EVENT_CLOSE
        Exit

        Case $Msg = $btn
            For $x = 1 To $var[0][0]
                If _IsChecked($Checks[$x]) Then
                    MsgBox(0, "verif", $var2 & $var[$x][1])
;~                  ShellExecuteWait($var2 & $var[$x][1])
                    If @error Then
                        MsgBox(4096, "", "Erreur, Installation non complète.")
                    EndIf
;~                  ProcessGetStats
                    Sleep(1000)
                EndIf
            Next

    EndSelect
WEnd

Func _get_default_gateway()
    $output = _get_cmd_output("netstat -rn")
    $arr = StringSplit($output, "0.0.0.0", 1)
    $arr2 = StringStripWS($arr[3], 1)
    $arr2 = StringSplit($arr2, " ")
    Return $arr2[1]
EndFunc

Func _get_cmd_output($cmd)
    $cmd_timeout = 2000
    $pid = Run($cmd,@WorkingDir,@SW_HIDE,2)
    $timer = TimerInit()
    while (ProcessExists($pid))
        sleep(50)
        If TimerDiff($timer) > $cmd_timeout Then ProcessClose($pid)
    WEnd
    $output = StdoutRead($pid)
    Return StringStripCR($output)
EndFunc

Func _IsChecked($control)
    Return BitAnd(GUICtrlRead($control),$GUI_CHECKED) = $GUI_CHECKED
EndFunc

Func _IsunChecked($control)
    Return BitAnd(GUICtrlRead($control),$GUI_UNCHECKED) = $GUI_UNCHECKED
EndFunc

Je ne voie pas comment la remplacer…

J'espère avoir été assez claire dans mon explication.

Merci de votre aide

Bonsoir

va voir de ce côté

_GUICtrlListView_GetItemChecked

A+

Bonsoir

Quand la curiosité nous ronge.....

► Afficher le texte

Bonjour,

Merci pour la réponse

On se rapproche de ce que je voulais comme résultat par contre j'ai décalage de 1.
Quand je sélectionne un logiciel dans liste, c'est l’exécutable de la ligne du dessous qui est prit en compte.

Dans mon exemple, si je sélectionne "vlc" c'est l'exécutable de pdf_creator (qui est sur le ligne du dessous) qui se lance. (ou alors j'ai mal compris votre solution...)

Je viens de regarder avec AutoIt Debugger et je m'aperçois que la valeur $listview est égale à 7 or j'ai 8 lignes... Je pense que la différence vient de là, mais je ne me l'explique pas.

Bonjour

je me suis fais une fonction pour ca:
Tu as au choix ($fArray) une chaine ou un tableau des index de ta listview dont l'item est coché.

Code : Tout sélectionner

; #FUNCTION# ====================================================================================================================
; Name...........: _GUICtrlListView_GetCheckedIndices
; Description ...: Retrieve indices of Checked item(s)
; Syntax.........: _GUICtrlListView_GetCheckedIndices($hWnd, $fArray = False)
; Parameters ....: $hWnd        - Handle to the control
;                  $fArray      - Return string or Array
;                   |True   - Returns array
;                   |False  - Returns pipe "|" delimited string
; Return values .: Success      - Selected indices Based on $fArray:
;                  +Array       - With the following format
;                  |[0] - Number of Items in array (n)
;                  |[1] - First item index
;                  |[2] - Second item index
;                  |[n] - Last item index
;                  |String      - With the following format
;                  |"0|1|2|n"
;                  Failure      - Based on $fArray
;                  |Array       - With the following format
;                  |[0] - Number of Items in array (0)
;                  |String      - Empty ("")
; Author ........: Gary delaMer
; Modified.......:
; Remarks .......:
; Related .......: _GUICtrlListView_GetSelectedIndices
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func My_GUICtrlListView_GetCheckedIndices($hWnd, $bArray = False)
    If $Debug_LV Then __UDF_ValidateClassName($hWnd, $__LISTVIEWCONSTANT_ClassName)

    Local $i = 0, $iCount = _GUICtrlListView_GetItemCount($hWnd)
    Local $sIndices, $aIndices[$iCount + 1] = [0]
    For $iItem = 0 To $iCount - 1
        If _GUICtrlListView_GetItemChecked($hWnd, $iItem) Then
            If (Not $bArray) Then
                If StringLen($sIndices) Then
                    $sIndices &= "|" & $iItem
                Else
                    $sIndices = $iItem
                EndIf
            Else
                $i += 1
                $aIndices[$i] = $iItem
            EndIf
        EndIf
    Next
    If (Not $bArray) Then
        Return String($sIndices)
    Else
        $aIndices[0] = $i
        ReDim $aIndices[$i + 1]
        Return $aIndices
    EndIf
EndFunc   ;==>My_GUICtrlListView_GetCheckedIndices

luxus a écrit :Je viens de regarder avec AutoIt Debugger et je m'aperçois que la valeur $listview est égale à 7 or j'ai 8 lignes... Je pense que la différence vient de là, mais je ne me l'explique pas.

Euh, je crois que c'est normal de trouver 7 à la valeur de $listview si tu as 8 lignes.
En commençant à compter de 0 à 7, ça fait bien 8 lignes.

@Warlh
après avoir fait qq tests, je me suis rendu compte que c'était un indice (la valeur est fix)

Après plusieurs essais, J'arrive à lancer le bon programme :

► Afficher le texte

Par contre j'ai un peu de mal à me servie de ta fonction GaRydelaMer.
Je m'en sers uniquement pour savoir si aucune checkbox n'est coché, mais il doit y avoir une meilleure façon l'exploiter...

Si tu pouvais me donner un exemple ça me permettrait de mieux la comprendre.

En tous cas merci à tous

Il vous suffit d'utiliser My_GUICtrlListView_GetCheckedIndices avec le handle retourné par votre ListView ($hWnd) et en choisissant le type de sortie désiré ($bArray).

Si $bArray est égal à True, alors vous aurez en retour un tableau contenant les différents index qui seraient cochés. Si $bArray est égal à False (valeur par défaut), alors vous aurez une chaine de la forme '1|4|5' contenant les index qui seraient cochés.

Donc $aIdx = My_GUICtrlListView_GetCheckedIndices($hWnd, True) renvoi dans la variable $aIdx un tableau contenant tous les indices cochés de la ListView $hWnd.
Une simple boucle de lecture For/Next vous permettra d'exploiter les valeurs de ce tableau.

Et ça ?

Code : Tout sélectionner

$text = ""
$nb = ControlListView ("APLLI", "", $listview, "GetItemCount")
For $i = 0 To $nb-1
    If _GUICtrlListView_GetItemChecked ($listview, $i) Then
        $text &= ControlListView ("APLLI", "", $listview, "GetText", $i, 1) & @CRLF
    EndIf
Next
MsgBox(0,"", $text)

C'est un peu ce qu'a fait GaRydelaMer mais en plus simple

Merci à tous pour vos explications Telm !

@ mikell : Je vais regarder ça

En tous cas merci à tous

AutoIt Français

[R] Récupérer la valeur des ChekBox dans une listview

[R] Récupérer la valeur des ChekBox dans une listview

Re: [..] Récupérer la valeur des ChekBox dans une listview

Re: [..] Récupérer la valeur des ChekBox dans une listview

Re: [..] Récupérer la valeur des ChekBox dans une listview

Re: [..] Récupérer la valeur des ChekBox dans une listview

Re: [..] Récupérer la valeur des ChekBox dans une listview

Re: [..] Récupérer la valeur des ChekBox dans une listview

Re: [R] Récupérer la valeur des ChekBox dans une listview

Re: [..] Récupérer la valeur des ChekBox dans une listview

Re: [..] Récupérer la valeur des ChekBox dans une listview

Re: [R] Récupérer la valeur des ChekBox dans une listview