AutoIt Français

Bonjour,

Voila je vien demander de l'aide car j'aimerais avoir la même loupe que celle présente dans control viewer hors je n'arrive pas à récupérer le code dans l'au3 de control viewer, de plus j'aimerais que la loupe suive le curseur de la souris avec les différents exemple glané sur les forum anglais et celui-ci je suis arrivé à a voir une loupe qui suis le curseur.

Si quelqu'un peux m'aider à avoir la même chose que control viewer mais sans la gui ce serait gentil.

Cordialement,
Scaff

[Ex] Loupe

merci pour la réponse orax j'ai déjà vu cet exemple ainsi que celui ou le code de shao est cité, mon souci viens du fait que je cherche a avoir le même résultat que celui de controlviewer que je n'arrive pas avoir justement

Je pensais vraiment que cet exemple conviendrait. J'ai un peu du mal de comprendre quel est exactement le résultat attendu. Il faut qu'il y ait une sorte de croix aussi (le "crossair") ?
Il y aussi le zoom qui peut être changé.

Code : Tout sélectionner

    Global Const $MagZoom = 3
    Global Const $MagWidth = $MagZoom * 25
    Global Const $MagHeight = $MagZoom * 25

Un code de Melba23 bricolé pour rajouter le crosshair et un zoom réglable

► Afficher le texte

Code : Tout sélectionner

; http://www.autoitscript.com/forum/topic/150136-window-zoom-out-tool/#entry1071721

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>

Opt("GUICloseOnESC", 0)
HotKeySet("{ESC}", "On_Exit")

Global $hMag_GUI, $hMagDC, $hDeskDC, $hPen, $oObj, $aMouse_Pos[2], $iLast_Mouse_X = 0, $iLast_Mouse_Y = 0, $zoom = 3

$hMag_Win = GUICreate("MAG", 100, 100, 0, 0, $WS_POPUP+$WS_BORDER, $WS_EX_TOPMOST)
GUISetState(@SW_SHOW, $hMag_Win)
$hMag_GUI = WinGetHandle("MAG")
$hMagDC = _WinAPI_GetDC($hMag_GUI)
$hDeskDC = _WinAPI_GetDC(0)
$hPen = _WinAPI_CreatePen($PS_SOLID, 1, 0x000000)
$oObj = _WinAPI_SelectObject($hMagDC, $hPen)


While 1
    $aMouse_Pos = MouseGetPos()
    If $aMouse_Pos[0] <> $iLast_Mouse_X Or $aMouse_Pos[1] <> $iLast_Mouse_Y Then
        Loupe($aMouse_Pos)
        $iLast_Mouse_X = $aMouse_Pos[0]
        $iLast_Mouse_Y = $aMouse_Pos[1]
    EndIf
WEnd


Func On_Exit()
    _WinAPI_SelectObject($hMagDC, $oObj)
    _WinAPI_DeleteObject($hPen)
    _WinAPI_ReleaseDC(0, $hDeskDC)
    _WinAPI_ReleaseDC($hMag_GUI, $hMagDC)
    GUIDelete($hMag_GUI)
    Exit
EndFunc   ;==>On_Exit


Func Loupe($aMouse_Pos)
    Local $iX, $iY
    _WinAPI_StretchBlt($hMagDC, 0, 0, 100, 100, $hDeskDC, $aMouse_Pos[0] - 10, $aMouse_Pos[1] - 10, 100/$zoom, 100/$zoom, $SRCCOPY)

    _WinAPI_MoveTo ($hMagDC, 0, 50)
    _WinAPI_LineTo ($hMagDC, 46, 50)
    _WinAPI_MoveTo ($hMagDC, 54, 50)
    _WinAPI_LineTo ($hMagDC, 100, 50)
    _WinAPI_MoveTo ($hMagDC, 50, 0)
    _WinAPI_LineTo ($hMagDC, 50, 46)
    _WinAPI_MoveTo ($hMagDC, 50, 54)
    _WinAPI_LineTo ($hMagDC, 50, 100)
    DllCall("gdi32.dll","int","Arc", "hwnd", $hMagDC, "int", 46, "int", 46, "int", 55, "int", 55, "int", 0, "int", 50, "int", 0, "int", 50)

    If $aMouse_Pos[0] < (@DesktopWidth - 100 -100/$zoom) Then
        $iX = $aMouse_Pos[0] + 100/$zoom
    Else
        $iX = $aMouse_Pos[0] - 100 -100/$zoom
    EndIf
    If $aMouse_Pos[1] < (@DesktopHeight - 120 -100/$zoom) Then
        $iY = $aMouse_Pos[1] + 100/$zoom
    Else
        $iY = $aMouse_Pos[1] - 100 -100/$zoom
    EndIf
    WinMove($hMag_GUI, "", $iX, $iY, 100, 100)
EndFunc   ;==>Loupe

Merci mikell (encore une fois), pour ce code c'est exactement ça juste quelques petit réglage à faire pour que le crosshair soit exactement ou le curseur ce trouve mais c'est ce que je rechercher, juste une question le zoom est dynamiquement réglable ou seulement via la variable $zoom ?

Peux tu également m'expliquer le coup du crosshair car je ne vois pas ou il se trouve dans le code.

Merci à orax également pour son aide

Je passe le sujet en résolu grâce à vous.

Une dernière question, je souhaiterais posté le code de mon outil de statistique de diablo 3 pour une correction ainsi que des critiques afin de corriger et de m'améliorai dans le langage autoit ou dois-je le posté dans le forum ?

Alors voilà :
- le crosshair est maintenant bien centré sur le curseur
- pour régler le zoom dynamiquement, tu tapes Ctrl + un chiffre de 1 à 9 et le zoom prend la valeur de ce chiffre
- la partie crosshair est marquée dans le code

► Afficher le texte

Code : Tout sélectionner

; http://www.autoitscript.com/forum/topic/150136-window-zoom-out-tool/#entry1071721

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>
#include <Misc.au3>

Opt("GUICloseOnESC", 0)
HotKeySet("{ESC}", "On_Exit")

Global $hMag_GUI, $hMagDC, $hDeskDC, $hPen, $oObj, $aMouse_Pos[2], $iLast_Mouse_X = 0, $iLast_Mouse_Y = 0, $zoom = 3

$hMag_Win = GUICreate("MAG", 100, 100, 0, 0, $WS_POPUP+$WS_BORDER, $WS_EX_TOPMOST)
GUISetState(@SW_SHOW, $hMag_Win)
$hMag_GUI = WinGetHandle("MAG")
$hMagDC = _WinAPI_GetDC($hMag_GUI)
$hDeskDC = _WinAPI_GetDC(0)
$hPen = _WinAPI_CreatePen($PS_SOLID, 1, 0x000000)
$oObj = _WinAPI_SelectObject($hMagDC, $hPen)


While 1
    $aMouse_Pos = MouseGetPos()
    If $aMouse_Pos[0] <> $iLast_Mouse_X Or $aMouse_Pos[1] <> $iLast_Mouse_Y Then
        Loupe($aMouse_Pos)
        $iLast_Mouse_X = $aMouse_Pos[0]
        $iLast_Mouse_Y = $aMouse_Pos[1]
    EndIf
    If _IsPressed("11") Then
       For $i = 31 to 39
           If _IsPressed($i) Then $zoom = $i-30
       Next
       For $i = 61 to 69
           If _IsPressed($i) Then $zoom = $i-60
       Next
       Loupe($aMouse_Pos)
    EndIf
WEnd


Func On_Exit()
    _WinAPI_SelectObject($hMagDC, $oObj)
    _WinAPI_DeleteObject($hPen)
    _WinAPI_ReleaseDC(0, $hDeskDC)
    _WinAPI_ReleaseDC($hMag_GUI, $hMagDC)
    GUIDelete($hMag_GUI)
    Exit
EndFunc   ;==>On_Exit


Func Loupe($aMouse_Pos)
    Local $iX, $iY
    _WinAPI_StretchBlt($hMagDC, 0, 0, 100, 100, $hDeskDC, $aMouse_Pos[0] - 50/$zoom +1, $aMouse_Pos[1] - 50/$zoom +1, 100/$zoom, 100/$zoom, $SRCCOPY)

; crosshair ========
    _WinAPI_MoveTo ($hMagDC, 0, 50)
    _WinAPI_LineTo ($hMagDC, 46, 50)
    _WinAPI_MoveTo ($hMagDC, 54, 50)
    _WinAPI_LineTo ($hMagDC, 100, 50)

    _WinAPI_MoveTo ($hMagDC, 50, 0)
    _WinAPI_LineTo ($hMagDC, 50, 46)
    _WinAPI_MoveTo ($hMagDC, 50, 54)
    _WinAPI_LineTo ($hMagDC, 50, 100)
    DllCall("gdi32.dll","int","Arc", "hwnd", $hMagDC, "int", 46, "int", 46, "int", 55, "int", 55, "int", 0, "int", 50, "int", 0, "int", 50)
;================

    If $aMouse_Pos[0] < (@DesktopWidth - 100 -100/$zoom) Then
        $iX = $aMouse_Pos[0] + 100/$zoom
    Else
        $iX = $aMouse_Pos[0] - 100 -100/$zoom
    EndIf
    If $aMouse_Pos[1] < (@DesktopHeight - 120 -100/$zoom) Then
        $iY = $aMouse_Pos[1] + 100/$zoom
    Else
        $iY = $aMouse_Pos[1] - 100 -100/$zoom
    EndIf
    WinMove($hMag_GUI, "", $iX, $iY, 100, 100)
EndFunc   ;==>Loupe

mikell a écrit :- le crosshair est maintenant bien centré sur le curseur

Non !

Control Viewer, à gauche, affiche bien le pixel au centre du petit rectangle ; alors que le script, à droite, l'affiche trop en bas à droite. Le problème est accentué quand le zoom est augmenté.

: loupe.png (2.41 Kio) Vu 1322 fois

Edité le code ci-dessus
Mais après, ce n'est pas ma faute si CV manque de précision

Merci à tous les deux

AutoIt Français

[R] Aide loupe sans GUI

[R] Aide loupe sans GUI

Re: [..]Aide loupe sans GUI

Re: [..]Aide loupe sans GUI

Re: [..]Aide loupe sans GUI

Re: [..] Aide loupe sans GUI

Re: [..] Aide loupe sans GUI

Re: [R] Aide loupe sans GUI

Re: [R] Aide loupe sans GUI

Re: [R] Aide loupe sans GUI

Re: [R] Aide loupe sans GUI