AutoIt Français

Bonjour.
J'utilise régulierement ce site pour mes petits problémes Autoit.
En retour, une petite contribution : Modifier la résolution de son écran automatiquement.
Je m'en sert pour avoir le maximum de données lorsque je capture des données d'un écran Web.
La source vient du site américain; j'ai simplement francisé pour le Windows français.
Testé sur Windows XP.
Cordialement.

Code : Tout sélectionner

;=========================== Résolution souhaitée
     $res = "1280 par 960 pixels"
;=========================== (Attention aux espaces)

run("control desk.cpl")  ; Execution du programme de paramètrage Ecran
winwait("Propriétés de Affichage")

for $i = 1 to 4    ;  4 onglets
   controlcommand("Propriétés de Affichage", "", "SysTabControl321", "TabRight")   ; onglet  Paramètres
next
winwait("Propriétés de Affichage", "Paramètres")  ; Settings

$controltext = controlgettext("Propriétés de Affichage", "Paramètres", "Static8")  ; Display Properties"
while $controltext <> $res ; Déplacement vers la droite
  controlsend("Propriétés de Affichage", "", "msctls_trackbar321", "{RIGHT}")
  $lastcontroltext = $controltext
  $controltext = controlgettext("Propriétés de Affichage", "Paramètres", "Static8")
  if $lastcontroltext = $controltext then exitloop
wend

while $controltext <> $res ; Déplacement vers la gauche
  controlsend("Propriétés de Affichage", "", "msctls_trackbar321", "{LEFT}")
  $lastcontroltext = $controltext
  $controltext = controlgettext("Propriétés de Affichage", "Paramètres", "Static8")
  if $lastcontroltext = $controltext then exitloop
wend


if $controltext <> $res then
  msgbox(4096, "Résolution", "  Echec", 4)
  exit(1)
else
  msgbox(4096, "Résolution", "  Réussite", 2)
endif

controlclick("Propriétés de Affichage", "", "OK")

winwait("Paramètres du moniteur", "")  ; Monitor Settings
controlclick("Paramètres du moniteur", "", "&Oui" )  ; &Yes

Salut!

C'est cool, mais j'aime bien éviter d'utiliser les interfaces graphiques.

J'ai trouvé sur le site anglophone la fonction qui est inclues dans ce script, j'ai ajouté la possibilité d'utiliser la largeur d'écran comme paramètre, mais il y a 1001 utilisations possible:

► Afficher le texte

Code : Tout sélectionner

#NoTrayIcon
#cs
ChangeRes.exe
Pour changer la résolution de l'écran
Doit être appellé tel que :  ChangeRes.exe paramètre      (800, 1024 ou 1280)
                               ex: ChangeRes 1280      

#ce


    Select
        Case $CmdLine[1] = 800
        $iWidth = 800
        $iHeight = 600

        Case $CmdLine[1] = 1024
            $iWidth = 1024
            $iHeight = 768

        Case $CmdLine[1] = 1280
            $iWidth = 1280
            $iHeight = 1024

    Case Else
        $iWidth = 1024
            $iHeight = 768


    EndSelect


$vRes = _ChangeScreenRes($iWidth, $iHeight);, $iBitsPP, $iRefreshRate)
If @error Then
    MsgBox(262160, "Problème!", "Le changement de résolution n'a pas fonctionné.")
EndIf
Exit

Func _ChangeScreenRes($i_Width = @DesktopWidth, $i_Height = @DesktopHeight, $i_BitsPP = @DesktopDepth, $i_RefreshRate = @DesktopRefresh)
    Local Const $DM_PELSWIDTH = 0x00080000
    Local Const $DM_PELSHEIGHT = 0x00100000
    Local Const $DM_BITSPERPEL = 0x00040000
    Local Const $DM_DISPLAYFREQUENCY = 0x00400000
    Local Const $CDS_TEST = 0x00000002
    Local Const $CDS_UPDATEREGISTRY = 0x00000001
    Local Const $DISP_CHANGE_RESTART = 1
    Local Const $DISP_CHANGE_SUCCESSFUL = 0
    Local Const $HWND_BROADCAST = 0xffff
    Local Const $WM_DISPLAYCHANGE = 0x007E
    If $i_Width = "" Or $i_Width = -1 Then $i_Width = @DesktopWidth ; default to current setting
    If $i_Height = "" Or $i_Height = -1 Then $i_Height = @DesktopHeight ; default to current setting
    If $i_BitsPP = "" Or $i_BitsPP = -1 Then $i_BitsPP = @DesktopDepth ; default to current setting
    If $i_RefreshRate = "" Or $i_RefreshRate = -1 Then $i_RefreshRate = @DesktopRefresh ; default to current setting
    Local $DEVMODE = DllStructCreate("byte[32];int[10];byte[32];int[6]")
    Local $B = DllCall("user32.dll", "int", "EnumDisplaySettings", "ptr", 0, "long", 0, "ptr", DllStructGetPtr($DEVMODE))
    If @error Then
        $B = 0
        SetError(1)
        Return $B
    Else
        $B = $B[0]
    EndIf
    If $B <> 0 Then
        DllStructSetData($DEVMODE, 2, BitOR($DM_PELSWIDTH, $DM_PELSHEIGHT, $DM_BITSPERPEL, $DM_DISPLAYFREQUENCY), 5)
        DllStructSetData($DEVMODE, 4, $i_Width, 2)
        DllStructSetData($DEVMODE, 4, $i_Height, 3)
        DllStructSetData($DEVMODE, 4, $i_BitsPP, 1)
        DllStructSetData($DEVMODE, 4, $i_RefreshRate, 5)
        $B = DllCall("user32.dll", "int", "ChangeDisplaySettings", "ptr", DllStructGetPtr($DEVMODE), "int", $CDS_TEST)
        If @error Then
            $B = -1
        Else
            $B = $B[0]
        EndIf
        Select
            Case $B = $DISP_CHANGE_RESTART
                $DEVMODE = ""
                Return 2
            Case $B = $DISP_CHANGE_SUCCESSFUL
                DllCall("user32.dll", "int", "ChangeDisplaySettings", "ptr", DllStructGetPtr($DEVMODE), "int", $CDS_UPDATEREGISTRY)
                DllCall("user32.dll", "int", "SendMessage", "hwnd", $HWND_BROADCAST, "int", $WM_DISPLAYCHANGE, _
                        "int", $i_BitsPP, "int", $i_Height * 2 ^ 16 + $i_Width)
                $DEVMODE = ""
                Return 1
            Case Else
                $DEVMODE = ""
                SetError(1)
                Return $B
        EndSelect
    EndIf
EndFunc ;==>_ChangeScreenRes

à pluche

Hello,

j'aime le code de tplanet, car c'est que du script et on utilise pas les fenêtre. Car selon les systèmes, ce n'est pas applicable, par exemple moi j'ai 5 onglets et pas forcément une machine en français. Je sais, on peut modifier dans le code (ce que j'ai fait pour tester), mais ce n'est pas assez générique et il y aurait trop de tests à faire.

~~Pour compléter le code de tplanet, il y a-t-il la possibilité de connaître la résolution actuelle de l'affichage?~~ J'ai trouvé : @DesktopWidth

les macros @DesktopWidth et @DesktopHeight.

Merci, j'ai édité mon topic, j'avais trouvé.

AutoIt Français

[Ex] Résolution Ecran

[Ex] Résolution Ecran

Re: [Ex] Résolution Ecran

Re: [Ex] Résolution Ecran

Re: [Ex] Résolution Ecran

Re: [Ex] Résolution Ecran