AutoIt Français

Bonjour le peuple !

Pour moi autoit est devenu indispensable et je trouverais sa génial de le modernisé et plus particulièrement notre fameuse listview qui nous rend de grand service :')
Actuellement on dispose de la fonction "GUICtrlCreateListView" , elle est performante mais je la trouve pas adapter à différent design et trop "ancien"

J'ai essayer de trouver cette fonction pour voir comment il fonctionne mais je n'est pas trouver.
J'aimerais pouvoir réaliser une listview comme sur cette image.

Pouvez-vous m'expliquer ce que je dois savoir afin de pouvoir réaliser un truc similaire ? (Les colonnes et les lignes doivent être modulable comme la listview normal et pourquoi pas les couleurs également sa peut être sympa

)
Le but est de faire participer tout le monde afin d'obtenir un résultat agréable et utilisable par tous, n'hésitez pas à faire part de vos idées.

Merci à tous

Autoit propose la lisview Windows de base, ce que tu veux c'est de la personnalisation
Pour ça il faut jouer avec les styles et les diverses fonctions disponibles _GUICtrlListView*
Par exemple :

► Afficher le texte

Code : Tout sélectionner

;http://www.autoitscript.com/forum/topic/130653-changing-listview-column-headers-color/
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <FontConstants.au3>
#include <GuiListView.au3>
#include <Constants.au3>
#include <GuiImageList.au3>

Opt('MustDeclareVars', 1)

Global $hGUI, $cListView, $hListView
Global $iDllGDI = DllOpen("gdi32.dll")
Global $iDllUSER32 = DllOpen("user32.dll")

Local $sURL = "http://www.autoitscript.com/autoit3/files/graphics/autoit9_wall_grey_800x600.jpg"
Local $sFilePath = @TempDir & "\AutoIt.jpg"
InetGet($sURL, $sFilePath)


;Three column colours
Global $aCol[3][2] = [[0xFFFF00, 0x494E49],[0xFFFF00, 0x0000FF],[0xFFFFFF, 0x0D0E0F]]

;One colour to rule them all
;blow off array and just set SetTextColor() / SetBkColor() with one colour
;Global $aCol[3][2] = [[0xFFFF00, 0x0000FF], [0xFFFF00, 0x0000FF], [0xFFFF00, 0x0000FF]]

;Convert RBG to BGR for SetText/BkColor()
For $i = 0 To UBound($aCol)-1
    $aCol[$i][0] = _BGR2RGB($aCol[$i][0])
    $aCol[$i][1] = _BGR2RGB($aCol[$i][1])
Next


$hGUI = GUICreate("Custom listview", 620, 500)
GUISetBkColor(0xFFFFFF)

$cListView = GUICtrlCreateListView("Items List|SubItems1  |SubItems2 large", 10, 10, 600, 480, -1,  $WS_EX_TRANSPARENT)
;get ListView handle from control ID
GUICtrlSetFont(-1, 9, 800, 0, "Comic Sans MS", $ANTIALIASED_QUALITY)
;GUICtrlSetBkColor(-1, 0xabcdef)

$hListView = GUICtrlGetHandle($cListView)
_GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_DOUBLEBUFFER, $LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES)) ;, $LVS_EX_GRIDLINES
DllCall('ole32.dll', 'long', 'CoInitializeEx', 'ptr', 0, 'dword', 0x02)
_GUICtrlListView_SetBkImage($hListView, $sFilePath)

;get handle to child SysHeader32 control of ListView
Global $hHeader = HWnd(GUICtrlSendMsg($cListView, $LVM_GETHEADER, 0, 0))
;Turn off theme for header
DllCall("uxtheme.dll", "int", "SetWindowTheme", "hwnd", $hHeader, "wstr", "", "wstr", "")
;subclass ListView to get at NM_CUSTOMDRAW notification sent to ListView
Global $wProcNew = DllCallbackRegister("_LVWndProc", "ptr", "hwnd;uint;wparam;lparam")
Global $wProcOld = _WinAPI_SetWindowLong($hListView, $GWL_WNDPROC, DllCallbackGetPtr($wProcNew))

;Optional: Flat Header - remove header 3D button effect
Global $iStyle = _WinAPI_GetWindowLong($hHeader, $GWL_STYLE)
_WinAPI_SetWindowLong($hHeader, $GWL_STYLE, BitOR($iStyle, $HDS_FLAT))

Global $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @Autoitexe, 0)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 132)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 209)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 138)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
_GUICtrlListView_SetImageList($hListView, $hImage, 1)

For $i = 1 To 15
    _GUICtrlListView_AddItem($hListView, "Item" & $i, 0)
    _GUICtrlListView_AddSubItem($hListView, $i - 1, "SubItem" & $i, 1, 1)
    _GUICtrlListView_AddSubItem($hListView, $i - 1, "SubItem" & $i, 2, 2)
Next
_GUICtrlListView_SetItemImage($hListView, 14, 5, 2)

_GUICtrlListView_SetColumnWidth($hListView, 0, 90) 
_GUICtrlListView_SetColumnWidth($hListView, 1, $LVSCW_AUTOSIZE_USEHEADER)
_GUICtrlListView_SetColumnWidth($hListView, 2, $LVSCW_AUTOSIZE_USEHEADER)

GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

If $wProcOld Then _WinAPI_SetWindowLong($hListView, $GWL_WNDPROC, $wProcOld)
; Delete callback function
If $wProcNew Then DllCallbackFree($wProcNew)
DllCall('ole32.dll', 'long', 'CoUinitialize') 
GUIDelete()
FileDelete($sFilePath)
Exit

;====================================================

Func _LVWndProc($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    If $iMsg = $WM_NOTIFY Then
        Local $tNMHDR, $hWndFrom, $iCode, $iItem, $hDC
        $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
        $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
        $iCode = DllStructGetData($tNMHDR, "Code")
        ;Local $IDFrom = DllStructGetData($tNMHDR, "IDFrom")

        Switch $hWndFrom
            Case $hHeader
                Switch $iCode
                    Case $NM_CUSTOMDRAW
                        Local $tCustDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
                        Switch DllStructGetData($tCustDraw, "dwDrawStage")
                            Case $CDDS_PREPAINT
                                Return $CDRF_NOTIFYITEMDRAW
                            Case $CDDS_ITEMPREPAINT
                                $hDC = DllStructGetData($tCustDraw, "hDC")
                                $iItem = DllStructGetData($tCustDraw, "dwItemSpec")
                                DllCall($iDllGDI, "int", "SetTextColor", "handle", $hDC, "dword", $aCol[$iItem][0])
                                DllCall($iDllGDI, "int", "SetBkColor", "handle", $hDC, "dword", $aCol[$iItem][1])
                                Return $CDRF_NEWFONT
                                Return $CDRF_SKIPDEFAULT
                        EndSwitch
                EndSwitch
        EndSwitch
    EndIf
    ;pass the unhandled messages to default WindowProc
    Local $aResult = DllCall($iDllUSER32, "lresult", "CallWindowProcW", "ptr", $wProcOld, _
            "hwnd", $hWnd, "uint", $iMsg, "wparam", $wParam, "lparam", $lParam)
    If @error Then Return -1
    Return $aResult[0]
EndFunc   ;==>_LVWndProc

Func _BGR2RGB($iColor)
    ;Author: Wraithdu
    Return BitOR(BitShift(BitAND($iColor, 0x0000FF), -16), BitAND($iColor, 0x00FF00), BitShift(BitAND($iColor, 0xFF0000), 16))
EndFunc   ;==>_BGR2RGB

J'ai testé le code mais cela ne me correspond pas, je trouve le code beaucoup trop compliqué juste pour changer la couleur de la première ligne. Même en décortiquant le code et en essayant de refaire à côté je n'arrive pas à obtenir le résultat.

Il n'y pas un moyen de crée une listview fait "maison" ? Avec un code "buvable" ? x)

"juste pour changer la couleur de la première ligne" ne correspond pas tout à fait à l'ensemble des exigences que sous-entendent l'image postée dans ton message précédent et le fait de vouloir "réaliser un truc similaire"

Tu devrais reformuler ta question de manière plus précise

Pour la couleur uniquement il y a des exemples ici : http://www.autoitscript.com/forum/topic ... alternate/

mikell a écrit :"juste pour changer la couleur de la première ligne" ne correspond pas tout à fait à l'ensemble des exigences que sous-entendent l'image postée dans ton message précédent et le fait de vouloir "réaliser un truc similaire"
Tu devrais reformuler ta question de manière plus précise

Non j'ai bien formuler ma question mais changer la couleur de la première ligne était un exemple.
Je veux effectivement customisé le tout.

@ORAX :

Ce que tu propose est intéressant je suis preneur

Après si tu a une solution pour coloriser la première ligne tout en haut je veux bien également.
Plus précisément cette ligne :

Code : Tout sélectionner

GUICtrlCreateListView("Name|Age|Sex", 10, 10, 350, 250)

EDIT :

Alors voila, une alternative qui me convient, en reprenant un peu le code de Mikell et celui d'Orax :

► Afficher le texte

Si on pourrait trouver comment changer la couleur de la ligne grise à volonté sa serait parfait.
Les icônes dans la listview sont un plus mais cette façon me convient également.

Code : Tout sélectionner

;subclass ListView to get at NM_CUSTOMDRAW notification sent to ListView
Global $wProcNew = DllCallbackRegister("_LVWndProc", "ptr", "hwnd;uint;wparam;lparam")
Global $wProcOld = _WinAPI_SetWindowLong($hListView, $GWL_WNDPROC, DllCallbackGetPtr($wProcNew))

Cette partie de code ne vous sert à rien, vous n'avez pas créé de fonction associée.

Oui j'ai oublié de l'enlever.

Nativement, AutoIt ne permet pas de créer des contrôles ou GUI avec un look différent de celui de base.
Regarde sur le forum US, il y a des UDF sympa pour gérer les skins :
- _UskinLibrary.au3
- XSkin.au3

Oui m'enfin bon, si on veut customiser on peut quand même le faire sans udf externes, quitte à accepter quelques minimes "complications"

Tiens voilà un exemple qui pique moins les yeux

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <Constants.au3>
#include <WinAPI.au3>

Global $hGUI, $cListView, $hListView

$hGUI = GUICreate("Custom listview", 400, 300)
GUISetBkColor(0xFFFFFF)
$cListView = GUICtrlCreateListView("", 30, 10, 280, 280, -1,  $WS_EX_TRANSPARENT) ; remove LV border
GUICtrlSetColor(-1, 0xeeeeee)

;get ListView handle from control ID
$hListView = GUICtrlGetHandle($cListView)
_GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_DOUBLEBUFFER, $LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES)) ;, $LVS_EX_GRIDLINES

; Add columns
_GUICtrlListView_AddColumn($hListView, "", 0)
_GUICtrlListView_AddColumn($hListView, "Items List")
_GUICtrlListView_AddColumn($hListView, "SubItems 1")
_GUICtrlListView_AddColumn($hListView, "SubItems 2 large")
; Size columns
_GUICtrlListView_SetColumnWidth($hListView, 1, 90) 
_GUICtrlListView_SetColumnWidth($hListView, 2, $LVSCW_AUTOSIZE_USEHEADER)
_GUICtrlListView_SetColumnWidth($hListView, 3, $LVSCW_AUTOSIZE_USEHEADER)
    
; Add Items
For $i = 1 To 15
   GUICtrlCreateListViewItem("| Item" & $i & "|SubItem" & $i & "|SubItem" & $i , $cListView)
   If Mod($i, 2) = 0 Then 
      GUICtrlSetBkColor(-1, 0x3467BA)
   Else
      GUICtrlSetBkColor(-1, 0x4272BE)
   EndIf
Next

;Header
Global $hHeader = _GUICtrlListView_GetHeader($hListView)
;Turn off theme for header
DllCall("uxtheme.dll", "int", "SetWindowTheme", "hwnd", $hHeader, "wstr", "", "wstr", "")
;subclass ListView to get at NM_CUSTOMDRAW notification sent to ListView
Global $wProcNew = DllCallbackRegister("_LVWndProc", "ptr", "hwnd;uint;wparam;lparam")
Global $wProcOld = _WinAPI_SetWindowLong($hListView, $GWL_WNDPROC, DllCallbackGetPtr($wProcNew))

;Optional: Flat Header - remove header 3D button effect
Global $iStyle = _WinAPI_GetWindowLong($hHeader, $GWL_STYLE)
_WinAPI_SetWindowLong($hHeader, $GWL_STYLE, BitOR($iStyle, $HDS_FLAT))

GUISetState()


Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

; Exit
; reset style
If $wProcOld Then _WinAPI_SetWindowLong($hListView, $GWL_WNDPROC, $wProcOld)
; Delete callback function
If $wProcNew Then DllCallbackFree($wProcNew)
GUIDelete()
Exit

;====================================================

Func _LVWndProc($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    If $iMsg = $WM_NOTIFY Then
        Local $tNMHDR, $hWndFrom, $iCode, $hDC
        $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
        $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
        $iCode = DllStructGetData($tNMHDR, "Code")

        Switch $hWndFrom
            Case $hHeader
                Switch $iCode
                    Case $NM_CUSTOMDRAW
                        Local $tCustDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
                        Switch DllStructGetData($tCustDraw, "dwDrawStage")
                            Case $CDDS_PREPAINT
                                Return $CDRF_NOTIFYITEMDRAW
                            Case $CDDS_ITEMPREPAINT
                                $hDC = DllStructGetData($tCustDraw, "hDC")
                               _WinAPI_SetTextColor($hDC, 0xFFFF99)
                               _WinAPI_SetBkColor($hDC, 0x000000)
                                Return $CDRF_NEWFONT
                        EndSwitch
                EndSwitch
        EndSwitch
    EndIf
    ;pass the unhandled messages to default WindowProc
    Return _WinAPI_CallWindowProc($wProcOld, $hWnd, $iMsg, $wParam, $lParam )
EndFunc   ;==>_LVWndProc

Pour rajouter mon grains de sel je trouve qu'autoit n'est pas un langage axée sur le développement d'interfaces "moderne" mais d'avantage sur sa facilité à effectuer des tâches avec un minimum de code.

Pour mes quelques interfaces "soignées" je me suis toujours dépatouillé à créer des images de gouts puis de les inclure dans ma GUI avec un système d’événement lors du survole et du clic.

...ce qui correspond à peu près au fonctionnement des udfs mentionnées par jguinch

A mes yeux, Autoit est plus un outil pour permettre de compléter Windows, utilisant à peu pres les mêmes fonctions de base que Microsoft et ses développeurs.
Pour changer l’apparence des contrôles sans utiliser de fonctions complexes, il est toujours possible de changer les styles visuels de base (panneau de configuration...)(bonne chance).
Cependant le résultat ne sera pas celui demandé dans le premier message.(mais c'est un début).

Quel est le problème des UDF externes ?
C'est parce qu'ils viennent de l’extérieur ou parce que ce sont des UDF ?

Il est possible de créer son propre UDF pour faire une listview, avec moins d'options que les vraies mais conçues pour nos besoins (on est jamais mieux servis que par soi-même).
En oubliant totalement les fonctions de listview, il est possible de créer avec des boucles un label par ligne pour le fond,
un ou plusieurs autre pour du texte (transparent ou non), et éventuellement des icônes ou images.

@Mikell :
Tout d'abord merci, pour avoir remodifier le code

Cette exemple est mieux ^^
Y a t-il vraiment aucune solution pour modifier la bande grise ? une piste ?

yohan8 a écrit :Pour rajouter mon grains de sel je trouve qu'autoit n'est pas un langage axée sur le développement d'interfaces "moderne" mais d'avantage sur sa facilité à effectuer des tâches avec un minimum de code.

Pour mes quelques interfaces "soignées" je me suis toujours dépatouillé à créer des images de gouts puis de les inclure dans ma GUI avec un système d’événement lors du survole et du clic.

Je ne suis pas d'accord

Je trouve que vu les capacités d'autoit, le développement d'interfaces "moderne" est possible. Nous n'avons juste pas "encore" les compétences requises pour pouvoir en faire ce qu'on veux totalement.
En ce qui concerne les interfaces soignés j'utilise également des images.

Le développement d'interfaces modernes est possibles, mais la taille de nos codes est conséquente.
On ne peut pas avoir une interface parfaite avec un minimum de code.
Cela devient encore plus vrai quand on veut des bord et des angles bien arrondis,de jolis dégradés etc.

La solution que j'ai trouvé pour l'instant est de faire une multitude de labels ou de passer par GDI+ avec des images qui ne s'affichent pas toujours. Je ne sais pas si c'est ce qui te convient.

Sans voir le résultat je ne peux pas avoir d'appriorie dessus.
Mais on va dire que si j'ai lancer ce sujet c'est pour avoir différente façon de procéder, voir comment les autres fonctionne et quelles méthode ils emploie. Dans le cas présent on parle de la listview et pas vraiment d'interface moderne général.

Ks10 a écrit :Je ne suis pas d'accord
Je trouve que vu les capacités d'autoit, le développement d'interfaces "moderne" est possible. Nous n'avons juste pas "encore" les compétences requises pour pouvoir en faire ce qu'on veux totalement.
En ce qui concerne les interfaces soignés j'utilise également des images.

Bien sur que c'est possible mais ce n'est pas facile, pas aussi facile qu'automatiser certaine tâche.

On peut dire qu'autoit évolue en intégrant de plus en plus d'udf de création graphique plus ou moins simplifié.

mikell a écrit :...ce qui correspond à peu près au fonctionnement des udfs mentionnées par jguinch

Je ne pensais pas que les interfaces d'exemple résultait d'un jeux d'image

Très sympa

Sinon j'avais mis de coté un script permettant de changer la couleur des bords d'un GUICtrlCreateGroup :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <StringSize.au3>

Example()

Func Example()
    Local $hGUI = GUICreate('_GUICtrlCreateGroup()')
    _GUICtrlCreateGroupEx('Group 1', 10, 10, 200, 140) ; Default Colors.
    GUICtrlCreateRadio('Radio 1', 15, 25, 60, 20)
    GUICtrlCreateRadio('Radio 2', 15, 45, 60, 20)

    _GUICtrlCreateGroupEx('Group 2', 10, 160, 230, 100, 0x48036F, 0xAD66D5)
    GUICtrlCreateRadio('Radio 3', 15, 175, 60, 20)
    GUICtrlCreateRadio('Radio 4', 15, 195, 60, 20)

    _GUICtrlCreateGroup('Group 3', 10, 275, 100, 50, 0xA64A00)
    GUICtrlCreateRadio('Radio 5', 15, 290, 60, 20)

    GUISetState(@SW_SHOW, $hGUI)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd
    GUIDelete($hGUI)
EndFunc   ;==>Example


Func _GUICtrlCreateGroup($sText, $iLeft, $iTop, $iWidth, $iHeight, $bColor = 0x000000)
    Local $aLabel[6] = [5]
    Local $aStringSize = _StringSize($sText)

    $aLabel[1] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + 1, 1, $iHeight) ; Left Line.
    $aLabel[2] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + 1, 10, 1) ; Top Left Line.
    GUICtrlCreateLabel(' ' & $sText, $iLeft + 7, $iTop - 6, $aStringSize[2] - 3, 15)
    $aLabel[3] = GUICtrlCreateLabel('', $iLeft + $aStringSize[2] + 4, $iTop + 1, $iWidth - $aStringSize[2] - 3, 1) ; Top Right Line.
    $aLabel[4] = GUICtrlCreateLabel('', $iLeft + $iWidth + 1, $iTop + 1, 1, $iHeight) ; Right Line.
    $aLabel[5] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + $iHeight + 1, $iWidth + 1, 1) ; Bottom Line.
    For $i = 1 To $aLabel[0]
        GUICtrlSetBkColor($aLabel[$i], $bColor)
    Next
EndFunc   ;==>_GUICtrlCreateGroup

Func _GUICtrlCreateGroupEx($sText, $iLeft, $iTop, $iWidth, $iHeight, $bColor = 0xC0C0C0, $OutlineColor = 0xFFFFFF)
    Local $aLabel[6] = [5], $aLabelInner[6] = [5]
    Local $aStringSize = _StringSize($sText)
    $aLabel[1] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + 1, 1, $iHeight) ; Left Line.
    $aLabelInner[1] = GUICtrlCreateLabel('', $iLeft + 2, $iTop + 1, 1, $iHeight) ; Inner/Outer Left Line.
    $aLabel[2] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + 1, 10, 1) ; Top Left Line.
    $aLabelInner[2] = GUICtrlCreateLabel('', $iLeft + 2, $iTop + 2, 10 - 1, 1) ; Top Inner/Outer Left Line.
    GUICtrlCreateLabel(' ' & $sText, $iLeft + 7, $iTop - 6, $aStringSize[2] - 3, 15)
    $aLabel[3] = GUICtrlCreateLabel('', $iLeft + $aStringSize[2] + 4, $iTop + 1, $iWidth - $aStringSize[2] - 3, 1) ; Top Right Line.
    $aLabelInner[3] = GUICtrlCreateLabel('', $iLeft + $aStringSize[2] + 4, $iTop + 2, $iWidth - $aStringSize[2] - 3, 1) ; Top Inner/Outer Right Line.
    $aLabel[4] = GUICtrlCreateLabel('', $iLeft + $iWidth + 1, $iTop + 1, 1, $iHeight) ; Right Line.
    $aLabelInner[4] = GUICtrlCreateLabel('', $iLeft + $iWidth + 2, $iTop + 1, 1, $iHeight + 1) ; Right Inner/Outer Line.
    $aLabel[5] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + $iHeight + 1, $iWidth + 1, 1) ; Bottom Line.
    $aLabelInner[5] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + $iHeight + 2, $iWidth + 2, 1) ; Bottom Inner/Outer Line.
    For $i = 1 To $aLabel[0]
        GUICtrlSetBkColor($aLabel[$i], $bColor)
        GUICtrlSetBkColor($aLabelInner[$i], $OutlineColor)
    Next
EndFunc   ;==>_GUICtrlCreateGroupEx

Ah oui, le _GUICtrlCreateGroup de Guiness... (http://www.autoitscript.com/forum/topic ... eategroup/)
J'avais un peu bricolé le truc pour un autre post : http://www.autoitscript.fr/forum/viewto ... 575#p84575

Ks10 a écrit :Y a t-il vraiment aucune solution pour modifier la bande grise ? une piste ?

Si par "bande grise" tu veux dire le header, il me semble que mon code donne la solution...

Maintenant faut être clair : Autoit exploite les fonctions de base de Windows, donc la listview est la listview de base proposée et assemblée par Windows
Pour la customiser il faut la décortiquer et utiliser d'autres fonctions Windows pour la reconfigurer et c'est pas toujours simple, mais t'as pas le choix. Autoit te facilite la tâche en permettant une manipulation plus conviviale de ces fonctions mais fatalement ça fera du code ^^

Ou alors comme TomAijerrie tu te fabriques ton propre controle, ce qui n'est pas une mauvaise idée et a déjà été essayé par exemple ici

Ou encore tu fais comme yohan, l'esthétique sera au rendez-vous mais viens pas râler après parce que le code est compliqué

Voilà Mikell !
Tu a répondu totalement à ma question.

La solution qui a déjà était essayer avec l'UDF Table.au3 me convient totalement

Sujet résolu

AutoIt Français

[R] Modernisation d'Autoit (nouvelle listview)

[R] Modernisation d'Autoit (nouvelle listview)

Re: [..] Modernisation d'Autoit (nouvelle listview)

Re: [..] Modernisation d'Autoit (nouvelle listview)

Re: [..] Modernisation d'Autoit (nouvelle listview)

Re: [..] Modernisation d'Autoit (nouvelle listview)

Re: [..] Modernisation d'Autoit (nouvelle listview)

Re: [..] Modernisation d'Autoit (nouvelle listview)

Re: [..] Modernisation d'Autoit (nouvelle listview)

Re: [..] Modernisation d'Autoit (nouvelle listview)

Re: [..] Modernisation d'Autoit (nouvelle listview)

Re: [..] Modernisation d'Autoit (nouvelle listview)

Re: [..] Modernisation d'Autoit (nouvelle listview)

Re: [..] Modernisation d'Autoit (nouvelle listview)

Re: [..] Modernisation d'Autoit (nouvelle listview)

Re: [..] Modernisation d'Autoit (nouvelle listview)

Re: [..] Modernisation d'Autoit (nouvelle listview)

Re: [..] Modernisation d'Autoit (nouvelle listview)

Re: [..] Modernisation d'Autoit (nouvelle listview)

Re: [..] Modernisation d'Autoit (nouvelle listview)

Re: [..] Modernisation d'Autoit (nouvelle listview)