AutoIt Français

B onjour à tous !

je souhaiterais générer une image à partir du code ci dessous pouvez vous svp m'expliquer
quelle est la meilleure manière de procéder ... je présume qu'il faut utiliser les fonctions suivantes
mais comment placer le texte dans l'image ?

_GDIPlus_GraphicsDrawImage
_GDIPlus_ImageSaveToFile

En vous remerciant pour vos conseils

Jean-Marc

► Afficher le texte

Bonjour,

► Afficher le texte

Code : Tout sélectionner

#include <GDIPlus.au3>
;#include <WinAPI.au3> est appelé par GDIPlus.au3 si ma mémoire est bonne
    Example()
    Func Example()
        Global $hGUI, $hGraphic

        ; Create GUI
        $hGUI = GUICreate("Signature Outlook", 400, 400)
        GUISetBkColor(0x00FFFF)
        $input = GUICtrlCreateInput("coco",10,300)
        GUISetState(@SW_SHOW)

        ; Draw a string
        _GDIPlus_Startup()
        $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
        _GDIPlus_GraphicsDrawString($hGraphic, "Nom :" , 10, 20)
        _GDIPlus_GraphicsDrawString($hGraphic, "Prenom :", 10,40)
        _GDIPlus_GraphicsDrawString($hGraphic, "Fonction :", 10, 60)
        _GDIPlus_GraphicsDrawString($hGraphic, "Tél Fixe :", 10, 80)
        _GDIPlus_GraphicsDrawString($hGraphic, "Tél Mobile :", 10, 100)
        _GDIPlus_GraphicsDrawString($hGraphic, "Email :", 10, 120)
        _GDIPlus_GraphicsDrawString($hGraphic, "Campagne:", 10, 140)
        _GDIPlus_GraphicsDrawString($hGraphic, "Adresse  :", 10, 160)

        ;$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
        _GDIPlus_GraphicsDrawString($hGraphic,GUICtrlRead($input),110,20)
        _GDIPlus_GraphicsDrawString($hGraphic, GUICtrlRead($input), 110,40)
        _GDIPlus_GraphicsDrawString($hGraphic,"En week end", 110, 60)
       ; _GDIPlus_GraphicsDrawString($hGraphic, GUICtrlRead($input_TelFixe), 110, 80)
       ; _GDIPlus_GraphicsDrawString($hGraphic,GUICtrlRead($input_mobile), 110, 100)
       ; _GDIPlus_GraphicsDrawString($hGraphic, GUICtrlRead($input_Email), 110, 120)
       ; _GDIPlus_GraphicsDrawString($hGraphic, GUICtrlRead($check_Adresse), 110, 140)
       ; _GDIPlus_GraphicsDrawString($hGraphic, GUICtrlRead($check_Campagne), 110, 160)
        ; Loop until the user exits.
$bitmap = _GDIPlus_GetBitmapFromGraphic($hGUI, 400, 300);http://www.autoitscript.fr/forum/viewtopic.php?f=11&t=13253
_GDIPlus_ImageSaveToFile ( $bitmap, @ScriptDir & "\test.png" )
ShellExecute(@ScriptDir & "\test.png" )
        Do
        Until GUIGetMsg() = -3

        ; Clean up resources
        _GDIPlus_BitmapDispose ( $bitmap )
        _GDIPlus_GraphicsDispose($hGraphic)
        _GDIPlus_Shutdown()
    EndFunc   ;==>Example
    Func _GDIPlus_GetBitmapFromGraphic($hWnd, $iWidth, $iHeight)
        Local Const $hDC = _WinAPI_GetDC($hWnd)
        Local Const $memDC = _WinAPI_CreateCompatibleDC($hDC)
        Local Const $memBmp = _WinAPI_CreateCompatibleBitmap($hDC, $iWidth, $iHeight)
        _WinAPI_SelectObject ($memDC, $memBmp)
        _WinAPI_BitBlt($memDC, 0, 0, $iWidth, $iHeight, $hDC, 0, 0, 0x00CC0020) ;  0x00CC0020 = $SRCCOPY
        Local Const $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP ($memBmp)
        _WinAPI_ReleaseDC($hWnd, $hDC)
        _WinAPI_DeleteDC($memDC)
        _WinAPI_DeleteObject($memBmp)
        Return $hBitmap
    EndFunc

La fonction ajoutée a été extraite du tuto http://www.autoitscript.fr/forum/viewto ... 11&t=13253 (à lire et à relire

)

Il y a aussi cette méthode qui est pas mal.
On crée une image dont le fond est plus ou moins transparent mais il faut un Pic (explication dans le script)

► Afficher le texte

Code : Tout sélectionner

#include <GDIPlus.au3>
    Example()
    Func Example()
        Global $hGUI, $hGraphic
        Global Const $STM_SETIMAGE = 0x172
        ; Create GUI
        $hGUI = GUICreate("Signature Outlook", 400, 400)
        GUISetBkColor(0x00FFFF)
        $iPic = GUICtrlCreatePic("", 0, 0, 400, 300)
        $input = GUICtrlCreateInput("coco",10,300,200,20)
        GUISetState(@SW_SHOW)

        ; Draw a string
        _GDIPlus_Startup()
$hImage = _GDIPlus_BitmapCreateFromScan0(400, 300);image vide
$hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage);graphique créé de l'image
;_GDIPlus_GraphicsClear ( $hGraphic , 0xFFFFFFFF);100% 0xFF..... opaque
;_GDIPlus_GraphicsClear ( $hGraphic , 0xA5FFFFFF);65%
_GDIPlus_GraphicsClear ( $hGraphic , 0x3FFFFFFF);25% ==> 0% 0x00..... transparent ou on supprime Clear
        _GDIPlus_GraphicsDrawString($hGraphic, "Nom :" , 10, 20)
        _GDIPlus_GraphicsDrawString($hGraphic, "Prenom :", 10,40)
        _GDIPlus_GraphicsDrawString($hGraphic, "Fonction :", 10, 60)
        _GDIPlus_GraphicsDrawString($hGraphic, "Tél Fixe :", 10, 80)
        _GDIPlus_GraphicsDrawString($hGraphic, "Tél Mobile :", 10, 100)
        _GDIPlus_GraphicsDrawString($hGraphic, "Email :", 10, 120)
        _GDIPlus_GraphicsDrawString($hGraphic, "Campagne:", 10, 140)
        _GDIPlus_GraphicsDrawString($hGraphic, "Adresse  :", 10, 160)

        ;$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
        _GDIPlus_GraphicsDrawString($hGraphic,GUICtrlRead($input),110,20)
        _GDIPlus_GraphicsDrawString($hGraphic, GUICtrlRead($input), 110,40)
        _GDIPlus_GraphicsDrawString($hGraphic,"En week end", 110, 60)
       ; _GDIPlus_GraphicsDrawString($hGraphic, GUICtrlRead($input_TelFixe), 110, 80)
       ; _GDIPlus_GraphicsDrawString($hGraphic,GUICtrlRead($input_mobile), 110, 100)
       ; _GDIPlus_GraphicsDrawString($hGraphic, GUICtrlRead($input_Email), 110, 120)
       ; _GDIPlus_GraphicsDrawString($hGraphic, GUICtrlRead($check_Adresse), 110, 140)
       ; _GDIPlus_GraphicsDrawString($hGraphic, GUICtrlRead($check_Campagne), 110, 160)
        ; Loop until the user exits.

$hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
GUICtrlSendMsg($iPic, $STM_SETIMAGE, $IMAGE_BITMAP, $hBitmap);on place l'image dans le pic
_WinAPI_DeleteObject($hBitmap)


_GDIPlus_ImageSaveToFile ( $hImage, @ScriptDir & "\test.png" )
ShellExecute(@ScriptDir & "\test.png" )
        Do
        Until GUIGetMsg() = -3

        ; Clean up resources
        _GDIPlus_BitmapDispose ( $hImage )
        _GDIPlus_GraphicsDispose($hGraphic)
        _GDIPlus_Shutdown()
    EndFunc   ;==>Example

Mais je ne suis qu'un scripteur du dimanche. Il y a sur le forum des spécialistes comme matwachich, TommyDDR, mikell, et d'autres qui auront certainement des solutions plus simples ou plus pro

[Edit] J'ai remis la main sur un exemple de Maître Uez (texte et sauvegarde)

► Afficher le texte

Code : Tout sélectionner

;coded by UEZ 2013-04-26
#include <GDIPlus.au3>
_GDIPlus_Startup()

Global $iW = 650, $iH = 210, $aResult
Global Const $hGUI = GUICreate("Test", $iW, $iH)
GUISetBkColor(0xFFFFFF)
GUISetState()

Global Const $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
Global Const $hBitmap = _GDIPlus_BitmapCreateFromGraphics($iW, $iH, $hGraphics)
Global Const $hCtxt = _GDIPlus_ImageGetGraphicsContext($hBitmap)
_GDIPlus_GraphicsSetPixelOffsetMode($hCtxt, 2)
_GDIPlus_GraphicsSetTextRenderingHint($hCtxt, 4)
_GDIPlus_GraphicsSetSmoothingMode($hCtxt, 2)

$aResult = _GDIPlus_DrawText($hCtxt, @ComputerName, 40, 20, 15, "Arial", 0xF00000FF, 0x80808020)
$aResult = _GDIPlus_DrawText($hCtxt, "Online", 40, $aResult[0] + $aResult[2] + 40, 15, "Arial", 0xF000FF00, 0xA8A0A0A0, 3)

$aResult = _GDIPlus_DrawText($hCtxt, @ComputerName, 70, 20, 120, "Arial", 0xFFFFFFFF, 0x80808020, 0.75, 3)
$aResult = _GDIPlus_DrawText($hCtxt, "Offline", 70, $aResult[0] + $aResult[2] + 40, 120, "Arial", 0xFFFF0000, 0xA8808080, 3, 1)

_GDIPlus_GraphicsDrawImageRect($hGraphics, $hBitmap, 0, 0, $iW, $iH)
_GDIPlus_ImageSaveToFile($hBitmap, @ScriptDir & "\Text.png")

Do
    If GUIGetMsg() = -3 Then
        _GDIPlus_GraphicsDispose($hCtxt)
        _GDIPlus_GraphicsDispose($hGraphics)
        _GDIPlus_BitmapDispose($hBitmap)
        _GDIPlus_Shutdown()
        GUIDelete()
        Exit
    EndIf
Until False

Func _GDIPlus_DrawText($hGraphics, $sText, $fFontSize, $iX = 0, $iY = 0, $sFontName = "Arial", $iFGColor = 0xFF0000FF, $iBGColor = 0xF8FFFFFF, $fStretch = 1, $iPenSize = 1) ;coded by UEZ 2013
    Local Const $hFormat = _GDIPlus_StringFormatCreate()
    Local Const $hFamily = _GDIPlus_FontFamilyCreate($sFontName)
    Local Const $hPath = _GDIPlus_PathCreate()
    Local Const $tLayout = _GDIPlus_RectFCreate(0, 0, 0, 0)
    Local Const $hLineBrush = _GDIPlus_LineBrushCreate(0, 0, 20, 4, 0x80000000, $iBGColor, 1)
    Local Const $hPen = _GDIPlus_PenCreate2($hLineBrush, $iPenSize)
    Local Const $fRad = ACos(-1) / 180
    Local $i
    For $i = 1 To 360 Step 90
        DllStructSetData($tLayout, "X", $iX + Cos($i * $fRad))
        DllStructSetData($tLayout, "Y", $iY + Sin($i * $fRad))
        _GDIPlus_PathAddString($hPath, $sText, $tLayout, $hFamily, 0, $fFontSize, $hFormat)
    Next
    _GDIPlus_GraphicsDrawPath($hGraphics, $hPath, $hPen)
    Local $aWorldBounds = _GDIPlus_PathGetWorldBounds($hPath)
    _GDIPlus_PathReset($hPath)
    Local Const $iFGColorShift = 0xFF000000 + BitShift(BitAND($iFGColor, 0xFF0000), 1) + BitShift(BitAND($iFGColor, 0xFF00), 1) + BitShift(BitAND($iFGColor, 0xFF), 1) ;half RGB color values
    Local Const $hBrush = _GDIPlus_LineBrushCreate(0, 0, $aWorldBounds[2] * $fStretch, $aWorldBounds[3] * 1.5, $iFGColorShift, $iFGColor, 1)
    _GDIPlus_LineBrushSetGammaCorrection($hBrush, True)
    DllStructSetData($tLayout, "X", $iX)
    DllStructSetData($tLayout, "Y", $iY)
    _GDIPlus_PathAddString($hPath, $sText, $tLayout, $hFamily, 0, $fFontSize, $hFormat)
    _GDIPlus_GraphicsFillPath($hGraphics, $hPath, $hBrush)
    $aWorldBounds = _GDIPlus_PathGetWorldBounds($hPath)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_BrushDispose($hLineBrush)
    _GDIPlus_PathDispose($hPath)
    Return $aWorldBounds
EndFunc   ;==>_GDIPlus_DrawText

AutoIt Français

[R] GDIPLUS convertir en image

[R] GDIPLUS convertir en image

Re: [..] GDIPLUS convertir en image

Re: [..] GDIPLUS convertir en image