AutoIt Français • [R] Filtrer les lignes d'un tableau

Page 1 sur 2

[R] Filtrer les lignes d'un tableau

Posté : mer. 29 avr. 2009 19:56

par pierrotm777

Bonjour à tous,

Pour ceux qui seraient intéréssés, ce porgramme permet de convertir des fichier .csv format GARMIN en un format compatible
avec un programme , "speedlimite.exe" ,http://www.mp3car.com/vbulletin/rr-plug ... igger.html , utilisé en parallèle avec RideRunner, frontend pour CarPc .

Je voudrais filtrer certaines lignes d'un fichier passant par un tableau qui le reformate (Merci Tlem) en fonction d'un combo .

Voici donc mon Gui fonctionnel :

► Afficher le texte

Code : Tout sélectionner

;Onglet Trapster
GUICtrlCreateTabItem("Trapster")
GUICtrlSetFont(-1, 8, 800, 0, "Arial")
$Annuler3 = GUICtrlCreateButton($aLang[4], 392, 296, 75, 25)
$OK3 = GUICtrlCreateButton("OK", 480, 296, 75, 25)
$Group5 = GUICtrlCreateGroup($aLang[5], 8, 20, 297, 170)
$Fic_RF3 = GUICtrlCreateInput("", 16, 63, 250, 21)
$Choix_RF3 = GUICtrlCreateButton("...", 270, 63, 20, 20)
$Lb_RF3 = GUICtrlCreateLabel($aLang[6]&" (speed-trap):", 16, 39, 400, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Fic_RFR3 = GUICtrlCreateInput("", 16, 119, 250, 20)
$Choix_RFR3 = GUICtrlCreateButton("...", 270, 119, 20, 20)
$Lb_RFR3 = GUICtrlCreateLabel($aLang[8]&" (redlight-camera):", 16, 95, 400, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Cb_Fusion3 = GUICtrlCreateCheckbox($aLang[10], 16, 155, 280, 17)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)

[color=#FF0000]$Group6 = GUICtrlCreateGroup(" Trapster Import ", 312, 20, 241, 90)
$setuptrapsterFilter = "ALL SETPOINTS"
$labeltrapsterFilter = GUICtrlCreateLabel("With Filter = " & $setuptrapsterFilter, 330, 160, 400, 100)
$trapsterFilter = GUICtrlCreateCombo("", 350, 50, 150, 25)
GUICtrlSetData(-1, "HIGH CONFIDENCE|MEDIUM CONFIDENCE|LOW CONFIDENCE|ALL SETPOINTS", $setuptrapsterFilter )[/color]

GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlCreateLabel('Input :  Longitude,Latitude,xxxx', 50, 220, 300, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
GUICtrlCreateLabel('Output : Latitude,Longitude,Web_Site_Origin,"TYPE_RADAR",level,', 50, 240, 500, 300)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
GUICtrlCreateLabel('Filter Not Available !!!', 350, 90, 200, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Group7 = GUICtrlCreateGroup(" Result ", 312, 110, 241, 80)
;$labelZlist3 = GUICtrlCreateLabel("ZONES IMPORTED : "&$nbZlst, 330, 130, 400, 100)

GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
;Fin Onglet Traster

Voici ce qui se trouve dans ma boucle while :

Code : Tout sélectionner

;Boucle pour Onglet Trapster
        Case $GUI_EVENT_CLOSE, $Annuler3
            Exit
            
[color=#FF0000]     Case $trapsterFilter
            $setuptrapsterFilter = GUICtrlRead($trapsterFilter)
            GetRide()[/color]
            
        Case $Choix_RF3
            $aFic_RF3 = FileOpenDialog($aLang[6], @ScriptDir, $aLang[20]& " asc (*.csv)", 1)
            If $aFic_RF3 <> "" Then GUICtrlSetData($Fic_RF3, $aFic_RF3)

        Case $Choix_RFR3
            $aFic_RFR3 = FileOpenDialog($aLang[8], @ScriptDir, $aLang[20]& " asc (*.csv)", 1)
            If $aFic_RFR3 <> "" Then GUICtrlSetData($Fic_RFR3, $aFic_RFR3)
            
        Case $MenuAPropos
            _Apropos()
            
        Case $OK3
            $vFic_RF3 = GUICtrlRead($Fic_RF3)
            $vFic_RFR3 = GUICtrlRead($Fic_RFR3)
            $vFic_ZlistRF3 = GUICtrlRead($Fic_RF3)
            $vFic_ZlistRFR3 = GUICtrlRead($Fic_RFR3)
            
            If $vFic_RF3 & $vFic_RFR3 <> "" Then
                SplashTextOn("", "Conversion en cours ...", 250, 60, -1, -1, 32, "", 12, 800)


                Dim $aRF3, $aRFR3 , $aZlistRF3 , $aZlistRFR3 
                _FileReadToArray($vFic_RF3, $aRF3)
                _FileReadToArray($vFic_RFR3, $aRFR3)
                _FileReadToArray($vFic_zlistRF3, $aZlistRF3)
                _FileReadToArray($vFic_zlistRFR3, $aZlistRFR3)

                Dim $sRF3, $sRFR3, $sZlistRF3, $sZlistRFR3 , $TypeRadar3
                If IsArray($aRF3) Then
                    $aRF3 = _DoIt3($aRF3, $TypeRadar3 )
                    $sRF3 = _ArrayToString($aRF3, @CRLF)
                EndIf

                If IsArray($aRFR3) Then
                    $aRFR3 = _DoIt3($aRFR3, $TypeRadar3 )
                    $sRFR3 = _ArrayToString($aRFR3, @CRLF)
                EndIf
                
                If IsArray($aZlistRF3) Then
                    $aZlistRF3 = _DoItZlist3($aZlistRF3, $TypeRadar3 )
                    $sZlistRF3 = _ArrayToString($aZlistRF3, @CRLF)

                EndIf
                
                If IsArray($aZlistRFR3) Then
                    $aZlistRFR3 = _DoItZlist3($aZlistRFR3, $TypeRadar3 )
                    $sZlistRFR3 = _ArrayToString($aZlistRFR3, @CRLF)
                EndIf

                If _IsChecked($Cb_Fusion3) Then
                    FileWrite("Zones.csv", $sRF3 & @CRLF & $sRFR3)
                Else
                    If $sRF3 <> "" Then _SaveNewFile($vFic_RF3, $sRF3)
                    If $sRFR3 <> "" Then _SaveNewFile($vFic_RFR3, $sRFR3)
                EndIf
                    FileWrite("ZLST.TXT", $sZlistRF3 & @CRLF & $sZlistRF3)
                    
                SplashOff()
;                MsgBox(64, "Csv2SpeedZoneLimit Convertion", "Conversion finished"&@CRLF&"ZONES IMPORTED = "&$nbZlist)
                MsgBox(64, "Csv2SpeedZoneLimit Convertion", "Conversion finished")
                GetRide()
            EndIf
;Fin Boucle pour Onglet Trapster

Voici ma fonction de traitement :

Code : Tout sélectionner

Func _DoIt3($aRadars3, $Level3 )
    Local $k, $Var, $Var2, $Longitude3, $Latitude3, $Vitesse3
    For $k = 1 To $aRadars3[0]
        $Filter = StringSplit($setuptrapsterFilter, ' ')
            ;mise en miniscule de $filter pour test avec $level3 ,impossible si MIN MAJ
            If $Filter[1] = "ALL" Then $Filter[1] = "all"
            If $Filter[1] = "HIGH" Then $Filter[1] = "high"
            If $Filter[1] = "MEDIUM" Then $Filter[1] = "medium"
            If $Filter[1] = "LOW" Then $Filter[1] = "low"
            
        If StringInStr($aRadars3[$k], $Filter[1]) Then;Test sur le filtrage à réaliser
        $Var = StringSplit($aRadars3[$k], ',')

        $Longitude3 = $Var[2]
        $Latitude3 = $Var[1]
        $TypeRadar3 = $Var[3]
        
        $Var2 = StringSplit($Var[4]," ")
        $Level3 = $Var2[2]

        $aRadars3[$k] = $Longitude3 & ',' & $Latitude3 & ',TRAPSTER,' & $TypeRadar3 & ',' & $Level3 & ','
        
        Else;Si le filtre est sur "ALL" alors toutes les lignes sont traitées et gardées
            If $Filter[1] = "all" Then
            $Var = StringSplit($aRadars3[$k], ',')

            $Longitude3 = $Var[2]
            $Latitude3 = $Var[1]
            $TypeRadar3 = $Var[3]
        
            $Var2 = StringSplit($Var[4]," ")
            $Level3 = $Var2[2]

            $aRadars3[$k] = $Longitude3 & ',' & $Latitude3 & ',TRAPSTER,' & $TypeRadar3 & ',' & $Level3 & ','   
            EndIf       
        Endif
    Next

Mon filtre se fait donc sur 4 possibiltés:

ALL SETPOINTS , Je traite toutes les lignes de mon fichier d'entrée .
HIGH CONFIDENCE , Je ne traite ET NE GARDE que les lignes contenant high.
MEDIUM CONFIDENCE , Je ne traite ET NE GARDE que les lignes contenant medium.
LOW CONFIDENCE , Je ne traite ET NE GARDE que les lignes contenant low.

Mon filtre semble fonctionner , le traitement est bien fait selon mon critère .
MAIS, les lignes à ne pas traiter restent tel quel dans mon fichier final au lieu d'être effacées .

Je pense que mon erreur est dans ma fonction de traitement (_DoIt3) _ArrayDelete pourrait
convenir mais je n'arrive pas à l'utiliser

Je joint mon fichier source pour une meilleur compréhension , ainsi qu'un exemple de fichier d'entré.

Qui peut me dire où est mon erreur ?

Merci pour votre aide par avance !

Re: [..] Filtrer les lignes d'un tableau

Posté : mer. 29 avr. 2009 21:39

par Tlem

Rajoutez les balise de code dans votre message.
Je sait, ça fait bizarre de mettre les balises de code dans les balise spoiler, mais c'est bien plus lisible.

Et puis, comme d'habitude, si il était possible d'avoir quelque chose de fonctionnel pour tester, ce serait plus facile.
Là, il faut s'imaginer plein de chose, reconstruire un script fonctionnel, etc ...
Autant dire que personne ne regardera.

Re: [..] Filtrer les lignes d'un tableau

Posté : jeu. 30 avr. 2009 18:50

par orax

Bonjour,
j'ai quelques difficultés pour comprendre comment tester le script.

J'ai téléchargé les fichiers joints trapster_radars.csv et csv2speedzonelimit_v1.4.zip ; je lance le script ; et ensuite...?
J'ai essayé d'aller dans l'onglet Trapster pour y mettre le fichier trapster_radars mais visiblement ça ne semble pas marcher, le script plante : Array variable has incorrect number...

Re: [..] Filtrer les lignes d'un tableau

Posté : jeu. 30 avr. 2009 21:51

par Tlem

Je viens de jeter un oeil sur le code (presque 1500 lignes

) et d'après ce que j'ai vu, dans vos fonctions tel que la fonction _DoIt3 par exemple, vous envoyez un tableau qui contient des lignes vides !!!

Il est clair dans ce cas, que si vous ne faite pas d'exception pour ne par traiter la ligne vide, vous allez droit au mur.

Vous avez donc deux possibilités :

1 - dans vos fonctions, vous rajoutez un contrôle du contenu de la ligne et si cette ligne est vide on ne la traite pas. Par contre le tableau contiendra toujours ces lignes vides qui ne vous sont pas forcément utiles.

2 - Rajouter une fonction qui élimine les lignes vides du tableau afin de faire vos traitement _DoItx.
Rajoutez après avoir chargé vos fichiers dans le tableau (après la ligne 591) ces lignes :

Code : Tout sélectionner

$aRF3 = _CleanBlankLine($aRF3)
$aRFR3 = _CleanBlankLine($aRFR3)
$aZlistRF3 = _CleanBlankLine($aZlistRF3)
$aZlistRFR3 = _CleanBlankLine($aZlistRFR3)

Puis à la fin du code, rajoutez la fonction _CleanBlankLine :

Code : Tout sélectionner

Func _CleanBlankLine($aArrayToClean)
    Local $i
    If IsArray($aArrayToClean) Then
        For $i = Ubound($aArrayToClean)-1 to 1 Step -1
            If $aArrayToClean[$i] = "" Then _ArrayDelete($aArrayToClean, $i)
        Next
    EndIf
    Return $aArrayToClean
EndFunc

Re: [..] Filtrer les lignes d'un tableau

Posté : ven. 01 mai 2009 11:52

par pierrotm777

Bonjour,

Je vous joints l'ensembles des fichiers , pensez juste à modifier les lignes 41 à 48
en fonction du directory où se trouvent vos fichiers .

http://www.mediafire.com/?sharekey=3420 ... b9a8902bda

Re: [..] Filtrer les lignes d'un tableau

Posté : ven. 01 mai 2009 12:23

par Tlem

Oui, mais pourquoi faire ?

Re: [..] Filtrer les lignes d'un tableau

Posté : ven. 01 mai 2009 12:42

par pierrotm777

Bonjour Tlem,

Merci pour votre aide .

J'ai réalisé les ajouts recommandés , mais j'ai toujours dans mon fichier de sortie les lignes qui
ne sont pas traités :

Exemple de fichier résultant:

► Afficher le texte

Code : Tout sélectionner

35.141600,-80.904700,TRAPSTER,"Bonne Mère",medium,
33.098700,-117.200000,TRAPSTER,"Police Often Hide Here",medium,
33.052100,-117.233000,TRAPSTER,"Police Often Hide Here",medium,
-81.544900,41.560800,"Police Often Hide Here","Confidence: low, Last vote time: 2007-12-12 20:07:14, First voter: amit2607, Last voter: amit2607, Address: 0 mi from intersection E 193rd St and Euclid Ave, Euclid"
34.744500,-83.401200,TRAPSTER,"Police Often Hide Here",medium,
34.111100,-118.265000,TRAPSTER,"Police Often Hide Here",medium,
-80.344800,39.527400,"Police Often Hide Here","Confidence: low, Last vote time: 2007-12-08 14:57:56, First voter: GateWiz, Last voter: GateWiz, Address: 300 High Street Mannington 26582"
41.747600,-73.183600,TRAPSTER,"Police Often Hide Here",medium,
-81.384100,28.792400,"Police Often Hide Here","Confidence: low, Last vote time: 2008-03-23 00:12:13, First voter: flagator, Last voter: FlaBoy, Address: markham rd sanford 32771"
26.146600,-80.286900,TRAPSTER,"Police Often Hide Here",medium,
-73.113700,41.761900,"Police Often Hide Here","Confidence: low, Last vote time: 2009-01-11 16:49:56, First voter: jak119, Last voter: bsilgolf13, Address: 0.08 mi from intersection State Highway 8 and Litchfield Rd, Northwest Harwinton"
41.769903,-71.323650,TRAPSTER,"Police Often Hide Here",medium,
-71.169800,41.656800,"Police Often Hide Here","Confidence: high, Last vote time: 2008-09-25 14:49:44, First voter: offthegrid, Last voter: boxster, Address: Cannot find matching intersection"
-71.151900,41.671900,"Police Often Hide Here","Confidence: high, Last vote time: 2009-01-23 21:52:44, First voter: offthegrid, Last voter: Sgttuba69, Address: 0.09 mi from intersection Stafford Rd and Progress St, Fall River"
40.837200,-96.708600,TRAPSTER,"Police Often Hide Here",medium,
33.062800,-117.238000,TRAPSTER,"Police Often Hide Here",medium,
-78.502500,35.967200,"Police Often Hide Here","Confidence: low, Last vote time: 2007-12-12 09:45:22, First voter: ericdetwiler, Last voter: ericdetwiler, Address: 0.07 mi from intersection Ledgerock Ct and Rockville Rd, Wake Forest"
-83.863700,36.035900,"Police Often Hide Here","Confidence: low, Last vote time: 2007-12-18 19:41:12, First voter: skootle, Last voter: skootle, Address: 640 east and millertown pike  knoxville 37918"
-75.191500,39.975900,"Police Often Hide Here","Confidence: high, Last vote time: 2009-01-05 12:51:56, First voter: blis, Last voter: jeffjeff2007, Address: 0.02 mi from intersection Kelly Dr and N Brewery Hill Dr, Philadelphia"
-75.164100,40.131800,"Police Often Hide Here","Confidence: low, Last vote time: 2007-12-19 13:37:27, First voter: blis, Last voter: blis, Address: 0.04 mi from intersection Pebblewood Ln and Twining Rd, Aiden Lair"
-75.142800,40.150200,"Police Often Hide Here","Confidence: low, Last vote time: 2007-12-19 13:38:50, First voter: blis, Last voter: blis, Address: 0.06 mi from intersection Dale Rd and Twining Rd, Crestmont"
-80.838600,35.509500,"Police Often Hide Here","Confidence: low, Last vote time: 2007-12-23 09:40:36, First voter: LANG, Last voter: LANG, Address: 0.11 mi from intersection Shearer St and Sherer St, Davidson"
35.504100,-80.865400,TRAPSTER,"Police Often Hide Here",medium,
35.789700,-80.861600,TRAPSTER,"Police Often Hide Here",medium,
-77.059200,39.364500,"Police Often Hide Here","Confidence: low, Last vote time: 2007-12-24 00:01:02, First voter: Dustinber, Last voter: Dustinber, Address: 7621 Woodbine Rd woodbine 21797"
-77.017300,39.376300,"Police Often Hide Here","Confidence: low, Last vote time: 2007-12-24 00:06:59, First voter: Dustinber, Last voter: Dustinber, Address: Cannot find matching intersection"
-77.008200,39.430300,"Police Often Hide Here","Confidence: low, Last vote time: 2007-12-24 00:08:00, First voter: Dustinber, Last voter: Dustinber, Address: 0.09 mi from intersection Washington Rd and Old Liberty Rd, Gist"
-76.992900,39.431800,"Police Often Hide Here","Confidence: low, Last vote time: 2007-12-24 00:08:52, First voter: Dustinber, Last voter: Dustinber, Address: 0.07 mi from intersection Richards Dr and S Klees Mill Rd, Eldersburg"

J'ai fait ici le choix de medium :
Toutes les lignes comportant le terme "medium" sont bien traitées ,
mais les autres , bien que non traitées , ne sont pas effacées .

Dans votre fonction , la ligne " If $aArrayToClean[$i] = "" Then _ArrayDelete($aArrayToClean, $i) " , si je comprends bien,
efface toute ligne vide . Si c'est bien le cas , je voudrais en fait que la fonction efface toute ligne qui ne comporte pas ce que je choisi dans mon filtre . all , high , medium ou low .

??

Re: [..] Filtrer les lignes d'un tableau

Posté : ven. 01 mai 2009 17:42

par GaRydelaMer

Bonjour

si je peux me permettre de te bouleverser, mais j'ai une bonne solution a te proposer. Vous savez que j'aime les base de données et en particulier l'utilisation de ADO.

Avec ADO, il est possible d'ouvrir un fichier csv, de plus les Recorset sont pratique pour filtrer et parcourir les données.

Je te propose d'ouvrir le Fichier cvs avec ADO, d'obtenir un un objet recordset qui te permettra d'écrire ton fichier résultant facilement. Moyennant 1 petit truc a faire avant juste de créer un Fichier Schema.ini dans le même dossier que le fichier csv, et de faire un tour pour plus d'info sur le schema:
http://www.connectionstrings.com/textfile
http://msdn.microsoft.com/en-us/library/ms709353.aspx

► Afficher le texteSchema.ini

Et le code j'utilise ConsoleWrite pour écrire les résultat mais tu peux trés bien écrire dans un fichier ou alimenter un tableau enfin ce que tu veux quoi

Code : Tout sélectionner

Global Const $adoProvider = "Microsoft.Jet.OLEDB.4.0"
Global Const $adOpenStatic = 3
Global Const $adLockUnspecified = -1

Local $basedir = @ScriptDir
Local $oConn = ObjCreate("ADODB.Connection")
$oConn.ConnectionString = "Provider=" & $adoProvider & ";Extended Properties='text';Data Source=" & $basedir
$oConn.Open

Local $oRs = ObjCreate("ADODB.Recordset")
$oRs.Open("SELECT * FROM trapster_radars.csv", $oConn, $adOpenStatic, $adLockUnspecified)
$oRs.Filter = "Latitude <> '' AND Champ2 Like '%high%'"

While Not $oRs.EOF
    For $i = 0 To $oRs.Fields.Count - 1
        ConsoleWrite($oRs.Fields($i).Name & "=" & $oRs.Fields($i).Value & @LF)
    Next
    ConsoleWrite(@LF)
    $oRs.MoveNext
WEnd
$oRs.Close
$oConn.Close

et le résultat dans la console en filtrant les ligne vide et le choix high.
Cela se fait a la ligne $oRs.Filter = "Latitude <> '' AND Champ2 Like '%high%'"
remplace high, par low ou medium ou alors pour tous enlève la partie AND Champ2 Like '%high%'

Code : Tout sélectionner

Latitude=-71.169800
Longitude=41.656800
Champ1=Police Often Hide Here
Champ2=Confidence high
Champ3=Last vote time 2008-09-25 144944
Champ4=First voter offthegrid
Champ5=Last voter boxster
Champ6=Address Cannot find matching intersection
Champ7=

Latitude=-71.151900
Longitude=41.671900
Champ1=Police Often Hide Here
Champ2=Confidence high
Champ3=Last vote time 2009-01-23 215244
Champ4=First voter offthegrid
Champ5=Last voter Sgttuba69
Champ6=Address 0.09 mi from intersection Stafford Rd and Progress St
Champ7=Fall River

Re: [..] Filtrer les lignes d'un tableau

Posté : ven. 01 mai 2009 18:13

par GaRydelaMer

Pour obtenir ton fichier résultat

Code : Tout sélectionner

Global Const $adoProvider = 'Microsoft.Jet.OLEDB.4.0'
Global Const $adOpenStatic = 3
Global Const $adLockUnspecified = -1

Local $basedir = @ScriptDir
Local $Filter[2]
$Filter[1] = "medium"
Local $Site = "TRAPSTER"

Local $oConn = ObjCreate("ADODB.Connection")
$oConn.ConnectionString = "Provider=" & $adoProvider & ";Extended Properties='text';Data Source=" & $basedir
$oConn.Open
Local $oRs = ObjCreate("ADODB.Recordset")
$oRs.Open("SELECT * FROM trapster_radars.csv WHERE Latitude <> '' ORDER BY Latitude", $oConn, $adOpenStatic, $adLockUnspecified)
Switch $Filter[1]
    Case "HIGH"
        $oRs.Filter = "Champ2 Like '%high%'"
    Case "MEDIUM"
        $oRs.Filter = "Champ2 Like '%medium%'"
    Case "LOW"
        $oRs.Filter = "Champ2 Like '%low%'"
    Case Else
        $oRs.Filter = ""
EndSwitch

Local $out = ""
While Not $oRs.EOF
    $out &= $oRs.Fields(1).Value & "," & $oRs.Fields(0).Value & _
            "," & $Site & "," & $oRs.Fields(2).Value & "," & $Filter[1] & @LF
    $oRs.MoveNext
WEnd
ConsoleWrite($out)

$oRs.Close
$oConn.Close

Résultat

Code : Tout sélectionner

35.141600,-80.904700,TRAPSTER,Bonne Mère,Medium
33.098700,-117.200000,TRAPSTER,Police Often Hide Here,Medium
33.052100,-117.233000,TRAPSTER,Police Often Hide Here,Medium
34.744500,-83.401200,TRAPSTER,Police Often Hide Here,Medium
34.111100,-118.265000,TRAPSTER,Police Often Hide Here,Medium
41.747600,-73.183600,TRAPSTER,Police Often Hide Here,Medium
26.146600,-80.286900,TRAPSTER,Police Often Hide Here,Medium
41.769903,-71.323650,TRAPSTER,Police Often Hide Here,Medium
40.837200,-96.708600,TRAPSTER,Police Often Hide Here,Medium
33.062800,-117.238000,TRAPSTER,Police Often Hide Here,Medium

Re: [..] Filtrer les lignes d'un tableau

Posté : ven. 01 mai 2009 19:57

par pierrotm777

Bonjour GaRydelaMer,

Merci de t'intéresser à mon problème , mais ta solution m'obligerait à repenser tout mon script .

Je ferais un test de ta solution pour une autre appli , mais pour l'instant , j'essai d'assimiler le peu que je connais d'autoit .

Merci encore .

Re: [..] Filtrer les lignes d'un tableau

Posté : ven. 01 mai 2009 21:11

par GaRydelaMer

Re,

pas tant que ca regarde ce code, j'ai repris ta logique.
le seul truc c'est de créer le fichier Schema.ini, FileWrite fera l'affaire. Aprés c'est vrai que tu pourrais faire ca pour les autres fichiers.

En fait au lieu de lire le fichier et le stocker dans un tableau

► Afficher le texte

Pour le fichier Schema.ini tu le créer une fois, les sections c'est le nom du fichier.

Re: [..] Filtrer les lignes d'un tableau

Posté : sam. 02 mai 2009 09:57

par pierrotm777

Merci encore GaRydelaMer pour votre aide,

J'ai testé et jobtiens cela:

Code : Tout sélectionner

C:\tmp\AutoIt\Ride Runner Scripts\Csv2SpeedZoneLimit\essai_bd.au3 (42) : ==> The requested action with this object has failed.:
$oRs.Filter = "Latitude <> '' AND Champ2 Like '%low%'"
$oRs.Filter = "Latitude <> '' AND Champ2 Like '%low%'"^ ERROR

Vraiment , je préfèrerais une solution de type Tlem, sans vouloir vous vexer !

Re: [..] Filtrer les lignes d'un tableau

Posté : sam. 02 mai 2009 15:30

par GaRydelaMer

Bonjour

Pour l'erreur je pense que ca vient du fichier Schema.ini.

Le filtre utilise les noms des champs défini dans ce fichier.

Je vais te donner une autre fonction qui créer le Schema de façon automatique, les champs sont nommé Colx, avec x = 1 pour le 1er champ puis incrémenter de 1.
Et tu remplace le Filtre par:

Code : Tout sélectionner

    ;$Filter = StringSplit($setuptrapsterFilter, ' ')
    Switch StringLower($Filter[1])
        Case "HIGH"
            $oRs.Filter = "Col1 <> '' AND Col4 Like '%high%'"
        Case "MEDIUM"
            $oRs.Filter = "Col1 <> '' AND Col4  Like '%medium%'"
        Case "LOW"
            $oRs.Filter = "Col1 <> '' AND Col4 Like '%low%'"
        Case Else
            $oRs.Filter = "Col1 <> ''"
    EndSwitch

Tu utilise la fonction comme ca dans le while:
_ADO_CreateSchema($vFic_RF3)
$aRF3 = _DoIt3($vFic_RF3, "level3")

$File le fichier avec ou sans le chemin voir même un chemin relatif
$HDR, [Oui/Non] Oui peut être "Yes", "True", 1 Définie si le fichier cvs à les nom des champs sur la 1ere Ligne
$FMT, [CVSdelimited/TABdelimited/un caractère ex "|"] Le format du fichier, le séparateur de Champ
CVSdelimited= Séparateur (,)
TabDelimited= Séparateur (@TAB)

Code : Tout sélectionner

Func _ADO_CreateSchema($File, $HDR = "no", $FMT = "CSVDelimited")
    ; Définie le Dossier et le nom du fichier, pour le parametre BaseDir et le Nom de la Table
    $File = _PathFull($File)
    Local $Drive, $BaseDir, $Table, $ext
    _PathSplit($File, $Drive, $BaseDir, $Table, $ext)
    $BaseDir = $Drive & $BaseDir
    $Table = $Table & $ext
    ; Données à écrire dans le Schema
    Local $datas
    ; Nom des Colonnes sur la 1ere Ligne
    Switch $HDR
        Case "Oui", "Yes", "True", 1
            $HDR = "Yes"
            $datas &= "ColNameHeader=True" & @LF
        Case Else
            $HDR = "No"
            $datas &= "ColNameHeader=False" & @LF
    EndSwitch
    ; Format de séparation des colonnes
    Switch $FMT
        Case "CSVDelimited", "TabDelimited", "FixedLength"
        Case Else
            $FMT = "Delimited(" & $FMT & ")"
    EndSwitch
    $datas &= "Format=" & $FMT & @LF
    IniWriteSection($BaseDir & "Schema.ini", $Table, $datas)
    ; Ouverture du Fichier et lectures des Champs
    Local $oRs = ObjCreate("ADODB.Recordset")
    With $oRs
        .ActiveConnection = "Provider=" & $adoProvider & _
                ";Extended Properties='text;HDR=" & $HDR & ";FMT=" & $FMT & "'" & _
                ";Data Source=" & $BaseDir
        .Source = "SELECT * FROM " & $Table
        .Open
        ; Ajoute les champs à $Datas
        Local $Name
        For $i = 0 To .Fields.Count - 1
            $Name = .Fields($i).Name
            If $Name = "F" & $i + 1 Then $Name = "Col" & $i + 1
            $datas &= "Col" & $i + 1 & "=" & $Name & " Char" & @LF
        Next
        .Close
    EndWith
    ; Ecriture complète du Schema de la Table
    IniWriteSection($BaseDir & "Schema.ini", $Table, $datas)
EndFunc   ;==>_ADO_CreateSchema

Re: [..] Filtrer les lignes d'un tableau

Posté : jeu. 07 mai 2009 13:14

par pierrotm777

Bonjour,

Bon , jai testé et voilà ce que jobtiens .

Code : Tout sélectionner

C:\tmp\AutoIt\Ride Runner Scripts\Csv2SpeedZoneLimit\csv2speedzonelimit_v1.4old.au3(984,62) : WARNING: $oRs possibly not declared/created yet
            $oRs.Filter = "Col1 <> '' AND Col4 Like '%high%'"
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
C:\tmp\AutoIt\Ride Runner Scripts\Csv2SpeedZoneLimit\csv2speedzonelimit_v1.4old.au3(1529,56) : WARNING: $adoProvider: possibly used before declaration.
        .ActiveConnection = "Provider=" & $adoProvider &
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
C:\tmp\AutoIt\Ride Runner Scripts\Csv2SpeedZoneLimit\csv2speedzonelimit_v1.4old.au3(1529,56) : ERROR: $adoProvider: undeclared global variable.
        .ActiveConnection = "Provider=" & $adoProvider &
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
C:\tmp\AutoIt\Ride Runner Scripts\Csv2SpeedZoneLimit\csv2speedzonelimit_v1.4old.au3 - 1 error(s), 2 warning(s)

Re: [..] Filtrer les lignes d'un tableau

Posté : jeu. 07 mai 2009 19:29

par pierrotm777

Tlem a écrit :Oui, mais pourquoi faire ?

Pour pouvoir compiler s'il le souhaite .

Re: [..] Filtrer les lignes d'un tableau

Posté : jeu. 07 mai 2009 19:43

par pierrotm777

Tlem a écrit :Je viens de jeter un oeil sur le code (presque 1500 lignes ) et d'après ce que j'ai vu, dans vos fonctions tel que la fonction _DoIt3 par exemple, vous envoyez un tableau qui contient des lignes vides !!!
Il est clair dans ce cas, que si vous ne faite pas d'exception pour ne par traiter la ligne vide, vous allez droit au mur.

Vous avez donc deux possibilités :

1 - dans vos fonctions, vous rajoutez un contrôle du contenu de la ligne et si cette ligne est vide on ne la traite pas. Par contre le tableau contiendra toujours ces lignes vides qui ne vous sont pas forcément utiles.

2 - Rajouter une fonction qui élimine les lignes vides du tableau afin de faire vos traitement _DoItx.
Rajoutez après avoir chargé vos fichiers dans le tableau (après la ligne 591) ces lignes :
Code : Tout sélectionner
$aRF3 = _CleanBlankLine($aRF3)
$aRFR3 = _CleanBlankLine($aRFR3)
$aZlistRF3 = _CleanBlankLine($aZlistRF3)
$aZlistRFR3 = _CleanBlankLine($aZlistRFR3)
Puis à la fin du code, rajoutez la fonction _CleanBlankLine :
Code : Tout sélectionner
Func _CleanBlankLine($aArrayToClean)
    Local $i
    If IsArray($aArrayToClean) Then
        For $i = Ubound($aArrayToClean)-1 to 1 Step -1
            If $aArrayToClean[$i] = "" Then _ArrayDelete($aArrayToClean, $i)
        Next
    EndIf
    Return $aArrayToClean
EndFunc

J'ai remplacé le fichier trapster_radars.csv qui était mauvais .

Je ne vois pas où il y a besoin de traiter des lignes vides Tlem, (avec tout mon respect) .
Je souhaite faire un trie en fonction de mon combo .

Re: [..] Filtrer les lignes d'un tableau

Posté : jeu. 07 mai 2009 20:53

par Tlem

D'après les tests que j'avais effectué, tout comme orax, je m'étais retrouvé avec une erreur : Array variable has incorrect number...

Donc après analyse, il se trouvait que le tableau résultant de la lecture du fichier (ligne 588 à 591) avait une ligne sur deux qui était une ligne vide.
Donc lors du lancement de la fonction _DoIt3, le traitement effectué par cette dernière impliquait inévitablement une erreur car le traitement de la fonction ne pouvait aboutir sur une ligne vide.
D'où la solution que je vous ait proposé, pour éliminer ces lignes vides.

Re: [..] Filtrer les lignes d'un tableau

Posté : jeu. 07 mai 2009 21:20

par Tlem

J'ai modifié votre fonction _DoIt3 pour la simplifiée, et pour ajouter le test de ligne vide.
Voici ce que cela donne :

Code : Tout sélectionner

Func _DoIt3($aRadars3, $Level3 )
    Local $k, $Var, $Var2, $Longitude3, $Latitude3, $Vitesse3
    
    For $k = 1 To $aRadars3[0]
        If $aRadars3[$k] <> "" And Not StringIsSpace($aRadars3[$k]) Then 
            $Var = StringSplit($aRadars3[$k], ',')

            $Longitude3 = $Var[2]
            $Latitude3 = $Var[1]
            $TypeRadar3 = $Var[3]
        
            $Var2 = StringSplit($Var[4],' ')
            $Level3 = $Var2[2]
        
            If StringInStr ($setuptrapsterFilter, "all") Then
                $aRadars3[$k] = $Longitude3 & ',' & $Latitude3 & ',TRAPSTER,' & $TypeRadar3 & ',' & $Level3 & ','   
            EndIf       
        EndIf   
    Next

    _ArrayDelete($aRadars3, 0) ; On supprime le nombre d'élément du tableau
    Return $aRadars3
EndFunc   ;==>_DoIt3

A vous de me dire si ça fonctionne.

Re: [..] Filtrer les lignes d'un tableau

Posté : ven. 08 mai 2009 15:06

par pierrotm777

Bonjour Tlem,

Merci de votre aide.

La fonction ainsi modifiée marche bien si je choisi "all" .S
si je choisi "high" , "medium" ou "low" , aucun trie n'est fait (toutes les lignes existent non traitées), aucun traitement non plus .

Re: [..] Filtrer les lignes d'un tableau

Posté : ven. 08 mai 2009 21:48

par Tlem

Oui, c'est normal, car dans votre fonction (et donc dans la mienne) aucun traitement n'est effectué dans les autres cas.

Pourriez-vous définir exactement le(s) traitement(s) dont vous auriez besoin ?
Devez-vous ne garder que les lignes du choix du combo et renvoyer le tableau ainsi filtré ?