AutoIt Français

Bonjour,

Voici la question que je me pose,
Quel est selon vous le plus performant et le plus réactif pour un script ?
Créer une fonction renvoyée par GuiGetMsg, puis ensuite gérer le flux important de données avec des if et switch
Ou de filtre au préalable les informations avec plusieurs GUIRegisterMsg
Car je n'ai pas réussi à trouver une méthode me permettant de comparer ces deux façons de faire.

Pour ma part, je suis parti sur la seconde solution (le GUIRegisterMsg) en me disant que les informations sont près filtrés donc moins lourd à interpréter pour la machine.
Mais ... Aucune idée s'il s'agit de la bonne solution.

Edite :
Utiliser GuiGetMsg pour gagner en performance et fiabilité.
utiliser GuiRegisterMsg pour les cas exceptionnels.

Voici par exemple :

Code : Tout sélectionner

GUIRegisterMsg($WM_NOTIFY, "FTreeAction") ; Filtre les actions sur le tableau
GUIRegisterMsg($WM_COMMAND, "FMenuAction") ; Filtre les actions sur le menu
GUIRegisterMsg($WM_INITMENU,"FMenuAction") ; Filtre les actions sur le menu

Opt("GUIOnEventMode", 1)
GUISetOnEvent($GUI_EVENT_CLOSE, "FClose", $Interface) ; Fermeture de l'interface
GUISetOnEvent($GUI_EVENT_CLOSE, "FCtrlClose", $Recherche) ; Fermeture de la recherche

; Gestion des actions
Func FClose() ; Action de fermeture
   MsgBox(0, "Fermeture", "Ca va faire noire !!", 1)
   GUIDelete()
   Exit
EndFunc

Func FCtrlClose() ; Action de fermeture
   If @GUI_WinHandle = $Recherche Then
      ; ------------
   EndIf
EndFunc

Func FTreeAction($hWnd, $iMsg, $iwParam, $ilParam) ; Action sourie sur tree
   #forceref $hWnd, $iMsg, $iwParam
   $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
   $iCode = DllStructGetData($tNMHDR, "Code")
   Switch $iCode
      Case $NM_DBLCLK ; Clique gauche double
        ; -------------
      Case $NM_RCLICK ; Clique droit simple
        ; -------------
   EndSwitch
EndFunc

Func FMenuAction($hWnd, $iMsg, $iwParam, $ilParam) ; Action sourie sur tree
   #forceref $hWnd, $iMsg, $iwParam
   If $hWnd = $Interface Then
      Switch $iwParam
         Case $MenuId[1][1]
            ; ------------
         Case $MenuId[2][1]
            ; ------------
         Case $AutreRechBtn
            ; ------------
      EndSwitch
   ElseIf $hWnd = $Info Then
      If $iMsg = 278 Then
         ; ------------
      EndIf
   EndIf
EndFunc

Je ne vois pas bien ce que tu veux dire par 'filtrer'
En revanche pour la réactivité (vaudrait mieux parler de priorité en fait) il y a bien une hiérarchie : GuiRegisterMsg > OnEvent > GuiGetMsg
Voilà un petit code qui met en évidence quelques unes de ces priorités

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

;~ Par défaut dans AutoIt "ESC" correspond au clic sur la croix de fermeture de la gui
;~ Le comportement est différent si la hotkey est posée pour quitter le script 
HotKeySet("{ESC}", "_exit")

Opt("GuiOnEventMode", 1)

GUICreate("My GUI") 
GUISetOnEvent($GUI_EVENT_CLOSE, "_close")
$btn = GUICtrlCreateButton("stop", 10, 50, 50, 20)
GUICtrlSetOnEvent(-1, "_btn")
$label = GUICtrlCreateLabel("0", 100, 50, 20, 20)
GUISetState() 
 
GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")
GUIRegisterMsg($WM_SYSCOMMAND, "_WM_SYSCOMMAND")  

Local $aAccelKeys[1][2] = [["{SPACE}", $btn]]
GUISetAccelerators($aAccelKeys)

Global $stop = 0, $close = 0

While 1
   If $stop <> 0 Then Exitloop
   If $close <> 0 Then Exit
   Sleep(300)
   GuiCtrlSetData($label, GuiCtrlRead($label)+1)
Wend
Msgbox(64,"", "stopped")

Opt("GuiOnEventMode", 0)
While 1
   Switch GuiGetMsg() 
       Case $GUI_EVENT_CLOSE 
             $close = 4
             Msgbox(64, $close, "close GuiGetMsg")
       Case  $btn
             Msgbox(64, "", "bouton GuiGetMsg")
   EndSwitch
   If $close <> 0 Then Exit
   Sleep(10)
Wend
;=========================================

;~ fonction appelée par eventmode (bouton)
Func _btn()
    $stop = 1
    Msgbox(64, $stop, "bouton on event")
EndFunc

;~ fonction appelée par eventmode (croix)
Func _close()
    $close = 1
    Msgbox(64, $close, "close on event")
EndFunc

;~ interception du message Windows (bouton)
Func _WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
 #forceref $hWnd, $Msg, $lParam
   If BitAND($wParam, 0xFFFF) = $btn Then
        $stop = 2
        Msgbox(64, $stop, "bouton wm_command")
   EndIf
  Return 'GUI_RUNDEFMSG'
EndFunc  

;~ interception du message Windows (croix)
Func _WM_SYSCOMMAND($hWnd, $Msg, $wParam, $lParam)
 #forceref $hWnd, $Msg, $lParam
    If BitAND($wParam, 0xFFF0) = 0xF060 Then   ; 0xF060 = $SC_CLOSE
       $close = 2
       Msgbox(64, $close, "close wm_syscommand") 
    EndIf
EndFunc

;~ fonction appelée par HotKeySet ESC
Func _exit()
    $close = 3
    Msgbox(64, $close, "close hotkey") 
EndFunc

Disons que d'une manière générale, le mode événementiel est plus "performant" que le mode messageloop, et que le GuiRegisterMsg devrait - en principe - être réservé aux actions qui nécessitent une priorité particulièrement haute ou qui ne peuvent être définies avec suffisamment de précision dans les 2 autres modes (comme certains messages particuliers en wm_notify par exemple)

Tu pourrais avoir un manque de réactivité si, par exemple, en cliquant sur un bouton la fonction associée au bouton met du temps pour se terminer. => https://www.autoitscript.com/wiki/Inter ... g_function

Et également comme le dit la doc - dans les remarques - pour GUIRegisterMsg il ne faut pas de trucs bloquants. Voir l'exemple en bas de la page https://www.autoitscript.com/wiki/Tutor ... egisterMsg ; il utilise GUIGetMsg + GUIRegisterMsg car il y a un MsgBox bloquant.
Personnellement je préfère utiliser GUIRegisterMsg que si ça s'avère vraiment nécessaire.

Bonjour,

Un grand merci a vos reponses très clair.

j'imaginais a tors exactement l'inverse de la réalité.

Je vais donc revoir mon code.

Je reste toujours tres impressionné par le nombre impressionnant de calcul que gère notre processeur à chaque instant,

Merci encore.

Perso, j'utilise GuiGetMsg pour les "petits" trucs, et le mon OnEvent pour les trucs un peu plus costauds.
Pour GUIRegisterMsg, je le réserve uniquement pour ce que je ne peux pas faire plus haut

orax tu as raison, je n'ai mis des Msgbox dans mon exemple que pour la démo mais en bonne pratique j'aurais dû mettre des Consolewrite ou des Msgbox non bloquantes

Dans le 2ème exemple que tu cites, je n'aime pas particulièrement la vérification de variable en continu dans la boucle While principale (méthode que perso je m'efforce d'utiliser le moins possible)

mikell a écrit : des Msgbox non bloquantes

Tu pense au tooltip et autres ?
Je me suis aperçu que dans certain cas GUIRegisterMsg passait outre les blocages style MsgBox
Dans le script ci-dessous je me suis amusé à manœuvrer un MsgBox comme une vulgaire Form et de réaliser ce que je pensais impossible. Le script n'est pas beau, ce n'était qu'un essai pour voir.

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <ProgressConstants.au3>
#include <Timers.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>
Global $g_idMemo, $g_hStatus, $g_idProgress, $g_iPercent = 0, $g_iDirection = 1
Global $g_iTimer1, $g_iTimer2, $hGUI, $ctr = 1

_Example_Events()

Func _Example_Events()
    Local  $idChange, $iWait = 10, $idState
    Local $aParts[3] = [75, 330, -1]

    $hGUI = GUICreate("Timers Using WM_TIMER Events", 400, 320)
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 226, BitOR($WS_HSCROLL, $WS_VSCROLL))
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    $idState = GUICtrlCreateButton("Start Progress Bar", 70, 270, 100, 25)
    $idChange = GUICtrlCreateButton("Change", 215, 270, 90, 25)
    GUICtrlSetState($idChange, $GUI_DISABLE)
    $g_hStatus = _GUICtrlStatusBar_Create($hGUI, $aParts)
    _GUICtrlStatusBar_SetText($g_hStatus, "Timers")
    _GUICtrlStatusBar_SetText($g_hStatus, @TAB & @TAB & StringFormat("%02d:%02d:%02d", @HOUR, @MIN, @SEC), 2)
    $g_idProgress = GUICtrlCreateProgress(0, 0, -1, -1, $PBS_SMOOTH)
    GUICtrlSetColor($g_idProgress, 0xff0000)
    _GUICtrlStatusBar_EmbedControl($g_hStatus, 1, GUICtrlGetHandle($g_idProgress))
    GUISetState(@SW_SHOW)

    GUIRegisterMsg($WM_TIMER, "WM_TIMER")

    $g_iTimer1 = _Timer_SetTimer($hGUI, 1000)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $idState
                If GUICtrlRead($idState) = "Start Progress Bar" Then
                    $g_iTimer2 = _Timer_SetTimer($hGUI, $iWait) ; create timer
                    If @error Or $g_iTimer2 = 0 Then ContinueLoop
                    GUICtrlSetData($idState, "Stop Progress Bar")
                    GUICtrlSetState($idChange, $GUI_ENABLE)
                    $msg = MsgBox(3,"AA","AAAAAAAAAazertyuiopazertyuiopazertyuiopAAAAAAAAAazertyuiopazertyuiopazertyuiop" & @CRLF & @CRLF & @CRLF & @CRLF & "AAAAAAAAAazertyuiopazertyuiopazertyuiop",0,$hGUI)
                    If $msg = 6 Or $msg = 7 Then $ctr = 1
                Else
                    GUICtrlSetState($idChange, $GUI_DISABLE)
                    _Timer_KillTimer($hGUI, $g_iTimer2)
                    GUICtrlSetData($idState, "Start Progress Bar")
                EndIf

            Case $idChange
                If $iWait = 10 Then
                    $iWait = 250
                Else
                    $iWait = 10
                EndIf
                MemoWrite("Timer for _UpdateProgressBar set at: " & $iWait & " milliseconds")
                $g_iTimer2 = _Timer_SetTimer($hGUI, $iWait, "", $g_iTimer2) ; reuse timer with different interval
        EndSwitch
    WEnd

    ConsoleWrite("Killed All Timers? " & _Timer_KillAllTimers($hGUI) & @CRLF)
    GUIDelete()
EndFunc   ;==>_Example_Events

; Timer Events
Func WM_TIMER($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $lParam

    Switch _Timer_GetTimerID($wParam)
        Case $g_iTimer1
            _UpdateStatusBarClock()
                $splash1 = winGetHandle("[TITLE:AA]","")

                If Not @error And $ctr = 1 Then
                $splash = ControlGetHandle("[TITLE:AA]","","Static1")

    Local $aSplahSizeP = WinGetPos($splash1 )
    If IsArray($aSplahSizeP) Then
                ConsoleWrite($splash & @SEC & @CR)
                $HeightP = $aSplahSizeP[3] + 100
                WinMove($splash1,"",400,200,$aSplahSizeP[2] ,$HeightP,50)
                $buttonpos = ControlGetPos($splash1,"","Button2")
                ControlMove($splash1,"","Button2",100,$HeightP - $buttonpos[3] - 30)
                ControlMove($splash1,"","Button1",100,0)
                ControlSetText($splash1,"","Static1","coucou"& @CRLF & @CRLF & @CRLF & @CRLF & @CRLF & "aaaaaaaaa")
                Sleep(100)
                    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($splash1 )
        $hBitmap = _GDIPlus_BitmapCreateFromMemory(BinGIFImage())
    Local $iImageWidth = _GDIPlus_ImageGetWidth ($hBitmap)
    Local $iImageHeight = _GDIPlus_ImageGetHeight ($hBitmap)
    Local $aSplahSize = WinGetClientSize($splash1 )
    $iX = Ceiling ($aSplahSize[0] - $iImageWidth) / 2
     $iY = Ceiling ($aSplahSize[1] - $iImageHeight) / 2
    _GDIPlus_GraphicsDrawImage($hGraphic, $hBitmap, $iX, $iY)
     EndIf
    _GDIPlus_BitmapDispose($hBitmap)
    ; Shut down GDI+ library
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
    $ctr = 0
    EndIf
        Case $g_iTimer2
            _UpdateProgressBar()


    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_TIMER

Func _UpdateStatusBarClock()
    _GUICtrlStatusBar_SetText($g_hStatus, @TAB & @TAB & StringFormat("%02d:%02d:%02d", @HOUR, @MIN, @SEC), 2)
EndFunc   ;==>_UpdateStatusBarClock

Func _UpdateProgressBar()
    $g_iPercent += 5 * $g_iDirection
    GUICtrlSetData($g_idProgress, $g_iPercent)
    If $g_iPercent = 100 Or $g_iPercent = 0 Then $g_iDirection *= -1
    If $g_iPercent = 100 Then
        GUICtrlSetColor($g_idProgress, 0xff0000)
    ElseIf $g_iPercent = 0 Then
        GUICtrlSetColor($g_idProgress, 0x0000ff)
    EndIf
EndFunc   ;==>_UpdateProgressBar

; Write a line to the memo control
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite
Func BinGIFImage() ;test GIF image converted to a binary string
    Local $sBinGIFImage = '0x47494638396144004700F70000FFFFFF1831711C357D182D6D1C3982182D691C35791C3986CACACA1831751C3D9614246118316D14286914357D1835791C398A183575204192142D65C2C2C2BE9296142459203D92AEAAAEC69A9AB2B2B6BAB6B6CACACEBEAA41142D7520398A395D9618358614317DA29E9E1028751C3D8A0C2455797979A27D7918316941699ECEA2A23D4955101C4955595961656100041C86828214358E182861B6A23DEBEBEBBEBEBE142D71E7B2B220419EB28E8E10246D2D3959DFA6AA10245D8E8A8EA29641696969CAB241202D49082065C6C6CA0C1C516165556979927D61616186B2183179AAAAAAC6C6C2969296DBDBDF243D718A71712031591C3582DFAEAE8E7D86A2A6A6314579866969AA828214285D20316910246592928E1031860410353D5D92F3F3F328499A14399A14203D3539497D754986868E0C2059A28282E3E3E3081024AE9A3D967171454545355992494D61AE8A8E7175797D869ED7A2A26555554D4D51B69296DBD7D7394969928A4D555D65D7A6AA8A7D39142855CAA6AA203982EBCACE5D6569AE9A359E9E9E715959183161B6C2DF5186C22D4169928A55414965BABABE615971AE9E9E0C18394559755979AAEBE3DF31498A5179A22439694159A6313128A6964D9EAABEDFBABE314982514924081849495565A696396969610C287D4535352035719682867171557171694571A64D5D861C3D92D2BE41514141DBCACAEFB6BA49393D24459A315586394561082471C6B649614D55B6AA5D1C2D59BE969A3D49717D7959614949CAB2AE514139244186E3C6CAF3EFEB756935797965867D55595D4561758AFBBEC23D659A1C357161551CBAAA49413D456D798A7D8282617DA2141C35000C2820283D24418A79753DE3DFDB24395D9692695D6986283965B2B2B23559968A8279FBFBEF8692AEEFD74D516D96C6B6559A8E45353541A69E5D82615D967D79454531D2BE4D92864561869E14244D554D456D6555393D555D61613159A6B286867592B29E8A351C316DF7FBFBFFC6C665757D1C397D555D7DCECACA1C3979182D71BEC2CE4539206D611C866561FFFFFF21F904010000FF002C00000000440047000008FF00FF091C48B0A0C18308132A5CC8B0A1C38710233E74674CA2C58B08C5E4B8900F16C68F1651697C152011C8930E977DD3A6F100CA970BC5C9C92166D92431307316540149C2AB1CDE64EA1CFA2FDA87483968CE01878E684E246A7E591A9369DBBE664E5F669254E357264BD3BAE2819715243C0A3FAA90DA45CF519518562894FDA8A451851E3DA8E0C0DBA34D3D25733156A0A32990AFC281FED02115F862333AACE6593A24F550183EB71A5BAC42C7579843785A1D7A52435306249A1F12BB1567452B568134E10864184706478C5333248645C70A3E545A151BDE8A'
    $sBinGIFImage &= '0F9F0C59C645D2BD70CE381D192A00C7419DCA0AE851A200669E905B1B1D59A264FFD171A7C29D3869B0544893663BF7834AD2E878A7AE1096FB5892D4D185FCC77B8555E8E0883AAEF0B2CA81AE8812C31F59CCF15F4255E013060241ACE2CA856E7451430DBBA0F6E0418CFC5243183570D0055C4F90D855261F1AC44D586AE0F1C4346AA8F1C41378C818A3832D0E840D1E1C144101214EFC10430C4E60C0880D08E063458F0229C10436D830614A21B75041051F59D47186154C6060857B1FCE51A413419CB0CB1F155470CB1F8EB473C20F3F10D2548F679C70423B31E0C301051B6CC008051CD810449A319C01A529EDB8C00C0708441A24A44D3212840B413003252EE198B2411191861AAA9056B4C303253D9E3204343130C108A8A246FF4A81065604F185212DBA13CB258F04E1043636C03A2A234CFCA0CC1A5FE4F3E03DB598334B1F6EC44008B0C2526003064E9832C4140494100D18DCF522432DDD74534D19A074C1C4061414E1AE0DD88C10831B054860EF0507BC919A0AD1C880CA37D598730509653033EDA0D6128BE6B6537C7081BD074CD258360294708135937821483B32D8F282BA1BD8400123D8101283324B8883CB14164B700104F69C52960A0F5C60732A1008E0413E071C50C60907DBB001B62E4C708F399E784080C33643207156BD9470EF070404208F008094F0801D203342EB093CC8608A397AA4B0440810A4F28A045364E3943153D82B412A5E3CD04002F6007240098604FF31ED06D83861C703105C318B10476CB1C726D5D4A3C0058038958FD46B07014A0A2CE0220001807C00010F3160808D152FC853C20121E4A20A382C60924C300AACDDF650F55CA1B602F5D4D2411FEB94620FE77B2F01C70818FCC043CF3D8B20CCEE8360E2F0BDBDE8D40C2EA9DC1B0D208B00B345289BEBBD770A273001C7143D0302880022E4314C1F1D4002814F1240103D4C9BBC7F2F014B7051C60D09189037F221488420187000F3018200F610C0120AE086580822040FB3D71440F01228340010AF78C5053E20007DF8410AFA08C0037EE73DADF9E0000448E10113688014A4C30709C89A4F2E20002D80EB24D780C11A5A6080541CC00033184201FF18C0800808200421F0DE01A7600F6EA590850C68413A182000089460028F58C31A6E884318E8900706F0C0AA0650800124E00182B84212CD470001B8F1776D34C00306E087474CE0015080C61A74C8459424E20BCEE045387CD0023F04A000050880084C910C35AED08D6E4CA1000C60802D68E11146B0052F44B10632F4112588384521508002657CA100FA2840031409095528220492A42424DD28823DB8800B8F20C328DB0087ACB4860A7480430306708D44DC2014B998C52C1E294B01E4037DA1D0830B88900E72E0E0388A220A12B290811564200EF220A6191251'
    $sBinGIFImage &= '8A0ECC2219BF73A32C45100C458002141D580711E0E0CD1554801CA81A0A12DE91FF810CD4E116A318C004A4C1860E744008C110813A2949497B2842151DA0011086D18834446105B7408153908002D69021035018400358400321084118906428431F600045449406D2684414D8B18238A0603943B1863FB2F38524E0A2003358C0223CE10903A4F4014865E812842104894A610FEC18421AFC5108A750A20E3B8506341800542D34C0032260E94A2380D40788E00542D0831ED8C0834E7CA10EE4488237B2428946D022099C40A416B45080049075AC11202B4BDBF182048C420F7048072D0AA18BB9CEC50EC0E0C43576E003BE06E0AF728C4002361BD80878C00309F040256231047570E21E8808CC30E2818C3E9881053E48A45FCBBAD900FF6CF6B6B5D5470386800C7E78642E8860413FFAF00970B821B60CB02D529790800038D7B9B7752E5787C08974FC762E9740C627CEB10534F035B99BBD022E3C10007DDCE0B9CF256201A4A08E4E5C372B60E0871DCC30081E547688B6F5401E30510912546211E7452F03C8A88572E432302A4807170A60063BA0C102654CAE7E69908B2300C11301962E570B5060673C2230C630C1041A90026A5800C22918803E46E10920B08106A5B80111931B00F572D80816480788455C8009CCC0027C2D803C4A01840EB0E1C87990F18C67ACD774580057733184052640E519F821C80CA8C41ECC70641A80A312FA604098990CD47418410B08DEEB0C66A0852B237269C0B258041BCE710433B840C9649E409BAFA002CDC0020A50D0420BA6FCE61BC0810D89D8C10EE4B1641B4FC0022A482D734E01060BC416913758443B1AA0CA05AC79060D6840507D9082147C48056F28B53C183D80141862132088B5AC63FD069941E9D6B84E484000003B'
    Return Binary($sBinGIFImage)
EndFunc   ;==>BinGIFImage

Je n'ai pas poussé plus loin mes essais. Ce n'est peut être qu'une particularité due à un timer ?

Bah à ma connaissance il n'y a que 2 moyens de faire une Msgbox non bloquante : faire une gui msgbox-like, ou faire comme le code là-dessous, ça marche très bien mais on ne peut pas intégrer de variable du script dans la msgbox

► Afficher le texte

AutoIt Français

[R] GuigetMsg vs GUIRegisterMsg performance

[R] GuigetMsg vs GUIRegisterMsg performance

Re: [..] GuigetMsg vs GUIRegisterMsg performance

Re: [..] GuigetMsg vs GUIRegisterMsg performance

Re: [..] GuigetMsg vs GUIRegisterMsg performance

Re: [R] GuigetMsg vs GUIRegisterMsg performance

Re: [R] GuigetMsg vs GUIRegisterMsg performance

Re: [R] GuigetMsg vs GUIRegisterMsg performance

Re: [R] GuigetMsg vs GUIRegisterMsg performance