AutoIt Français

Code : Tout sélectionner

HotKeySet('g', 'get')

Global $CTRLS_INITIALIZED = False
Global $Z_Color
Global $Z_Label

$gui = GUICreate('')
GUISetState()

$zoom = zoom2($gui, 25, 25, 20, 20, MouseGetPos(0) - 5, MouseGetPos(1) - 5)

While 1
    Sleep(5000)
WEnd

Func get()
    $zoom = zoom2($gui, 25, 25, 20, 20, MouseGetPos(0) - 5, MouseGetPos(1) - 5, $zoom)
EndFunc   ;==>get



Func zoom2(ByRef $Z_Gui, $Z_NbX, $Z_NbY, $Z_LX, $Z_LY, $Z_CX, $Z_CY, $Z_Maj = "")
    Local $Z_winpos = WinGetPos($Z_Gui)
    WinMove($Z_Gui, "", $Z_winpos[0], $Z_winpos[1], $Z_NbX * $Z_LX, $Z_NbY * $Z_LY)
    GUISwitch($Z_Gui)

    If $Z_Maj = "" Then
        Dim $Z_Color[$Z_NbX][$Z_NbY]
        Dim $Z_Label[$Z_NbX][$Z_NbY]
        For $Z_i = 0 To $Z_NbX - 1
            For $Z_u = 0 To $Z_NbY - 1
                $Z_Color[$Z_i][$Z_u] = PixelGetColor($Z_i + $Z_CX, $Z_u + $Z_CY)
                If Not $CTRLS_INITIALIZED Then
                    $Z_Label[$Z_i][$Z_u] = GUICtrlCreateLabel('', $Z_i * $Z_LX, $Z_u * $Z_LY, $Z_LX, $Z_LY)
                EndIf
                GUICtrlSetBkColor($Z_Label[$Z_i][$Z_u], $Z_Color[$Z_i][$Z_u])
            Next
        Next
    Else
        Dim $Z_Color[$Z_NbX][$Z_NbY]
        $Z_Label = $Z_Maj
        For $Z_i = 0 To $Z_NbX - 1
            For $Z_u = 0 To $Z_NbY - 1
                $Z_Color[$Z_i][$Z_u] = PixelGetColor($Z_i + $Z_CX, $Z_u + $Z_CY)
                If Not $CTRLS_INITIALIZED Then
                    $Z_Label[$Z_i][$Z_u] = GUICtrlCreateLabel('', $Z_i * $Z_LX, $Z_u * $Z_LY, $Z_LX, $Z_LY)
                EndIf
                GUICtrlSetBkColor($Z_Label[$Z_i][$Z_u], $Z_Color[$Z_i][$Z_u])
            Next
        Next
    EndIf
    $CTRLS_INITIALIZED = True
    Return $Z_Label
EndFunc   ;==>zoom2

Code : Tout sélectionner

HotKeySet('g','get')
Global $Z_Label
Global $Z_Color
Global $Z_Color_old
$gui = GUICreate('')
GUISetState()
Global $zoom

$zoom = zoom2($gui, 25,25,20,20,MouseGetPos(0)-5,MouseGetPos(1)-5)

While   1
    Sleep(5000)
WEnd

Func get()
    $zoom = zoom2($gui, 25,25,20,20,MouseGetPos(0)-5,MouseGetPos(1)-5, $zoom)   
EndFunc



Func zoom2(ByRef $Z_Gui, $Z_NbX, $Z_NbY, $Z_LX, $Z_LY, $Z_CX, $Z_CY, $Z_Maj = "")
    Local $Z_winpos = WinGetPos($Z_Gui)
    WinMove($Z_Gui,"" ,$Z_winpos[0],$Z_winpos[1] ,$Z_NbX * $Z_LX, $Z_NbY * $Z_LY)
    GUISwitch($Z_Gui)
   
    If $Z_Maj = "" Then
        Dim $Z_Color[$Z_NbX][$Z_NbY]
        Dim $Z_Color_old[$Z_NbX][$Z_NbY]
        Dim $Z_Label[$Z_NbX][$Z_NbY]
        For $Z_i = 0 To $Z_NbX -1
            For $Z_u = 0 To $Z_NbY -1
                $Z_Color[$Z_i][$Z_u] = PixelGetColor($Z_i + $Z_CX, $Z_u + $Z_CY)
                $Z_Label[$Z_i][$Z_u] = GUICtrlCreateLabel('', $Z_i * $Z_LX, $Z_u * $Z_LY, $Z_LX, $Z_LY)
                GUICtrlSetbkColor($Z_Label[$Z_i][$Z_u], $Z_Color[$Z_i][$Z_u])
                $Z_Color_old[$Z_i][$Z_u]=$Z_Color[$Z_i][$Z_u]
            Next
        Next
        Return $Z_Label
    Else
        Dim $Z_Color[$Z_NbX][$Z_NbY]
        $Z_Label = $Z_Maj
        For $Z_i = 0 To $Z_NbX -1
            For $Z_u = 0 To $Z_NbY -1
                $Z_Color[$Z_i][$Z_u] = PixelGetColor($Z_i + $Z_CX, $Z_u + $Z_CY)
                ;$Z_Label[$Z_i][$Z_u] = GUICtrlCreateLabel('', $Z_i * $Z_LX, $Z_u * $Z_LY, $Z_LX, $Z_LY)
                If $Z_Color_old[$Z_i][$Z_u]<>$Z_Color[$Z_i][$Z_u] Then
                    GUICtrlSetbkColor($Z_Label[$Z_i][$Z_u], $Z_Color[$Z_i][$Z_u])
                    $Z_Color_old[$Z_i][$Z_u]=$Z_Color[$Z_i][$Z_u]
                EndIf
            Next
        Next
        Return $Z_Label
    EndIf
EndFunc
 

Code : Tout sélectionner

#include <GDIPlus.au3>
#include <WindowsConstants.au3>

HotKeySet("{F5}", "OnAutoItExit")

Global Const $MagZoom = 2
Global Const $MagWidth = $MagZoom * 112
Global Const $MagHeight = $MagZoom * 80

Global $dll[2]
$dll[0] = DllOpen("user32.dll")
$dll[1] = DllOpen("gdi32.dll")

Global $GUI, $TrayMenuExit, $h_graphics
$GUI = GUICreate("Zoom x" & $MagZoom & " Au3", $MagWidth, $MagHeight, MouseGetPos(0), MouseGetPos(1), $WS_POPUP + $WS_BORDER, $WS_EX_TOPMOST)
$TrayMenuExit = TrayCreateItem("Quitter")

GUISetState(@SW_SHOW)
TraySetState()
_GDIPlus_Startup()
$h_graphics = _GDIPlus_GraphicsCreateFromHWND($GUI)

Global $LastPos[2] = [0, 0], $MousePos, $msg
While 1
    $MousePos = MouseGetPos()
    $msg = TrayGetMsg()
    MAG()
    
    Select
        Case $LastPos[0] <> $MousePos[0] Or $LastPos[1] <> $MousePos[1]
            $right = $MousePos[0] + $MagWidth * 1.25
            $bottom = $MousePos[1] + $MagHeight * 1.25
            Select
                Case $right < @DesktopWidth And $bottom < @DesktopHeight
                    WinMove("Zoom x" & $MagZoom & " Au3", "", $MousePos[0] + $MagWidth / 4, $MousePos[1] + $MagHeight / 4)
                Case $right >= @DesktopWidth And $bottom < @DesktopHeight
                    WinMove("Zoom x" & $MagZoom & " Au3", "", $MousePos[0] - $MagWidth * 1.25, $MousePos[1] + $MagHeight / 4)
                Case $right < @DesktopWidth And $bottom >= @DesktopHeight
                    WinMove("Zoom x" & $MagZoom & " Au3", "", $MousePos[0] + $MagWidth / 4, $MousePos[1] - $MagHeight * 1.25)
                Case $right >= @DesktopWidth And $bottom >= @DesktopHeight
                    WinMove("Zoom x" & $MagZoom & " Au3", "", $MousePos[0] - $MagWidth * 1.25, $MousePos[1] - $MagHeight * 1.25)
            EndSelect
            $LastPos[0] = $MousePos[0]
            $LastPos[1] = $MousePos[1]
        Case $msg = $TrayMenuExit
            OnAutoItExit()
    EndSelect
    
    Sleep(10)
WEnd


Func MAG()
    Local $DeskHDC, $GUIHDC, $left, $top, $right, $bottom
    
    $DeskHDC = DllCall($dll[0], "int", "GetDC", "hwnd", 0)
    $GUIHDC = DllCall($dll[0], "int", "GetDC", "hwnd", $GUI)
    If Not @error Then
        $left = $MousePos[0] - $MagWidth / (2 * $MagZoom)
        $top = $MousePos[1] - $MagHeight / (2 * $MagZoom)
        $right = $MousePos[0] + $MagWidth / (2 * $MagZoom)
        $bottom = $MousePos[1] + $MagHeight / (2 * $MagZoom)
        
        If $left < 0 Then
            $left = 0
        ElseIf $right > @DesktopWidth Then
            $left = @DesktopWidth - $MagWidth / $MagZoom
        EndIf
        If $top < 0 Then
            $top = 0
        ElseIf $bottom > @DesktopHeight Then
            $top = @DesktopHeight - $MagHeight / $MagZoom
        EndIf
        
        DllCall($dll[1], "int", "StretchBlt", "int", $GUIHDC[0], "int", 0, "int", 0, "int", $MagWidth, "int", $MagHeight, "int", $DeskHDC[0], "int", $left, "int", $top, "int", $MagWidth / $MagZoom, "int", $MagHeight / $MagZoom, "long", $SRCCOPY)
        DllCall($dll[0], "int", "ReleaseDC", "int", $DeskHDC[0], "hwnd", 0)
        DllCall($dll[0], "int", "ReleaseDC", "int", $GUIHDC[0], "hwnd", $GUI)
    EndIf
    If $left < 0 And $MousePos[0] < $LastPos[0] Then
        _GDIPlus_GraphicsFillRect($h_graphics, $left * $MagZoom, 0, $LastPos[0] - $MousePos[0], $MagHeight)
    EndIf
EndFunc   ;==>MAG


Func OnAutoItExit()
    DllClose($dll[0])
    DllClose($dll[1])
    _GDIPlus_GraphicsDispose($h_graphics)
    _GDIPlus_Shutdown()
    Exit
EndFunc   ;==>OnAutoItExit