AutoIt Français

Bonjour,

Sur mon projet de script, j'ai un problème concernant les boutons "Valider" "Annuler et la croix pour la "fermeture de l'applet :

-Les bouton n'ont aucune action, seul moyen pour clore : le gestionnaire des tâches ...

bref une demi journée de retard, je commence à tourné en rond....
ci joint le script :

► Afficher le texte

Code : Tout sélectionner


#cs ----------------------------------------------------------------------------

    AutoIt Version : 3.3.0.0
    Auteur:         hakim

    Fonction du Script : lancement du process de connexion VPN + Mapping des lecteurs reseaux

#ce ----------------------------------------------------------------------------

#NoTrayIcon
#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>
#include <EditConstants.au3>
#include <Array.au3>
#include <IE.au3>
#include <WindowsConstants.au3>


Example()

Func Example()
  
    Local $Button_1, $Button_2, $Button_3
    Dim $username
    Dim $VPNSRV
    Dim $Program
    Dim $params
    Dim $Password

        ;reinitialisation des variables

    $username = ""
    $Password = ""
    $VPNSRV = ""
    $Program = ""
    $params = ""
    

;Définition de la boite de dialogue

GUICreate("Connexion VPN  - wolrd company",375,500)
GUICtrlCreateLabel ("URL du serveur VPN:",10,15)
$VPNSRV = GUICtrlCreateInput ("adress.serveur.com:Nport",150,10,200 )           ;saisie : serveur vpn 
GUICtrlCreateLabel ("Login :",10,45)                                                    ;saisie :  username, password
$username = GUICtrlCreateInput ("Saisissez ici le nom de l'utilisateur",150,40,200,$username)       ;

GUICtrlCreateLabel ("Mot de passe :",10,75)                                             ;   
$Password = GUICtrlCreateInput ("",150,70,200,20,$ES_PASSWORD)                          ;

;fin saisie 

;checkbox choix serveur
GuiCtrlCreateGroup("Veuillez cocher votre site  de travail: R:\", 5, 240, 366, 90)
$Checkbox1 = GUICtrlCreateCheckbox("Serveur A", 32,140)
$Checkbox2 = GUICtrlCreateCheckbox("Serveur B",250, -1 )
$Checkbox3 = GUICtrlCreateCheckbox("Serveur C", 32, 190)
$Checkbox4 = GUICtrlCreateCheckbox("Serveur D", 250, -1)
GUICtrlCreateGroup ("",-99,-99,1,1)  ;close group

;fin  checkbox


;bouton Choix de connexion : 3G ADSL ....

GuiCtrlCreateGroup("Veuillez cocher le serveur ou se trouve vos données de travail: R:\", 5, 100, 366, 120)
$Button_1 = GUICtrlCreateCheckbox("3G", 32,260,75)
$Button_2 = GUICtrlCreateCheckbox("ADSL",150,260, -1 )
$Button_3 = GUICtrlCreateCheckbox("Bureau ", 260, -1)
GUICtrlCreateGroup ("",-99,-99,1,1)  ;close group

;fin bouton

;bouton OK / annuler
$Valider = GUICtrlCreateButton("Valider",100,450,75,25,-1)
$Annuler = GUICtrlCreateButton("Annuler",200,450,75,25,-1)

;fin bouton annuler / ok
    
    GUISetState()   ; will display an  dialog box with 2 button

; Run the GUI until the dialog is closed

    While 1
        $msg = GUIGetMsg(1)
        
            select  
            
                Case $msg = $GUI_EVENT_CLOSE 
                    Exit    
                       
                        ElseIf $Button_2 = true then 
                        RunWait('regedit /s "C:\Program Files\Fortinet\SSLVPNclient\3G\adsl.reg"') ;Lance l'application 
                         MsgBox(64, 'Vérification', 'présrequis ADSL validés', @CRLF , 2) ;valide l'installation du .reg
                                               
                    
                                Elseif $Button_3 = true then 
                                MsgBox(0, 'Vérification', 'Fonction non implémentée',2)
                    
                
                                    ElseIf      
                                    $Checkbox1 = true then   
                                    DriveMapAdd ("R:", "\\serveurC,8)       ; MAP DFS A
                            
            
                                        ElseIf $Checkbox2 = true then   
                                        DriveMapAdd ("R:", "\\serveurB,8)        ;MAP DFS B
            
                            
                                        ElseIf $Checkbox3 = true then   
                                        DriveMapAdd ( "R:", "\\serveurC,8)  ;MAP DFS C
                                
                                        ElseIf $Checkbox4 = true then   
                                        DriveMapAdd ("R:", \\serveurD,8)       ;MAP DFS D
                                             
$Program = 'C:\Program Files\Fortinet\SSLVPNclient\FortiSSLVPNclient.exe'
$params = "connect  -h " & GUICtrlRead($VPNSRV) & " -u """ & GUICtrlRead($username,0) & """:"""  & GUICtrlRead($Password) & """"
ShellExecute ($Program, $params)
    EndIf

            Endselect       
        wend                           

EndFunc   

adresseIPcheck()

func adresseIPcheck()

Local $ip1=@IPAddress1

If StringInStr($ip1,"x.X.Y.") Then 
    ;MsgBox(64, "","connexion vpn établie, connexion de votre M: : "&@CRLF & $ip1, 0,5)
    DriveMapAdd ( "M:", @homeshare , 8 )                ;Map répertoire privé de l'utilisateur
    
else 
    MsgBox(48, "","connexion vpn non établie : "&@CRLF & $ip1, 0,5 )
    

EndIf

EndFunc

Merci de m'aider, le cas échéant me mettrre sur la piste .

ps: je fais un max d'effort pour comprendre, mais là y a un truc qui m'échappe :/

hakim !

Bonjour à toi,

Ne pouvant pas tester ton script je l'ai regardé, et je pense que le problème vient de la première ligne dans ta boucle infinie:

Code : Tout sélectionner

$msg = GUIGetMsg(1)

Je pense qu'il faut enlever le 1 entre parenthèse:

Code : Tout sélectionner

$msg = GUIGetMsg()

Comme ceci, tu n'as créé qu'une seule GUI, tu n'as pas de fenêtres enfants donc pas besoin de paramètre.

bonsoir, effectivement il y a ceci comme problème.
Maintenant, il y en a d'autres ^^
Pour savoir si une checkbox, ou une radiobox est cocher, le test n'est pas if $ctrl = true, mais if GUICtrlRead($ctrl) = $GUI_CHECKED

j'ai remodeler le script d'origine pour clarifier la boucle principale de la GUI pour la réduire en taille, en isolant la partie sélection du serveur dans une fonction, et montage du lecteur réseau dans une autre. Du coups j'ai du rendre certaine variable un peu plus globale ... Mais bon ceci n'est qu'une suggestion.
De même j'ai remplacé les checkbox par des radiobox, comme le choix à l'air exclusif (ie, un serveur la fois), ces dernières sont plus adaptées

► Afficher le texte

Code : Tout sélectionner

#cs ----------------------------------------------------------------------------
    AutoIt Version : 3.3.0.0
    Auteur:         hakim
    Fonction du Script : lancement du process de connexion VPN + Mapping des lecteurs reseaux
#ce ----------------------------------------------------------------------------
#NoTrayIcon
#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>
#include <EditConstants.au3>
#include <Array.au3>
#include <IE.au3>
#include <WindowsConstants.au3>
Dim $Button_1,$Button_2,$Button_3
Dim $Checkbox1,$Checkbox2,$Checkbox3,$Checkbox4
Dim $VPNSRV,$username,$Password
Example()
Func Example()

 ;reinitialisation des variables
    $username = ""
    $Password = ""
    $VPNSRV = ""
    $Program = ""
    $params = ""

;Définition de la boite de dialogue
GUICreate("Connexion VPN  - wolrd company",375,500)
GUICtrlCreateLabel ("URL du serveur VPN:",10,15)
$VPNSRV = GUICtrlCreateInput ("adress.serveur.com:Nport",150,10,200 )           ;saisie : serveur vpn
GUICtrlCreateLabel ("Login :",10,45)                                                    ;saisie :  username, password
$username = GUICtrlCreateInput ("Saisissez ici le nom de l'utilisateur",150,40,200,$username)       ;
GUICtrlCreateLabel ("Mot de passe :",10,75)                                             ;
$Password = GUICtrlCreateInput ("",150,70,200,20,$ES_PASSWORD)                          ;
;fin saisie
;checkbox choix serveur
GuiCtrlCreateGroup("Veuillez cocher votre site  de travail: R:\", 5, 240, 366, 90)
$Checkbox1 = GUICtrlCreateRadio("Serveur A", 32,140,110)
$Checkbox2 = GUICtrlCreateRadio("Serveur B",250, 140,110 )
$Checkbox3 = GUICtrlCreateRadio("Serveur C", 32, 190,110)
$Checkbox4 = GUICtrlCreateRadio("Serveur D", 250, 190,110)
GUICtrlCreateGroup ("",-99,-99,1,1)  ;close group
;fin  checkbox

;bouton Choix de connexion : 3G ADSL ....
GuiCtrlCreateGroup("Veuillez cocher le serveur ou se trouve vos données de travail: R:\", 5, 100, 366, 120)
$Button_1 = GUICtrlCreateRadio("3G", 32,260,80)
$Button_2 = GUICtrlCreateRadio("ADSL",150,260, 80 )
$Button_3 = GUICtrlCreateRadio("Bureau ", 260,260, 80)
GUICtrlCreateGroup ("",-99,-99,1,1)  ;close group
;fin bouton
;bouton OK / annuler
$Valider = GUICtrlCreateButton("Valider",100,450,75,25)
$Annuler = GUICtrlCreateButton("Annuler",200,450,75,25)
;fin bouton annuler / ok

    GUISetState()   ; will display an  dialog box with 2 button
; Run the GUI until the dialog is closed
    While 1
        $msg = GUIGetMsg()

            select

                Case $msg = $GUI_EVENT_CLOSE
                    Exit
                Case $msg = $Annuler
     Exit
    Case $msg = $Valider
     If Not Set_Server() Then ContinueLoop
     Connect_drive()

            Endselect
        wend
EndFunc
adresseIPcheck()
Func Set_Server()
 If GUICtrlRead($Button_1) = $GUI_CHECKED Then
  MsgBox(0, 'Vérification', 'Fonction non implémentée',2)
  Return 0
 ElseIf GUICtrlRead($Button_2) = $GUI_CHECKED Then
  RunWait('regedit /s "'&@ProgramFilesDir&'\Fortinet\SSLVPNclient\3G\adsl.reg"') ;Lance l'application
  MsgBox(64, 'Vérification', 'présrequis ADSL validés', @CRLF , 2) ;valide l'installation du .reg
  Return 1
 ElseIf GUICtrlRead($Button_3) = $GUI_CHECKED Then
  MsgBox(0, 'Vérification', 'Fonction non implémentée',2)
  Return 0
 Else
  MsgBox(48,'Paramètre manquant','Merci de cocher une case de chaque groupe svp')
  Return 0
 EndIf
EndFunc

Func Connect_drive()
 If GUICtrlRead($Checkbox1) = $GUI_CHECKED Then
  DriveMapAdd ("R:", "\\serveurC",8)       ; MAP DFS A
 ElseIf GUICtrlRead($Checkbox2) = $GUI_CHECKED then
     DriveMapAdd ("R:", "\\serveurB",8)        ;MAP DFS B
    ElseIf  GUICtrlRead($Checkbox3) = $GUI_CHECKED then
  DriveMapAdd ( "R:", "\\serveurC",8)  ;MAP DFS C
 ElseIf  GUICtrlRead($Checkbox4) = $GUI_CHECKED then
  DriveMapAdd ( "R:", "\\serveurD",8)  ;MAP DFS D
 Else
  MsgBox(48,'Paramètre manquant','Merci de cocher une case de chaque groupe svp')
 Return 0
 EndIf
 $Program = '"'&@ProgramFilesDir&'\Fortinet\SSLVPNclient\FortiSSLVPNclient.exe"'
 $params = "connect  -h " & GUICtrlRead($VPNSRV) & " -u """ & GUICtrlRead($username,0) & """:"""  & GUICtrlRead($Password) & """"
 ShellExecute ($Program, $params)
    Return 1

EndFunc
func adresseIPcheck()
Local $ip1=@IPAddress1
If StringInStr($ip1,"x.X.Y.") Then
    ;MsgBox(64, "","connexion vpn établie, connexion de votre M: : "&@CRLF<mailto:&@CRLF> & $ip1, 0,5)
    DriveMapAdd ( "M:", @homeshare , 8 )                ;Map répertoire privé de l'utilisateur

else
    MsgBox(48, "","connexion vpn non établie : "&@CRLF&@CRLF & $ip1, 0,5 )

EndIf
EndFunc

Bonne continuation

Oui effectivement...
Je trouvais juste la structure du code pas très clair mais après j'ai pas fait attention je suis resté sur le problème des boutons qui n'exécute rien

Heureusement il y a des gens derrières qui regardent le code entier!

Bonjour,

Merci beaucoup pour les corrections et les informations.
j'ai gardé l'ancien script, pour m'amuser avec et générer des erreurs, pour m'entrainer.
Maintenant je vais essayer de mettre en place une fermeture du script après que les tâches est été effectuées.

Encore merci pour votre aide.
Vraiment un site d'entraide génial !

Pas de soucis!

Si tu as d'autres soucis n'hésite pas!

AutoIt Français

[R] Fermeture, annulation et cloture impossible

[R] Fermeture, annulation et cloture impossible

Re: [..]fermeture, annulation et cloture impossible

Re: [..]fermeture, annulation et cloture impossible

Re: [..]fermeture, annulation et cloture impossible

[R] Fermeture, annulation et cloture impossible

Re: [R] Fermeture, annulation et cloture impossible