AutoIt Français

Bonjour,

Je m'adresse à vous car j'ai un problème d'affichage dans une listview. Je voudrais afficher une liste de fichiers d'un répertoire, modifiés entre deux dates, pour ce qui est de l'affichage de la liste complète des fichiers du répertoire en question, pas de soucis. Dès que j'essaye de lister les fichiers modifiés entre date de début et date de fin, aucun résultat

Voici le code de ma gui :

► Afficher le texte

Code : Tout sélectionner

;===============
;== Variables ==
;===============
#include <DateTimeConstants.au3>
#include <GuiListView.au3>
#include <GUIConstantsEx.au3>

$A = @ScriptDir & "\Fichiers"
$B = @ScriptDir & "\Traites"


;================================================
;== Début de l'Interface Graphique Utilisateur ==
;================================================
$Reprise = GUICreate ("Reprise Envoi Fichiers RUB", 280, 440)
$Group0 = GUICtrlCreateGroup ("Dossier", 10, 10, 250, 50)
GUICtrlSetFont (-1, 10, 800, 0, "Comic Sans MS")
GUICtrlSetColor (-1, 0x0000FF)
$g0_Label1 = GUICtrlCreateLabel ("Chemin : "&$A, 20, 35, 220, 20)
GUICtrlSetFont(-1, 10, 400, 0)
$Group1 = GUICtrlCreateGroup ("Selection des fichiers", 10, 70, 250, 320)
GUICtrlSetFont (-1, 10, 800, 0, "Comic Sans MS")
GUICtrlSetColor (-1, 0x0000FF)
$g1_Label1 = GUICtrlCreateLabel ("Fichiers créés entre : ", 20, 95, 150, 20)
GUICtrlSetFont (-1, 10, 400, 0)
$g1_Label2 = GUICtrlCreateLabel ("Date de Début :", 20, 120, 110, 20)
GUICtrlSetFont (-1, 10, 400, 0)
$g1_Label3 = GUICtrlCreateLabel ("Date de Fin :", 150, 120, 100, 20)
GUICtrlSetFont (-1, 10, 400, 0)
$g1_Date1 = GUICtrlCreateDate ("", 20, 140, 100, 20, $DTS_SHORTDATEFORMAT)  ; correspond à la date de début de recherche
$dd = GUICtrlRead ($g1_Date1)
$add = StringRight ($dd, 4)
$mdd = StringMid ($dd, 4, 2)
$jdd = StringLeft ($dd, 2)
$dateD = $add&$mdd&$jdd                                                     ; date de début de recherche au format YYYYMMDD
$g1_Date2 = GUICtrlCreateDate ("", 150, 140, 100, 20, $DTS_SHORTDATEFORMAT) ; correspond à la date de fin de recherche
$df = GUICtrlRead ($g1_Date2)
$adf = StringRight ($df, 4)
$mdf = StringMid ($df, 4, 2)
$jdf = StringLeft ($df, 2)
$dateF = $adf&$mdf&$jdf                                                     ; date de fin de recherche au format YYYYMMDD
$g1_List1 = GUICtrlCreateListView ("Fichier | Date",20, 170, 220, 210, $LVS_SHOWSELALWAYS, $LVS_EX_CHECKBOXES)  ; céation listview avec cases à cocher
_GUICtrlListView_SetColumnWidth ($g1_List1, 0, 110)
_GUICtrlListView_SetColumnWidth ($g1_List1, 1, 90)
    $chemin = ($B & "\")
    $search = FileFindFirstFile ($chemin & "*.*")
        While 1
            $file = FileFindNextFile ($search)
            If @error Then ExitLoop
            $t = FileGetTime ($chemin & $file, 0, 1)
            $a = StringLeft ($t, 4)
            $m = StringLeft (StringTrimLeft ($t, 4), 2)
            $j = StringRight (StringTrimRight ($t, 6), 2)
            $dateM = $a&$m&$j
            $date = $j & "/" & $m & "/" & $a                                
            If $dateM > $dateD And $dateM < $dateF Then                     ; comparaison date de modification fichier entre date de début et date de fin
                GUICtrlCreateListViewItem ( $file & "|" & $date, $g1_List1) ; affichage de la listview
            EndIf
        WEnd
$Valider = GUICtrlCreateButton( "Valider", 10, 400, 100, 30, 0)
GUICtrlSetFont(-1, 10, 800, 0, "Comic Sans MS")
$Annuler = GUICtrlCreateButton ("Annuler", 160, 400, 100, 30, 0)
GUICtrlSetFont(-1, 10, 800, 0, "Comic Sans MS")
GUISetState(@SW_SHOW)
;=========================
;== Début du traitement ==
;=========================
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Annuler
            Exit
        Case $Valider
            GUISetState(@SW_HIDE)
            $ListNb = _GUICtrlListView_GetItemCount($g1_List1)
            For $i = 0 to $ListNb - 1
                $ItemText = _GUICtrlListView_GetItemText($g1_List1, $i)
                $ItemState = _GUICtrlListView_GetItemChecked($g1_List1, $i)
                If $ItemState = 1 Then
                    $ItemState = "Coché"
                Else
                    $ItemState = "Décoché"
                EndIf
            MsgBox(0, '', $ItemText & " est " & $ItemState)
            Next
        Exit
    EndSwitch
WEnd

Merci de votre aide.

Voici quelques indications avant de partir
pour ma journée.

Premièrement,

Code : Tout sélectionner

 $search = FileFindFirstFile ($chemin & "*.*")

ne peut pas être utilisé comme ça.

$chemin, dans votre script correspond à un label.
Si vous placez une ligne de console directement dessous cette fonction
afin de voir le résultat de cette fonction, il donnera toujours '-1' ce qui
explique que rien ne fonctionne correctement.

Vous devez utilisez 'GuiCtrlRead' afin de lire la valeur d'un contrôle.

La même erreur est présente ici

Code : Tout sélectionner

 If $dateM > $dateD And $dateM < $dateF Then

ajoutez un consolewrite($dateM & @crlf) et vous verrez que la valeur
n'est pas la date.

Pour terminer, vous effectuez dès le départ dans la boucle While ... Wend

Par contre, lorsque l'on clique sur valider, rien n'est fait de la sorte pour peupler
la listview.

J'essaierai de revenir voir votre progression sur ce problème en revenant
des études ce soir mais en attendant, c'est mon premier constat.

Bonsoir,
Je viens de suivre les instructions afin de vérifier ce qui est retourné par ConsoleWrite :

>Running:(3.3.6.0):C:\Program Files (x86)\AutoIt3\autoit3_x64.exe "K:\Donnees\Areva\gui.au3"
K:\Donnees\Areva\Traites\ ==> pour ce qui est de la variable $chemin
20100513
20100513 ==> Date modification fichier
20100513
20100513
20100513
20100526
20100526
20100526
20100526
+>17:49:09 AutoIT3.exe ended.rc:0
>Exit code: 0 Time: 18.184

Rest à étudier le problème de la boucle.

Bonsoir à tous, j'ai résolu mon problème, il suffisait de lire les dates au bon endroit du code !

Ci après le code de la GUI fonctionnel :

► Afficher le texte

Code : Tout sélectionner

;===============
;== Variables ==
;===============
#include <DateTimeConstants.au3>
#include <GuiListView.au3>
#include <GUIConstantsEx.au3>
#include <Constants.au3>
#include<File.au3>

$Chemin = @ScriptDir & "\Traites\"

;================================================
;== Début de l'Interface Graphique Utilisateur ==
;================================================
$Reprise = GUICreate ("Reprise Envoi Fichiers RUB", 280, 500)
$Group0 = GUICtrlCreateGroup ("Dossier", 10, 10, 260, 50)
GUICtrlSetFont (-1, 10, 800, 0, "Comic Sans MS")
GUICtrlSetColor (-1, 0x0000FF)
$g0_Label1 = GUICtrlCreateLabel (@ScriptDir & "\Traites\*.old" , 20, 35, 240, 20)
GUICtrlSetFont (-1, 10, 400, 0)
$Group1 = GUICtrlCreateGroup ("Selection des fichiers", 10, 70, 260, 380)
GUICtrlSetFont (-1, 10, 800, 0, "Comic Sans MS")
GUICtrlSetColor (-1, 0x0000FF)
$g1_Label1 = GUICtrlCreateLabel ("Fichiers créés entre : ", 20, 95, 150, 20)
GUICtrlSetFont (-1, 10, 400, 0)
$g1_Label2 = GUICtrlCreateLabel ("Date de Début :", 20, 120, 110, 20)
GUICtrlSetFont (-1, 10, 400, 0)
$g1_Label3 = GUICtrlCreateLabel ("Date de Fin :", 150, 120, 100, 20)
GUICtrlSetFont (-1, 10, 400, 0)
$g1_Date1 = GUICtrlCreateDate ("", 20, 140, 100, 20, $DTS_SHORTDATEFORMAT)                                      ; correspond à la date de début de recherche
$g1_Date2 = GUICtrlCreateDate ("", 150, 140, 100, 20, $DTS_SHORTDATEFORMAT)                                     ; correspond à la date de fin de recherche
$g1_List1 = GUICtrlCreateListView ("Fichier | Date",20, 170, 240, 200, $LVS_SHOWSELALWAYS, $LVS_EX_CHECKBOXES)  ; céation listview avec cases à cocher
GUICtrlSetFont (-1, 10, 400, 0, "Comic Sans MS")
GUICtrlSetColor (-1, 0x0000FF)
_GUICtrlListView_SetColumnWidth ($g1_List1, 0, 110)
_GUICtrlListView_SetColumnWidth ($g1_List1, 1, 110)
_GUICtrlListView_SetBkColor ($g1_List1, $CLR_MONEYGREEN)
_GUICtrlListView_SetTextColor ($g1_List1, $CLR_BLACK)
_GUICtrlListView_SetTextBkColor ($g1_List1, $CLR_MONEYGREEN)
$g1_Radio1 = GUICtrlCreateRadio ("Sélectionner tout", 70, 380, 120, 15)
GUICtrlSetFont (-1, 10, 400, 0)
GUICtrlSetState (-1, $GUI_DISABLE)
$g1_Btn0 = GUICtrlCreateButton( "Rafraîchir", 30, 410, 95, 30)
GUICtrlSetFont (-1, 10, 800, 0, "Comic Sans MS")
$g1_Btn1 = GUICtrlCreateButton ("Réinitialiser", 155, 410, 95, 30)
GUICtrlSetFont (-1, 10, 800, 0, "Comic Sans MS")
$Valider = GUICtrlCreateButton ("Valider", 30, 460, 95, 30)
GUICtrlSetFont(-1, 10, 800, 0, "Comic Sans MS")
$Annuler = GUICtrlCreateButton ("Annuler", 155, 460, 95, 30)
GUICtrlSetFont(-1, 10, 800, 0, "Comic Sans MS")
GUISetState (@SW_SHOW, $Reprise)
;=========================
;== Début du traitement ==
;=========================
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Annuler
            Exit
        Case $g1_Radio1
            _GUICtrlListView_SetItemChecked ($g1_List1, -1)
        Case $g1_Btn0
            GUICtrlSetState ($g1_Radio1, $GUI_ENABLE)
            $dd = GUICtrlRead ($g1_Date1)
            $add = StringRight ($dd, 4)
            $mdd = StringMid ($dd, 4, 2)
            $jdd = StringLeft ($dd, 2)
            $dateD = $add & $mdd & $jdd
            $df = GUICtrlRead ($g1_Date2)
            $adf = StringRight ($df, 4)
            $mdf = StringMid ($df, 4, 2)
            $jdf = StringLeft ($df, 2)
            $dateF = $adf & $mdf & $jdf
            $search = FileFindFirstFile ($chemin & "*.old")
            While 1
                $file = FileFindNextFile ($search)
                If @error Then ExitLoop
                $t = FileGetTime ($chemin & $file, 0, 1)
                $a = StringLeft ($t, 4)
                $m = StringLeft (StringTrimLeft ($t, 4), 2)
                $j = StringRight (StringTrimRight ($t, 6), 2)
                $dateM = $a & $m & $j
                $date = $j & "/" & $m & "/" & $a
                If ($dateM > $dateD And $dateM < $dateF) Then
                    GUICtrlCreateListViewItem ( $file & "|" & $date, $g1_List1)
                EndIf
            Wend
        Case $g1_Btn1
            GUICtrlSetData ($g1_Date1, "")
            GUICtrlSetData ($g1_Date2, "")
            _GUICtrlListView_DeleteAllItems ($g1_List1)
            GUICtrlSetState ($g1_Radio1, $GUI_UNCHECKED)
            GUICtrlSetState ($g1_Radio1, $GUI_DISABLE)
        Case $Valider
            GUISetState (@SW_HIDE)
            $Liste = FileOpen (@ScriptDir & "\Resultats\Resultat.txt", 2)
            $ListNb = _GUICtrlListView_GetItemCount ($g1_List1)
            For $i = 0 to $ListNb - 1
                $ItemText = _GUICtrlListView_GetItemText ($g1_List1, $i)
                $ItemState = _GUICtrlListView_GetItemChecked ($g1_List1, $i)
                If $ItemState = 1 Then
                    $Result0 = $ItemText
                    FileWriteLine ($Liste, $Result0)
                EndIf
            Next
            FileClose ($Liste)
            Exit
    EndSwitch
WEnd

Je vous joint une image de la GUI :

AutoIt Français

[R] Problème d'affichage dans une listview

[R] Problème d'affichage dans une listview

Re: [..] Pb affichge dans une listview

Re: [..] Pb affichge dans une listview

Re: [..] Problème d'affichage dans une listview