AutoIt Français

Bonjour à tous,
J'aimerais faire un copie coller tout d'abord :
- D'un fichier ini à une liste dans une interface graphique
- De remplir un input et quand on appuie sur valider ca copie les lettres et ça met dans la colonne nom.

Voici mon code si cela vous facilite la compréhension :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

Global $ini = @ScriptDir & "\programme.ini"

#Region ### START Koda GUI section ### Form=T:\cstf\mainForm.kxf

$monprogramme = GUICreate("Mon Programme", 499, 435, 386, 164)
$Label1 = GUICtrlCreateLabel("Liste des programmes", 8, 8, 158, 20) ; titre liste des programmes
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")                      ; ajouter image
$executer = GUICtrlCreateButton("Execute", 352, 304, 121, 41)       ; bouton excuter
$quitter = GUICtrlCreateButton("Quiter", 352, 352, 121, 41)         ; bouton quitter
$ajouter = GUICtrlCreateButton("Ajouter", 352, 32, 121, 41)         ; bouton ajouter
$sauvegarder = GUICtrlCreateButton("Supprimer", 352, 128, 121, 41)      ; bouton sauvegarder
$sauver = GUICtrlCreateButton("Sauver", 352, 176, 121, 41)          ; bouton sauver
$Pic1 = GUICtrlCreatePic("***", 8, 352, 329, 49) ; image **
$Pic2 = GUICtrlCreatePic("", 352, 224, 121, 73)                     ; image logiciel
$Label2 = GUICtrlCreateLabel("Version .099", 272, 408, 77, 20)      ; version 0.99
$modifier = GUICtrlCreateButton("Modifier", 352, 80, 121, 41)       ; bouton modifié
$ListView1 = GUICtrlCreateListView("|Nom|Programme", 8, 32, 337, 313) ; colonne checkbox,nom,programme
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 50)
GUISetState(@SW_SHOW)
;GUICtrlSetState($executer,$GUI_DISABLE)


#EndRegion ### END Koda GUI section ###


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $ajouter
            _ajoutprogramme()               ; lance la focntion ajoutprogramme
        Case $modifier
            _modificationpro()
        Case $ListView1
        Case $quitter
        Exit
    EndSwitch
WEnd



Func _ajoutprogramme()                      ; lance la fentre dialogue 1
$Dialogueajout = GUICreate("ajouter un programme", 477, 152, 400, 320)
$GroupBox1 = GUICtrlCreateGroup("", 18, 9, 437, 102)
$Label1 = GUICtrlCreateLabel("Nom", 32, 32, 33, 20)
$Input1 = GUICtrlCreateInput("", 80, 32, 281, 24)
$Input2 = GUICtrlCreateInput("", 80, 64, 281, 24)
$Label2 = GUICtrlCreateLabel("Fichier", 32, 64, 44, 20)
$parcourir = GUICtrlCreateButton("Parcourir", 368, 64, 73, 25)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$valider = GUICtrlCreateButton("Valider", 254, 106, 92, 31)
$cancel = GUICtrlCreateButton("&Cancel", 351, 107, 93, 31)
GUISetState(@SW_SHOW)
;GUICtrlSetState($valider,$GUI_DISABLE)
While 2
        $ndialoajout = GUIGetMsg()
    Switch $ndialoajout
        Case $parcourir
            $choixfichier = FileOpenDialog("Fichier à ajouter", "****", "Tous (*.*)", 4)
                if IniRead($ini,"LISTE",$ini,"") ="" Then
                IniWrite($ini, "LISTE", "", $choixfichier)
                IniWrite($Input2,"","",$choixfichier)
            EndIf
        Case $Input2
        GUICtrlRead($Input2)
        Case $cancel
            GUIDelete($Dialogueajout)
            Return($monprogramme)
        case $valider
            Clipput(GUICtrlRead($Input1))

    EndSwitch
WEnd
EndFunc

Func _modificationpro() ;fonction modifier programem
$dialoguemodif = GUICreate("modification du programme", 477, 152, 400, 320)
GUISetIcon("D:\002.ico", -1)
$GroupBox1 = GUICtrlCreateGroup("", 10, -15, 525, 238)
$Group1 = GUICtrlCreateGroup("", 28, 10, 437, 102)
$Label1 = GUICtrlCreateLabel("Nom", 42, 33, 33, 20)
$Input1 = GUICtrlCreateInput("", 90, 33, 281, 24)
$Input2 = GUICtrlCreateInput("", 90, 65, 281, 24)
$Label2 = GUICtrlCreateLabel("Fichier", 42, 65, 44, 20)
$parcourir = GUICtrlCreateButton("Parcourir", 378, 65, 73, 25)
$valider = GUICtrlCreateButton("&Valider", 254, 106, 92, 31)
$annuler = GUICtrlCreateButton("&Annuler", 351, 107, 93, 31)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUISetState(@SW_SHOW)
;GUICtrlSetState($valider,$GUI_DISABLE)
While 3
    $ndialoguemodif = GUIGetMsg()
    Switch $ndialoguemodif
        Case $parcourir
            $choixfichier = FileOpenDialog("Fichier à ajouter", "\\sr0-archives\refimage$", "Tous (*.*)", 4) ; fenetre chemin
            If @error Then
                MsgBox(1, "", "Veuillez choisir un programme")
            EndIf
        Case $annuler
            GUIDelete($dialoguemodif)           ;enlever fenetre dialogue
            Return($monprogramme)
    EndSwitch
WEnd
EndFunc

Merci de votre aide

Message déplacé dans Aide générale

Bonjour, je te conseillerai de te servir d'inputbox et de msgbox au lieu de creer differentes gui .
de voir du coter de de l"include GuiListView.au3 et du tuto http://www.autoitscript.fr/forum/viewto ... =11&t=9652 sur l'utilisation des fichier ini.

je risque de t'enbrouiller en te donnant des explications car je debute en autoit moi aussi et je risque de ne pas etre claire, j'ai preferer modifier un peut ton script pour repondre a tes question.
je ne suis pas sur d'avoir comprit ce que tu voullai fair avec ta fonction pour modifier ou supprimer mais voila un exemple :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>

Global $ini = @ScriptDir & "\programme.ini"
Global Const $monprogramme = GUICreate("Mon Programme", 499, 435, 386, 164)
Global Const $Label1 = GUICtrlCreateLabel("Liste des programmes", 8, 8, 158, 20) ; titre liste des programmes
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif") ; ajouter image
Global Const $executer = GUICtrlCreateButton("Execute", 352, 304, 121, 41) ; bouton excuter
Global Const $quitter = GUICtrlCreateButton("Quiter", 352, 352, 121, 41) ; bouton quitter
Global Const $ajouter = GUICtrlCreateButton("Ajouter", 352, 32, 121, 41) ; bouton ajouter
Global Const $supprimer = GUICtrlCreateButton("Supprimer", 352, 128, 121, 41) ; bouton sauvegarder
Global Const $sauver = GUICtrlCreateButton("Sauver", 352, 176, 121, 41) ; bouton sauver
Global Const $Pic1 = GUICtrlCreatePic("***", 8, 352, 329, 49) ; image **
Global Const $Pic2 = GUICtrlCreatePic("", 352, 224, 121, 73) ; image logiciel
Global Const $Label2 = GUICtrlCreateLabel("Version .099", 272, 408, 77, 20) ; version 0.99
Global Const $modifier = GUICtrlCreateButton("Modifier", 352, 80, 121, 41) ; bouton modifié

Global Const $ListView1 = GUICtrlCreateListView("Nom|Chemin", 8, 32, 337, 313) ; colonne checkbox,nom,programme
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 80)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 500)
_charger_la_liste_avec_le_fichier_param()

GUISetState(@SW_SHOW)

While 1
    Local $aSelected, $Iitem, $Litem, $taille_du_programm, $staille_du_programm
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $ajouter
            Local $ajout_nom_du_programme = InputBox("Nom du programme", "entrer le nom du programme ici : ", "")
            If Not @error Then
                Local $ajout_choixfichier = FileOpenDialog("Fichier à ajouter", "****", "Tous (*.*)", 4)
                If Not @error Then
                    Local $choix_ajout_programme = MsgBox(4, "Ajout d'un nouveau programmes", "voulllez vous ajouter : " & $ajout_nom_du_programme & " a la liste ")
                    If $choix_ajout_programme = 6 Then

                        $taille_du_programm = FileGetSize($ajout_choixfichier) ; retourne la taille de ton fichier
                        $staille_du_programm = StringFormat("%.2f", $taille_du_programm / 1048576) ;  on converti en megabyte et on arrange la string

                        ; on creer une section dans le fichier ini attribuer au programme
                        IniWrite($ini, $ajout_nom_du_programme, "nom", $ajout_nom_du_programme)
                        IniWrite($ini, $ajout_nom_du_programme, "chemin", $ajout_choixfichier)
                        IniWrite($ini, $ajout_nom_du_programme, "taille", $staille_du_programm)

                    EndIf
                    GUICtrlCreateListViewItem($ajout_nom_du_programme & "|" & $ajout_choixfichier, $ListView1) ; ajout des information du programme au listview
                Else
                    MsgBox(48, "", "Aucun fichier n'a etait selectionner")
                EndIf
            EndIf
        Case $modifier
            $aSelected = _GUICtrlListView_GetSelectedIndices($ListView1, True) ; on verifi si un element et selectionner
            If $aSelected[0] > 0 Then ; si ou alors :
                $Iitem = $aSelected[1]
                $Litem = _GUICtrlListView_GetItemText($ListView1, $Iitem)
                Local $choix_modification_programme = MsgBox(4, "modifiecation du chemin du programme selectionner", "voulllez vous modifier le chemin du programme : " & $Litem)
                If $choix_modification_programme = 6 Then
                    Local $modifier_choixfichier = FileOpenDialog("Fichier à ajouter", "****", "Tous (*.*)", 4)
                    If Not @error Then
                        $taille_du_programm = FileGetSize($modifier_choixfichier) ; retourne la taille de ton fichier
                        $staille_du_programm = StringFormat("%.2f", $taille_du_programm / 1048576) ;  on converti en megabyte et on arrange la string
                        $choix_modification_programme = MsgBox(4, "modifiecation du chemin du programme selectionner", "Nouveau chemin : " & $modifier_choixfichier & @LF & "Taille : " & $staille_du_programm & " Mb" & @LF & "    Valider la modifications :")
                        If $choix_modification_programme = 6 Then
                            IniWrite($ini, $Litem, "chemin", $modifier_choixfichier)
                            IniWrite($ini, $Litem, "taille", $staille_du_programm)
                            MsgBox(0, "modifiecation du chemin du programme selectionner", "Nouveau chemin : " & $modifier_choixfichier & @LF & "Taille : " & $staille_du_programm & " Mb")
                            _GUICtrlListView_DeleteItemsSelected($ListView1) ; on retire la ligne du programme selectionner
                            GUICtrlCreateListViewItem($Litem & "|" & $modifier_choixfichier, $ListView1) ; on ajoute une nouvelle ligne avec les modifications
                        EndIf
                    Else
                        MsgBox(48, "", "Aucun fichier n'a etait selectionner")
                    EndIf
                EndIf
            Else
                MsgBox(48, "", "Il faut selectionner un fichier dans la liste pour pouvoir le modifier")
            EndIf
        Case $supprimer
            $aSelected = _GUICtrlListView_GetSelectedIndices($ListView1, True)
            If $aSelected[0] > 0 Then
                $Iitem = $aSelected[1]
                $Litem = _GUICtrlListView_GetItemText($ListView1, $Iitem)
                Local $choix_supprimer_programme = MsgBox(4, "supprimer le programme selectionner", "voulllez vous supprimer definitivement : " & $Litem)
                If $choix_supprimer_programme = 6 Then
                    Local $chemin_supprimer_programme = IniRead($ini, $Litem, "chemin", "")
                    FileDelete($chemin_supprimer_programme) ; supprimer definitivement le programme
                    _GUICtrlListView_DeleteItemsSelected($ListView1)
                    IniDelete($ini, $Litem) ; on supprime la section du programme selectionner
                EndIf
            Else
                MsgBox(48, "", "Il faut selectionner un fichier dans la liste pour pouvoir le supprimer")
            EndIf
        Case $executer
            $aSelected = _GUICtrlListView_GetSelectedIndices($ListView1, True)
            If $aSelected[0] > 0 Then
                $Iitem = $aSelected[1]
                $Litem = _GUICtrlListView_GetItemText($ListView1, $Iitem)
                Local $programme_a_executer = IniRead($ini, $Litem, "chemin", "")
                ShellExecute($programme_a_executer) ; on execute avec la fonction Shellexecute qui me semble approprier pour les fichier type executable ou multimedia
            Else
                MsgBox(48, "", "Il faut selectionner un fichier dans la liste pour pouvoir le lancer")
            EndIf
        Case $quitter
            Exit
    EndSwitch
WEnd

Func _charger_la_liste_avec_le_fichier_param()
    If FileExists($ini) Then
        Local $list = IniReadSectionNames($ini)
        For $i = 1 To UBound($list) - 1 ; on lit toute les section du fichier ini
            GUICtrlCreateListViewItem(IniRead($ini, $list[$i], "nom", "") & "|" & IniRead($ini, $list[$i], "chemin", ""), $ListView1) ; ajout des information du programme au listview, section par section
        Next
    EndIf
EndFunc   ;==>_charger_la_liste_avec_le_fichier_param

J'esperr que ça pourra t'aider .

Merci mais c'est pas trop ce que je voulais ça m'aide pour continuer quand même. Merci.

AutoIt Français

[R] Copie/coller d'un fichier ini et d'un input à une liste

[R] Copie/coller d'un fichier ini et d'un input à une liste

Re: [..] Copie/coller d'un fichier ini et d'un input à une l

Re: [..] Copie/coller d'un fichier ini et d'un input à une l

Re: [..] Copie/coller d'un fichier ini et d'un input à une l