AutoIt Français

Code : Tout sélectionner

#include <Array.au3>
#include <File.au3>

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$search = _FolderExplorer(@ScriptDir & "\Omega", "*.*", 1)

Dim $Button[$search[0]]

$Form1 = GUICreate("Form1", 800, 600)
$step = 5
For $i = 1 To $search[0] Step $step
    For $j = 1 To $step
        If ($i + $j < $search[0] + 2) And ($i + $j > 1) Then
            $btntxt1 = StringSplit($search[$i + $j - 1], "\")
            $btntxt2 = StringSplit($btntxt1[$btntxt1[0]], ".")
            $Button[$i + $j - 2] = GUICtrlCreateButton($btntxt2[1], (($i / $step) * 88) + 5, (($j - 1) * 30) + 5, 83, 25, $WS_GROUP)
        EndIf
    Next
Next
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
    For $i = 0 To $search[0] - 1
        If $nMsg = $Button[$i] Then
            MsgBox(0, "", "vous avez apuyé le boutton suivant :" & @CRLF _
                     & "ID boutton        : " & $Button[$i] & @CRLF _
                     & "N° boutton        : " & $i & @CRLF _
                     & "Label Boutton     : " & GUICtrlRead($Button[$i]) & @CRLF _
                     & "Chemin du fichier : " & $search[$i + 1])
        EndIf
    Next

WEnd



Func _FolderExplorer($Racine, $Filtre = "*.*", $FileOrDir = "0", $FullPath = True, $Recursif = True)
;~  $Racine :       Racine à explorer

;~  $Filtre :       [optionnel] Masque de filtrage des fichiers (n'impacte pas le nom des sous répertoires ou la recherche se fera)
;~                      Par défaut le masque est *.*

;~  $FileOrDir :    [Optionnel] Indique si la fonction doit renvoyer des fichiers et/ou les deux
;~                      $FileOrDir=0 (défaut) Fichiers & dossiers
;~                      $FileOrDir=1 Fichiers seulement
;~                      $FileOrDir=2 Répertoires seulement

;~  $FullPath :     [Optionnel] Indique si la fonction renvoie le chemin complet ou le chemin relatif
;~                      $FullPath = 0/false renvoie le chemin relatif à $Racine
;~                      $FullPath = 1/true (defaut) renvoie le chemin complet

;~  $Recursif :     Explore ou non les sous répertoires
;~                      $Recursif = 0/false n'explore que le répertoire $Racine
;~                      $Recursif = 1/true (défaut) explore toute la sous arborescence

    Local $ListeFichiers, $CptrFichier

    If $Filtre = -1 Then $Filtre = "*.*"
    If $FileOrDir = Default Or $FileOrDir = -1 Then $FileOrDir = 0 ; convertit les options "par défaut" standard en true
    If $Recursif = Default Or $Recursif = -1 Then $Recursif = True ; convertit les options "par défaut" standard en true
    If $FullPath = Default Or $FullPath = -1 Then $FullPath = True ; convertit les options "par défaut" standard en true

    $ListeFichiers = FolderParser($Racine, $Filtre, $FileOrDir, $Recursif) ; on parse le dossier

    If $FullPath <> True Then ; si le retour doit etre relatif
        _ArrayTrim($ListeFichiers, StringLen($Racine & "\"), 0, 1) ; on coupe le début des lignes
    EndIf
    $CptrFichier = UBound($ListeFichiers) - 1 ; on met a jour le compteur avec le nombre de lignes dans le tableau
    $ListeFichiers[0] = $CptrFichier
    Return $ListeFichiers ; et on sort

EndFunc   ;==>_FolderExplorer

Func FolderParser($Racine, $Filtre = "*.*", $FileOrDir = "0", $Recursif = True)
    Local $TabFichier, $i, $Chemin, $SubFolderFileList
    Local $CptrFichier = 0
    Dim $FullFileList[1] = [0]

    $TabFichier = _FileListToArray($Racine, $Filtre, $FileOrDir)
    If Not @error Then
        For $i = 1 To $TabFichier[0]
            $Chemin = $Racine & "\" & $TabFichier[$i] ; recupere le chemin du fichier
            If not (StringInStr(FileGetAttrib($Chemin), "D") And $Recursif = True) Then ; trouvé fichier correspondant au filtre
                $CptrFichier = $CptrFichier + 1 ; incrementation du compteur
                ReDim $FullFileList[$CptrFichier + 1] ; redimensionnement du tableau de liste
                $FullFileList[0] = $CptrFichier ; mise a jour du compteur dans le tableau
                $FullFileList[$CptrFichier] = $Chemin ; ajout de la ligne
            EndIf
            If StringInStr(FileGetAttrib($Chemin), "D") And $FileOrDir <> 1 Then ; trouvé répertoire correspondant au filtre
                $CptrFichier = $CptrFichier + 1 ; incrementation du compteur
                ReDim $FullFileList[$CptrFichier + 1] ; redimensionnement du tableau de liste
                $FullFileList[0] = $CptrFichier ; mise a jour du compteur dans le tableau
                $FullFileList[$CptrFichier] = $Chemin ; ajout de la ligne
            EndIf

        Next
    EndIf
    If $Recursif = True Then ; récursif ?
        $TabFichier = _FileListToArray($Racine)
        If Not @error Then
            For $i = 1 To $TabFichier[0]
                $Chemin = $Racine & "\" & $TabFichier[$i] ; recupere le chemin
                If StringInStr(FileGetAttrib($Chemin), "D") Then ; c'est un répertoire
                    $SubFolderFileList = FolderParser($Chemin, $Filtre, $FileOrDir, $Recursif) ; explorer le sous repertoire par appel recursif de la fonction
                    _ArrayDelete($SubFolderFileList, 0) ; on suprimer l'enregistrement zero (nb de lignes )
                    _ArrayConcatenate($FullFileList, $SubFolderFileList) ; et on concatene dans le tableau de liste
                    $CptrFichier = UBound($FullFileList) - 1 ; et on compte combien on a maintenant de fichiers dans la liste
                EndIf
            Next
        EndIf
    EndIf
    Return $FullFileList ; on renvoie le tableaui
EndFunc   ;==>FolderParser