AutoIt Français

Code : Tout sélectionner

#cs ----------------------------------------------------------------------------

AutoIt Version: 3.3.8.1
Author:      Ken Piper

Script Function:
    Template multi-client server base code.
    Use as a base for making an efficient server program.

    This base will just accept connections and echo back what it receives,
        and kill the connection if it is dead or inactive for x seconds.
    It will not do any other work, that must be added seperately!

#ce ----------------------------------------------------------------------------

TCPStartup()
Opt("TCPTimeout", 0)

#region ;Safe-to-edit things are below
Global $BindIP = @IPAddress1   ;Listen on all addresses
Global $BindPort = 9995       ;Listen on port 8080
Global $Timeout = 15000        ;Max idle time is 15 seconds before calling a connection "dead"
Global $PacketSize = 2048    ;Max packet size per-check is 2KB
Global $MaxClients = 50        ;Max simultaneous clients is 50
#endregion ;Stuff you shouldn't touch is below

Global $Listen
Global $Clients[1][4] ;[Index][Socket, IP, Timestamp, Buffer]
Global $Ws2_32 = DllOpen("Ws2_32.dll") ;Open Ws2_32.dll, it might get used a lot
Global $NTDLL = DllOpen("ntdll.dll") ;Open ntdll.dll, it WILL get used a lot
Global $CleanupTimer = TimerInit() ;This is used to time when things should be cleaned up

OnAutoItExitRegister("Close") ;Register this function to be called if the server needs to exit

$Clients[0][0] = 0
$Listen = TCPListen($BindIP, $BindPort, $MaxClients) ;Start listening on the given IP/port
If @error Then Exit 1 ;Exit with return code 1 if something was already bound to that IP and port

While 1
    USleep(5000, $NTDLL) ;This is needed because TCPTimeout is disabled. Without this it will run one core at ~100%.
    ;The USleep function takes MICROseconds, not milliseconds, so 1000 = 1ms delay.
    ;When working with this granularity, you have to take in to account the time it takes to complete USleep().
    ;1000us (1ms) is about as fast as this should be set. If you need more performance, set this from 5000 to 1000,
    ;but doing so will make it consume a bit more CPU time to get that extra bit of performance.
    Check() ;Check recv buffers and do things
    If TimerDiff($CleanupTimer) > 1000 Then ;If it has been more than 1000ms since Cleanup() was last called, call it now
        $CleanupTimer = TimerInit() ;Reset $CleanupTimer, so it is ready to be called again
        Cleanup() ;Clean up the dead connections
    EndIf
    Local $iSock = TCPAccept($Listen) ;See if anything wants to connect
    If $iSock = -1 Then ContinueLoop ;If nothing wants to connect, restart at the top of the loop
    Local $iSize = UBound($Clients, 1) ;Something wants to connect, so get the number of people currently connected here
    If $iSize - 1 > $MaxClients And $MaxClients > 0 Then ;If $MaxClients is greater than 0 (meaning if there is a max connection limit) then check if that has been reached
        TCPCloseSocket($iSock) ;It has been reached, close the new connection and continue back at the top of the loop
        ContinueLoop
    EndIf
    ReDim $Clients[$iSize + 1][4] ;There is room for a new connection, allocate space for it here
    $Clients[0][0] = $iSize ;Update the number of connected clients
    $Clients[$iSize][0] = $iSock ;Set the socket ID of the connection
    $Clients[$iSize][1] = SocketToIP($iSock, $Ws2_32) ;Set the IP Address the connection is from
    $Clients[$iSize][2] = TimerInit() ;Set the timestamp for the last known activity timer
    $Clients[$iSize][3] = "" ;Blank the recv buffer
WEnd

Func Check() ;Function for processing
    If $Clients[0][0] < 1 Then Return ;If there are no clients connected, stop the function right now
    For $i = 1 To $Clients[0][0] ;Loop through all connected clients
        $sRecv = TCPRecv($Clients[$i][0], $PacketSize) ;Read $PacketSize bytes from the current client's buffer
        If $sRecv <> "" Then $Clients[$i][3] &= $sRecv ;If there was more data sent from the client, add it to the buffer
        If $Clients[$i][3] = "" Then ContinueLoop ;If the buffer is empty, stop right here and check more clients
        $Clients[$i][2] = TimerInit() ;If it got this far, there is data to be parsed, so update the activity timer
        #region ;Example packet processing stuff here. This is handling for a simple "echo" server with per-packet handling
            $sRecv = StringLeft($Clients[$i][3], StringInStr($Clients[$i][3], @CRLF, 0, -1)) ;Pull all data to the left of the last @CRLF in the buffer
            ;This does NOT pull the first complete packet, this pulls ALL complete packets, leaving only potentially incomplete packets in the buffer
            If $sRecv = "" Then ContinueLoop ;Check if there were any complete "packets"
            $Clients[$i][3] = StringTrimLeft($Clients[$i][3], StringLen($sRecv) + 1) ;remove what was just read from the client's buffer
            $sPacket = StringSplit($sRecv, @CRLF, 1) ;Split all complete packets up in to an array, so it is easy to work with them
            For $j = 1 To $sPacket[0] ;Loop through each complete packet; This is where any packet processing should be done
                TCPSend($Clients[$i][0], "Echoing line: " & $sPacket[$j] & @CRLF) ;Echo back the packet the client sent
            Next
        #endregion ;Example
    Next
EndFunc

Func Cleanup() ;Clean up any disconnected clients to regain resources
    If $Clients[0][0] < 1 Then Return ;If no clients are connected then return
    Local $iNewSize = 0
    For $i = 1 To $Clients[0][0] ;Loop through all connected clients
        $Clients[$i][3] &= TCPRecv($Clients[$i][0], $PacketSize) ;Dump any data not-yet-seen in to their recv buffer
        If @error Or TimerDiff($Clients[$i][2]) > $Timeout Then ;Check to see if the connection has been inactive for a while or if there was an error
            TCPCloseSocket($Clients[$i][0]) ;If yes, close the connection
            $Clients[$i][0] = -1 ;Set the socket ID to an invalid socket
        Else
            $iNewSize += 1
        EndIf
    Next
    If $iNewSize < $Clients[0][0] Then ;If any dead connections were found, drop them from the client array and resize the array
        Local $iSize = UBound($Clients, 2) - 1
        Local $aTemp[$iNewSize + 1][$iSize + 1]
        Local $iCount = 1
        For $i = 1 To $Clients[0][0]
            If $Clients[$i][0] = -1 Then ContinueLoop
            For $j = 0 To $iSize
                $aTemp[$iCount][$j] = $Clients[$i][$j]
            Next
            $iCount += 1
        Next
        $aTemp[0][0] = $iNewSize
        $Clients = $aTemp
    EndIf
EndFunc

Func Close()
    DllClose($Ws2_32) ;Close the open handle to Ws2_32.dll
    DllClose($NTDLL) ;Close the open handle to ntdll.dll
    For $i = 1 To $Clients[0][0] ;Loop through the connected clients
        TCPCloseSocket($Clients[$i][0]) ;Force the client's connection closed
    Next
    TCPShutdown() ;Shut down networking stuff
EndFunc

Func SocketToIP($iSock, $hDLL = "Ws2_32.dll") ;A rewrite of that _SocketToIP function that has been floating around for ages
    Local $structName = DllStructCreate("short;ushort;uint;char[8]")
    Local $sRet = DllCall($hDLL, "int", "getpeername", "int", $iSock, "ptr", DllStructGetPtr($structName), "int*", DllStructGetSize($structName))
    If Not @error Then
        $sRet = DllCall($hDLL, "str", "inet_ntoa", "int", DllStructGetData($structName, 3))
        If Not @error Then Return $sRet[0]
    EndIf
    Return "0.0.0.0" ;Something went wrong, return an invalid IP
EndFunc

Func USleep($iUsec, $hDLL = "ntdll.dll") ;A rewrite of the _HighPrecisionSleep function made by monoceres (Thanks!)
    Local $hStruct = DllStructCreate("int64")
    DllStructSetData($hStruct, 1, -1 * ($iUsec * 10))
    DllCall($hDLL, "dword", "ZwDelayExecution", "int", 0, "ptr", DllStructGetPtr($hStruct))
EndFunc

Code : Tout sélectionner

TCPStartup()
Opt("TCPTimeout", 0)

#region ;Safe-to-edit things are below / Choses à modifier 
Global $BindIP = @IPAddress1   ; L'adresse IP que le programme va écouter, ici : Localhost / 127.0.0.1
Global $BindPort = 9995       ;  Le port d'écoute, ici :9995 ( N'oublie pas de le rediriger sur ton ordinateur )
Global $Timeout = 15000        ;Durée maximale avant de déclarer un client "mort"/déconnecté
Global $PacketSize = 2048    ; Taille maximum des packets par reception, ici : 2kb  / Je suis pas sur mais c'est équivaut à 2048 charactère je crois
Global $MaxClients = 50        ; Nombre max de clients
#endregion ; Cette régions comporte les choses que tu devrais modifier pour adapter le truc à tes besoins

Global $Listen 
Global $Clients[1][4] ;[Index][Socket, IP, Timestamp, Buffer]   On défini la taille de l'array qui contiendrat des informations importantes à la gestion de tes clients ...

Global $Ws2_32 = DllOpen("Ws2_32.dll") ;Open Ws2_32.dll, it might get used a lot / On ouvre Ws2_32.dll qui sera souvent utilisé par ce serveur
Global $NTDLL = DllOpen("ntdll.dll") ;Open ntdll.dll, it WILL get used a lot / On ouvre ntdll.dll qui sera souvent utilisé par ce serveur
Global $CleanupTimer = TimerInit() ; On démare le timer / chronomètre, il nous servira plus tard afin de faire appelle à la fonction cleanup() qui a pour but d'effacer les client dead/déconnecté 

OnAutoItExitRegister("Close") ; Permet de faire appelle à la fonction close() lorsque l'utilisateur ferme le script... La fonction close fermera les DLL précédamment ouvertes et éteindra le protocole TCP à l'aide de TCPshutdown()


$Clients[0][0] = 0
$Listen = TCPListen($BindIP, $BindPort, $MaxClients) ; On commence à ecouter dans l'ip et le port défini ci-dessus !
If @error Then Exit 1 ; Si un programme est déjà entrain d'écouter au port que tu as mentionné ci-dessus, alors on quitte le script

While 1
    USleep(5000, $NTDLL)    ; Cette fonction est important ! C'est un sleep amélioré qui a pour rôle de sleep et désactiver le TCPtimeout ... C'est important car elle diminu fortement l'utilisation du core ( CPU )
    ; CEPENDANT, elle fonctionne avec des micros secondes et pas des mili secondes, example ... Ici :  1000 = 1ms 
    ; Retirer cette fonction rendra le code plus ou moins + performant, mais cramera ton CPU xD

    Check() ; Fonction qui check les packets recus
 

Code : Tout sélectionner

Func Check() ;Function for processing
    If $Clients[0][0] < 1 Then Return ;If there are no clients connected, stop the function right now
    For $i = 1 To $Clients[0][0] ;Loop through all connected clients
        $sRecv = TCPRecv($Clients[$i][0], $PacketSize) ;Read $PacketSize bytes from the current client's buffer
        If $sRecv <> "" Then $Clients[$i][3] &= $sRecv ;If there was more data sent from the client, add it to the buffer
        If $Clients[$i][3] = "" Then ContinueLoop ;If the buffer is empty, stop right here and check more clients
        $Clients[$i][2] = TimerInit() ;If it got this far, there is data to be parsed, so update the activity timer
        #region ;Example packet processing stuff here. This is handling for a simple "echo" server with per-packet handling
            $sRecv = StringLeft($Clients[$i][3], StringInStr($Clients[$i][3], @CRLF, 0, -1)) ;Pull all data to the left of the last @CRLF in the buffer
            ;This does NOT pull the first complete packet, this pulls ALL complete packets, leaving only potentially incomplete packets in the buffer
            If $sRecv = "" Then ContinueLoop ;Check if there were any complete "packets"
            $Clients[$i][3] = StringTrimLeft($Clients[$i][3], StringLen($sRecv) + 1) ;remove what was just read from the client's buffer
            $sPacket = StringSplit($sRecv, @CRLF, 1) ;Split all complete packets up in to an array, so it is easy to work with them
            For $j = 1 To $sPacket[0] ;Loop through each complete packet; This is where any packet processing should be done
                TCPSend($Clients[$i][0], "Echoing line: " & $sPacket[$j] & @CRLF) ;Echo back the packet the client sent
            Next
        #endregion ;Example
    Next
EndFunc

Code : Tout sélectionner

#cs ----------------------------------------------------------------------------

 AutoIt Version : 3.3.12.0
 Auteur:         Jonathan

 Fonction du Script :
    Modèle de Script AutoIt.

#ce ----------------------------------------------------------------------------

; Début du script - Ajouter votre code ci-dessous.
#pragma compile(Icon, E:\Program Files\AutoIt3\Icons\au3.ico)

#include <Array.au3>

HotKeySet("{ESC}","_Exit") ; assigne la fonction "quitter" à la touche "Echappe"
HotKeySet("{F1}","_ClientsShow") ; assigne la fonction "afficher la liste des clients" à la touche "F1"

Global $IPAddress = @IPAddress1, $port = 9958, $listener = -1, $socketsArray[2] = [0,-1], $maxSockets = 100, $temp, $tempArray, $datas ; on déclare les variables accessibles depuis tout le script

TCPStartup() ; on démarre le service TCP

$listener = TCPListen($IPAddress,$port,$maxSockets) ; création du socket d'écoute
If $listener = -1 Then ; si il y a une erreur, on l'affiche et on ferme service TCP et programme
    MsgBox(16,"Erreur","Erreur lors de la création du socket d'écoute : n°" & @error)
    TCPCloseSocket($listener)
    TCPShutdown()
EndIf

While 1 ; boucle principale du serveur
    If UBound($socketsArray)-1 = $socketsArray[0] Then _ArrayAdd($socketsArray,-1) ; si jamais le nombre de connexion noté (socketsArray[0]) est égale au nombre de clients connectés, on ajoute un dernier élément qui sera utilisé pour accepter un autre client

;~  ### DETECTION DES CLIENTS TOUJOURS CONNECTÉS ###
    If $socketsArray[0] <> 0 Then ; s'il y a un ou des clients connectés
        For $i = 1 To $socketsArray[0] ; pour chacun des clients connectés
            $temp = TCPSend($socketsArray[$i],"TestConnexion") ; on envoie un packet de données
            If $temp = 0 Then ; si le paquet n'est pas bien transmis
                TCPCloseSocket($socketsArray[$i]) ; on ferme (pour être propre) la connexion
                $socketsArray[0] -= 1 ; on enlève 1 au nombre de clients connectés
                _ArrayDelete($socketsArray,$i) ; on enlève l'élément de rang $i de l'array
            EndIf
        Next
    EndIf

;~  ### AJOUT D'UN NOUVEAU CLIENT ###
    If $socketsArray[0] = 0 Then ; s'il n'y a aucun client de connecté
        $socketsArray[1] = TCPAccept($listener) ; on accepte une connexion en tant qu'élément 1 du tableau
        If $socketsArray[1] <> -1 Then ; s'il n'y a pas d'erreur
            _ArrayAdd($socketsArray,-1) ; on ajoute un dernier élément qui sera utilisé pour accepter un autre client
            $socketsArray[0] += 1 ; on ajoute 1 au nombre de clients connectés
        EndIf
    Else ; sinon (ça veut dire qu'au moins un client est connecté)
        $socketsArray[$socketsArray[0]+1] = TCPAccept($listener) ; on accepte une connexion en tant que dernier élément du tableau
        If $socketsArray[$socketsArray[0]+1] <> -1 Then ; s'il n'y a pas d'erreur
            _ArrayAdd($socketsArray,-1) ; on ajoute un dernier élément qui sera utilisé pour accepter un autre client
            $socketsArray[0] += 1 ; on ajoute 1 au nombre de clients connectés
        EndIf
    EndIf

;~  ### RECEPTIONS DES DONNÉES DE TOUS LES CLIENTS ###
    For $i = 1 To $socketsArray[0] ; pour chacun des clients connectés
        $temp = TCPRecv($socketsArray[$i],9999) ; on attend la réception de données
        If $temp <> "" Then $datas &= $temp & @CRLF ; si jamais on reçoit quelque chose, on l'ajoute à la suite de la variable $datas avec un retour à la ligne
    Next
WEnd

Func _Exit()
    For $i = 1 To $socketsArray[0] ; pour chacun des clients
        TCPCloseSocket($socketsArray[$i]) ; on ferme la connexion
    Next
    TCPCloseSocket($listener) ; on ferme le socket d'écoute
    TCPShutdown() ; on arrête le service TCP
    Exit
EndFunc

Func _ClientsShow()
    _ArrayDisplay($socketsArray,"Etat connexions") ; affiche la liste des clients connectés
EndFunc

Code : Tout sélectionner

#cs ----------------------------------------------------------------------------

 AutoIt Version : 3.3.12.0
 Auteur:         Jonathan

 Fonction du Script :
    Modèle de Script AutoIt.

#ce ----------------------------------------------------------------------------

; Début du script - Ajouter votre code ci-dessous.
#pragma compile(Icon, E:\Program Files\AutoIt3\Icons\au3.ico)

HotKeySet("{ESC}","_Exit")

Global $IPAddress = @IPAddress1, $port = 9958, $socket = -1

TCPStartup()

Do
    $socket = TCPConnect($IPAddress,$port)
    Sleep(10)
Until $socket <> -1

While 1
    TCPRecv($socket,9999)
    Sleep(10)
WEnd

Func _Exit()
    TCPCloseSocket($socket)
    TCPShutdown()
    Exit
EndFunc

Code : Tout sélectionner

Do
    $connexion = TCPAccept($socketEcoute)
Until $connexion <> -1

While 1
    boucle principale
WEnd

Code : Tout sélectionner

While 1
        $connexion = TCPAccept($socketEcoute)
        If $connexion <> -1 Then ajouter la connexion dans la liste des clients connectés
        boucle principale
WEnd

Code : Tout sélectionner

#pragma compile(Icon, E:\Program Files\AutoIt3\Icons\au3.ico)

#include <Array.au3>

HotKeySet("{ESC}","_Exit") ;je définis des raccourcis clavier afin de quitter le programme
HotKeySet("{F1}","_ClientsShow"); .... ou d'afficher la liste des clients connectés

Global $IPAddress = @IPAddress1, $port = 9958, $listener = -1, $socketsArray[2] = [0,-1], $maxSockets = 100, $temp, $tempArray, $datas

TCPStartup()

$listener = TCPListen($IPAddress,$port,$maxSockets);création d'un socket d'écoute
If $listener = -1 Then; gère les erreurs de création de socket
    MsgBox(16,"Erreur","Erreur lors de la création du socket d'écoute : n°" & @error)
    TCPCloseSocket($listener)
    TCPShutdown()
EndIf

While 1
If UBound($socketsArray)-1 = $socketsArray[0] Then _ArrayAdd($socketsArray,-1); là je n'ai pas compris, mais je traduit: "Si la dernière valeur du tableau $socketArray vaut celle de la première valeur, alors on ajoute la valeure -1 au tableau $socketArray

;~  ### DETECTION DES CLIENTS TOUJOURS CONNECTÉS ###
    If $socketsArray[0] <> 0 Then ;si il y a un client connecté alors
        For $i = 1 To $socketsArray[0] ;on boucle sur le nombre de valeurs dans $socketArray
            $temp = TCPSend($socketsArray[$i],"TestConnexion") ;et on envois "TestConnexion" à tous les clients
            If $temp = 0 Then ;en cas d'erreur
                TCPCloseSocket($socketsArray[$i])
                $socketsArray[0] -= 1
                _ArrayDelete($socketsArray,$i) ;je supprime le client n'existant plus
            EndIf
        Next
    EndIf

;~  ### AJOUT D'UN NOUVEAU CLIENT ###
    If $socketsArray[0] = 0 Then ;si la liste des clients est vierge (?)
        $socketsArray[1] = TCPAccept($listener) ;le socket du client est placé dans $socketArray[1]
        If $socketsArray[1] <> -1 Then ;si pas d'erreur
            _ArrayAdd($socketsArray,-1) ;on ajoute ce socket au tableau
            $socketsArray[0] += 1 ;et on ajoute une case au tableau
        EndIf
;~     Else ;sinon (C'est la que je comprends pas aussi: au dessus vous mettez  "If $socketsArray[0] <> 0", et là vous avez mis "If $socketsArray[0] = 0", donc ce Else devrait signifier "$socketsArray[0] <> 0" non?
        $socketsArray[$socketsArray[0]+1] = TCPAccept($listener) ;on ajoute 1 client
        If $socketsArray[$socketsArray[0]+1] <> -1 Then
            _ArrayAdd($socketsArray,-1)
            $socketsArray[0] += 1
        EndIf
    EndIf
;~ ; apres le reste je comprends
;~  ### RECEPTIONS DES DONNÉES DE TOUS LES CLIENTS ###
    For $i = 1 To $socketsArray[0]
        $temp = TCPRecv($socketsArray[$i],9999)
        If $temp <> "" Then $datas &= $temp & @CRLF
    Next
WEnd

Func _Exit()
    For $i = 1 To $socketsArray[0]
        TCPCloseSocket($socketsArray[$i])
    Next
    TCPCloseSocket($listener)
    TCPShutdown()
    Exit
EndFunc

Func _ClientsShow()
    _ArrayDisplay($socketsArray,"Etat connexions")
EndFunc