[R] Problème avec un objet IE

[nano54120]

Bonjour,

J'ai un problème avec un objet IE. Voici l'exemple d'un programme :

► Afficher le texteExemple

#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <FileConstants.au3>
#include <StringConstants.au3>
#include <File.au3>
#include <IE.au3>

Opt("GUIOnEventMode", 1)
#Region ### START Koda GUI section
$Form = GUICreate("Test", 762, 424, 202, 121)
GUISetOnEvent($GUI_EVENT_CLOSE, "FormClose")
GUISetOnEvent($GUI_EVENT_MINIMIZE, "FormMinimize")
GUISetOnEvent($GUI_EVENT_MAXIMIZE, "FormMaximize")
GUISetOnEvent($GUI_EVENT_RESTORE, "FormRestore")
$Web = GUICtrlCreateButton("Web", 40, 336, 41, 41)
GUICtrlSetOnEvent(-1, "WebClick")
$Modif = GUICtrlCreateButton("Saisie", 152, 336, 41, 41)
GUICtrlSetOnEvent(-1, "ModifClick")
$oIE = _IECreateEmbedded()
$oIE_ctrl = GUICtrlCreateObj($oIE, 352, 96, 305, 225)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


#Region ### START Koda GUI section
$Saisie = GUICreate("Saisie", 489, 308, 253, 172,-1)
GUISetOnEvent($GUI_EVENT_CLOSE, "SaisieFiltreClose")
GUISetOnEvent($GUI_EVENT_MINIMIZE, "SaisieFiltreMinimize")
GUISetOnEvent($GUI_EVENT_MAXIMIZE, "SaisieFiltreMaximize")
GUISetOnEvent($GUI_EVENT_RESTORE, "SaisieFiltreRestore")
$Titre = GUICtrlCreateInput("", 72, 64, 321, 21)
GUICtrlSetOnEvent(-1, "TitreChange")
$OkSaisie = GUICtrlCreateButton("OK", 72, 224, 75, 25)
GUICtrlSetOnEvent(-1, "OkSaisieClick")
#EndRegion ### END Koda GUI section ###

;***********************************************************************
Func OkSaisieClick()
   GUISetState(@SW_HIDE,$Saisie)
EndFunc

Func FormClose()
   Exit
EndFunc
;***********************************************************************
Func ModifClick()
   GUISetState(@SW_SHOW,$Saisie)
EndFunc

Func WebClick()
      _IENavigate($oIE, "http://www.google.com")
EndFunc

While 1
 Sleep(100)
WEnd

Quand on n'envoie pas de lien dans l'objet IE, sur la form de saisie on éditer le champ de saisie avec la touche Backspace.
Mais quand on envoie un lien (clic sur le bouton Web) dans l'objet IE et qu'on redemande la form de saisie alors il n'est plus possible de modifier le champ de saisie avec Backspace. Ce n'est pas pratique !

Quelqu'un aurait une solution ?

Merci

[jguinch]

Je pense avoir une solution mais pas d'explication : à priori, il suffit de créer la GUI de saisie en premier

► Afficher le texteCode qui marche chez moi

Code : Tout sélectionner

Opt("GUIOnEventMode", 1)

$oIE = ObjCreate("Shell.Explorer.2")

$Saisie = GUICreate("Saisie", 489, 308, 253, 172)
$Titre = GUICtrlCreateInput("", 72, 64, 321, 21)
$OkSaisie = GUICtrlCreateButton("OK", 72, 224, 75, 25)
GUICtrlSetOnEvent(-1, "OkSaisieClick")

$Form = GUICreate("Test", 762, 424, 202, 121)
GUISetOnEvent(-3, "FormClose")
$Web = GUICtrlCreateButton("Web", 40, 336, 41, 41)
GUICtrlSetOnEvent(-1, "WebClick")
$Modif = GUICtrlCreateButton("Saisie", 152, 336, 41, 41)
GUICtrlSetOnEvent(-1, "ModifClick")
$oIE_ctrl = GUICtrlCreateObj($oIE, 352, 96, 305, 225)
GUISetState(@SW_SHOW, $Form)


While 1
 Sleep(100)
WEnd

Func OkSaisieClick()
   GUISetState(@SW_HIDE,$Saisie)
EndFunc

Func FormClose()
   Exit
EndFunc

Func ModifClick()
   GUISetState(@SW_SHOW,$Saisie)
EndFunc

Func WebClick()
      $oIE.navigate("http://www.google.com")
EndFunc
 

J'ai fait le test en virant tous les Include (au cas où), j'ai également testé le mode non-Event, c'est là même chose...

► Afficher le texteCode qui merdouille en mode non-Event

Code : Tout sélectionner

$oIE = ObjCreate("Shell.Explorer.2")

$Form = GUICreate("Test", 762, 424, 202, 121)
$Web = GUICtrlCreateButton("Web", 40, 336, 41, 41)
$Modif = GUICtrlCreateButton("Saisie", 152, 336, 41, 41)
$oIE_ctrl = GUICtrlCreateObj($oIE, 352, 96, 305, 225)
GUISetState(@SW_SHOW)

$Saisie = GUICreate("Saisie", 489, 308, 253, 172)
$Titre = GUICtrlCreateInput("", 72, 64, 321, 21)
$OkSaisie = GUICtrlCreateButton("OK", 72, 224, 75, 25)

While 1
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $Web
            $oIE.navigate("http://www.google.com")
        Case $Modif
            GUISetState(@SW_SHOW,$Saisie)
        Case $OkSaisie
            GUISetState(@SW_HIDE,$Saisie)
    EndSwitch
WEnd


 

A comprends pas...

[nano54120]

C'est excellent ! Ca règle mon problème ! Et dire que j'ai passé un temps pas possible à trouver une solution, à réécrire le code , a chercher sur le net et le forum ... Et tout ça pour inverser l'ordre de création des GUI !! Enfin, le forum est pour la aussi. Mille mercis ! Ca fait du bien !

Je pense que l'objet IE influe sur la form fille. Si on ne met rien derrière alors pas de problème.

Ce code fait partie d'un programme plus important et cette méthode fonctionne très bien.

[jguinch]

Pense à utiliser la balise Spoiler pour le code pour une meilleure lecture ..