Page 1 sur 1
[R] Changer texte affiché dans un lien hypertexte excel ?
Posté : jeu. 15 janv. 2015 16:14
par Clampu
Bonjour !
J'ai une petite question concernant l'UDF Excel.au3. J'utilise la fonction _Excel_RangeLinkAddRemove pour écrire un lien hypertexte dans mon fichier excel. Or, le fichier est sur le réseau ce qui fait que le lien prend beaucoup de place (80% de l'écran). Ce n'est pas très ergonomique (d’autant plus qu'il y a 3 liens à la suite).
Comment puis-je modifier ce lien hypertexte pour raccourcir son libellé ? Autrement dis, comment utiliser le "Texte à afficher" présent initialement dans Excel ?
Je trouve dommage que ce ne soit pas présent dans _Excel_RangeLinkAddRemove puisqu'on a accès au screenTip qui me semble de la même trempe.
Merci
Re: [..] Changer texte affiché dans un lien hypertexte excel
Posté : jeu. 15 janv. 2015 16:44
par Y01
Il suffit de créer un lecteur réseau pointant sur le dossier où se situe le fichier Excel.
Voici la manière suggérée par Microsoft pour mapper un lecteur réseau.
Re: [..] Changer texte affiché dans un lien hypertexte excel
Posté : jeu. 15 janv. 2015 17:41
par Clampu
Ça pourrait fonctionner, merci. Je vais me renseigner car ce mapping doit être fait sur tous les poste utilisateurs, ce qui pourrai poser problème à mon chef.
Re: [..] Changer texte affiché dans un lien hypertexte excel
Posté : jeu. 15 janv. 2015 19:45
par orax
En regardant le code de l'UDF, on voit que la méthode
Hyperlinks.Add est utilisée. La propriété TextToDisplay est le texte à afficher.
Je n'ai pas modifié directement l'UDF, il est recommandé de créer plutôt une autre fonction.
► Afficher le texte
Code : Tout sélectionner
__Excel_RangeLinkAddRemove($oWorkbook, $oWorkbook.Activesheet, "A1:C1", "http://www.autoitscript.com", Default, "AutoIt Homepage", "texte affiché")
Func __Excel_RangeLinkAddRemove($oWorkbook, $vWorksheet, $vRange, $sAddress, $sSubAddress = Default, $sScreenTip = Default, $sTextToDisplay = "")
Local $oLink
If Not IsObj($oWorkbook) Or ObjName($oWorkbook, 1) <> "_Workbook" Then Return SetError(1, 0, 0)
If Not IsObj($vWorksheet) Then
If $vWorksheet = Default Then
$vWorksheet = $oWorkbook.ActiveSheet
Else
$vWorksheet = $oWorkbook.WorkSheets.Item($vWorksheet)
EndIf
If @error Or Not IsObj($vWorksheet) Then Return SetError(2, @error, 0)
ElseIf ObjName($vWorksheet, 1) <> "_Worksheet" Then
Return SetError(2, @error, 0)
EndIf
If Not IsObj($vRange) Then
$vRange = $vWorksheet.Range($vRange)
If @error Or Not IsObj($vRange) Then Return SetError(3, @error, 0)
EndIf
If $sAddress = "" Then
$vRange.Hyperlinks.Delete()
If @error Then Return SetError(4, @error, 0)
Return 1
Else
$oLink = $vWorksheet.Hyperlinks.Add($vRange, $sAddress, $sSubAddress, $sScreenTip, $sTextToDisplay)
If @error Then Return SetError(4, @error, 0)
Return $oLink
EndIf
EndFunc ;==>_Excel_RangeLinkAddRemove
Re: [..] Changer texte affiché dans un lien hypertexte excel
Posté : ven. 16 janv. 2015 09:00
par Y01
Clampu a écrit :Ça pourrait fonctionner, merci. Je vais me renseigner car ce mapping doit être fait sur tous les poste utilisateurs, ce qui pourrai poser problème à mon chef.
Le mapping peut être fait via Autoit ou par GPO au choix
PS : Le démappage aussi peut être fait avec l'un ou l'autre.
Re: [..] Changer texte affiché dans un lien hypertexte excel
Posté : ven. 16 janv. 2015 09:46
par Clampu
Y01 a écrit :Clampu a écrit :Ça pourrait fonctionner, merci. Je vais me renseigner car ce mapping doit être fait sur tous les poste utilisateurs, ce qui pourrai poser problème à mon chef.
Le mapping peut être fait via Autoit ou par GPO au choix
PS : Le démappage aussi peut être fait avec l'un ou l'autre.
Oui je pensais le faire via AutoIt. La question était plutôt : ai-je le droit ?
@orax
Super ! C'est exactement ce qu'il me faut. J'aurai presque pu faire ça moi même si j'avais pensé à aller voir Hyperlinks.Add
Re: [..] Changer texte affiché dans un lien hypertexte excel
Posté : ven. 16 janv. 2015 13:42
par Y01
Clampu a écrit :Y01 a écrit :
Le mapping peut être fait via Autoit ou par GPO au choix
PS : Le démappage aussi peut être fait avec l'un ou l'autre.
Oui je pensais le faire via AutoIt. La question était plutôt : ai-je le droit ?
Par défaut, tout utilisateur peut mapper un lecteur sur son poste à partir du moment où il a accès au dossier qu'il veux mapper.
Après, si on parle de droit vis à vis de la charte informatique de la société, c'est à voir en interne.
Re: [R] Changer texte affiché dans un lien hypertexte excel
Posté : ven. 16 janv. 2015 15:02
par Clampu
Oui c'était bien des droits vis à vis de la société et pas les droits "techniques" dont je parlais.