AutoIt Français

Bonjour , cela fais longtemps que je ne suis pas venus héhé ^^
Et je vais vous présenter un de mes programmes , qui je pense , peut intéresser le plus de monde

Darkex'dock =)

C'est a la base un programme personnel , donc la "beauté" n'est pas au rendez vous ^^" m'enfin bon .

Cette fenetre vient se nicher dans le coin supérieur droite de votre écran et est invisible.
Lorque votre curseur frole la partie rouge du screen la fénetre apparait , et elle disparait si votre curseur sort hors de la fenetre.

Ce qui le rend trés maniable , sauf dans quelques situations , comme lorsque on fais un grand mouvement de souris pour fermer une fenetre , pour cela que le bouton - a eter ajouter

Mais le but principal de ce programme c'est quoi ?

Et bien vous voyer les petites cases au milieu ? si vous mettez votre curseur dessus , elles s'éclairent et si vous cliquez dessus , elle ouvre le programme que vous avez choisis avec le clic droit :

Et le joli bouton "firefox pwnage" sert a supprimer le procc firefox.exe , pour ceux qui ont souvent l'erreur "firefox est deja en cours d'éxécution" , c'est un petit raccourcis a la place du géstionnaire.

Ce programme se regles sous n'importe quelle résolution , automatiquement.

Je suis jeune , et je sais que mon prog n'est pas spécialement génial , mon code est encore pire ^^"
mais j'aimerais savoir si vous pensez a des améliorations , pas d'alégement du script existant , je le trouve quand meme bien.
Et le soucis est que les images de fond doivent etres modifié a la main sur paint ou photophiltre =S

Lien de téléchargement avec les sources :

http://hackedbydarkex.free.fr/DarkexDock.rar

N'hésitez pas à vous exprimer , je suis jeune , et je voudrais surement le présenter comme exemple pour mon entrée en bts info l'année prochaine , lui et d'autres script , mais les autres sont niquels ^^"
Merci.

Bonjour à toi. Déjà l'age n'est guère un problème en informatique , heureusement pour moi quand j'ai commencé Autoit à à peu près ton âge.
Concernant ton prog, je pense que tu as déjà pointé les principaux défauts : Il doit être plus configurable pour une présentation en public et ne pas être à ton usage personnel (a moins que tu ne le présentes comme tel, les gens aiment bien voir les programmeurs qu'ils recrutent utiliser leurs propres outils de simplification de vie, ca montre qu'ils sont debrouillards et pas sans cesse dépendant d'un avis/aide extérieure.)

Voici donc quelques idées d'améliorations de mon gout:

-Une nouvelle fenetre de configuration, un fichier .ini de sauvegarde des paramètres, possibilité de changer les icones plus facilement.
-Ne pas afficher ton script si ma souris est dans le pixel le plus en haut à droite, ca evitera les problèmes a chaque fois que je voudrais fermer une fenêtre. Si je veux utiliser ton dock, je vais aller en haut a droite, mais pas dans le coin, donc j'aimerais que le script ne soit pas affiché dans le coin, ca resoudrait ton problème d'affichage intempestif.
-Fusionner souris.exe avec ton programme principal, j'aime pas avoir des multiples applications pour un seul usage, ca te permettrait de limiter l'usage de la RAM, élement essentiel si tu veux rendre ton DOCK publique. Un Dock qui commence trop de RAM ne pourra jamais être adopté par une communauté.
-Dans le même ordre d'idée, rajoute des sleep plus importants dans tes boucles ca permettra de reduire l'utilisation mémoire alors que cette utilisation semble inutile. (Que ton panneau n'apparaisse que 100ms après que j'ai mis mon pointeur de souris ne va pas me deranger vu que je ne m'en apercevrai meme pas)
-Gerer le Systray, peut etre en rajoutant une icone, des options, empêcher de cliquer sur Pause et exit pour Mouse.exe (D'ailleurs je viens de le fermer, mais ton programme marche encore, a quoi sert Mouse.exe???)

Après quelques remarques au niveau de ton code:
-Un petit coup de Autoit Tidy est toujours le bienvenu

► Afficher le texteMouse.exe

► Afficher le texteDock.exe

Voici le debut de ton script 'amélioré', je pense que tu auras saisi le principe pour continuer seul, ce qui te permettra en changeant juste une variable (nombre de ligne ou nombre de colonnes) d'actualiser ton script automatiquement ! Tu pourras remarquer qu'on s'y retrouve également bien mieux à la lecture.

► Afficher le texte

Code : Tout sélectionner

#NoTrayIcon
#include <WindowsConstants.au3>
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <File.au3>
#include <Misc.au3>
#include <GDIPlus.au3>; this is where the magic happens, people
HotKeySet("{F4}", "CODE2")
ProcessClose("mouse.exe")

;Initialisation des variables
$nomlogic = "Darkex'Dock V1.0 bêta"
$Xresol = @DesktopWidth
$Yresol = @DesktopHeight
$nombre_colonnes = 5
$nombre_lignes = 4
$nombre_items = $nombre_colonnes * $nombre_items
$LISTE = @ScriptDir & "\option.txt"
For $i = 1 To $nombre_items + 1 Do
    Assign("p" & $i, FileReadLine($LISTE, $i);r101
Next

;Creation de la GUI
$GUI = GUICreate($nomlogic, 158, 190, $Xresol - 158, 0, $WS_POPUP)
GUIRegisterMsg($WM_NCHITTEST, "WM_NCHITTEST")
$Button1 = GUICtrlCreateButton("Firefox Pwnage", 5, 30, 110, 25, $WS_GROUP)
$Button2 = GUICtrlCreateButton("-", 140, 1, 18, 18, $WS_GROUP)
$Button3 = GUICtrlCreateButton("Fermer Darkex'Dock", 5, 160, 150, 25, $WS_GROUP)
$count = 0
For $i = 1 To 4
    For $j = 1 To 5
        $count += 1
        Assign("u" & $count, GUICtrlCreateButton("u" & $count, 16 + 26 * ($j - 1), 55 + 26 * ($i - 1), 26, 26, BitOR($BS_BITMAP, $WS_GROUP)))
        GUICtrlSetImage(-1, @ScriptDir & "\images\u" & $count & ".bmp", -1)
        ControlHide($nomlogic, "", Eval("u" & $count))
    Next
Next
$Pic1 = GUICtrlCreatePic(@ScriptDir & "\images\1655.bmp", 16, 55, 131, 105, BitOR($SS_NOTIFY, $WS_GROUP, $WS_CLIPSIBLINGS))
GUISetState(@SW_HIDE)
$colorf = "0x000000"
$color = "0xffffff"
$Label1 = GUICtrlCreateLabel("x , y", 66, 20, 70, 17)
GUICtrlSetColor($Label1, $color)
$Label2 = GUICtrlCreateLabel("- Darkex'dock -", 8, 6, 90, 17)
GUICtrlSetColor($Label2, $color)
$fois = $p21
$Label3 = GUICtrlCreateLabel("x " & $fois, 125, 35, 20, 17)
GUICtrlSetColor($Label3, $color)
GUISetBkColor($colorf, $GUI)
$acti = 0
$Pipi = GUICtrlCreatePic(@ScriptDir & "\images\fond.bmp", 0, 0, 158, 190, BitOR($SS_NOTIFY, $WS_GROUP, $WS_CLIPSIBLINGS))
Run(@ScriptDir & "\mouse.exe")
While 1
    $nMsg = GUIGetMsg()
    $pos = MouseGetPos()
    $x = $pos[0]
    $y = $pos[1]
    GUICtrlDelete($Label1)
    $Label1 = GUICtrlCreateLabel($x & " , " & $y, 85, 6, 55, 17)
    GUICtrlSetColor($Label1, $color)
    Sleep(10)
    ;Traitement des actions
    Switch $nMsg
        Case $GUI_EVENT_CLOSE,$Button3
            ProcessClose("mouse.exe")
            Exit
        Case $Button2
            GUISetState(@SW_HIDE)
            $acti = 0
        Case $Button1
            If ProcessExists("firefox.exe") Then
                GUICtrlDelete($Label3)
                $fois = $fois + 1
                $x = $fois
                _FileWriteToLine($LISTE, 21, $x, 1)
                $Label3 = GUICtrlCreateLabel("x " & $fois, 125, 35, 20, 17)
                GUICtrlSetColor($Label3, $color)
                ProcessClose("firefox.exe")
            Else
                MsgBox(1, "Firefox n'est pas lancé", "Firefox n'est pas lancé.")
            EndIf
    EndSwitch
    For $i = 1 to $nombre_items Do
        If $nMsg = Eval("u"&$i) Then
            If Eval("p"&$i) = "Rien" Then
                MsgBox(1, "Ajouter", "Modifier le fichier option.txt ligne "&$i)
            Else
                Run(Eval("p"&$i))
            EndIf
        EndIf
    Next

Bon courage pour la suite

En ce qui me concerne, je n'ai rien contre les liens externes, mais j'aimerais bien que dans le premier message, une version y soit copiée en pièce jointe.

Imaginez que dans quelques années vous changiez de prestataire, ou que le compte soit bloqué par Free sous un quelconque prétexte ...

C'est fais Tlem

Hum , Merci Timmalos , j'ai changer ce que tu ma dis , c'est vrai que c'est beaucoup plus light ^^"
Pour la fenetre option , j'ai une idée , peut etre avec changement d'image de fond et ouverture au lancement de windows par exemple ?
Pour le fichier de sauvegarde , j'ai plutot utiliser un fichier .txt au lieu de .ini .
Et c'est vrai que pour le pixel tout en haut a droite , sa peut être beaucoup plus pratique , je n'y avais pas penser , merci !

Hum , Mouse.exe est le programme qui affiche la ptite fenetre de pour changer le raccourcis , je l'au creer sur un autre programme , car j'ai un soucis depuis longtemps , je n'arrive pas a gerer deux fenetres en memes temps , j'ai chercher longtemps a quoi c'etais dû et je ne le sais toujours pas >__< (j'ai parcourue ce forum de fond en combles ^^ )
Gerer le Systray...Hum , pareil l'idée ne m'etais pas venue , mais je ne sais pas trop quelles options je pourais ajouter a ce systray =S

Hum , et auriez vous une idée de comment je pourais mettre en place un script pour que la personne choisissent elle meme l'image , mais qu'elle devienne quand meme plus "éclairé" lorsque l'icone passe devant ?

Merci encore !

Je vous conseille de jeter un coup d'oeil à l'UDF GUICtrlSetOnHover

http://www.autoitscript.fr/forum/viewto ... ilit=hover
http://www.autoitscript.com/forum/index ... 55120&st=0

J'avais pas vu ce petit utilitaire!
Il est vraiment très sympa!
Malheureusement je ne m'en servirai pas car je n'aime pas toute ces petites "babioles de l'informatique" mais au niveau apprentissage, il est vraiment utile, j'avais jamais pensé à une fonction hover qui affiche la GUI, très bien pensé!
Je pense me resservir de ton code dans mes propres programmes

Dommage qu'il soit en .exe car j'aurais bien voulu voir comment tu as mis les images avec clic droit modifier/parcourir
Mais il est vraiment sympa

@floriande26 : Décompresse le Rar, les sources AU3 sont avec.

@Darkex: Certaines parties sont de véritables usines à gaz :s Je pense que tu as moyen de factoriser pas mal de codes (genre les 20 répétitions de

Code : Tout sélectionner

If $x > $Xresol-142 AND $x < $Xresol-116 AND $y > 55 AND $y < 81 Then
WinMove($nomlogic2,  "", $x1,$y, 86, 97)
GUISetState(@SW_SHOW,$GUI)
Global $num = 1
Num()

En travaillant un peu par modulo, tu peux gérer avec des choses comme $col = Mod($x-$Xresol+12, 26) et $row = Mod($y-55, 26) pour ensuite travailler sur le numéro de col et de ligne dans ta grille. Idem pour le corps de ton prog, en voici un exemple remanié

► Afficher le texteVersion remaniée

Code : Tout sélectionner

#NoTrayIcon
#include <WindowsConstants.au3>
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <File.au3>
#Include <Misc.au3>
#include <GDIPlus.au3>; this is where the magic happens, people

Hotkeyset("{F4}", "CODE2")
ProcessClose("mouse.exe")
$nomlogic = "Darkex'Dock V1.0 bêta"
$Xresol=@DesktopWidth
$Yresol=@DesktopHeight

$GUI = GUICreate($nomlogic, 158,190, $Xresol-158, 0,$WS_POPUP)
GUIRegisterMsg($WM_NCHITTEST, "WM_NCHITTEST")

$Button1 = GUICtrlCreateButton("Firefox Pwnage", 5, 30, 110, 25, $WS_GROUP)
$Button2 = GUICtrlCreateButton("-", 140, 1, 18, 18, $WS_GROUP)
$Button3 = GUICtrlCreateButton("Fermer Darkex'Dock", 5, 160, 150, 25, $WS_GROUP)

Dim $u[21]
$u[0] = 20 ; Nombre de cases
For $i = 1 To $u[0]
    Local $col = Mod($i-1, 5) ; 5 cases par ligne
    Local $row = ($i-1-$col)/5  ; quand on sait la colonne, on trouve la ligne
    $u[$i] = GUICtrlCreateButton("u"&$i, 16+26*$col, 55+26*$row, 26, 26, BitOR($BS_BITMAP,$WS_GROUP))
    GUICtrlSetImage(-1, @ScriptDir & "\images\u"&$i&".bmp", -1)
    ControlHide($nomlogic,  "", $u[$i])
Next

$Pic1 = GUICtrlCreatePic(@ScriptDir & "\images\1655.bmp", 16, 55, 131, 105, BitOR($SS_NOTIFY,$WS_GROUP,$WS_CLIPSIBLINGS))

Global $LISTE = @ScriptDir & "\option.txt"
;INIT

Dim $p[22]
$p[0] = 21 ; Nombre de cases
For $i = 1 To $p[0]
    $p[$i] = FileReadLine($LISTE,$i) ;r101
Next
;INIT

GUISetState(@SW_HIDE)
$colorf = "0x000000"
$color = "0xffffff"
$Label1 = GUICtrlCreateLabel("x , y", 66, 20, 70, 17)
GUICtrlSetColor ($Label1,$color)
$Label2 = GUICtrlCreateLabel("- Darkex'dock -", 8, 6, 90, 17)
GUICtrlSetColor ($Label2,$color)
$fois = $p[21]
$Label3 = GUICtrlCreateLabel("x " & $fois, 125, 35, 20, 17)
GUICtrlSetColor ($Label3,$color)
GUISetBkColor($colorf,$GUI)
$acti = 0
$Pipi = GUICtrlCreatePic(@ScriptDir & "\images\fond.bmp", 0, 0, 158, 190, BitOR($SS_NOTIFY,$WS_GROUP,$WS_CLIPSIBLINGS))
Run(@ScriptDir  & "\mouse.exe")

While 1
    $nMsg = GUIGetMsg()

    $x = MouseGetPos(0)
    $y = MouseGetPos(1)
    GUICtrlDelete($Label1)
    $Label1 = GUICtrlCreateLabel($x & " , " & $y, 85, 6, 55, 17)
    GUICtrlSetColor ($Label1,$color)
    Sleep(10)

    If $nMsg = $GUI_EVENT_CLOSE Or $nMsg = $Button3 Then
        ProcessClose("mouse.exe")
        Exit
    Endif

    If $nMsg = $Button2 Then
        GUISetState(@SW_HIDE)
        $acti = 0
    Endif

    If $nMsg = $Button1 Then

        If ProcessExists("firefox.exe") Then
            GUICtrlDelete($Label3)
            $fois = $fois + 1
            $x = $fois
            _FileWriteToLine($LISTE, 21, $x, 1)
            $Label3 = GUICtrlCreateLabel("x " & $fois, 125, 35, 20, 17)
            GUICtrlSetColor ($Label3,$color)
            ProcessClose("firefox.exe")
        Else
            Msgbox(1,"Firefox n'est pas lancé","Firefox n'est pas lancé.")
        EndIf


    Endif

    For $i = 1 To $u[0]
        If $nMsg = $u[$i] Then
            If $p[$i] = "Rien" Then
                msgbox(1,"Ajouter","Modifier le fichier option.txt ligne "&$i)
            Else
                Run($p[$i])
            Endif
        Endif
    Next
    If $acti = 0 Then
        If $x > $Xresol-157 AND $x < $Xresol-1 AND $y = 0 Then
            $acti = 1
            GUISetState(@SW_SHOW)
        Endif
    Else
        If $x > $Xresol-157 AND $x <= $Xresol AND $y >= 0 AND $y < 189 Then
            ;si open
            ;If $x > 1298 AND $x < 1428 AND $y > 55 AND $y < 159 Then
            ;TOUT LE CARRé !
            ;Endif
            For $i = 1 To $u[0]
                Local $col = Mod($i-1, 5) ; 5 cases par ligne
                Local $row = ($i-1-$col)/5  ; quand on sait la colonne, on trouve la ligne
                If $x > $Xresol-142+26*$col AND $x < $Xresol-116+26*$col AND $y > 55+26*$row AND $y < 81+26*$row Then
                    ControlShow($nomlogic,  "", $u[$i])
                Else
                    ControlHide($nomlogic,  "", $u[$i])
                Endif
            Next
        Else
            GUISetState(@SW_HIDE)
            $acti = 0
        Endif
    Endif

WEnd

Func CODE2()
    Exit
EndFunc   ;==>CODE2

Func WM_NCHITTEST($hWnd, $iMsg, $iwParam, $ilParam)
    If ($hWnd = $GUI) And ($iMsg = $WM_NCHITTEST) Then Return $HTCAPTION
EndFunc   ;==>WM_NCHITTEST

A bientôt !

PS: Apprends aussi à indenter/commenter ton code, parce que c'est inbuvable ^^

Oups ...

J'avais pas vu

Beau boulot

AutoIt Français

[Ex] Darkex'dock

[Ex] Darkex'dock

Re: [Ex] Darkex'dock

Re: [Ex] Darkex'dock

Re: [Ex] Darkex'dock

Re: [Ex] Darkex'dock

Re: [Ex] Darkex'dock

Re: [Ex] Darkex'dock

Re: [Ex] Darkex'dock

Re: [Ex] Darkex'dock