AutoIt Français

Bonjour à tous,

J'ai vu qu'il était possible avec une edibox de récupérer la section d'un mot avec _GUICtrlEdit_GetSel

► Afficher le textecode Editbox

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiEdit.au3>


Global $selectedData

#Region ### START Koda GUI section ### Form=
Global $_1_1 = GUICreate("", 889, 571, -1, -1, BitOR($WS_MAXIMIZEBOX,$WS_MINIMIZEBOX,$WS_SIZEBOX,$WS_THICKFRAME,$WS_SYSMENU,$WS_CAPTION,$WS_OVERLAPPEDWINDOW,$WS_TILEDWINDOW,$WS_POPUP,$WS_POPUPWINDOW,$WS_GROUP,$WS_TABSTOP,$WS_BORDER,$WS_CLIPSIBLINGS))
Global $rapport = GUICtrlCreateInput("", 136, 8, 481, 21)
Global $Path = GUICtrlCreateButton("Parcourir", 632, 8, 75, 25, $WS_GROUP)
Global $Edit = GUICtrlCreateEdit("", 16, 56, 862, 438)
GUICtrlSetState($Edit, $GUI_FOCUS)
Global $SyslogButton = GUICtrlCreateButton("Syslog", 177, 504, 57, 31, $WS_GROUP)
Global $SystemlookupButton = GUICtrlCreateButton("SystemlookUp", 3, 504, 100, 31, $WS_GROUP)
Global $boldButton = GUICtrlCreateButton("StartUpList", 105, 504, 70, 31, $WS_GROUP)


GUISetState()
While 1
    $msg = GUIGetMsg()
    Switch $msg
      Case $Path
            $OpenDialog = FileOpenDialog("Ouvrir le rapport", @DesktopDir & "\", "rapport (*.txt;*.log)", 1) ; ouverture du fichier placé sur le bureau au format txt, log
            GUICtrlSetData($rapport, $OpenDialog) ; controle le fichier de la dialogbox dans l'inputbox$
            $file = FileOpen($OpenDialog, 0)
            $ligne = FileRead($file)
            GUICtrlSetData($Edit, $ligne) ; et on injecte la ligne dans la liste
        Case $SyslogButton
            MySelection()
            ShellExecute("http://www.sysinfo.org/startuplist.php?filter="&$selectedData)
        Case $SystemlookupButton
            MySelection()
            ShellExecute("http://www.systemlookup.com/search.php?type=filename&search="&$selectedData)
        Case $GUI_EVENT_CLOSE
            ExitLoop

    EndSwitch
    Sleep(30)
WEnd

Func MySelection()
    $SelectedArr = _GUICtrlEdit_GetSel($Edit)
    $SelectedArr[0] += 1
    $count = $SelectedArr[1] - $SelectedArr[0] + 1
    If $count > 0 Then
        $allText = _GUICtrlEdit_GetText($Edit)
        $selectedData = StringMid($allText, $SelectedArr[0], $count)
    EndIf
EndFunc ;==>Replace_MySelection

Je voudrai savoir si il était possible avec une ligne à cochée de pouvoir selectionner un mot dans cette ligne, pour lancer une action, soit via un bouton soit via un menu contextuel.

Mon script charge un fichier txt et lit chaque ligne en ajouter une case à cocher devant.

► Afficher le textecode Listbox

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

#include <Array.au3>



Opt("GUIDataSeparatorChar", Chr(0)) ; permet de supprimer le bug du | sur les lignes contenant le symbole |
Global $itemNb, $Item, $RapportFile, $rapport, $ReadFile, $file, $OpenDialog, $EditText, $LigneCochee, $EditTexte, $String1; déclaration des variables
Global $j, $k, $m



#Region ###############Gui Modifié
Global $_1_1 = GUICreate("RapportMe", 888, 570, -1, -1, $WS_OVERLAPPEDWINDOW)
GUICtrlSetResizing($_1_1, $GUI_DOCKAUTO + $GUI_DOCKBOTTOM + $GUI_DOCKTOP)
Global $List1 = GUICtrlCreateListView("Lignes", 8, 40, 784, 300, -1, BitOR($WS_EX_CLIENTEDGE, $LVS_EX_CHECKBOXES))
GUICtrlSendMsg($List1, $LVM_SETCOLUMNWIDTH, 0, 780)



Global $Label0 = GUICtrlCreateLabel("Entrée sélectionnée :", 8, 510, 775, 17)
Global $Label1 = GUICtrlCreateLabel("", 8, 530, 775, 17, $SS_SUNKEN)
GUICtrlSetBkColor(-1, 0xFFFFFF)
Global $Syslog = GUICtrlCreateButton("Syslog", 804, 40, 75, 25, $WS_GROUP)
Global $Systemlook = GUICtrlCreateButton("Systemlook", 804, 72, 75, 25, $WS_GROUP)

[color=#008000];menu contextuel pour les lignes.
$iCtxt0 = GUICtrlCreateContextMenu($List1)
$iCtxt1 = GUICtrlCreateMenuItem("SysLog", $List1)
$iCtxt1 = GUICtrlCreateMenuItem("Syslookup", $List1)[/color]

Global $Edit1 = GUICtrlCreateEdit("", 8, 344, 785, 153)
GUICtrlSetData(-1, "")
Global $rapport = GUICtrlCreateInput("", 136, 8, 481, 21)
Global $Path = GUICtrlCreateButton("Parcourir", 632, 8, 75, 25, $WS_GROUP)
Global $Rappor = GUICtrlCreateLabel("Rapport to :", 8, 8, 95, 17)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Do
    $nMsg = GUIGetMsg()
    Switch $nMsg

        Case $Path
            $OpenDialog = FileOpenDialog("Ouvrir le rapport", @DesktopDir & "\", "rapport (*.txt;*.log)", 1) ; ouverture du fichier placé sur le bureau au format txt, log
            $itemNb = "" ; déclaration de variable vide
            $Item = "" ; déclaration de variable vide

            GUICtrlSetData($rapport, $OpenDialog) ;
            _GUICtrlListView_DeleteAllItems($List1) ;

            $file = FileOpen($OpenDialog, 0)
            Dim $Item[1] ; on crée un tableau pour stocker les lignes => tableau 1D
            $itemNb = 0

            While 1 ; donc on fait une boucle
                $ligne = FileReadLine($file)
                If @error = -1 Then ExitLoop
                $Trouve = False ;
                If $ligne <> "" Then
                    $itemNb += 1
                    ReDim $Item[$itemNb + 1]
                    $Item[$itemNb] = GUICtrlCreateListViewItem($ligne, $List1) ;
                EndIf
            WEnd
            FileClose($file); A la fin on oublie pas de fermer le fichier

        [color=#FF0000]Case $Syslog
            $selectedData = ""
            ShellExecute("http://www.sysinfo.org/startuplist.php?filter=" & $selectedData)
        Case $Systemlook
            ShellExecute("http://www.systemlookup.com/search.php?type=filename&search=" & $selectedData)[/color]

        Case Else ;
            If $OpenDialog <> "" Then
                $lbl = "Lignes sélectionnées : "
                $LigneCochee = ""
                For $i = 0 To $itemNb
                    If GUICtrlRead($Item[$i], 1) = 1 Then
                        $lbl = $lbl & ", " & $i
                        If Not StringInStr($LigneCochee, _GUICtrlListView_GetItemText($List1, $i - 1)) Then
                            $LigneCochee &= _GUICtrlListView_GetItemText($List1, $i - 1) & @CRLF
                        EndIf

                    EndIf
                Next

                If $lbl = "Lignes sélectionnées : " Then ; si aucun N° de ligne n'a été ajouté...
                    $lbl = "Aucune ligne sélectionnée" ; ... c'est qu'aucune ligne n'a été sélectionnée
                EndIf
                If GUICtrlRead($Label1) <> $lbl Then ; pour éviter le scintillement on ne met a jour le label que si il a changé
                    GUICtrlSetData($Label1, $lbl)

                EndIf
            EndIf

    EndSwitch

Until $nMsg = $GUI_EVENT_CLOSE

est ce possible ?
Merci à ceux qui m'aideront
bonne journée
Laddy

Hello,

A moins que je ne me trompe, le retour d'info de ce genre (sélection d'un morceau de texte dans le contenu d'une case, elle même étant dans une listbox) n'est pas possible par une listbox.
Tu as moyen de faire une édition d'une case (ou d'une ligne si tu as une seule colonne comme ton exemple), et de pouvoir remplacer à la main ton texte, mais ce n'est pas ce que tu recherches.

Le moyen un peu zarb que tu pourrais utiliser, c'est de cliquer sur une ligne (selection, pas coche), et d'afficher le contenu de la ligne dans un edit en dessous de ta liste. Là tu pourras sélectionner ton texte et effectuer la même manip que dans ton premier exemple (en gros passer par un tout petit edit d'une seule ligne, ou un input, comme un tampon dans ton algo).

(le souci, c'est que ça risque de surcharger pas mal ton interface. Pourquoi tu ne veux pas garder ton système déjà en place avec l'Edit?)

A plus !

EDIT : Si tu souhaites faire une listbox pour restreindre les sélections à une même ligne, je pense qu'en passant par un GUICtrlSendMsg tu peux traiter une sélection qui resterait sur la même ligne, une combinaison de GUICtrlSendMsg($edit, $EM_LINEINDEX,-1,0) et/ou GUICtrlSendMsg($edit, $EM_LINEFROMCHAR,$n,0).
EDIT2 : Je te prépare un exemple

Bonjour
parce que mon interface est beaucoup plus complète que ça, j'ai d'autres boutons avec des actions spécifiques, j'ai réduit en minimum pour travailler sur cette partie.
Mon interface contient déjà une editbox, mais qui sert déjà pour ses autres boutons....
je ne peux pas mettre cette ligne non sélectionné dans celle ci car les actions ne sont pas les memes.

pour ta solution je ne vois pas comment la mettre en place

Edit 1: oui merci pour l'exemple car je ne t'ai pas suis

Re,

Voici un exemple qui fait un mix entre ton premier et ton second code :

► Afficher le texteEditBox+ListBox

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#Include <GuiEdit.au3>

#include <Array.au3>



Opt("GUIDataSeparatorChar", Chr(0)) ; permet de supprimer le bug du | sur les lignes contenant le symbole |
Global $itemNb, $Item, $RapportFile, $rapport, $ReadFile, $file, $OpenDialog, $EditText, $LigneCochee, $EditTexte, $String1, $selectedData ; déclaration des variables
Global $j, $k, $m



#Region ###############Gui Modifié
Global $_1_1 = GUICreate("RapportMe", 888, 570, -1, -1, $WS_OVERLAPPEDWINDOW)
GUICtrlSetResizing($_1_1, $GUI_DOCKAUTO + $GUI_DOCKBOTTOM + $GUI_DOCKTOP)
Global $List1 = GUICtrlCreateListView("Lignes", 8, 40, 784, 285, -1, BitOR($WS_EX_CLIENTEDGE, $LVS_EX_CHECKBOXES))
GUICtrlSendMsg($List1, $LVM_SETCOLUMNWIDTH, 0, 780)



Global $Label0 = GUICtrlCreateLabel("Entrée sélectionnée :", 8, 510, 775, 17)
Global $Label1 = GUICtrlCreateLabel("", 8, 530, 775, 17, $SS_SUNKEN)
GUICtrlSetBkColor(-1, 0xFFFFFF)
Global $Syslog = GUICtrlCreateButton("Syslog", 804, 40, 75, 25, $WS_GROUP)
Global $Systemlook = GUICtrlCreateButton("Systemlook", 804, 72, 75, 25, $WS_GROUP)

;menu contextuel pour les lignes.
$iCtxt0 = GUICtrlCreateContextMenu($List1)
$iCtxt1 = GUICtrlCreateMenuItem("SysLog", $iCtxt0)
$iCtxt2 = GUICtrlCreateMenuItem("Syslookup", $iCtxt0)

Global $Edit_LIGNE = GUICtrlCreateEdit("", 8, 331, 785, 22,$ES_READONLY)
Global $Edit1 = GUICtrlCreateEdit("", 8, 359, 785, 153)
GUICtrlSetData(-1, "")
Global $rapport = GUICtrlCreateInput("", 136, 8, 481, 21)
Global $Path = GUICtrlCreateButton("Parcourir", 632, 8, 75, 25, $WS_GROUP)
Global $Rappor = GUICtrlCreateLabel("Rapport to :", 8, 8, 95, 17)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Do
    $nMsg = GUIGetMsg()
    Switch $nMsg

        Case $Path
            $OpenDialog = FileOpenDialog("Ouvrir le rapport", @DesktopDir & "\", "rapport (*.txt;*.log)", 1) ; ouverture du fichier placé sur le bureau au format txt, log
            $itemNb = "" ; déclaration de variable vide
            $Item = "" ; déclaration de variable vide

            GUICtrlSetData($rapport, $OpenDialog) ;
            _GUICtrlListView_DeleteAllItems($List1) ;

            $file = FileOpen($OpenDialog, 0)
            Dim $Item[1] ; on crée un tableau pour stocker les lignes => tableau 1D
            $itemNb = 0

            While 1 ; donc on fait une boucle
                $ligne = FileReadLine($file)
                If @error = -1 Then ExitLoop
                $Trouve = False ;
                If $ligne <> "" Then
                    $itemNb += 1
                    ReDim $Item[$itemNb + 1]
                    $Item[$itemNb] = GUICtrlCreateListViewItem($ligne, $List1) ;
                EndIf
            WEnd
            FileClose($file); A la fin on oublie pas de fermer le fichier

        Case $Syslog, $iCtxt1
            MySelection()
            ; Test
            MsgBox(0,"Selection [SysLog]", '"'&$selectedData&'"')
;~             ShellExecute("http://www.sysinfo.org/startuplist.php?filter=" & $selectedData)

        Case $Systemlook, $iCtxt2
            MySelection()
            ; Test
            MsgBox(0,"Selection [Syslookup]", '"'&$selectedData&'"')
;~             ShellExecute("http://www.systemlookup.com/search.php?type=filename&search=" & $selectedData)

        Case Else ;
            If $OpenDialog <> "" Then
                $lbl = "Lignes cochées : "
                $lbl2 = ""
                $LigneCochee = ""
                $LigneSelectionnee = ""
                For $i = 0 To $itemNb
                    If GUICtrlRead($Item[$i], 1) = 1 Then
                        $lbl = $lbl & ", " & $i
                        If Not StringInStr($LigneCochee, _GUICtrlListView_GetItemText($List1, $i - 1)) Then
                            $LigneCochee &= _GUICtrlListView_GetItemText($List1, $i - 1) & @CRLF
                        EndIf
                    EndIf
                    If _GUICtrlListView_GetItemSelected($List1, $i) Then
                        $lbl2 = " / Ligne selectionnée : "&($i+1)
                        $LigneSelectionnee = _GUICtrlListView_GetItemText($List1, $i)
                    EndIf
                Next
                ; si aucun N° de ligne n'a été ajouté, c'est qu'aucune ligne n'a été sélectionnée
                If $lbl = "Lignes chochées : " Then $lbl = "Aucune ligne chochée"

                $lbl &= $lbl2
                If GUICtrlRead($Label1) <> $lbl Then ; pour éviter le scintillement on ne met a jour le label que si il a changé
                    GUICtrlSetData($Label1, $lbl)
                    If $LigneSelectionnee <> "" Then GUICtrlSetData($Edit_LIGNE, $LigneSelectionnee)
                EndIf
            EndIf

    EndSwitch

Until $nMsg = $GUI_EVENT_CLOSE

Func MySelection()
    $SelectedArr = _GUICtrlEdit_GetSel($Edit_LIGNE)
    $SelectedArr[0] += 1
    $count = $SelectedArr[1] - $SelectedArr[0] + 1
    If $count > 0 Then
        $allText = _GUICtrlEdit_GetText($Edit_LIGNE)
        $selectedData = StringMid($allText, $SelectedArr[0], $count)
    EndIf
EndFunc ;==>Replace_MySelection

Vu que je n'ai pas compris à quoi te servait les coches dans le cas présent (sélection de texte, ça n'a rien à voir je pense?), j'ai préféré la sélection de la ligne (clic sur le texte d'une entrée de la listbox, pas sur la coche en tête) pour la mise à jour du champ Edit_LIGNE que tu vois entre ta listbox du haut et ton edit du bas. (Ce n'est qu'un exemple, à modifier surement de fond en comble pour ce que tu veux obtenir ^^)

A bientôt !

Ah oui pas mal du tout ça, même excellent, crois tu que c'est possible de mettre un menu contextuel à la place des boutons ?
J ai essayé en place $List1 par $Edit_LIGNE et j'ai un msgbox en boucle à l'ouverture de la gui.

$iCtxt0 = GUICtrlCreateContextMenu($Edit_LIGNE)
$iCtxt1 = GUICtrlCreateMenuItem("SysLog", $iCtxt0)
$iCtxt2 = GUICtrlCreateMenuItem("Syslookup", $iCtxt0)

~~Ah, ils ne marchent pas chez toi?~~ Exact, j'ai zappé de les activer. Je vérifie de mon coté, et je te renvoye une version qui fonctionne.
EDIT : Dixit la doc d'AutoIt : Note: You can't create context menus for controls that already have system context menus, i.e. edit or input controls..
Par contre, les menus contextuels de la listBox fonctionnent si tu les mets dessus, non?
Tu peux peut etre aussi contourner la restriction autoIt en détectant un clic droit sur l'$Edit_LIGNE, et en remplaçant l'action par un ContextMenu posé sur un Dummy ^^ (je te prépare un exemple, pas sûr que ça fonctionne).

Impeccable, donc si je comprend bien on peut pas mettre le menucontextuel sur une editbox ?
c'est chiant ça aurait été plus pratique sur le mot selectionné.

Merci infiniment pour ton aide et le mix

Cadeau, je pense que ça va te plaire ^^

► Afficher le texteVersion avec clic droit pris en compte sur Edit avec Dummy

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#Include <GuiEdit.au3>

#include <Array.au3>

Opt("GUIDataSeparatorChar", Chr(0)) ; permet de supprimer le bug du | sur les lignes contenant le symbole |
Global $itemNb, $Item, $RapportFile, $rapport, $ReadFile, $file, $OpenDialog, $EditText, $LigneCochee, $EditTexte, $String1, $selectedData ; déclaration des variables
Global $j, $k, $m

#Region ###############Gui Modifié
Global $_1_1 = GUICreate("RapportMe", 888, 570, -1, -1, $WS_OVERLAPPEDWINDOW)
GUICtrlSetResizing($_1_1, $GUI_DOCKAUTO + $GUI_DOCKBOTTOM + $GUI_DOCKTOP)
Global $List1 = GUICtrlCreateListView("Lignes", 8, 40, 784, 285, -1, BitOR($WS_EX_CLIENTEDGE, $LVS_EX_CHECKBOXES))
GUICtrlSendMsg($List1, $LVM_SETCOLUMNWIDTH, 0, 780)

Global $Label0 = GUICtrlCreateLabel("Entrée sélectionnée :", 8, 510, 775, 17)
Global $Label1 = GUICtrlCreateLabel("", 8, 530, 775, 17, $SS_SUNKEN)
GUICtrlSetBkColor(-1, 0xFFFFFF)
Global $Syslog = GUICtrlCreateButton("Syslog", 804, 40, 75, 25, $WS_GROUP)
Global $Systemlook = GUICtrlCreateButton("Systemlook", 804, 72, 75, 25, $WS_GROUP)


Global $Edit_LIGNE = GUICtrlCreateEdit("", 8, 331, 785, 22,$ES_READONLY)
Global $Edit1 = GUICtrlCreateEdit("", 8, 359, 785, 153)
GUICtrlSetData(-1, "")
Global $rapport = GUICtrlCreateInput("", 136, 8, 481, 21)
Global $Path = GUICtrlCreateButton("Parcourir", 632, 8, 75, 25, $WS_GROUP)
Global $Rappor = GUICtrlCreateLabel("Rapport to :", 8, 8, 95, 17)

; Menu contextuel pour les lignes.
$iCtxt0 = GUICtrlCreateContextMenu($List1)
$iCtxt1 = GUICtrlCreateMenuItem("SysLog", $iCtxt0)
$iCtxt2 = GUICtrlCreateMenuItem("Syslookup", $iCtxt0)

; Menu contextuel pour le dummy lié à $edit_LIGNE.
Global $iCtxt0_LIGNE = GUICtrlCreateContextMenu(GUICtrlCreateDummy())
Global _
    $iCtxt1_LIGNE = GUICtrlCreateMenuItem("SysLog", $iCtxt0_LIGNE), _
    $iCtxt2_LIGNE = GUICtrlCreateMenuItem("Syslookup", $iCtxt0_LIGNE)
#EndRegion ### END Koda GUI section ###

GUISetState(@SW_SHOW)

Do
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_SECONDARYDOWN
            If isHoveringCtrl($_1_1,$Edit_LIGNE) Then sousmenu($_1_1, $Edit_LIGNE, $iCtxt0_LIGNE)
        Case $Path
            $OpenDialog = FileOpenDialog("Ouvrir le rapport", @DesktopDir & "\", "rapport (*.txt;*.log)", 1) ; ouverture du fichier placé sur le bureau au format txt, log
            $itemNb = "" ; déclaration de variable vide
            $Item = "" ; déclaration de variable vide

            GUICtrlSetData($rapport, $OpenDialog) ;
            _GUICtrlListView_DeleteAllItems($List1) ;

            $file = FileOpen($OpenDialog, 0)
            Dim $Item[1] ; on crée un tableau pour stocker les lignes => tableau 1D
            $itemNb = 0

            While 1 ; donc on fait une boucle
                $ligne = FileReadLine($file)
                If @error = -1 Then ExitLoop
                $Trouve = False ;
                If $ligne <> "" Then
                    $itemNb += 1
                    ReDim $Item[$itemNb + 1]
                    $Item[$itemNb] = GUICtrlCreateListViewItem($ligne, $List1) ;
                EndIf
            WEnd
            FileClose($file); A la fin on oublie pas de fermer le fichier

        Case $Syslog, $iCtxt1, $iCtxt1_LIGNE
            MySelection()
            ; Test
            MsgBox(0,"Selection [SysLog]", '"'&$selectedData&'"')
;~             ShellExecute("http://www.sysinfo.org/startuplist.php?filter=" & $selectedData)

        Case $Systemlook, $iCtxt2, $iCtxt2_LIGNE
            MySelection()
            ; Test
            MsgBox(0,"Selection [Syslookup]", '"'&$selectedData&'"')
;~             ShellExecute("http://www.systemlookup.com/search.php?type=filename&search=" & $selectedData)

        Case Else ;
            If $OpenDialog <> "" Then
                $lbl = "Lignes cochées : "
                $lbl2 = ""
                $LigneCochee = ""
                $LigneSelectionnee = ""
                For $i = 0 To $itemNb
                    If GUICtrlRead($Item[$i], 1) = 1 Then
                        $lbl = $lbl & ", " & $i
                        If Not StringInStr($LigneCochee, _GUICtrlListView_GetItemText($List1, $i - 1)) Then
                            $LigneCochee &= _GUICtrlListView_GetItemText($List1, $i - 1) & @CRLF
                        EndIf
                    EndIf
                    If _GUICtrlListView_GetItemSelected($List1, $i) Then
                        $lbl2 = " / Ligne selectionnée : "&($i+1)
                        $LigneSelectionnee = _GUICtrlListView_GetItemText($List1, $i)
                    EndIf
                Next
                ; si aucun N° de ligne n'a été ajouté, c'est qu'aucune ligne n'a été sélectionnée
                If $lbl = "Lignes chochées : " Then $lbl = "Aucune ligne chochée"

                $lbl &= $lbl2
                If GUICtrlRead($Label1) <> $lbl Then ; pour éviter le scintillement on ne met a jour le label que si il a changé
                    GUICtrlSetData($Label1, $lbl)
                    If $LigneSelectionnee <> "" Then GUICtrlSetData($Edit_LIGNE, $LigneSelectionnee)
                EndIf
            EndIf

    EndSwitch

Until $nMsg = $GUI_EVENT_CLOSE

Func MySelection()
    $SelectedArr = _GUICtrlEdit_GetSel($Edit_LIGNE)
    $SelectedArr[0] += 1
    $count = $SelectedArr[1] - $SelectedArr[0] + 1
    If $count > 0 Then
        $allText = _GUICtrlEdit_GetText($Edit_LIGNE)
        $selectedData = StringMid($allText, $SelectedArr[0], $count)
    EndIf
EndFunc ;==>Replace_MySelection

Func isRightClicPushed($window)
    Local $mouse = GUIGetCursorInfo($window)
    Return ($mouse[3] = 1)
EndFunc
Func isHoveringCtrl($window,$ctrl)
    Local $mouse = GUIGetCursorInfo($window)
    Return ($mouse[4] = $ctrl)
EndFunc
Func sousmenu($gui, $target, $context)
    Local $opt = Opt("MouseCoordMode")
    Opt("MouseCoordMode", 2)
    Local $menu = GUICtrlGetHandle($context), $position = ControlGetPos($gui, "", $target), $coords = DllStructCreate("int;int")
    DllStructSetData($coords, 1, MouseGetPos(0))
    DllStructSetData($coords, 2, MouseGetPos(1))
    DllCall("user32.dll", "int", "ClientToScreen", "hwnd", $gui, "ptr", DllStructGetPtr($coords))
    DllCall("user32.dll", "int", "TrackPopupMenuEx", "hwnd", $menu, "int", 0, "int", DllStructGetData($coords, 1), "int", DllStructGetData($coords, 2), "hwnd", $gui, "ptr", 0)
    Opt("MouseCoordMode", $opt)
EndFunc

Comme quoi, en shuntant les rares kouneries qu'AutoIt impose, il y a souvent moyen de faire des trucs sympas ^^

Merci beaucoup waou mais ça bugge par mal sur mon pc, le menu n'apparait une fois deux mais c'est pas grave je vais rester avec la version précédente

Bonjour ZDS

Vu que je n'ai pas compris à quoi te servait les coches dans le cas présent (sélection de texte, ça n'a rien à voir je pense?), j'ai préféré la sélection de la ligne (clic sur le texte d'une entrée de la listbox, pas sur la coche en tête) pour la mise à jour du champ Edit_LIGNE que tu vois entre ta listbox du haut et ton edit du bas. (Ce n'est qu'un exemple, à modifier surement de fond en comble pour ce que tu veux obtenir ^^)

Ah oui je vois, du coup ça a rendu les cases cochés inactives, et le reste de mon code fonctionne plus

Le champ des entrées sélectionnés me permet de voir si la case est cochée et réaliser une action avec un autre de mes boutons, les lignes cochées sont alors mise dans mon editbox en bas de la gui.
Ma capture d'écran est plus parlante celle que j'ai mise plus haut.

Je vais regarder pour corriger en espérant y arriver à sàparer les deux actions cases cochés, cases décochée -> selectionné pour l'edibox et la recherche

► Afficher le textecode utilisé

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#Include <GuiEdit.au3>

#include <Array.au3>



Opt("GUIDataSeparatorChar", Chr(0)) ; permet de supprimer le bug du | sur les lignes contenant le symbole |
Global $itemNb, $Item, $RapportFile, $rapport, $ReadFile, $file, $OpenDialog, $EditText, $LigneCochee, $EditTexte, $String1, $selectedData ; déclaration des variables
Global $j, $k, $m



#Region ###############Gui Modifié
Global $_1_1 = GUICreate("RapportMe", 888, 570, -1, -1, $WS_OVERLAPPEDWINDOW)
GUICtrlSetResizing($_1_1, $GUI_DOCKAUTO + $GUI_DOCKBOTTOM + $GUI_DOCKTOP)
Global $List1 = GUICtrlCreateListView("Lignes", 8, 40, 784, 285, -1, BitOR($WS_EX_CLIENTEDGE, $LVS_EX_CHECKBOXES))
GUICtrlSendMsg($List1, $LVM_SETCOLUMNWIDTH, 0, 780)



Global $Label0 = GUICtrlCreateLabel("Entrée sélectionnée :", 8, 510, 775, 17)
Global $Label1 = GUICtrlCreateLabel("", 8, 530, 775, 17, $SS_SUNKEN)
GUICtrlSetBkColor(-1, 0xFFFFFF)
Global $Syslog = GUICtrlCreateButton("Syslog", 804, 40, 75, 25, $WS_GROUP)
Global $Systemlook = GUICtrlCreateButton("Systemlook", 804, 72, 75, 25, $WS_GROUP)
Global $StartUplist = GUICtrlCreateButton("StartupList", 804, 102, 75, 25, $WS_GROUP)
Global $Threatexpert = GUICtrlCreateButton("Threatexpert", 804, 134, 75, 25, $WS_GROUP)
Global $Processlibary = GUICtrlCreateButton("ProcessLibrary", 804, 134, 75, 25, $WS_GROUP)
;menu contextuel pour les lignes.
$iCtxt0 = GUICtrlCreateContextMenu($List1)
$iCtxt1 = GUICtrlCreateMenuItem("SysLog", $iCtxt0)
$iCtxt2 = GUICtrlCreateMenuItem("Syslookup", $iCtxt0)
$iCtxt3 = GUICtrlCreateMenuItem("StartUpList", $iCtxt0)
$iCtxt4 = GUICtrlCreateMenuItem("Threatexpert", $iCtxt0)
$iCtxt5 = GUICtrlCreateMenuItem("Processlibary", $iCtxt0)

Global $Edit_LIGNE = GUICtrlCreateEdit("", 8, 331, 785, 22,$ES_READONLY)
Global $Edit1 = GUICtrlCreateEdit("", 8, 359, 785, 153)
GUICtrlSetData(-1, "")
Global $rapport = GUICtrlCreateInput("", 136, 8, 481, 21)
Global $Path = GUICtrlCreateButton("Parcourir", 632, 8, 75, 25, $WS_GROUP)
Global $Rappor = GUICtrlCreateLabel("Rapport to :", 8, 8, 95, 17)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Do
    $nMsg = GUIGetMsg()
    Switch $nMsg

        Case $Path
            $OpenDialog = FileOpenDialog("Ouvrir le rapport", @DesktopDir & "\", "rapport (*.txt;*.log)", 1) ; ouverture du fichier placé sur le bureau au format txt, log
            $itemNb = "" ; déclaration de variable vide
            $Item = "" ; déclaration de variable vide

            GUICtrlSetData($rapport, $OpenDialog) ;
            _GUICtrlListView_DeleteAllItems($List1) ;

            $file = FileOpen($OpenDialog, 0)
            Dim $Item[1] ; on crée un tableau pour stocker les lignes => tableau 1D
            $itemNb = 0

            While 1 ; donc on fait une boucle
                $ligne = FileReadLine($file)
                If @error = -1 Then ExitLoop
                $Trouve = False ;
                If $ligne <> "" Then
                    $itemNb += 1
                    ReDim $Item[$itemNb + 1]
                    $Item[$itemNb] = GUICtrlCreateListViewItem($ligne, $List1) ;
                EndIf
            WEnd
            FileClose($file); A la fin on oublie pas de fermer le fichier

        Case $Syslog, $iCtxt1
            MySelection()
            ; Test
           ; MsgBox(0,"Selection [SysLog]", '"'&$selectedData&'"')
          ShellExecute("http://www.sysinfo.org/startuplist.php?filter=" & $selectedData)

        Case $Systemlook, $iCtxt2
            MySelection()
            ; Test
            MsgBox(0,"Selection [Syslookup]", '"'&$selectedData&'"')
;~             ShellExecute("http://www.systemlookup.com/search.php?type=filename&search=" & $selectedData)
Case $StartupList, $iCtxt3
     MySelection()
    ShellExecute("http://www.bleepingcomputer.com/startups/?&act=search&st=0&keyword"& $selectedData)
Case $Threatexpert, $iCtxt4
     MySelection()
ShellExecute("http://www.threatexpert.com/reports.aspx?find="& $selectedData)
Case $Processlibary, $iCtxt5
     MySelection()
    ShellExecute("http://www.processlibrary.com/fr/search/?q="& $selectedData)

        Case Else ;
            If $OpenDialog <> "" Then
                $lbl = "Lignes cochées : "
                $lbl2 = ""
                $LigneCochee = ""
                $LigneSelectionnee = ""
                For $i = 0 To $itemNb
                    If GUICtrlRead($Item[$i], 1) = 1 Then
                        $lbl = $lbl & ", " & $i
                        If Not StringInStr($LigneCochee, _GUICtrlListView_GetItemText($List1, $i - 1)) Then
                            $LigneCochee &= _GUICtrlListView_GetItemText($List1, $i - 1) & @CRLF
                        EndIf
                    EndIf
                    If _GUICtrlListView_GetItemSelected($List1, $i) Then
                        $lbl2 = " / Ligne selectionnée : "&($i+1)
                        $LigneSelectionnee = _GUICtrlListView_GetItemText($List1, $i)
                    EndIf
                Next
                ; si aucun N° de ligne n'a été ajouté, c'est qu'aucune ligne n'a été sélectionnée
                If $lbl = "Lignes chochées : " Then $lbl = "Aucune ligne chochée"

                $lbl &= $lbl2
                If GUICtrlRead($Label1) <> $lbl Then ; pour éviter le scintillement on ne met a jour le label que si il a changé
                    GUICtrlSetData($Label1, $lbl)
                    If $LigneSelectionnee <> "" Then GUICtrlSetData($Edit_LIGNE, $LigneSelectionnee)
                EndIf
            EndIf

    EndSwitch

Until $nMsg = $GUI_EVENT_CLOSE

Func MySelection()
    $SelectedArr = _GUICtrlEdit_GetSel($Edit_LIGNE)
    $SelectedArr[0] += 1
    $count = $SelectedArr[1] - $SelectedArr[0] + 1
    If $count > 0 Then
        $allText = _GUICtrlEdit_GetText($Edit_LIGNE)
        $selectedData = StringMid($allText, $SelectedArr[0], $count)
    EndIf
EndFunc ;==>Replace_MySelection

AutoIt Français

[R] Sélectionner un mot dans une listbox ligne à cocher ?

[R] Sélectionner un mot dans une listbox ligne à cocher ?

Re: [..] Sélectionner un mot dans une listbox ligne à cocher

Re: [..] Sélectionner un mot dans une listbox ligne à cocher

Re: [..] Sélectionner un mot dans une listbox ligne à cocher

Re: [..] Sélectionner un mot dans une listbox ligne à cocher

Re: [..] Sélectionner un mot dans une listbox ligne à cocher

Re: [..] Sélectionner un mot dans une listbox ligne à cocher

Re: [..] Sélectionner un mot dans une listbox ligne à cocher

Re: [..] Sélectionner un mot dans une listbox ligne à cocher

Re: [R] Sélectionner un mot dans une listbox ligne à cocher