AutoIt Français

Bonjour,

Je cherche à créer un script qui récupérer le nom d'un fichier sans extension de type "fichier" à la racine d'un lecteur USB.

Par exemple quand j'insère ma clé USB qui prend une lettre au hasard, le script que je lance retrouve automatiquement le nom du fichier GENERIC.

Le but est de créer un petit lanceur pour truecrypt.

Merci d'avance pour votre aide

Bonjour mokoto,

J'utilise aussi Truecrypt qui est génial et j'ai sur ma clé un volume TC que je lance avec un script TC recompilé sous Autoit.

TC a un assistant pour créer des volumes sur un média amovible (Tools > Traveler Disk Setup).

Que cherches tu à faire exactement ? Lancer la fenêtre du mot de passe d'ouverture de ton volume à l'insertion de la clé ?

Dis nous en un peu plus que l'on puisse répondre exactement ce que tu cherches.

Amicalement.

BM

En fait il faut que l'utilisation de TrueCrypt soit la plus simple possible.

Voici comment se compose l'arborescence de la clé (il faut que ce soit comme ça) :

Racine ----- TrueCrypt
| |
| |_ le programme original portable
|
|_ Un fichier sans extension nommé pour l'exemple GENERIC (le volume dont le nom est modifiable)
|_ Lanceur du programme qui lance le fichier GENERIC
|_ Programme pour déconnecter le volume

En ce moment j'utilise un script vbs transformé en exécutable qui marche plutôt bien mais j'utilise une version commercial limité pour créer l'exécutable dont j'ai pas la licence . J'ai fait le programme en Visual Basic mais les ordinateurs n'ont pas .NET Framework....

Je veux transposé mon programme en autoIt qui est libre de droit.

Donc déjà je sais lancé mon programme :

Code : Tout sélectionner

Run ( "\TrueCrypt\TrueCrypt.exe /v GENERIC /l /m rm /auto /q /e" )

Le problème c'est que le nom GENERIC doit être modifiable à volonté sans passé par une fenêtre qui demande le nom du fichier, bien sûr c'est possible de lui donné une extension style ".tc" si c'est nécessaire. Au final l'utilisateur ne doit avoir que la fenêtre pour rentrer son mot de passe (le lanceur) et l'executable pour déconnecter le volume.

Si j'ai bien compris tu as sur la clé 1 seul fichier TC.

Je te conseille de lui donner l'extension TC (j'avais rencontré des soucis en cas de sauvegarde de la clé avec les fichiers sans extensions).

1. Tu récupères la lettre de ta clé avec :

Code : Tout sélectionner

StringLeft(@ScriptDir,3)

2. Tu lances une recherche sur ta clé avec une fonction style _FileListToArrayEx en ne cherchant que l'extension .tc :
http://www.autoitscript.fr/forum/viewtopic.php?p=34893

Code : Tout sélectionner

#include<Array.au3>
#include<FileListToArrayEx.au3>

$ar_Array = _FileListToArrayEx (StringLeft(@ScriptDir,3), "*.tc", 0, "", True)

_ArrayDisplay($ar_Array)

3. Tu récupères le nom de ton fichier pour lancer ta ligne de commande :

Code : Tout sélectionner

$cmd_chaine='TrueCrypt.exe /q background /lR /m rm /v "'& $ar_Array[1] &'"'
Run(@ComSpec & " /c " & $cmd_chaine, "", @SW_HIDE)

En espérant avoir pu t'aider.

Amicalement.

BM

Merci pour ton aide j'en suis là :

Code : Tout sélectionner

$Lettre = StringLeft(@ScriptDir,3)

$ar_Array = _FileListToArrayEx (StringLeft(@ScriptDir,3), "*.tc", 1, "", True)

Run ( "\TrueCrypt\TrueCrypt.exe /v" & $ar_Array & "/l /m rm /auto /q /e" )

Le problème c'est que je ne sais pas comment récupérer le résultat de la recherche puisque $ar_Array retourne un tableau.

Regarde mon point 3

$ar_Array[1]

Amicalement.

BM

Merci beaucoup pour ton aide voilà les scripts finaux :

Lanceur normal :

Code : Tout sélectionner

#include<Array.au3>
#include<FileListToArrayEx.au3>

$Lettre = StringLeft(@ScriptDir,3)

$ar_Array = _FileListToArrayEx (StringLeft(@ScriptDir,3), "*.tc", 1, "", True)

Run ( "\TrueCrypt\TrueCrypt.exe /v " & $ar_Array[1] & " /l /m rm /auto /q /e" )

Lanceur avec lettre spécifique :

Code : Tout sélectionner

#include<Array.au3>
#include<FileListToArrayEx.au3>

$Lettre = StringLeft(@ScriptDir,3)

$ar_Array = _FileListToArrayEx (StringLeft(@ScriptDir,3), "*.tc", 1, "", True)

$lettre = InputBox("Lettre du lecteur", "FACULTATIF: entrez une lettre de lecteur pour monter votre fichier. ATTENTION la lettre ne doit pas être déja utilisée par un périphérique ou un lecteur réseau. Exemple : V.")

Run ( "\TrueCrypt\TrueCrypt.exe /v " & $ar_Array[1] & " /l " & $lettre & " /m rm /auto /q /e" )

Déconnexion du volume :

Code : Tout sélectionner

Run ( "\TrueCrypt\TrueCrypt.exe /q /d" )

Tout fonctionne

Bonjour,

Tant mieux si j'ai pu t'aider.

Penses juste à mettre [R] dans ton premier post pour que les autres puissent savoir que le sujet est résolu.

Amicalement.

BM

Bonjour

tu peux aussi proposer une liste des lettres disponible.

Local $aDrives = DriveGetDrive("All") te retourne un tableau des lettres déjà utilisé.

Ensuite tu parcours les lettres de A(code ascii 65) à Z(code ascii 90), si c'est pas dans le tableau tu l'ajoute à une ListBox ou un tableau:

Code : Tout sélectionner

Local $aDrives = DriveGetDrive("All")
_ArrayDisplay($aDrives)
Local $aDrivesDispo[1]

For $Ascii = 65 To 90
    If _ArrayFindAll($aDrives, Chr($Ascii) & ":", 1) = -1 Then
        ReDim $aDrivesDispo[UBound($aDrivesDispo) + 1]
        $aDrivesDispo[UBound($aDrivesDispo) - 1] = Chr($Ascii) & ":"
        $aDrivesDispo[0] += 1
        ; ajoute aussi dans la liste
        _GUICtrlListBox_AddString($ListBox, $aDrivesDispo[$i])
    EndIf
Next
_ArrayDisplay($aDrivesDispo)

For $i = 1 To $aDrivesDispo[0]
    _GUICtrlListBox_AddString($ListBox, $aDrivesDispo[$i])
Next

Bonjour GaRydelaMer,

Merci pour ta suggestion, c'est une super idée mais je débute autoIt il va me falloir du temps pour que je puisse l'intégrer dans mon code

Bonjour,
J'ai trouvé Launcher pour Truecrypt, une solution complète basée sur Autoit à ce lien:
http://blog.usboffice.kr/?p=210
et voici le code:

► Afficher le texte

Code : Tout sélectionner

#NoTrayIcon
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=tcloader.ico
#AutoIt3Wrapper_outfile=TC_Loader.exe
#AutoIt3Wrapper_UseUpx=n
#AutoIt3Wrapper_Res_Comment=Portable launcher file for Truecrypt
#AutoIt3Wrapper_Res_Description=Launcher file for Truecrypt
#AutoIt3Wrapper_Res_Fileversion=1.1.6.0
#AutoIt3Wrapper_Res_LegalCopyright=Published in http://www.usboffice.kr
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Allow_Decompile=n
#include <GUIConstants.au3>

Global const $Appdir = @ScriptDir &"\Program files\TrueCrypt"
Global const $DataDir = @ScriptDir&"\Data"
Global const $SettingFile = $DataDir &"\settings.ini"
Global const $settingsDir = $datadir &"\settings"
Global const $CurrentDriveLetter = StringLeft(@ScriptDir, 2)
Global Const $AppExe = $AppDir & '\TrueCrypt.exe' ; ½ÇÁ¦ ½ÇÇà½ÃÅ³ ÇÁ·Î±×·¥
Local $Process = StringSplit($AppExe, '\')
Global Const $ProcessName = $Process[$Process[0]]
Global $Imagepath = IniRead($settingfile, "Truecrypt settings", "Imagepath", "")
Global $ImageLetter = IniRead($settingfile, "Truecrypt settings", "Imageletter", "")
Global $Drivetype = IniRead($settingfile, "Truecrypt settings", "Removable", "")
Global $ImgExplorer = IniRead($settingfile, "Truecrypt settings", "Explorer", "")


_initialize()

IF ProcessExists ( "TrueCrypt.exe") then 
    IF not $cmdline[0] = 0 then 
        IF $cmdline[1] = "-q" then   
            ShellExecuteWait("TrueCrypt.exe", "/q /d", $AppDir) 
            Sleep(250)          
            Filemove ( $appDir &"\configuration.xml", $settingsDir &"\configuration.xml",  1 )  
            While ProcessExists("TrueCrypt.exe")
                ProcessClose("TrueCrypt.exe")
            WEnd
            Exit
        EndIF
    Else
        If MsgBox(4 + 48 + 4096, "DisMount", "Dismount security volume")=6 then
            ShellExecuteWait("TrueCrypt.exe", "/q /d", $AppDir) 
            Sleep(250)
            Filemove ( $appDir &"\configuration.xml", $settingsDir &"\configuration.xml",  1 )      
            While ProcessExists("TrueCrypt.exe")
                ProcessClose("TrueCrypt.exe")
            WEnd
            Exit
        Else
        endIF   
    Endif
EndIF

_adjust()


If $ImgExplorer <> 1 Then
    $ImgExplorer = ""
Else
    $ImgExplorer = " /e"
EndIf

If $Drivetype <> 1 Then
    $Drivetype = ""
Else
    $Drivetype = "rm "
EndIf

If DriveStatus($ImageLetter) = "INVALID" Then
    
;   MsgBox (0,"","/q background /l" & $ImageLetter & " /m" & $drivetype  & $ImgExplorer &" /v " & '"' & $SecuArea&'"')
;       MsgBox (0,"","/q background /l" & $ImageLetter & $ImgExplorer & " /m rm /v " & $SecuArea)
    ShellExecute("TrueCrypt.exe", "/q background /l" & $ImageLetter & $ImgExplorer & " /m "& $Drivetype &"/v " & '"' & $CurrentDriveLetter & $Imagepath &'"', $AppDir )
    ;ShellExecute("TrueCrypt.exe", "/q background /l" & $ImageLetter & " /m" & $drivetype  & $ImgExplorer &" /v " & '"' & $SecuArea&'"', $AppDir )
    
Else
    if MsgBox(4 + 48 + 4096, "Drive letter conflict", "Drive letter is already occufied.  "& @CRLF & @CRLF &" Edit imageletter value in settings.ini. ")=6 Then
        ShellExecute ("settings.ini", "", $DataDir )
    Else
        Filemove ( $appDir &"\configuration.xml", $settingsDir &"\configurationlxml",  1 )
        Exit
    endif   
EndIf

_ProcessWaitClose ( $processname)

Filemove ( $appDir &"\configuration.xml", $settingsDir &"\configuration.xml",  1 )
ShellExecute("TrueCrypt.exe", "/q /d", $AppDir) 

Exit

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Func _Initialize()
    If Not FileExists($DataDir) Then DirCreate($DataDir)
    If Not FileExists($SettingsDir) Then DirCreate($SettingsDir)
    If Not FileExists($settingfile) Then MakeINI()      
EndFunc   ;==>_Initialize
    
Func _adjust()
    Filemove ( $settingsDir &"\configuration.xml", $appDir &"\configuration.xml", 0 )               
EndFunc 

Func MakeINI()
    $AForm1 = GUICreate("TrueCrypt Config", 440, 110, (@DesktopWidth - 370) / 2, (@DesktopHeight - 390) / 2)

    $Label2 = GUICtrlCreateLabel("Image", 8, 13, 65, 25)
    GUICtrlSetFont(-1, 10, 800, 0, "Arial")
    $Input2 = GUICtrlCreateInput("Select encrypted image file", 65, 11, 250, 24)
    $Label3 = GUICtrlCreateLabel("DRIVE", 8, 46, 65, 25)
    GUICtrlSetFont(-1, 10, 800, 0, "Arial")
    $Combo1 = GUICtrlCreateCombo("", 65, 45, 45, 25)
    $Letter = IniRead($settingfile, "Truecrypt settings", "Imageletter", "")
        
    $Checkbox1 = GUICtrlCreateCheckbox("Removable disk", 150, 42, 135, 25)
    GUICtrlSetFont(-1, 10, 800, 0, "Arial")
    
    If IniRead($settingfile, "Truecrypt settings", "Removable", "") = 1 Then
        GUICtrlSetState(-1, $GUI_CHECKED)
    Else
        GUICtrlSetState(-1, $GUI_UNCHECKED)
    EndIf
    
    $Checkbox2 = GUICtrlCreateCheckbox("Open Explorer", 295, 42, 135, 25)
    GUICtrlSetFont(-1, 10, 800, 0, "Arial")
    
    If IniRead($settingfile, "Truecrypt settings", "Explorer", "") = 1 Then
        GUICtrlSetState(-1, $GUI_CHECKED)
    Else
        GUICtrlSetState(-1, $GUI_UNCHECKED)
    EndIf
    $Button2 = GUICtrlCreateButton("Create", 375, 11, 50, 25, 0)
    $Button1 = GUICtrlCreateButton("Select", 320, 11, 50, 25, 0)
    $j = ""
    
    For $i = 65 To 90
        $j = $j & "|" & Chr($i)
        If $i = 90 Then GUICtrlSetData($Combo1, $j, $Letter)
    Next
    
    $Button3 = GUICtrlCreateButton("OK", 150, 80, 120, 25, 0)


    GUISetState(@SW_SHOW)
    
    IniWrite($settingfile, "Truecrypt settings", "Explorer", 0 )
    IniWrite($settingfile, "Truecrypt settings", "Removable", 0 )       
    
    While 1
        $nMsg = GUIGetMsg()
        Select
            Case $nMsg = $GUI_EVENT_CLOSE
                If FileExists($settingfile) Then
                    If $imagepath <> "" and $imageLetter <> "" Then
                        ExitLoop
                    Else
                        MsgBox(48, "Notice!!!", "Configration is not completed." & @CRLF & @CRLF & "Terminate process.")
                        If FileExists($settingfile) Then FileDelete($settingfile)
                        Filemove ( $appDir &"\configuration.xml", $settingsDir &"\configuration.xml",  1 )
                        Exit
                    EndIf
                Else
                    MsgBox(48, "Notice!!!", "Configration is not completed." & @CRLF & @CRLF & "Terminate process.")
                    Filemove ( $appDir &"\configuration.xml", $settingsDir &"\configuration.xml",  1 )  
                    exit
                EndIf
                
            Case $nMsg = $Combo1
                $ComboCheck = GUICtrlRead($Combo1)
                If @error = 0 Then
                    IniWrite($settingfile, "Truecrypt settings", "Imageletter", $ComboCheck&":")
                    $ImageLetter = $ComboCheck&":"
                EndIf
                
            Case $nMsg = $Checkbox1
                $CheckCheck = GUICtrlRead($Checkbox1)
                If $CheckCheck = 1 Then
                    $Check1 = 1
                Else
                    $Check1 = 0
                EndIf
                If @error = 0 Then
                    IniWrite($settingfile, "Truecrypt settings", "Removable", $Check1)
                    $Drivetype  = $check1
                EndIf

            Case $nMsg = $Checkbox2
                $CheckCheck2 = GUICtrlRead($Checkbox2)
                If $CheckCheck2 = 1 Then
                    $Check2 = 1
                Else
                    $Check2 = 0
                EndIf
                If @error = 0 Then
                    IniWrite($settingfile, "Truecrypt settings", "Explorer", $Check2)
                    $Drivetype = $Check2
                EndIf

            Case $nMsg = $Button1
                $file = FileOpenDialog("Select encrypted image file.", @ScriptDir, "All(*.*)", 1)
                $Image = StringSplit($file,"\")
                If @error = 0 Then
                    IniWrite($settingfile, "Truecrypt settings", "Imagepath", stringtrimleft($file,2))
                    GUICtrlSetData($Input2, $file)
                    $Imagepath = stringtrimleft($file,2)
                EndIf

            Case $nMsg = $Button2
                
                ShellExecute ( "TrueCrypt Format.exe", "", $Appdir)

            Case $nMsg = $Button3
                If FileExists($settingfile) Then
                    If IniRead($settingfile, "Truecrypt settings", "Imagepath", "") <> "" And IniRead($settingfile, "Truecrypt settings", "Imageletter", "") <> "" Then
                        ExitLoop
                    Else
                        MsgBox(48, "Notice!!!", "Configration is not completed." & @CRLF & @CRLF & "Terminate process.")
                        If FileExists($settingfile) Then FileDelete($settingfile)
                        Filemove ( $appDir &"\configuration.xml", $settingsDir &"\configuration.xml",  1 )  
                        Exit
                    EndIf
                Else
                    MsgBox(48, "Notice!!!", "Configration is not completed." & @CRLF & @CRLF & "Terminate process.")
                    Filemove ( $appDir &"\configuration.xml", $settingsDir &"\configuration.xml",  1 )  
                    Exit
                EndIf               
                
        EndSelect
    WEnd
    GUIDelete()
EndFunc


Func _processwaitclose ( $process )
    while ProcessExists ( $process )
        sleep (300)
    WEnd
EndFunc

Le principe est simple, le launcher en ZIP crée 3 dossiers. Dans Program files, vous avez le sous dossier Truecrypt où vous importez le logiciel Truecrypt.
Vous créez le container dans le même dossier.
En cliquant sur TC_Loader.exe, une MSbox s'ouvre pour indiquer le container et la lettre du lecteur. nouvelle fenêtre pour le mot de passe.
Par la suite, en cliquant sur TC_Loader.exe la fenêtre pour le mot de passe s'ouvre uniquement sans autre forme. (le chemin est inscrit sur un setting.ini)

Petite remarque sans rapport, le site est coréen dont http://www.usboffice.kr/ est la pièce maitresse avec un forum autoit. Google traduct est conseillé

AutoIt Français

[R] Script pour récupérer le nom d'un fichier

[R] Script pour récupérer le nom d'un fichier

Re: [..] Script pour récupérer le nom d'un fichier

Re: [..] Script pour récupérer le nom d'un fichier

Re: [..] Script pour récupérer le nom d'un fichier

Re: [..] Script pour récupérer le nom d'un fichier

Re: [..] Script pour récupérer le nom d'un fichier

Re: [..] Script pour récupérer le nom d'un fichier

Re: [R] Script pour récupérer le nom d'un fichier

Re: [R] Script pour récupérer le nom d'un fichier

Re: [R] Script pour récupérer le nom d'un fichier

Re: [R] Script pour récupérer le nom d'un fichier