Page 1 sur 1
[R] Aide pour refresh une GUI
Posté : jeu. 19 févr. 2015 16:23
par Scaff
Bonjour,
Je poste car je n'ai pas trouvé de solution à mon problème, je cherche à crée un outil qui affiche l'heure mais qui affiche également un chronomètre ( avec un bouton start/stop )
mon souci viens du fait que si j'active le chrono l'heure ne se met plus a jour et inversement. Vu que je débute je m'essaye à des choses et je cherche par moi même mais la je bloque alors je poste sur le forum pour avoir un peu d'aide.
Merci à tous
Re: [..] Aide pour refresh une GUI
Posté : jeu. 19 févr. 2015 18:59
par Clampu
Ta fonction chrono contient une boucle qui bloque le reste, c'est normal. Il faut appeler avec AdlibRegister toutes les secondes comme tu l'as fait avec heure(), et mettre une seule fois le chrono à jour (en rajoutant une seconde à un compteur par ex). Il faut supprimer ton for et mettre ton AdlibRegister(chrono(),1000) au même niveau que AdlibRegister(heure(), 1000)
Fait un boolean qui s'inverse ($a = Not $a) lorsque tu clic sur le bouton stop et start, il te servira pour savoir si tu doit incrémenter ou non ton chrono toutes les secondes.
Re: [..] Aide pour refresh une GUI
Posté : jeu. 19 févr. 2015 23:31
par mikell
En fait si le chrono et l'horloge ne sont pas synchronisés ça pique un peu les yeux
Pour éviter ça on peut tout mettre dans la même fonction
► Afficher le texte
Code : Tout sélectionner
#include <Date.au3>
#include <GUIConstantsEx.au3>
Global $Timer, $Secs, $Mins, $Hour, $Time, $toggle
GUICreate("test", 200, 100)
$chrono = GUICtrlCreateLabel("__:__:__", 10, 10, 50)
$btn = GUICtrlCreateButton("start/stop", 80, 10, 80, 20)
$heure = GUICtrlCreateLabel(@HOUR &":"& @MIN &":"& @SEC, 10, 50)
GUISetState(@SW_SHOW)
AdlibRegister("time", 1000)
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
Exit
Case $btn
$toggle = not $toggle
If $toggle Then $Timer = TimerInit()
EndSwitch
WEnd
func time()
GUICtrlSetData($heure, @HOUR &":"& @MIN &":"& @SEC)
If $toggle Then chrono()
EndFunc
func chrono()
_TicksToTime(Int(TimerDiff($Timer)), $Hour, $Mins, $Secs)
$Time = StringFormat("%02i:%02i:%02i", $Hour, $Mins, $Secs)
GuiCtrlSetData($chrono, $Time)
EndFunc
Re: [R] Aide pour refresh une GUI
Posté : ven. 20 févr. 2015 07:13
par Scaff
Merci a tous je me douter que la boucle de 24h étais la cause de tout mon malheur
je reprend mon code et je continu en espérant ne pas avoir a revenir demander de l'aide
Edit : Tous fonctionne au poil je peux continué mon outil merci Clampu et mikell
outil_diablo 3.au3