AutoIt Français

Code : Tout sélectionner

Local $iTimeout = 30 * 1000 ; timeout de 30 secondes
Local $hActive  ; Déclaration d'une variable qu'on utilisera plus tard (non obligatoire, question d'habitude)

; Création d'un timer (qui servira à calculer le temps écouler depuis le lancement du script)
Local $hTimer = TimerInit() 

; Déclaration d'un tableau contenant 3 éléments (exécutables des navigateurs) : à adapter selon les besoins
Local $aBrowsers[] = ["firefox.exe", "iexplore.exe", "chrome.exe"] 

; Dans les timeout n'est pas atteint, on boucle sans arrêt
While TimerDiff($hTimer) < $iTimeout
    ; On balaye chaque élément du tableau
    For $i = 0 To UBound($aBrowsers) - 1
        $hActive = WinGetHandle("[ACTIVE]") ; on récupère le handle de la fenêtre active
        
        ; _WinGetProcessName récupère le nom du processus correspondant à une fenêtre
        ; WinGetTitle récupère le titre de la fenêtre
        ; => Si le processus de la fenêtre active est $aBrowsers[$i] et que le titre n'est pas vide
        If _WinGetProcessName($hActive) = $aBrowsers[$i] AND WinGetTitle($hActive) <> "" Then
            WinClose($hActive) ; On ferme la fenêtre concernée
            ExitLoop 2 ; On quitte la boucle While 
        EndIf
    Next
    ; Une petite pause pour éviter de se faire tapper sur les doigts par l'utilisateur (usage CPU)
    Sleep(10) 
WEnd

; Pour _WinGetProcessName, je te laisse décortiquer (rien de compliqué, il faut prendre le temps) 

;===============================================================================
;
; Description:      _WinGetProcessName - Retrieves the name of the Process associated with a window.
; Syntax:           _WinGetProcessName ( $s_Title [, $s_Text ] )
; Parameter(s):     $s_Title - Title of the window to read.
;                   $s_Text [optional] - Text of the window to read.
; Return Value(s):  Success: Returns the name of the Process the window belongs to,
;                   and sets @extended to the Process ID
;                   Failure: Returns False, and sets @error to 1
; Author(s):        Saunders (rksaunders@gmail.com)
;
;===============================================================================

Func _WinGetProcessName($s_Title, $s_Text = '')
    Local $i_PID, $a_ProcList
    $i_PID = WinGetProcess($s_Title, $s_Text)
    If $i_PID <> -1 Then
        $a_ProcList = ProcessList()
        For $i_For = 1 to $a_ProcList[0][0]
            If $a_ProcList[$i_For][1] = $i_PID Then
                SetExtended($i_PID)
                Return $a_ProcList[$i_For][0]
            EndIf
        Next
    EndIf
    SetError(1)
    Return False
EndFunc