AutoIt Français

Bonjour.

Je souhaite en effet pouvoir déplacer, via un script AutoIt, la barre des tâches Windows.

Pour cela, et après recherche, ce topic (forum AutoIt US) apporte une solution : https://www.autoitscript.com/forum/topi ... e-taskbar/

Par contre, le souci : quand je veux mettre une interface graphique, ça foire.

Voici une capture de l'interface :

► Afficher le texteImage

En effet, j'ai créé un bouton (GAUCHE / HAUT / DROITE / BAS).
Et si je clique sur n'importe quel bouton, le curseur semble rester actif.

Je m'explique :

Si je déplace le curseur à droite (sans clic enfoncé), la barre se déplace à droite...
Si je déplace le curseur à gauche (sans clic enfoncé), la barre se met à gauche...
...et ainsi de suite...
Par contre, si je reclique gauche, la barre ne s'est pas déplacé, elle revient à son état initial.

Bref, on dirait que je clique gauche enfoncé pour déplacer la barre : procédure de base.
Mais que le (re)clic gauche ensuite ne fait pas le "boulot" ^^

Voici mon script :

► Afficher le texteCode avec interface

Code : Tout sélectionner

; #FUNCTION# ====================================================================================================================
; Name ..........: _MoveTaskBar
; Description ...: Moves the Windows 7 Taskbar to a New Location on the Screen.
; Syntax ........: _MoveTaskBar([$ScreenPosX [, $ScreenPosY = '']])
; Parameters ....: $ScreenPosX = Left, Right, Top, Bottom
;                or $ScreenPosX And $ScreenPosY = New Window Location
; Return values .: Success - True
;                 Failure - False
; Author ........: IanN1990
; Remarks .......:
; Example .......:
; Note ..........:
; ===============================================================================================================================

;~ _MoveTaskBar("top", "")
;~ sleep(2000)
;~ _MoveTaskBar("bottom", "")

#include <GuiButton.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $Form1 = GUICreate("Form1", 250, 170, 192, 124)

$VarBt = "GAUCHE"
$File = @TempDir & "\nbchar.txt"
$TmpFile = FileOpen($File, 2)
$nbchar = StringLen($VarBt)
$vardecoup = StringSplit($VarBt, "")
For $i = 1 To $nbchar
    FileWriteLine($TmpFile, $vardecoup[$i])
Next
FileClose($TmpFile)
$TxtLeft = FileRead($File)
$VarBt = "DROITE"
$File = @TempDir & "\nbchar.txt"
$TmpFile = FileOpen($File, 2)
$nbchar = StringLen($VarBt)
$vardecoup = StringSplit($VarBt, "")
For $i = 1 To $nbchar
    FileWriteLine($TmpFile, $vardecoup[$i])
Next
FileClose($TmpFile)
$TxtRight = FileRead($File)
FileDelete(@TempDir & "\nbchar.txt")


$TaskBarOnLeft = GUICtrlCreateButton($TxtLeft, 10, 10, 30, 150, $BS_MULTILINE)
$TaskBarOnTop = GUICtrlCreateButton("HAUT", 50, 10, 150, 30)
$TaskBarOnRight = GUICtrlCreateButton($TxtRight, 210, 10, 30, 150, $BS_MULTILINE)
$TaskBarOnBottom = GUICtrlCreateButton("BAS", 50, 130, 150, 30)


GUISetState(@SW_SHOW)



While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $TaskBarOnLeft
            _MoveTaskBar("left", "")
        Case $TaskBarOnTop
            _MoveTaskBar("top", "")
        Case $TaskBarOnRight
            _MoveTaskBar("right", "")
        Case $TaskBarOnBottom
            _MoveTaskBar("bottom", "")

    EndSwitch
WEnd




Func _MoveTaskBar($ScreenPosX, $ScreenPosY = '')
    Local $LockState = RegRead("HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced", "TaskbarSizeMove") ;Get Lock State
    Local $TaskBarPos = WinGetPos('[Class:Shell_TrayWnd]') ;Get Current TaskBar State

    If Not $LockState Then DllCall("user32.dll", "lresult", "SendMessageW", "hwnd", WinGetHandle("[CLASS:Shell_TrayWnd]"), "uint", 273, "wparam", 424, "lparam", 0) ;Unlock Taskbar
    ControlSend('[Class:Shell_TrayWnd]', '', '', '!{Space}' & '{l}' & '{Up}') ;Prepare TaskBar For Movement

    If $ScreenPosX = 'Left' Then
        MouseMove(0, @DesktopHeight / 2, 0)
    ElseIf $ScreenPosX = 'Right' Then
        MouseMove(@DesktopWidth / 1.25, @DesktopHeight / 2, 0)
    ElseIf $ScreenPosX = 'Top' Then
        MouseMove(@DesktopWidth / 2, 0, 0)
    ElseIf $ScreenPosX = 'Bottom' Then
        MouseMove(@DesktopWidth / 2, @DesktopHeight, 0)
    ElseIf IsNumber($ScreenPosX) And IsNumber($ScreenPosY) Then
        MouseMove($ScreenPosX, $ScreenPosY, 0)
    EndIf

    ControlSend('[Class:Shell_TrayWnd]', '', '', '{Enter}') ;Complete Movemenet
    ControlHide('[Class:Shell_TrayWnd]', '', '[CLASS:TrayClockWClass; INSTANCE:1]') ;Refresh Icons To New Location
    ControlShow('[Class:Shell_TrayWnd]', '', '[CLASS:TrayClockWClass; INSTANCE:1]')

    If Not $LockState Then DllCall("user32.dll", "lresult", "SendMessageW", "hwnd", WinGetHandle("[CLASS:Shell_TrayWnd]"), "uint", 273, "wparam", 424, "lparam", 1) ;Relock Taskbar

    Local $NewTaskBarPos = WinGetPos('[Class:Shell_TrayWnd]') ;Get New TaskBar State

    If IsArray($TaskBarPos) And IsArray($NewTaskBarPos) And Not ($TaskBarPos[0] + $TaskBarPos[1] = $NewTaskBarPos[0] + $NewTaskBarPos[1]) Then
        Return 1 ;Sucess
    Else
        Return 0 ;Failure
    EndIf


EndFunc   ;==>_MoveTaskBar

Ce code fonctionne par contre (sans interface graphique) :

► Afficher le texteCode sans interface

Code : Tout sélectionner

; #FUNCTION# ====================================================================================================================
; Name ..........: _MoveTaskBar
; Description ...: Moves the Windows 7 Taskbar to a New Location on the Screen.
; Syntax ........: _MoveTaskBar([$ScreenPosX [, $ScreenPosY = '']])
; Parameters ....: $ScreenPosX = Left, Right, Top, Bottom
;                or $ScreenPosX And $ScreenPosY = New Window Location
; Return values .: Success - True
;                 Failure - False
; Author ........: IanN1990
; Remarks .......:
; Example .......:
; Note ..........:
; ===============================================================================================================================

_MoveTaskBar("left", "")
sleep(1000)
_MoveTaskBar("top", "")
sleep(1000)
_MoveTaskBar("right", "")
sleep(1000)
_MoveTaskBar("bottom", "")

Func _MoveTaskBar($ScreenPosX, $ScreenPosY = '')
    Local $LockState = RegRead("HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced", "TaskbarSizeMove") ;Get Lock State
    Local $TaskBarPos = WinGetPos('[Class:Shell_TrayWnd]') ;Get Current TaskBar State

    If Not $LockState Then DllCall("user32.dll", "lresult", "SendMessageW", "hwnd", WinGetHandle("[CLASS:Shell_TrayWnd]"), "uint", 273, "wparam", 424, "lparam", 0) ;Unlock Taskbar
    ControlSend('[Class:Shell_TrayWnd]', '', '', '!{Space}' & '{l}' & '{Up}') ;Prepare TaskBar For Movement

    If $ScreenPosX = 'Left' Then
        MouseMove(0, @DesktopHeight / 2, 0)
    ElseIf $ScreenPosX = 'Right' Then
        MouseMove(@DesktopWidth / 1.25, @DesktopHeight / 2, 0)
    ElseIf $ScreenPosX = 'Top' Then
        MouseMove(@DesktopWidth / 2, 0, 0)
    ElseIf $ScreenPosX = 'Bottom' Then
        MouseMove(@DesktopWidth / 2, @DesktopHeight, 0)
    ElseIf IsNumber($ScreenPosX) And IsNumber($ScreenPosY) Then
        MouseMove($ScreenPosX, $ScreenPosY, 0)
    EndIf

    ControlSend('[Class:Shell_TrayWnd]', '', '', '{Enter}') ;Complete Movemenet
    ControlHide('[Class:Shell_TrayWnd]', '', '[CLASS:TrayClockWClass; INSTANCE:1]') ;Refresh Icons To New Location
    ControlShow('[Class:Shell_TrayWnd]', '', '[CLASS:TrayClockWClass; INSTANCE:1]')

    If Not $LockState Then DllCall("user32.dll", "lresult", "SendMessageW", "hwnd", WinGetHandle("[CLASS:Shell_TrayWnd]"), "uint", 273, "wparam", 424, "lparam", 1) ;Relock Taskbar

    Local $NewTaskBarPos = WinGetPos('[Class:Shell_TrayWnd]') ;Get New TaskBar State

    If IsArray($TaskBarPos) And IsArray($NewTaskBarPos) And Not ($TaskBarPos[0] + $TaskBarPos[1] = $NewTaskBarPos[0] + $NewTaskBarPos[1]) Then
        Return 1 ;Sucess
    Else
        Return 0 ;Failure
    EndIf


EndFunc   ;==>_MoveTaskBar

pouvez-vous m'aider, m'aiguiller ?

Je pense que la souris reste active alors qu'elle ne doit pas l'être.
En gros, exécuter l'action sans que le curseur de la souris l'empêche.

Merci

@++

Bonjour, pour la circonstance, j'ai écrit la fonction MoveTaskBar. Ce code vous convient il ?

► Afficher le texte

Code : Tout sélectionner

; Script testé sur Windows 7, Windows 8.1 et Windows 10
; Source : http://www.sevenforums.com/tutorials/1066-taskbar-move-location-desktop-screen.html

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


Opt("GUIOnEventMode", 1)
GUICreate("TaskBar Mover", 280, 320, 190, 125)
GUISetOnEvent($GUI_EVENT_CLOSE, "Quit")

GUICtrlCreateButton("Top", 65, 45, 145, 50)
GUICtrlSetOnEvent(-1, "Btn_TopClick")

GUICtrlCreateButton("Right", 210, 70, 50, 160)
GUICtrlSetOnEvent(-1, "Btn_RightClick")

GUICtrlCreateButton("Left", 15, 70, 50, 160)
GUICtrlSetOnEvent(-1, "Btn_LeftClick")

GUICtrlCreateButton("Bottom", 65, 205, 145, 50)
GUICtrlSetOnEvent(-1, "Btn_BottomClick")

GUICtrlCreateButton("Quit", 102, 280, 75, 25)
GUICtrlSetOnEvent(-1, "Quit")
GUISetState(@SW_SHOW)

While 1
    Sleep(100)
WEnd

Func Btn_BottomClick()
    MoveTaskBar("Bottom")
EndFunc   ;==>Btn_BottomClick

Func Btn_RightClick()
    MoveTaskBar("Right")
EndFunc   ;==>Btn_RightClick

Func Btn_LeftClick()
    MoveTaskBar("Left")
EndFunc   ;==>Btn_LeftClick

Func Btn_TopClick()
    MoveTaskBar("Top")
EndFunc   ;==>Btn_TopClick

Func Quit()
    Exit
EndFunc   ;==>Quit

Func MoveTaskBar($sPos = "Bottom")
   Local $StuckRects = "StuckRects2"
   If @OSVersion = "WIN_10" Then $StuckRects = "StuckRects3"
    Local $szBottom = "0x28000000ffffffff02000000030000003e0000002e000000000000008204000080070000b0040000"
    Local $szLeft = "0x28000000ffffffff02000000000000003e0000002e00000000000000000000003e000000b0040000"
    Local $szRight = "0x28000000ffffffff02000000020000003e0000002e000000420700000000000080070000b0040000"
    Local $szTop = "0x28000000ffffffff02000000010000003e0000002e0000000000000000000000800700002e000000"

    Select
        Case $sPos = "Bottom"
            $sPos = $szBottom

        Case $sPos = "Left"
            $sPos = $szLeft

        Case $sPos = "Right"
            $sPos = $szRight

        Case $sPos = "Top"
            $sPos = $szTop

        Case Else
            Return SetError(1, 0, 0)

    EndSelect

    ; Write new key
    RegWrite($HKey, "Settings", "REG_BINARY", $sPos)

    ; Restart Explorer
    $Kernel32 = DllOpen("kernel32.dll")
    $hproc = DllCall($Kernel32, 'int', 'OpenProcess', 'int', 0x1F0FFF, 'int', True, 'int', ProcessExists('explorer.exe'))
    DllCall($Kernel32, "int", "TerminateProcess", "int", $hproc[0], "dword", 0)
    DllClose($Kernel32)
    Return 1
EndFunc   ;==>MoveTaskBar

Salut Chef, et merci de votre réponse

Par contre, le code ne fonctionne pas.
Et je pense que cela est dû à mon système (windows 10)

Et explorer.exe ne se relance pas, donc j'ai rajouté un shellexecute("explorer.exe") au cas où.
La barre reste à la même place.

J'aurais bien une solution : coder chaque changement (HAUT / BAS / GAUCHE / DROITE) indépendamment du script initial.
De les inclure avec un fileinstall et d'appeler "le fichier" en conséquence.

Quelque chose me dit que les données de la valeur settings ne doit pas être les mêmes sous Windows 10.

Je vais tenter de mon côté.

@+ et encore merci.

Hummm, j'avoue que Windows 10 ne faisait pas partie de l'équation.

Je viens juste de passer ma Surface en 10 mais pas assez de temps pour faire des tests.

Jetez un oeil sur la clé mentionnée dans le code que je vous ai donné en fonction de la position de votre barre. Peut être que Microsoft a modifier la gestion de cette clé. ^^

Envoyé de mon appareil mobile avec Tapatalk.

C'est bizarre que ça ne marche pas dès lors qu'on utilise une GUI...

J'ai le même comportement sur mon PC (Windows 7).

Ça marche si on passe par Send au lieu de ControlSend, je comprends pas trop pourquoi (j'ai essayé le WinActivate, ControlFocus avant mais non).
Voilà la fonction légèrement modifiée :

► Afficher le texte

Salut à tous

Et merci à mon sauveur de vert vêtu

Ca fonctionne impeccable

D'ailleurs, j'ai fait aussi une version "clic droit sur le systray" et je rencontrais le même problème.
Je peux donc aussi le résoudre grâce à la fonction que tu as pris la peine de modifier.

Un grand merci à tous

Je passe en Résolu, et je repasserais pour mettre le code complet.

EDIT :
Bon, je suis curieux de nature, donc je me permet de voir si j'ai bien saisi la chose.

En fait, si j'ai bien compris : le souci venait de ce bout de cette ligne :
ControlSend('[Class:Shell_TrayWnd]', '', '', '!{Space}' & '{l}' & '{Up}') ;Prepare TaskBar For Movement

Que tu as donc modifié en faisant par étape, c'est à dire mise en place d'un WinActivate suivi de la commande Send

Je ne connaissais pas la commande BlockInput. En clair, elle permet, le temps de la prise de contrôle de la barre des tâches, de désactiver la souris MAIS également le clavier.

Pour résumer :
Tu as remplacé cette ligne ControlSend('[Class:Shell_TrayWnd]', '', '', '!{Space}' & '{l}' & '{Up}') ;Prepare TaskBar For Movement par :

Code : Tout sélectionner

    BlockInput(1)
    WinActivate(WinGetHandle("[CLASS:Shell_TrayWnd]"))
    Send('!{SPACE}{l}{DOWN}')
    BlockInput(0)

Ai-je tout compris ?

En tout cas, j'aurais appris des choses

@++ et bonne journée à tous.

Bonjour.
Bon, je me suis installé un Win10 dans une VM pour faire des tests et effectivement, Microsoft à apporté une petite modification.
Au lieu d'utiliser la clé :

Code : Tout sélectionner

HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\StuckRects2

Il faut modifier la clé :

Code : Tout sélectionner

HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\StuckRects3

J'ai éditer mon précédent code afin d'adapter la fonction MoveTaskBar() à Windows 10.

Salut

Merci Tlem, j'vais voir de suite

En attendant, je viens de "finir" (je vais encore le peaufiner) le script :
- J'ai ajouté des options via le clic droit sur l'icone de notification
- et la possibilité de masquer / afficher la barre des tâches windows.

Le voici :

► Afficher le texteCode opérationnel

Code : Tout sélectionner

; #FUNCTION# ====================================================================================================================
; Name ..........: _MoveTaskBar
; Description ...: Moves the Windows 7 Taskbar to a New Location on the Screen.
; Syntax ........: _MoveTaskBar([$ScreenPosX [, $ScreenPosY = '']])
; Parameters ....: $ScreenPosX = Left, Right, Top, Bottom
;                or $ScreenPosX And $ScreenPosY = New Window Location
; Return values .: Success - True
;                 Failure - False
; Author ........: IanN1990
; Remarks .......:
; Example .......:
; Note ..........:
; ===============================================================================================================================

;; Fonction '_MoveTaskBar' modifiée par jguinch (pour intégration GUI) ( merci à tous ! )
;; => http://www.autoitscript.fr/forum/viewtopic.php?p=95227#p95227

#include <GuiButton.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <TrayConstants.au3> ; Required for the $TRAY_ICONSTATE_SHOW constant.

Opt("TrayMenuMode", 3)
Global $LeftLabel, $TopLabel, $RightLabel, $BottomLabel

Global $Form1 = GUICreate("Form1", 250, 170, 192, 124)

_LabelBt()
$TaskBarOnLeft = GUICtrlCreateButton($LeftLabel, 10, 10, 30, 150, $BS_MULTILINE)
$TaskBarOnTop = GUICtrlCreateButton($TopLabel, 50, 10, 150, 30)
$TaskBarOnRight = GUICtrlCreateButton($RightLabel, 210, 10, 30, 150, $BS_MULTILINE)
$TaskBarOnBottom = GUICtrlCreateButton($BottomLabel, 50, 130, 150, 30)

Local $idLeft = TrayCreateItem("Barre des tâches : GAUCHE")
Local $idTop = TrayCreateItem("Barre des tâches : HAUT")
Local $idRight = TrayCreateItem("Barre des tâches : DROITE")
Local $idBottom = TrayCreateItem("Barre des tâches : BAS")
Local $separator = TrayCreateItem("")
Local $HideTaskBar = TrayCreateItem("Barre des tâches : MASQUER")
Local $ShowTaskBar = TrayCreateItem("Barre des tâches : AFFICHER")
Local $idExit = TrayCreateItem("Exit")

TraySetState($TRAY_ICONSTATE_SHOW) ; Show the tray menu.

GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $TaskBarOnLeft
            _MoveTaskBar("left")
        Case $TaskBarOnTop
            _MoveTaskBar("top")
        Case $TaskBarOnRight
            _MoveTaskBar("right")
        Case $TaskBarOnBottom
            _MoveTaskBar("bottom")
    EndSwitch

    Switch TrayGetMsg()
        Case $idExit ; Exit the loop.
            Exit
        Case $idLeft
            _MoveTaskBar("left")
        Case $idTop
            _MoveTaskBar("top")
        Case $idRight
            _MoveTaskBar("right")
        Case $idBottom
            _MoveTaskBar("bottom")
        Case $HideTaskBar
            _ShowTaskBar(1)
            _ShowHideTaskbar()
        Case $ShowTaskBar
            _ShowTaskBar(0)
            _ShowHideTaskbar()

    EndSwitch

WEnd


Func _LabelBt()
    $LeftLabel = "GAUCHE"
    $TopLabel = "HAUT"
    $RightLabel = "DROITE"
    $BottomLabel = "BAS"
    $File = @TempDir & "\nbchar.txt"
    $TmpFile = FileOpen($File, 2)
    $nbchar = StringLen($LeftLabel)
    $vardecoup = StringSplit($LeftLabel, "")
    For $i = 1 To $nbchar
        FileWriteLine($TmpFile, $vardecoup[$i])
    Next
    FileClose($TmpFile)
    $LeftLabel = FileRead($File)
    $TmpFile = FileOpen($File, 2)
    $nbchar = StringLen($RightLabel)
    $vardecoup = StringSplit($RightLabel, "")
    For $i = 1 To $nbchar
        FileWriteLine($TmpFile, $vardecoup[$i])
    Next
    FileClose($TmpFile)
    $RightLabel = FileRead($File)
    FileDelete(@TempDir & "\nbchar.txt")
EndFunc   ;==>_LabelBt

Func _MoveTaskBar($ScreenPosX, $ScreenPosY = '')
    Local $LockState = RegRead("HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced", "TaskbarSizeMove") ;Get Lock State
    Local $TaskBarPos = WinGetPos('[Class:Shell_TrayWnd]') ;Get Current TaskBar State

    If Not $LockState Then DllCall("user32.dll", "lresult", "SendMessageW", "hwnd", WinGetHandle("[CLASS:Shell_TrayWnd]"), "uint", 273, "wparam", 424, "lparam", 0) ;Unlock Taskbar
    BlockInput(1)
    WinActivate(WinGetHandle("[CLASS:Shell_TrayWnd]"))
    Send('!{SPACE}{l}{DOWN}')
    BlockInput(0)

    If $ScreenPosX = 'Left' Then
        MouseMove(0, @DesktopHeight / 2, 0)
    ElseIf $ScreenPosX = 'Right' Then
        MouseMove(@DesktopWidth / 1.25, @DesktopHeight / 2, 0)
    ElseIf $ScreenPosX = 'Top' Then
        MouseMove(@DesktopWidth / 2, 0, 0)
    ElseIf $ScreenPosX = 'Bottom' Then
        MouseMove(@DesktopWidth / 2, @DesktopHeight, 0)
    ElseIf IsNumber($ScreenPosX) And IsNumber($ScreenPosY) Then
        MouseMove($ScreenPosX, $ScreenPosY, 0)
    EndIf

    ControlSend('[Class:Shell_TrayWnd]', '', '', '{Enter}') ;Complete Movemenet
    ControlHide('[Class:Shell_TrayWnd]', '', '[CLASS:TrayClockWClass; INSTANCE:1]') ;Refresh Icons To New Location
    ControlShow('[Class:Shell_TrayWnd]', '', '[CLASS:TrayClockWClass; INSTANCE:1]')

    If Not $LockState Then DllCall("user32.dll", "lresult", "SendMessageW", "hwnd", WinGetHandle("[CLASS:Shell_TrayWnd]"), "uint", 273, "wparam", 424, "lparam", 1) ;Relock Taskbar

    Local $NewTaskBarPos = WinGetPos('[Class:Shell_TrayWnd]') ;Get New TaskBar State

    If IsArray($TaskBarPos) And IsArray($NewTaskBarPos) And Not ($TaskBarPos[0] + $TaskBarPos[1] = $NewTaskBarPos[0] + $NewTaskBarPos[1]) Then
        Return 1 ;Sucess
    Else
        Return 0 ;Failure
    EndIf
EndFunc   ;==>_MoveTaskBar

Func _ShowHideTaskbar()
    Global $SHTB = GUICreate("Afficher / masquer", 390, 50, 192, 124)
    $HideTaskBar = GUICtrlCreateButton("Cacher la barre des tâches", 10, 10, 180, 30)
    $ShowTaskBar = GUICtrlCreateButton("Afficher la barre des tâches", 200, 10, 180, 30)
    GUISetState(@SW_SHOW)

    While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE
                GUIDelete($SHTB)
                ExitLoop
            Case $HideTaskBar
                _ShowTaskBar(1)
            Case $ShowTaskBar
                _ShowTaskBar(0)
        EndSwitch
    WEnd

EndFunc   ;==>_ShowHideTaskbar

Func _ShowTaskBar($fShow)
    Local $hTaskBar
    If @OSVersion = "WIN_VISTA" Or @OSVersion = "WIN_2008" Or @OSVersion = "WIN_7" Then _ShowStartButton($fShow)
    $hTaskBar = _WinAPI_FindWindow("Shell_TrayWnd", "")
    If $fShow = 0 Then
        _WinAPI_ShowWindow($hTaskBar, @SW_SHOW)
    Else
        _WinAPI_ShowWindow($hTaskBar, @SW_HIDE)
        _WinAPI_ShowWindow($hTaskBar, @SW_DISABLE)
    EndIf
EndFunc   ;==>_ShowTaskBar
Func _ShowStartButton($fShow)
    Local $hTaskBar, $hStartButton
    If @OSVersion = "WIN_VISTA" Or @OSVersion = "WIN_2008" Or @OSVersion = "WIN_7" Then
        $hStartButton = _WinAPI_FindWindow("Button", "Start")
    Else
        $hTaskBar = _WinAPI_FindWindow("Shell_TrayWnd", "")
        $hStartButton = ControlGetHandle($hTaskBar, "", "Button1")
    EndIf
    If $fShow = 0 Then
        _WinAPI_ShowWindow($hStartButton, @SW_SHOW)
    Else
        _WinAPI_ShowWindow($hStartButton, @SW_HIDE)
        _WinAPI_ShowWindow($hStartButton, @SW_DISABLE)
    EndIf
EndFunc   ;==>_ShowStartButton

Maintenant, j'ai un script à étudier

++ et thanks everyone

Salut.

Oui c'est encore moi

Pour le script :
J'ai remplacé un bout de code et ça fonctionne

Mais j'ai toujours ce fichu souci de explorer.exe qui se ferme bien mais qui a peur de revenir.

Vais voir pourquoi il a peur de ce que je peux le faire subir. ^^

Un grand merci en tout cas.

@+

Bonjour.
Voici une version améliorée de mon code précédent :

► Afficher le texte

Code : Tout sélectionner

; Script testé sur Windows 7, Windows 8.1 et Windows 10
; Source : http://www.sevenforums.com/tutorials/1066-taskbar-move-location-desktop-screen.html

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


Opt("GUIOnEventMode", 1)
GUICreate("TaskBar Mover", 280, 390, 190, 125)
GUISetOnEvent($GUI_EVENT_CLOSE, "Quit")

GUICtrlCreateButton("Top", 65, 45, 145, 50)
GUICtrlSetOnEvent(-1, "Btn_TopClick")

GUICtrlCreateButton("Right", 210, 70, 50, 160)
GUICtrlSetOnEvent(-1, "Btn_RightClick")

GUICtrlCreateButton("Left", 15, 70, 50, 160)
GUICtrlSetOnEvent(-1, "Btn_LeftClick")

GUICtrlCreateButton("Bottom", 65, 205, 145, 50)
GUICtrlSetOnEvent(-1, "Btn_BottomClick")

GUICtrlCreateButton("AutoHide On", 70, 270, 70, 25)
GUICtrlSetOnEvent(-1, "Btn_AutoHideOn")

GUICtrlCreateButton("AutoHide Off", 140, 270, 70, 25)
GUICtrlSetOnEvent(-1, "Btn_AutoHideOff")

GUICtrlCreateButton("Lock On", 70, 305, 70, 25)
GUICtrlSetOnEvent(-1, "Btn_LockOn")

GUICtrlCreateButton("Lock Off", 140, 305, 70, 25)
GUICtrlSetOnEvent(-1, "Btn_LockOff")

GUICtrlCreateButton("Quit", 102, 350, 75, 25)
GUICtrlSetOnEvent(-1, "Quit")
GUISetState(@SW_SHOW)

While 1
    Sleep(100)
WEnd

Func Btn_BottomClick()
    _MoveTaskBar("Bottom")
EndFunc   ;==>Btn_BottomClick

Func Btn_RightClick()
    _MoveTaskBar("Right")
EndFunc   ;==>Btn_RightClick

Func Btn_LeftClick()
    _MoveTaskBar("Left")
EndFunc   ;==>Btn_LeftClick

Func Btn_TopClick()
    _MoveTaskBar("Top")
EndFunc   ;==>Btn_TopClick

Func Btn_AutoHideOn()
    _MoveTaskBar(-1, 1, -1)
EndFunc   ;==>Btn_AutoHideOn

Func Btn_AutoHideOff()
    _MoveTaskBar(-1, 0, -1)
EndFunc   ;==>Btn_AutoHideOff

Func Btn_LockOn()
    _MoveTaskBar(-1, -1, 1)
EndFunc   ;==>Btn_LockOn

Func Btn_LockOff()
    _MoveTaskBar(-1, -1, 0)
EndFunc   ;==>Btn_LockOff

Func Quit()
    Exit
EndFunc   ;==>Quit


; #FUNCTION# ====================================================================================================================
; Name ..........: _MoveTaskBar
; Description ...: Moves the Windows Taskbar to a New Location on the Screen.
; Syntax ........: _MoveTaskBar([$ScreenPos [, $iAutoHide = Default [, $iLock = Default]]])
; Parameters ....: $ScreenPosX = Left, Right, Top, Bottom or -1 if you want to keep actual position (default value Bottom)
;                  $iAutoHide = 0, 1 or -1 if you want to keep actual value (default value -1)
;                  $iLock = 0, 1 or -1 if you want to keep actual value (default value -1)
; Return values .: Success - True
;                  Failure - False and set @error = 1
; Author ........: Tlem
; Remarks .......: Tested on windows XP, 7, 8.1 and 10
; Example .......:
; Note ..........:
; ===============================================================================================================================
Func _MoveTaskBar($ScreenPos = "Bottom", $iAutoHide = -1, $iLock = -1)
    Local $StuckRects = (@OSVersion = "WIN_10") ? "StuckRects3" : "StuckRects2"
    Local $sStuckRectsHKey = "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\" & $StuckRects
    Local $sLockHKey = "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced\"

    $iAutoHide = ($iAutoHide = -1) ? StringMid(RegRead($sStuckRectsHKey, "Settings"), 19, 2) : (($iAutoHide = 0) ? "02" : "03")
    $iLock = ($iLock = -1) ? RegRead($sLockHKey, "TaskbarSizeMove") : (($iLock = 1) ? 0x00 : 0x01)

    Select
        Case $ScreenPos = "Bottom"
            $ScreenPos = "0x28000000ffffffff02000000030000003e0000002e000000000000008204000080070000b0040000"

        Case $ScreenPos = "Left"
            $ScreenPos = "0x28000000ffffffff02000000000000003e0000002e00000000000000000000003e000000b0040000"

        Case $ScreenPos = "Right"
            $ScreenPos = "0x28000000ffffffff02000000020000003e0000002e000000420700000000000080070000b0040000"

        Case $ScreenPos = "Top"
            $ScreenPos = "0x28000000ffffffff02000000010000003e0000002e0000000000000000000000800700002e000000"

        Case $ScreenPos = -1
            $ScreenPos = RegRead($sStuckRectsHKey, "Settings")

        Case Else
            Return SetError(1, 0, 0)

    EndSelect

    $ScreenPos = StringMid($ScreenPos, 1, 18) & $iAutoHide & StringMid($ScreenPos, 21)

    ; Write new keys
    RegWrite($sStuckRectsHKey, "Settings", "REG_BINARY", $ScreenPos)
    RegWrite($sLockHKey, "TaskbarSizeMove", "REG_DWORD", $iLock)

    ; Restart Explorer
    $Kernel32 = DllOpen("kernel32.dll")
    $hproc = DllCall($Kernel32, 'int', 'OpenProcess', 'int', 0x1F0FFF, 'int', True, 'int', ProcessExists('explorer.exe'))
    DllCall($Kernel32, "int", "TerminateProcess", "int", $hproc[0], "dword", 0)
    DllClose($Kernel32)
    Return 1
EndFunc   ;==>MoveTaskBar

Fonctionne de Windows XP à Windows 10.

Salut

Et merci à toi Tlem

Ca marche impeccable.

Maintenant, faut que je cherche comment relancer IE.
Ca doit être simple, donc je ne me fais pas de souci. ^^

@+ et bonne soirée à tous3

Salut.

Je savais bien que c'était un truc tout simple.
J'ai même honte de m'être fait avoir.

J'ai juste rajouté Run("explorer.exe") entre DllClose($Kernel32) et Return 1

Sinon, ton script - par rapport au "masquage" de la barre des tâches, ne fait pas la vraiment même chose.
Donc impeccable, ça apporte de nouvelles possibilités.

En effet, avec ton script, on peut activer le fameux "masquer automatiquement la barre des taches" (et aussi le verrouillage).
On va dire que dans mon script, je fais "pire" : je la cache en vrai. Voire "enlèvement" ^^

Elle n'apparait plus et ne peut plus apparaitre, même si on survole avec le curseur.

Bref, sympa

@++

AutoIt Français

[R] Souci de déplacement de la barre des tâches Windows

[R] Souci de déplacement de la barre des tâches Windows

Re: [..] Souci de déplacement de la barre des tâches Windows

Re: [..] Souci de déplacement de la barre des tâches Windows

Re: [..] Souci de déplacement de la barre des tâches Windows

Re: [..] Souci de déplacement de la barre des tâches Windows

Re: [..] Souci de déplacement de la barre des tâches Windows

Re: [R] Souci de déplacement de la barre des tâches Windows

Re: [R] Souci de déplacement de la barre des tâches Windows

Re: [R] Souci de déplacement de la barre des tâches Windows

Re: [R] Souci de déplacement de la barre des tâches Windows

Re: [R] Souci de déplacement de la barre des tâches Windows

Re: [R] Souci de déplacement de la barre des tâches Windows