AutoIt Français

Bonjour à tous!

Je faisais juste un petit test en autoit afin de tester un pong. Bon alors ça marche bien, mais la balle semble saccadé...

voyez par vous même:

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>

OnAutoItExitRegister("_Close")
Global $vitesse=10
Global $angle=-45
Global $FPS=25
Global $TimeUntilOtherPic=(1/$FPS)*1000
Global $xB=640/2,$yB=480/2
Global $iW = 640, $iH = 480,$colour

Global $Form1 = GUICreate("Pong", $iW, $iH)

_GDIPlus_Startup()
$hGraphics=_GDIPlus_GraphicsCreateFromHWND($Form1)
Local $hBitmap = _GDIPlus_BitmapCreateFromGraphics($iW, $iH, $hGraphics)
Local $hBackbuffer = _GDIPlus_ImageGetGraphicsContext($hBitmap)
_GDIPlus_GraphicsClear($hBackbuffer,0xFFFFFFFF)
GUIRegisterMsg($WM_ERASEBKGND, "WM_ERASEBKGND")
GUISetState(@SW_SHOW)

initBall($hGraphics)

$temps=TimerInit()

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch

    if TimerDiff($temps)>=$TimeUntilOtherPic Then
        $temps=TimerInit()
    if $xB>=$iW or $xB<=0 then
        calc_vert()
    ElseIf $yB>=$iH or $yB<=0 Then
        calc_hor()
    EndIf
        deplace($hGraphics,$angle,$vitesse)
    EndIf

WEnd


func initBall($hGraph)
    _GDIPlus_GraphicsFillEllipse2($hGraph,$iW/2,$iH/2,5)
EndFunc


Func calc_hor()
    $angle=360-$angle
EndFunc

Func calc_vert()
    $angle=180-$angle
EndFunc

Func deplace($graph,$angle,$vitesse)
    $temp=(3.141592654*$angle)/180
    _GDIPlus_GraphicsFillEllipse2($graph,$xB,$yB,5,0xFFFFFFFF)
    $xB+=$vitesse*Cos($temp)
    $yB+=$vitesse*sin($temp)
    _GDIPlus_GraphicsFillEllipse2($graph,$xB,$yB,5)
EndFunc

Func _GDIPlus_GraphicsFillEllipse2($hGrap, $x,$y,$r,$color=0xFF000000)
    $colour=_GDIPlus_BrushCreateSolid($color)
    _GDIPlus_GraphicsFillEllipse($hGrap,$x-($r/2),$y-($r/2),$r,$r,$colour)
EndFunc

Func WM_ERASEBKGND()
        _GDIPlus_GraphicsDrawImageRect($hGraphics, $hBitmap, 0, 0, $iW, $iH)
        Return 1
EndFunc
Func _Close()
    GUIRegisterMsg($WM_ERASEBKGND, "")
    _GDIPlus_BrushDispose($colour)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_GraphicsDispose($hBackbuffer)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
    GUIDelete($Form1)
    Exit
EndFunc

Hello le scientifique

Sur ma vieille machine le résultat est meilleur en baissant à la fois $vitesse et $TimeUntilOtherPic
Le petit effet saccadé restant est probablement dû au hardware

C'est donc ça! Oui d'accord, de toute façon c'était juste pour tester hein!
merci!

Sujet résolu un peu rapidement!
Ci dessous je crée la balle dans un bitmap, que je sauvegarde, même si ce n'est pas utile
et je déplace le bitmap de façon à ne pas reconstruire la balle à chaque pas de calcul.
Il me semble que c'est mieux. Qu'en pensez-vous?
Exercices:
1-Utiliser une matrice de rotation pour faire tourner la balle sur elle-même
2-Pourquoi ne pas utiliser une matrice de translation pour la déplacer?

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>

Global $hGui, $hGfxCtxt, $hBitmap, $hBmp, $hGraphics, $bArret=false


Example()

Func Example()
    AutoItSetOption("GUIOnEventMode", 1)

    ; Construit la balle dans $fich
    Local const $diam=30, $fich = "balle.jpg"
    BuildBalle($fich, $diam)

    ; Récupère la balle dans $fich
    _GDIPlus_Startup() ; Initialise GDI+
    $hBmp =_GDIPlus_BitmapCreateFromFile($fich)

    ; La fenêtre
    Local Const $iWidth = 600, $iHeight = 400, $iBgColor = 0x303030 ; RRGGBB
    $hGui = GUICreate("Balle", $iWidth, $iHeight) ; crée une GUI de test
    GUISetBkColor($iBgColor, $hGui) ; Définit la couleur de fond de la GUI
    GUISetState(@SW_SHOW)

    ; Crée un objet graphique à partir d'un handle de fenêtre
    $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
    ; Crée un bitmap
    $hBitmap = _GDIPlus_BitmapCreateFromGraphics($iWidth,$iHeight, $hGraphics)
    ; Crée un buffer graphique pour lisser les mouvements d'objets gfx
    $hGfxCtxt = _GDIPlus_ImageGetGraphicsContext($hBitmap)


    Local $iVectorX = Random(1.5, 2.5), $iVectorY = Random(1.5, 2.5) ; Définit un vecteur x,y
    Local $iX = 0.0, $iY = 0.0 ; Définit les coordonnéées de départ

    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")

    while not $bArret
        _GDIPlus_GraphicsClear($hGfxCtxt, 0xFF000000) ; Efface le bitmap pour le repeindre
        _GDIPlus_GraphicsDrawImage($hGfxCtxt, $hBmp, $iX, $iY) ; Dessine bitmap dans le backbuffer

        ;Copie le bitmap dessiné dans le handle graphique (GUI)
        _GDIPlus_GraphicsDrawImageRect($hGraphics, $hBitmap, 0, 0, $iWidth, $iHeight)  ;$iWidth, $iHeight)

        $iX += $iVectorX*1 ; Ajoute le x du vecteur au x de la position actuelle (augmenter le 1 pour accroitre la vitesse)
        $iY += $iVectorY*1 ; Ajoute le y du vecteur à la position y actuelle
        If $iX < 0 Or $iX > ($iWidth - $diam) Then $iVectorX *= -1 ; Lorsque x bordure est atteint inverse x du vecteur
        If $iY < 0 Or $iY > ($iHeight - $diam) Then $iVectorY *= -1 ; Quand y de frontière est atteint, inverse y du vecteur

        Sleep(10)  ; Réduire pour augmenter la vitesse

    wend

EndFunc

Func _Exit()
    $bArret = True
    _GDIPlus_GraphicsDispose($hGfxCtxt)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_BitmapDispose($hBMP)
    _GDIPlus_Shutdown()
    GUIDelete($hGui)

EndFunc


Func BuildBalle($fich, $diam)
    ; Définition de la balle: ne dépend pas de la gui
    Local $hBitmap, $hBmpCtxt, $hBrush

    _GDIPlus_Startup()
    $hBitmap = _GDIPlus_BitmapCreateFromScan0($diam, $diam) ; Crée un bitmap vide
    $hBmpCtxt = _GDIPlus_ImageGetGraphicsContext($hBitmap) ; Obtient le contexte graphique de l'image bitmap
    _GDIPlus_GraphicsSetSmoothingMode($hBmpCtxt, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
    _GDIPlus_GraphicsClear($hBmpCtxt, 0xFF000000) ; fond noir
    $hBrush = _GDIPlus_BrushCreateSolid(0xFFFFFF00)
    _GDIPlus_GraphicsFillEllipse($hBmpCtxt, 0, 0, $diam, $diam, $hBrush) ; Dessine un peu de texte dans le bitmap

    ; déco sur la balle: on dessine un arc de cercle
    ; x=rcos t  et y=r(1+sin t)     t € [-pi/3 ; +pi/3]
    local  $rayon = $diam/2, $hPen  ;, $pi = atan(1)
    $hPen = _GDIPlus_PenCreate(0xFFFF0000, 2)
    _GDIPlus_GraphicsDrawArc($hBmpCtxt, -$rayon, -$rayon, $diam, $diam,  0, 90, $hPen)
    _GDIPlus_GraphicsDrawArc($hBmpCtxt, $rayon, $rayon, $diam, $diam,  180, 90, $hPen)

    ; Sauvegarde le bitmap dans $fich
    _GDIPlus_ImageSaveToFile($hBitmap, $fich) ; Sauvegarde le bitmap sur le disque

    ; Nettoie les ressources GDI+
    _GDIPlus_GraphicsDispose($hBmpCtxt)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_Shutdown()
    ;ShellExecute($fich) ; Ouvre le bitmap avec l'application par défaut
EndFunc   ;==> Example

Ah oui avec un bitmap c est mieux c est vrai

!
Oui résolus rapidement, c est juste que j ai fait ça vite fait car je suis sur plein de trucs en même temps!

j ai recupe un script qui fait une peu pareil

► Afficher le texte

AutoIt Français

[R] Pong problème

[R] Pong problème

Re: [..] Pong problème

Re: [..] Pong problème

Re: [R] Pong problème

Re: [R] Pong problème

Re: [R] Pong problème