AutoIt Français

Code : Tout sélectionner

; #FUNCTION# ====================================================================================================================
; Name...........: _GDIPlus_BitmapSetResolution
; Description ...: Sets the resolution of this Bitmap object
; Syntax.........: _GDIPlus_BitmapSetResolution($hBitmap, $nDpiX, $nDpiY)
; Parameters ....: $hBitmap - Pointer to the Bitmap object
;   $nDpiX  - Value that specifies the horizontal resolution in dots per inch.
;   $nDpiX  - Value that specifies the vertical resolution in dots per inch.
; Return values .: Success  - True
;   Failure     - False and either:
;   |@error and @extended are set if DllCall failed
;   |$GDIP_STATUS contains a non zero value specifying the error code
; Remarks .......: None
; Related .......:
; Link ..........; @@MsdnLink@@ GdipBitmapSetResolution
; Example .......; Yes
; ===============================================================================================================================
Func _GDIPlus_BitmapSetResolution($hBitmap, $nDpiX, $nDpiY)
    Local $aResult = DllCall($ghGDIPDll, "uint", "GdipBitmapSetResolution", "hwnd", $hBitmap, "float", $nDpiX, "float", $nDpiY)

    If @error Then Return SetError(@error, @extended, False)
    $GDIP_STATUS = $aResult[0]
    Return $aResult[0] = 0
EndFunc ;==>_GDIPlus_BitmapSetResolution

Code : Tout sélectionner

#include <ScreenCapture.au3>

    Local  $hBmp, $hBitmap

    ; Initialize GDI+
    _GDIPlus_Startup()

    $hBmp = _ScreenCapture_Capture("", 0, 0, -1, -1, False)
    $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hBmp)

    ; Set Dots Per Inch to 96x144, usually 96x96 or 120x120: isotropic
    _GDIPlus_BitmapSetResolution($hBitmap, 320, 320)

    _GDIPlus_ImageSaveToFile($hBitmap, @MyDocumentsDir & "\96x144.jpg")
    ; Clean up
    _GDIPlus_ImageDispose($hBitmap)
    _WinAPI_DeleteObject($hBmp)

    ; Uninitialize GDI+
    _GDIPlus_Shutdown()

    ShellExecute(@MyDocumentsDir & "\96x144.jpg")


Func _GDIPlus_BitmapSetResolution($hBitmap, $nDpiX, $nDpiY)
    Local $aResult = DllCall($ghGDIPDll, "uint", "GdipBitmapSetResolution", "hwnd", $hBitmap, "float", $nDpiX, "float", $nDpiY)

    If @error Then Return SetError(@error, @extended, False)
    $GDIP_STATUS = $aResult[0]
    Return $aResult[0] = 0
EndFunc ;==>_GDIPlus_BitmapSetResolution