AutoIt Français

Bonjour à tous!!!

Voilà, j'ai ecrit un programme permettant d'installé des logiciels avec des checkbox, là il y a pas de soucis.

Mais j'ai un petit problème dont je ne sais pas comment résoudre:
Quand je coche un logiciel et que je clique sur le bouton installer, le logiciel s'installe (ça ok!), mais si je le décoche juste après, et bien, il se reinstalle.

Je veux que quand on decoche une checkbox, le logiciel ne s'installe pas (c'est comme si je ne l'avais pas décocher)

Merci d'avance!!!

Cela dépendra totalement de comment vous avez coder votre script, sans celui-ci sous les yeux, il sera difficile de vous apporter une aide.

Voila mon script!!!

► Afficher le texte

Code : Tout sélectionner

#RequireAdmin

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <IE.au3>


Opt("GUIOnEventMode", 1)  ; Activation du mode évenementiel

;Declaration de l'array principale!!!
Dim $a_installer[42][2]=[["", ""], ["0", "7zip.exe"], ["0", "AutoIt.exe"], ["0", "AveIcon2.exe"], ["0", "Camstudio.exe"], ["0", "Codec_Camstudio"], ["0", "CCleaner.exe"], ["0", "Cobian_Backup.exe"], ["0", "Dial_A_Fix.exe"], ["0", "Firefox.exe"], ["0", "Flash_Mozilla.exe"], ["0", "Flash_IE.exe"], ["0", "Foxit_Reader.exe"], ["0", "Full_Sync.exe"], ["0", "The_Gimp.exe"], ["0", "IP_Scan.exe"], ["0", "java.exe"], ["0", "Lupas_Rename.exe"], ["0", "Magic_IP.exe"], ["0", "Norton_Antivirus.exe"], ["0", "NotePad.exe"], ["0", "NX.exe"], ["0", "Open_Office.exe"], ["0", "PC_Inspector_File_Recovery.exe"], ["0", "PDF_Creator.exe"], ["0", "Photofiltre.exe"], ["0", "Putty_SSH.exe"], ["0", "R.exe"], ["0", "Rep_Listing.exe"], ["0", "Super_Copier.exe"], ["0", "Super_Scan.exe"], ["0", "Tex_Maker.exe"], ["0", "Thunderbird.exe"], ["0", "TightVNC.exe"], ["0", "UltraVNC.exe"], ["0", "VLC.exe"], ["0", "VSo_Image_Resizer.exe"], ["0", "Win2000_Plain_Password.exe"], ["0", "WireShark.exe"], ["0", "XMing.exe"], ["0", "XMing_fonts.exe"], ["0", "SciLab.exe"]]
; Si il y a plus de checkbox, remplacer le 42 par : (nombre de checkbox  + 1)


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;   Parametres globaux de l'interface graphique (cadre entier)  ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

$gui = GUICreate(" Selectionner les logiciels à installer ", 751, 666, 300, 37)
GUISetIcon("Data\autorun.ico")
GUISetOnEvent($GUI_EVENT_CLOSE, "quitter") ;On associe l'évenement "Close" (Alt+F4 / Croix rouge / echap / etc) à la fonction quit


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;   Placement et nom des boutons "Installer", "Quitter", "Documentation" et "A propos"  ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

$installer = GUICtrlCreateButton(" Installer ", 664, 632, 75, 25, 0) ; Création du bouton "installer"
GUICtrlSetOnEvent( -1,"install")
$quitter = GUICtrlCreateButton(" Quitter ", 576, 632, 75, 25, 0) ; Création du bouton "quitter"
GUICtrlSetOnEvent( -1,"quitter")
$documentation = GUICtrlCreateButton(" Documentation ", 8, 632, 83, 25, 0) ; Création du bouton "documentation"
GUICtrlSetOnEvent( -1,"documentation")


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;   Placement et nom de la checkbox (cases à cocher) pour tout selectionner    ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

$checkall = GUICtrlCreateCheckbox("Tout cocher / Tout décoher", 104, 584, 177, 17)
GUICtrlSetOnEvent( -1,"allcheck")

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;   Placement et nom de la checkbox (cases à cocher) pour tous les logiciels communs   ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

$checkcommun = GUICtrlCreateCheckbox("Selectionner les logiciels communs", 408, 584, 209, 17)
GUICtrlSetOnEvent( -1,"allcommun")

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;   Placement et nom des CheckBox (cases à cocher) pour chaque logiciels   ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

$Group7 = GUICtrlCreateGroup("Programmation", -4, 448, 245, 105)
$check2 = GUICtrlCreateCheckbox("AutoIt", 16, 480, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check20 = GUICtrlCreateCheckbox("NotePad", 16, 510, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
GUICtrlCreateGroup("", -99, -99, 1, 1)

$Group1 = GUICtrlCreateGroup("Sécurité", 0, 0, 245, 89)
$check7 = GUICtrlCreateCheckbox("Cobian Backup", 16, 60, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check19 = GUICtrlCreateCheckbox("Norton antivirus", 16, 30, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
GUICtrlCreateGroup("", -99, -99, 1, 1)

$Group2 = GUICtrlCreateGroup("Système", 252, 0, 245, 89)
$check6 = GUICtrlCreateCheckbox("CCleaner", 264, 30, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check8 = GUICtrlCreateCheckbox("Dial A Fix", 264, 60, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
GUICtrlCreateGroup("", -99, -99, 1, 1)

$Group3 = GUICtrlCreateGroup("Bureautique", 248, 376, 245, 177)
$check12 = GUICtrlCreateCheckbox("Foxit Reader", 264, 405, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check22 = GUICtrlCreateCheckbox("Open Office", 264, 435, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check24 = GUICtrlCreateCheckbox("PDF Creator", 264, 465, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check31 = GUICtrlCreateCheckbox("Tex Maker", 264, 495, 97, 17,0x0006)
GUICtrlCreateGroup("", -99, -99, 1, 1)

$Group4 = GUICtrlCreateGroup("Mutlimédia", 0, 88, 245, 361)
$check3 = GUICtrlCreateCheckbox("AveIcon 2", 16, 120, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check4 = GUICtrlCreateCheckbox("Camstudio", 16, 150, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check5 = GUICtrlCreateCheckbox("Codec Camstudio", 16, 180, 121, 17)
GUICtrlSetOnEvent( -1,"checkbox")
$check10 = GUICtrlCreateCheckbox("Flash IE", 16, 210, 137, 17)
GUICtrlSetOnEvent( -1,"checkbox")
$check11 = GUICtrlCreateCheckbox("Flash Mozilla", 16, 240, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check16 = GUICtrlCreateCheckbox("Java", 16, 270, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check25 = GUICtrlCreateCheckbox("Photofiltre", 16, 300, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check14 = GUICtrlCreateCheckbox("The Gimp", 16, 330, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check35 = GUICtrlCreateCheckbox("VLC", 16, 360, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check36 = GUICtrlCreateCheckbox("VSO Image Resizer", 16, 390, 137, 17)
GUICtrlSetOnEvent( -1,"checkbox")
GUICtrlCreateGroup("", -99, -99, 1, 1)

$Group5 = GUICtrlCreateGroup("Manipulation de fichiers", 252, 88, 245, 185)
$check13 = GUICtrlCreateCheckbox("Full Sync", 264, 120, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check17 = GUICtrlCreateCheckbox("Lupas Rename", 264, 180, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check23 = GUICtrlCreateCheckbox("PC Inspector File Recovery", 264, 210, 153, 17)
GUICtrlSetOnEvent( -1,"checkbox")
$check28 = GUICtrlCreateCheckbox("Rep Listing", 264, 240, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check29 = GUICtrlCreateCheckbox("Super Copier", 264, 150, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
GUICtrlCreateGroup("", -99, -99, 1, 1)

$Group6 = GUICtrlCreateGroup("Réseaux", 504, 0, 245, 465)
$check9 = GUICtrlCreateCheckbox("Firefox", 516, 30, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check15 = GUICtrlCreateCheckbox("IP Scan", 516, 60, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check18 = GUICtrlCreateCheckbox("Magic IP", 516, 90, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check21 = GUICtrlCreateCheckbox("NX", 516, 120, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check26 = GUICtrlCreateCheckbox("Putty SSH", 516, 150, 89, 17)
GUICtrlSetOnEvent( -1,"checkbox")
$check30 = GUICtrlCreateCheckbox("Super Scan", 516, 180, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check32 = GUICtrlCreateCheckbox("Thunderbird", 516, 210, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check33 = GUICtrlCreateCheckbox("TightVNC", 516, 240, 121, 17)
GUICtrlSetOnEvent( -1,"checkbox")
$check34 = GUICtrlCreateCheckbox("Ultr@VNC", 516, 270, 145, 17)
GUICtrlSetOnEvent( -1,"checkbox")
$check37 = GUICtrlCreateCheckbox("Win2000 Plain Password", 516, 300, 145, 17)
GUICtrlSetOnEvent( -1,"checkbox")
$check38 = GUICtrlCreateCheckbox("WireShark", 516, 330, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check39 = GUICtrlCreateCheckbox("XMing", 516, 360, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check40 = GUICtrlCreateCheckbox("XMing fonts", 516, 390, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
GUICtrlCreateGroup("", -99, -99, 1, 1)

$Group8 = GUICtrlCreateGroup("Scientifique", 248, 272, 245, 105)
$check27 = GUICtrlCreateCheckbox("R", 264, 300, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
$check41 = GUICtrlCreateCheckbox("SciLab", 264, 330, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
GUICtrlCreateGroup("", -99, -99, 1, 1)

$Group9 = GUICtrlCreateGroup("Utilitaires", 504, 464, 245, 89)
$check1 = GUICtrlCreateCheckbox("7zip", 516, 495, 97, 17,0x0006)
GUICtrlSetOnEvent( -1,"checkbox")
GUICtrlCreateGroup("", -99, -99, 1, 1)
GuiSetState ( )


While 1;Boucle infinie
    Sleep(100)
WEnd


;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;    LES FONCTIONS   ;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;



;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;   La fonction "checkbox"      ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Func checkbox()
    If _Ischecked2(@GUI_CtrlId) Then
        GUICtrlSetState(@GUI_CtrlId,$GUI_UNCHECKED)
    Else
        Switch @GUI_CtrlId
            Case $check1
                If _Ischecked($check1) then
                    $a_installer[1][0] = "1"
                Else
                    $a_installer[1][0] = "0"
                EndIf
            Case $check2
                If _Ischecked($check2) then
                    $a_installer[2][0] = "1"
                Else
                    $a_installer[2][0] = "0"
                EndIf
            Case $check3
                If _Ischecked($check3) then
                    $a_installer[3][0] = "1"
                Else
                    $a_installer[3][0] = "0"
                EndIf
            Case $check4
                If _Ischecked($check4) then
                    $a_installer[4][0] = "1"
                Else
                    $a_installer[4][0] = "0"
                EndIf
            Case $check5
                If _Ischecked($check5) then
                    $a_installer[5][0] = "1"
                Else
                    $a_installer[5][0] = "0"
                EndIf
            Case $check6
                If _Ischecked($check6) then
                    $a_installer[6][0] = "1"
                Else
                    $a_installer[6][0] = "0"
                EndIf
            Case $check7
                If _Ischecked($check7) then
                    $a_installer[7][0] = "1"
                Else
                    $a_installer[7][0] = "0"
                EndIf
            Case $check8
                If _Ischecked($check8) then
                    $a_installer[8][0] = "1"
                Else
                    $a_installer[8][0] = "0"
                EndIf
            Case $check9
                If _Ischecked($check9) then
                    $a_installer[9][0] = "1"
                Else
                    $a_installer[9][0] = "0"
                 EndIf
            Case $check10
                If _Ischecked($check10) then
                    $a_installer[10][0] = "1"
                Else
                    $a_installer[10][0] = "0"
                EndIf
            Case $check11
                If _Ischecked($check11) then
                    $a_installer[11][0] = "1"
                Else
                    $a_installer[11][0] = "0"
                EndIf
            Case $check12
                If _Ischecked($check12) then
                    $a_installer[12][0] = "1"
                Else
                    $a_installer[12][0] = "0"
                EndIf
            Case $check13
                If _Ischecked($check13) then
                    $a_installer[13][0] = "1"
                Else
                    $a_installer[13][0] = "0"
                EndIf
            Case $check14
                If _Ischecked($check14) then
                    $a_installer[14][0] = "1"
                Else
                    $a_installer[14][0] = "0"
                EndIf
            Case $check15
                If _Ischecked($check15) then
                    $a_installer[15][0] = "1"
                Else
                    $a_installer[15][0] = "0"
                EndIf
            Case $check16
                If _Ischecked($check16) then
                    $a_installer[16][0] = "1"
                Else
                    $a_installer[16][0] = "0"
                EndIf
            Case $check17
                If _Ischecked($check17) then
                    $a_installer[17][0] = "1"
                Else
                    $a_installer[17][0] = "0"
                EndIf
            Case $check18
                If _Ischecked($check18) then
                    $a_installer[18][0] = "1"
                Else
                    $a_installer[18][0] = "0"
                EndIf
            Case $check19
                If _Ischecked($check19) then
                    $a_installer[19][0] = "1"
                Else
                    $a_installer[19][0] = "0"
                EndIf
            Case $check20
                If _Ischecked($check20) then
                    $a_installer[20][0] = "1"
                Else
                    $a_installer[20][0] = "0"
                EndIf
            Case $check21
                If _Ischecked($check21) then
                    $a_installer[21][0] = "1"
                Else
                    $a_installer[21][0] = "0"
                EndIf
            Case $check22
                If _Ischecked($check22) then
                    $a_installer[22][0] = "1"
                Else
                    $a_installer[22][0] = "0"
                EndIf
            Case $check23
                If _Ischecked($check23) then
                    $a_installer[23][0] = "1"
                Else
                    $a_installer[23][0] = "0"
                EndIf
            Case $check24
                If _Ischecked($check24) then
                    $a_installer[24][0] = "1"
                Else
                    $a_installer[24][0] = "0"
                EndIf
            Case $check25
                If _Ischecked($check25) then
                    $a_installer[25][0] = "1"
                Else
                    $a_installer[25][0] = "0"
                EndIf
            Case $check26
                If _Ischecked($check26) then
                    $a_installer[26][0] = "1"
                Else
                    $a_installer[26][0] = "0"
                EndIf
            Case $check27
                If _Ischecked($check27) then
                    $a_installer[27][0] = "1"
                Else
                    $a_installer[27][0] = "0"
                EndIf
            Case $check28
                If _Ischecked($check28) then
                    $a_installer[28][0] = "1"
                Else
                    $a_installer[28][0] = "0"
                EndIf
            Case $check29
                If _Ischecked($check29) then
                    $a_installer[29][0] = "1"
                Else
                    $a_installer[29][0] = "0"
                EndIf
            Case $check30
                If _Ischecked($check30) then
                    $a_installer[30][0] = "1"
                Else
                    $a_installer[30][0] = "0"
                EndIf
            Case $check31
                If _Ischecked($check31) then
                    $a_installer[31][0] = "1"
                Else
                    $a_installer[31][0] = "0"
                EndIf
            Case $check32
                If _Ischecked($check32) then
                    $a_installer[32][0] = "1"
                Else
                    $a_installer[32][0] = "0"
                EndIf
            Case $check33
                If _Ischecked($check33) then
                    $a_installer[33][0] = "1"
                Else
                    $a_installer[33][0] = "0"
                EndIf
            Case $check34
                If _Ischecked($check34) then
                    $a_installer[34][0] = "1"
                Else
                    $a_installer[34][0] = "0"
                EndIf
            Case $check35
                If _Ischecked($check35) then
                    $a_installer[35][0] = "1"
                Else
                    $a_installer[35][0] = "0"
                EndIf
            Case $check36
                If _Ischecked($check36) then
                    $a_installer[36][0] = "1"
                Else
                    $a_installer[36][0] = "0"
                EndIf
            Case $check37
                If _Ischecked($check37) then
                    $a_installer[37][0] = "1"
                Else
                    $a_installer[37][0] = "0"
                EndIf
            Case $check38
                If _Ischecked($check38) then
                    $a_installer[38][0] = "1"
                Else
                    $a_installer[38][0] = "0"
                EndIf
            Case $check39
                If _Ischecked($check39) then
                    $a_installer[39][0] = "1"
                Else
                    $a_installer[39][0] = "0"
                EndIf
            Case $check40
                If _Ischecked($check40) then
                    $a_installer[40][0] = "1"
                Else
                    $a_installer[40][0] = "0"
                EndIf
            Case $check41
                If _Ischecked($check41) then
                    $a_installer[41][0] = "1"
                Else
                    $a_installer[41][0] = "0"
                EndIf

        EndSwitch
    EndIf
EndFunc


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;   La fonction "documentation"     ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


Func documentation()

               If _Ischecked($check1) then
                  MsgBox(64, "Informations sur 7zip", "J'aime les licones")
               EndIf

                If _Ischecked($check2) then
                  MsgBox(0, "Informations sur AutoIt", "J'adore l'europe, l'europe c'est super, j'adore l'europe, oui c'est vraiment d'enfer")
                EndIf

               If _Ischecked($check3) then
                MsgBox(64, "Informations sur AveIcon 2", "J'aime les licones")
               EndIf

               If _Ischecked($check4) then
                MsgBox(64, "Informations sur Camstudio", "J'aime les licones")
               EndIf

               If _Ischecked($check5) then
                MsgBox(64, "Informations sur Codec Camstudio", "J'aime les licones")
               EndIf

               If _Ischecked($check6) then
                MsgBox(64, "Informations sur CCleaner", "J'aime les licones")
               EndIf

               If _Ischecked($check7) then
                MsgBox(64, "Informations sur Cobian Backup", "J'aime les licones")
               EndIf

               If _Ischecked($check8) then
                MsgBox(64, "Informations sur Dial A Fix", "J'aime les licones")
               EndIf

               If _Ischecked($check9) then
                MsgBox(64, "Informations sur Firefox", "J'aime les licones")
               EndIf

               If _Ischecked($check10) then
                MsgBox(64, "Informations sur Flash IE", "J'aime les licones")
               EndIf

               If _Ischecked($check11) then
                MsgBox(64, "Informations sur Flash Mozilla", "J'aime les licones")
               EndIf

               If _Ischecked($check12) then
                MsgBox(64, "Informations sur Foxit Reader", "J'aime les licones")
               EndIf

               If _Ischecked($check13) then
                MsgBox(64, "Informations sur Full Sync", "J'aime les licones")
               EndIf

               If _Ischecked($check14) then
                MsgBox(64, "Informations sur The Gimp", "J'aime les licones")
               EndIf

               If _Ischecked($check15) then
                MsgBox(64, "Informations sur IP Scan", "J'aime les licones")
               EndIf

               If _Ischecked($check16) then
                MsgBox(64, "Informations sur Java", "J'aime les licones")
               EndIf

               If _Ischecked($check17) then
                MsgBox(64, "Informations sur Lupas Rename", "J'aime les licones")
               EndIf

               If _Ischecked($check18) then
                MsgBox(64, "Informations sur Magic IP", "J'aime les licones")
               EndIf

               If _Ischecked($check19) then
                MsgBox(64, "Informations sur Norton antivirus ", "J'aime les licones")
               EndIf

               If _Ischecked($check20) then
                MsgBox(64, "Informations sur NotePad", "J'aime les licones")
               EndIf

               If _Ischecked($check21) then
                MsgBox(64, "Informations sur NX", "J'aime les licones")
               EndIf

               If _Ischecked($check22) then
                MsgBox(64, "Informations sur Open Office", "J'aime les licones")
               EndIf

               If _Ischecked($check23) then
                MsgBox(64, "Informations sur PC Inspector File Recovery", "J'aime les licones")
               EndIf

               If _Ischecked($check24) then
                MsgBox(64, "Informations sur PDF Creator", "J'aime les licones")
               EndIf

               If _Ischecked($check25) then
                MsgBox(64, "Informations sur le logiciel", "J'aime les licones")
               EndIf

               If _Ischecked($check26) then
                MsgBox(64, "Informations sur Putty SSH", "J'aime les licones")
               EndIf

               If _Ischecked($check27) then
                MsgBox(64, "Informations sur R", "J'aime les licones")
               EndIf

               If _Ischecked($check28) then
                MsgBox(64, "Informations sur Rep Listing", "J'aime les licones")
               EndIf

               If _Ischecked($check29) then
                MsgBox(64, "Informations sur Super Copier", "J'aime les licones")
               EndIf

               If _Ischecked($check30) then
                MsgBox(64, "Informations sur Super Scan", "J'aime les licones")
               EndIf

               If _Ischecked($check31) then
                MsgBox(64, "Informations sur Tex Maker", "J'aime les licones")
               EndIf

               If _Ischecked($check32) then
                MsgBox(64, "Informations sur Thunderbird", "J'aime les licones")
               EndIf

               If _Ischecked($check33) then
                MsgBox(64, "Informations sur TightVNC", "J'aime les licones")
               EndIf

               If _Ischecked($check34) then
                MsgBox(64, "Informations sur Ultr@VNC", "J'aime les licones")
               EndIf

               If _Ischecked($check35) then
                MsgBox(64, "Informations sur VLC", "J'aime les licones")
               EndIf

               If _Ischecked($check36) then
                MsgBox(64, "Informations sur VSO Image Resizer", "J'aime les licones")
               EndIf

               If _Ischecked($check37) then
                MsgBox(64, "Informations sur Win2000 Plain Password", "J'aime les licones")
               EndIf

               If _Ischecked($check38) then
                MsgBox(64, "Informations sur WireShark", "J'aime les licones")
               EndIf

               If _Ischecked($check39) then
                MsgBox(64, "Informations sur XMing", "J'aime les licones")
               EndIf

               If _Ischecked($check40) then
                MsgBox(64, "Informations sur XMing fonts", "J'aime les licones")
               EndIf

               If _Ischecked($check41) then
                MsgBox(64, "Informations sur SciLab", "J'aime les licones")
               EndIf
EndFunc

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;       La fonction "allcheck"      ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


Func allcheck()
    If _Ischecked($checkall) Then
         GUICtrlSetState($checkcommun,$GUI_UNCHECKED)
         GUICtrlSetState($checkcommun,$GUI_DISABLE)
        Local $i
        GUICtrlSetState($check1,$GUI_CHECKED)
        GUICtrlSetState($check2,$GUI_CHECKED)
        GUICtrlSetState($check3,$GUI_CHECKED)
        GUICtrlSetState($check4,$GUI_CHECKED)
        GUICtrlSetState($check5,$GUI_CHECKED)
        GUICtrlSetState($check6,$GUI_CHECKED)
        GUICtrlSetState($check7,$GUI_CHECKED)
        GUICtrlSetState($check8,$GUI_CHECKED)
        GUICtrlSetState($check9,$GUI_CHECKED)
        GUICtrlSetState($check10,$GUI_CHECKED)
        GUICtrlSetState($check11,$GUI_CHECKED)
        GUICtrlSetState($check12,$GUI_CHECKED)
        GUICtrlSetState($check13,$GUI_CHECKED)
        GUICtrlSetState($check14,$GUI_CHECKED)
        GUICtrlSetState($check15,$GUI_CHECKED)
        GUICtrlSetState($check16,$GUI_CHECKED)
        GUICtrlSetState($check17,$GUI_CHECKED)
        GUICtrlSetState($check18,$GUI_CHECKED)
        GUICtrlSetState($check19,$GUI_CHECKED)
        GUICtrlSetState($check20,$GUI_CHECKED)
        GUICtrlSetState($check21,$GUI_CHECKED)
        GUICtrlSetState($check22,$GUI_CHECKED)
        GUICtrlSetState($check23,$GUI_CHECKED)
        GUICtrlSetState($check24,$GUI_CHECKED)
        GUICtrlSetState($check25,$GUI_CHECKED)
        GUICtrlSetState($check26,$GUI_CHECKED)
        GUICtrlSetState($check27,$GUI_CHECKED)
        GUICtrlSetState($check28,$GUI_CHECKED)
        GUICtrlSetState($check29,$GUI_CHECKED)
        GUICtrlSetState($check30,$GUI_CHECKED)
        GUICtrlSetState($check31,$GUI_CHECKED)
        GUICtrlSetState($check32,$GUI_CHECKED)
        GUICtrlSetState($check33,$GUI_CHECKED)
        GUICtrlSetState($check34,$GUI_CHECKED)
        GUICtrlSetState($check35,$GUI_CHECKED)
        GUICtrlSetState($check36,$GUI_CHECKED)
        GUICtrlSetState($check37,$GUI_CHECKED)
        GUICtrlSetState($check38,$GUI_CHECKED)
        GUICtrlSetState($check39,$GUI_CHECKED)
        GUICtrlSetState($check40,$GUI_CHECKED)
        GUICtrlSetState($check41,$GUI_CHECKED)

        For $i = 1 to Ubound($a_installer) - 1
            $a_installer[$i][0] = "1"
        Next
    Else
        Local $i
        GUICtrlSetState($checkcommun,$GUI_ENABLE)
        GUICtrlSetState($check1,$GUI_UNCHECKED)
        GUICtrlSetState($check2,$GUI_UNCHECKED)
        GUICtrlSetState($check3,$GUI_UNCHECKED)
        GUICtrlSetState($check4,$GUI_UNCHECKED)
        GUICtrlSetState($check5,$GUI_UNCHECKED)
        GUICtrlSetState($check6,$GUI_UNCHECKED)
        GUICtrlSetState($check7,$GUI_UNCHECKED)
        GUICtrlSetState($check8,$GUI_UNCHECKED)
        GUICtrlSetState($check9,$GUI_UNCHECKED)
        GUICtrlSetState($check10,$GUI_UNCHECKED)
        GUICtrlSetState($check11,$GUI_UNCHECKED)
        GUICtrlSetState($check12,$GUI_UNCHECKED)
        GUICtrlSetState($check13,$GUI_UNCHECKED)
        GUICtrlSetState($check14,$GUI_UNCHECKED)
        GUICtrlSetState($check15,$GUI_UNCHECKED)
        GUICtrlSetState($check16,$GUI_UNCHECKED)
        GUICtrlSetState($check17,$GUI_UNCHECKED)
        GUICtrlSetState($check18,$GUI_UNCHECKED)
        GUICtrlSetState($check19,$GUI_UNCHECKED)
        GUICtrlSetState($check20,$GUI_UNCHECKED)
        GUICtrlSetState($check21,$GUI_UNCHECKED)
        GUICtrlSetState($check22,$GUI_UNCHECKED)
        GUICtrlSetState($check23,$GUI_UNCHECKED)
        GUICtrlSetState($check24,$GUI_UNCHECKED)
        GUICtrlSetState($check25,$GUI_UNCHECKED)
        GUICtrlSetState($check26,$GUI_UNCHECKED)
        GUICtrlSetState($check27,$GUI_UNCHECKED)
        GUICtrlSetState($check28,$GUI_UNCHECKED)
        GUICtrlSetState($check29,$GUI_UNCHECKED)
        GUICtrlSetState($check30,$GUI_UNCHECKED)
        GUICtrlSetState($check31,$GUI_UNCHECKED)
        GUICtrlSetState($check32,$GUI_UNCHECKED)
        GUICtrlSetState($check33,$GUI_UNCHECKED)
        GUICtrlSetState($check34,$GUI_UNCHECKED)
        GUICtrlSetState($check35,$GUI_UNCHECKED)
        GUICtrlSetState($check36,$GUI_UNCHECKED)
        GUICtrlSetState($check37,$GUI_UNCHECKED)
        GUICtrlSetState($check38,$GUI_UNCHECKED)
        GUICtrlSetState($check39,$GUI_UNCHECKED)
        GUICtrlSetState($check40,$GUI_UNCHECKED)
        GUICtrlSetState($check41,$GUI_UNCHECKED)

        For $i = 1 to Ubound($a_installer) - 1
            $a_installer[$i][0] = "0"
        Next

    EndIf
EndFunc

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;       La fonction "allcommun"     ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Func allcommun()
    If _Ischecked($checkcommun) Then
        GUICtrlSetState($checkall,$GUI_DISABLE)
        GUICtrlSetState($checkall,$GUI_UNCHECKED)
        Local $i
        GUICtrlSetState($check1,$GUI_CHECKED)
        GUICtrlSetState($check6,$GUI_CHECKED)
        GUICtrlSetState($check7,$GUI_CHECKED)
        GUICtrlSetState($check9,$GUI_CHECKED)
        GUICtrlSetState($check10,$GUI_CHECKED)
        GUICtrlSetState($check11,$GUI_CHECKED)
        GUICtrlSetState($check12,$GUI_CHECKED)
        GUICtrlSetState($check16,$GUI_CHECKED)
        GUICtrlSetState($check19,$GUI_CHECKED)
        GUICtrlSetState($check21,$GUI_CHECKED)
        GUICtrlSetState($check22,$GUI_CHECKED)
        GUICtrlSetState($check23,$GUI_CHECKED)
        GUICtrlSetState($check24,$GUI_CHECKED)
        GUICtrlSetState($check25,$GUI_CHECKED)
        GUICtrlSetState($check31,$GUI_CHECKED)
        GUICtrlSetState($check36,$GUI_CHECKED)
        GUICtrlSetState($check38,$GUI_CHECKED)
        $a_installer[1][0] = "1"
        $a_installer[2][0] = "0"
        $a_installer[3][0] = "0"
        $a_installer[4][0] = "0"
        $a_installer[5][0] = "0"
        $a_installer[6][0] = "1"
        $a_installer[7][0] = "1"
        $a_installer[8][0] = "0"
        $a_installer[9][0] = "1"
        $a_installer[10][0] = "1"
        $a_installer[11][0] = "1"
        $a_installer[12][0] = "1"
        $a_installer[13][0] = "0"
        $a_installer[14][0] = "0"
        $a_installer[15][0] = "0"
        $a_installer[16][0] = "1"
        $a_installer[17][0] = "0"
        $a_installer[18][0] = "0"
        $a_installer[19][0] = "1"
        $a_installer[20][0] = "0"
        $a_installer[21][0] = "1"
        $a_installer[22][0] = "1"
        $a_installer[23][0] = "1"
        $a_installer[24][0] = "1"
        $a_installer[25][0] = "1"
        $a_installer[26][0] = "0"
        $a_installer[27][0] = "0"
        $a_installer[28][0] = "0"
        $a_installer[29][0] = "0"
        $a_installer[30][0] = "0"
        $a_installer[31][0] = "1"
        $a_installer[32][0] = "0"
        $a_installer[33][0] = "0"
        $a_installer[34][0] = "0"
        $a_installer[35][0] = "0"
        $a_installer[36][0] = "1"
        $a_installer[37][0] = "0"
        $a_installer[38][0] = "1"
        $a_installer[39][0] = "0"
        $a_installer[40][0] = "0"
        $a_installer[41][0] = "0"
    Else
        Local $i
        GUICtrlSetState($checkall,$GUI_ENABLE)
        GUICtrlSetState($check1,$GUI_UNCHECKED)
        GUICtrlSetState($check6,$GUI_UNCHECKED)
        GUICtrlSetState($check7,$GUI_UNCHECKED)
        GUICtrlSetState($check9,$GUI_UNCHECKED)
        GUICtrlSetState($check10,$GUI_UNCHECKED)
        GUICtrlSetState($check11,$GUI_UNCHECKED)
        GUICtrlSetState($check12,$GUI_UNCHECKED)
        GUICtrlSetState($check16,$GUI_UNCHECKED)
        GUICtrlSetState($check19,$GUI_UNCHECKED)
        GUICtrlSetState($check21,$GUI_UNCHECKED)
        GUICtrlSetState($check22,$GUI_UNCHECKED)
        GUICtrlSetState($check23,$GUI_UNCHECKED)
        GUICtrlSetState($check24,$GUI_UNCHECKED)
        GUICtrlSetState($check25,$GUI_UNCHECKED)
        GUICtrlSetState($check31,$GUI_UNCHECKED)
        GUICtrlSetState($check36,$GUI_UNCHECKED)
        GUICtrlSetState($check38,$GUI_UNCHECKED)

        $a_installer[1][0] = "0"
        $a_installer[2][0] = "1"
        $a_installer[3][0] = "1"
        $a_installer[4][0] = "1"
        $a_installer[5][0] = "1"
        $a_installer[6][0] = "0"
        $a_installer[7][0] = "0"
        $a_installer[8][0] = "1"
        $a_installer[9][0] = "0"
        $a_installer[10][0] = "0"
        $a_installer[11][0] = "0"
        $a_installer[12][0] = "0"
        $a_installer[13][0] = "1"
        $a_installer[14][0] = "1"
        $a_installer[15][0] = "1"
        $a_installer[16][0] = "0"
        $a_installer[17][0] = "1"
        $a_installer[18][0] = "1"
        $a_installer[19][0] = "0"
        $a_installer[20][0] = "1"
        $a_installer[21][0] = "0"
        $a_installer[22][0] = "0"
        $a_installer[23][0] = "0"
        $a_installer[24][0] = "0"
        $a_installer[25][0] = "0"
        $a_installer[26][0] = "1"
        $a_installer[27][0] = "1"
        $a_installer[28][0] = "1"
        $a_installer[29][0] = "1"
        $a_installer[30][0] = "1"
        $a_installer[31][0] = "0"
        $a_installer[32][0] = "1"
        $a_installer[33][0] = "1"
        $a_installer[34][0] = "1"
        $a_installer[35][0] = "1"
        $a_installer[36][0] = "0"
        $a_installer[37][0] = "1"
        $a_installer[38][0] = "0"
        $a_installer[39][0] = "1"
        $a_installer[40][0] = "1"
        $a_installer[41][0] = "1"

    EndIf
EndFunc

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;       La fonction "install"       ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Func install()
    Local $i
    Global $v_allCompanies[42] = [$check1, $check2, $check3, $check4, $check5, $check6, $check7, $check8, $check9, $check10, $check11, $check12, $check13, $check14, $check15, $check16, $check17, $check18, $check19, $check20, $check21, $check22, $check23, $check24, $check25, $check26, $check27, $check28, $check29, $check29, $check30, $check31, $check32, $check33, $check34, $check35, $check36, $check37, $check38, $check39, $check40, $check41]
    For $i = 1 to Ubound($a_installer)-1
        If $a_installer[$i][0] = "1" then
            Run( @ScriptDir &"\installation\"&$a_installer[$i][1])
            Sleep(1000)
            ;MsgBox(0,"",$a_installer[$i][1])

        EndIf
     Next
     Local $i

      If (GUICtrlRead($v_allCompanies[$i]) = $GUI_UNCHECKED Then
        MsgBox(0, "Erreur","Vous n'avez rien coché")
     EndIf
EndFunc

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;       La fonction "SpecialEvents"     ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Func quitter()
   Exit
EndFunc   ;==>SpecialEvents

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;       La fonction "Ischecked"     ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Func _Ischecked($control)
    Return BitAND(GUICtrlRead($control), $GUI_CHECKED) = $GUI_CHECKED
EndFunc ;==>_IsChecked
Func _Ischecked2($control)
    Return BitAND(GUICtrlRead($control), $GUI_INDETERMINATE) = $GUI_INDETERMINATE
 EndFunc ;==>_IsChecked

Un petit debug (remplace la fonction par ce code) :

Code : Tout sélectionner

Func checkbox()
  msgbox(0,"", GuiCtrlRead(@GUI_CtrlId, 1) &@crlf& "avant :  " & $a_installer[1][0])
   If _Ischecked(@GUI_CtrlId) Then
       GUICtrlSetState(@GUI_CtrlId, $GUI_CHECKED)
       $a_installer[1][0] = "1"
   Else
       GUICtrlSetState(@GUI_CtrlId, $GUI_UNCHECKED)
       $a_installer[1][0] = "0"
   EndIf
  msgbox(0,"", GuiCtrlRead(@GUI_CtrlId, 1) &@crlf& "après :  " & $a_installer[1][0])
EndFunc

Pour optimiser ton code qui en a grand besoin, tu devrais mettre les id des checkbox dans une array
exemple (gracieusement proposé par TommyDDR) : http://www.autoitscript.fr/forum/viewto ... 137#p87137

Je vais essayer de me pencher sur ce code un poil long ^^'

Avant toute chose : Pourquoi avoir des variables $check1, $check2, etc, je vois dans votre script que vous utilisez des tableaux ailleurs, alors pourquoi pas pour $check ?

Il faut savoir que dans 99.99% des cas où vous aurez $variable1, $variable2, $variable3, c'est que vous devez utiliser un tableau. Sinon vous allez faire que des copier coller de votre code.

EDIT : Voilà comment passer de 885 lignes à 177 lignes.
Savourez le j'y ai passé du temps ^^'

► Afficher le textecode

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <IE.au3>


;~ Opt("MustDeclareVars", 1)  ; À METTRE DANS TOUS VOS SCRIPTS !
Opt("GUIOnEventMode", 1)  ; Activation du mode évenementiel

;Declaration de l'array principale!!!
; Si il y a plus de checkbox, remplacer le 42 par : (nombre de checkbox  + 1)
; Depuis la derniere version d'AutoIt, vous n'êtes plus obligé d'indiquer le nombre de dimension lorsque vous déclarez le contenu explicitement

Enum $C_ID, $C_NOM, $C_NOMEXE, $C_COMMUN, $C_MSGBOX

Global $a_installer =   [   [   ["", "Sécurité",                      "",                                 False,  ""], _
                                ["", "Norton Antivirus",                "Norton_Antivirus.exe",             True,   "J'aime les licones"], _
                                ["", "Cobian Backup",                   "Cobian_Backup.exe",                True,   "J'aime les licones"]], _
                            [   ["", "Multimédia",                     "",                                 False,  ""], _
                                ["", "AveIcon2",                        "AveIcon2.exe",                     False,  "J'aime les licones"], _
                                ["", "Camstudio",                       "Camstudio.exe",                    False,  "J'aime les licones"], _
                                ["", "Codec Camstudio",                 "Codec_Camstudio",                  False,  "J'aime les licones"], _
                                ["", "Flash IE",                        "Flash_IE.exe",                     True,   "J'aime les licones"], _
                                ["", "Flash Mozilla",                   "Flash_Mozilla.exe",                True,   "J'aime les licones"], _
                                ["", "Java",                            "java.exe",                         True,   "J'aime les licones"], _
                                ["", "Photofiltre",                     "Photofiltre.exe",                  True,   "J'aime les licones"], _
                                ["", "The Gimp",                        "The_Gimp.exe",                     False,  "J'aime les licones"], _
                                ["", "VLC",                             "VLC.exe",                          False,  "J'aime les licones"], _
                                ["", "VSO Image Resizer",               "VSo_Image_Resizer.exe",            True,   "J'aime les licones"]], _
                            [   ["", "Programmation",                   "",                                 False,  ""], _
                                ["", "AutoIt",                          "AutoIt.exe",                       False,  "J'adore l'europe, l'europe c'est super, j'adore l'europe, oui c'est vraiment d'enfer"], _
                                ["", "Notepad",                         "NotePad.exe",                      False,  "J'aime les licones"]], _
                            [   ["", "Système",                            "",                                 False,  ""], _
                                ["", "CCleaner",                        "CCleaner.exe",                     True,   "J'aime les licones"], _
                                ["", "Dial A Fix",                      "Dial_A_Fix.exe",                   False,  "J'aime les licones"]], _
                            [   ["", "Manipulation de fichiers",        "",                                 False,  ""], _
                                ["", "Full Sync",                       "Full_Sync.exe",                    False,  "J'aime les licones"], _
                                ["", "Super Copier",                    "Super_Copier.exe",                 False,  "J'aime les licones"], _
                                ["", "Lupas Rename",                    "Lupas_Rename.exe",                 False,  "J'aime les licones"], _
                                ["", "PC Inspector File Recovery",      "PC_Inspector_File_Recovery.exe",   True,   "J'aime les licones"], _
                                ["", "Rep Listing",                     "Rep_Listing.exe",                  False,  "J'aime les licones"]], _
                            [   ["", "Scientifique",                    "",                                 False,  ""], _
                                ["", "R",                               "R.exe",                            False,  "J'aime les licones"], _
                                ["", "SciLab",                          "SciLab.exe",                       False,  "J'aime les licones"]], _
                            [   ["", "Bureautique",                     "",                                 False,  ""], _
                                ["", "Foxit Reader",                    "Foxit_Reader.exe",                 True,   "J'aime les licones"], _
                                ["", "Open Office",                     "Open_Office.exe",                  True,   "J'aime les licones"], _
                                ["", "PDF Creator",                     "PDF_Creator.exe",                  True,   "J'aime les licones"], _
                                ["", "Tex Maker",                       "Tex_Maker.exe",                    True,   "J'aime les licones"]], _
                            [   ["", "Réseaux",                            "",                                 False,  ""], _
                                ["", "Firefox",                         "Firefox.exe",                      True,   "J'aime les licones"], _
                                ["", "IP Scan",                         "IP_Scan.exe",                      False,  "J'aime les licones"], _
                                ["", "Magic IP",                        "Magic_IP.exe",                     False,  "J'aime les licones"], _
                                ["", "NX",                              "NX.exe",                           True,   "J'aime les licones"], _
                                ["", "Putty SSH",                       "Putty_SSH.exe",                    False,  "J'aime les licones"], _
                                ["", "Super Scan",                      "Super_Scan.exe",                   False,  "J'aime les licones"], _
                                ["", "Thunderbird",                     "Thunderbird.exe",                  False,  "J'aime les licones"], _
                                ["", "TightVNC",                        "TightVNC.exe",                     False,  "J'aime les licones"], _
                                ["", "Ultr@VNC",                        "UltraVNC.exe",                     False,  "J'aime les licones"], _
                                ["", "Win2000 Plain Password",          "Win2000_Plain_Password.exe",       False,  "J'aime les licones"], _
                                ["", "Wireshark",                       "WireShark.exe",                    True,   "J'aime les licones"], _
                                ["", "XMing",                           "XMing.exe",                        False,  "J'aime les licones"], _
                                ["", "XMing Fonts",                     "XMing_fonts.exe",                  False,  "J'aime les licones"]], _
                            [   ["", "Utilitaires",                     "",                                 False,  ""], _
                                ["", "7Zip",                            "7zip.exe",                         True,   "J'aime les licones"]]]

Global $tailleGui = [751, 666]

$gui = GUICreate(" Selectionner les logiciels à installer ", $tailleGui[0], $tailleGui[1])
GUISetIcon("Data\autorun.ico")
GUISetOnEvent($GUI_EVENT_CLOSE, "quitter") ;On associe l'évenement "Close" (Alt+F4 / Croix rouge / echap / etc) à la fonction quit

$installer = GUICtrlCreateButton(" Installer ", $tailleGui[0]-90, $tailleGui[1]-35, 75, 25, 0) ; Création du bouton "installer"
$quitter = GUICtrlCreateButton(" Quitter ", $tailleGui[0]-175, $tailleGui[1]-35, 75, 25, 0) ; Création du bouton "quitter"
$documentation = GUICtrlCreateButton(" Documentation ", 8, $tailleGui[1]-35, 83, 25, 0) ; Création du bouton "documentation"
$checkall = GUICtrlCreateCheckbox("Tout cocher / Tout décoher", 105, $tailleGui[1]-80, 177, 17)
$checkcommun = GUICtrlCreateCheckbox("Selectionner les logiciels communs", $tailleGui[0]-340, $tailleGui[1]-80, 209, 17)
GUICtrlSetOnEvent($installer, "install")
GUICtrlSetOnEvent($quitter, "quitter")
GUICtrlSetOnEvent($documentation, "documentation")
GUICtrlSetOnEvent($checkall, "allcheck")
GUICtrlSetOnEvent($checkcommun, "allcommun")

Local $pos = [5, 5]
Local $taille = [245, 0]
Local $tailleCheckbox = [100, 17]
Local $tailleDecalage = $tailleCheckbox[1]+15
For $i = 0 To UBound($a_installer, 1)-1
    $taille[1] = getTailleByIndex($i)*$tailleDecalage+15
    If($pos[1] + $taille[1] >= $tailleGui[1]-100) Then
        $pos[0] += $taille[0] + 5
        $pos[1] = 5
    EndIf
    $a_installer[$i][0][$C_ID] = GUICtrlCreateGroup($a_installer[$i][0][$C_NOM], $pos[0], $pos[1], $taille[0], $taille[1])
    $pos[1] += 20
    For $j = 1 To UBound($a_installer, 2)-1
        If(StringLen($a_installer[$i][$j][$C_NOM]) = 0) Then ExitLoop
        $a_installer[$i][$j][$C_ID] = GUICtrlCreateCheckbox($a_installer[$i][$j][$C_NOM], $pos[0]+20, $pos[1], $tailleCheckbox[0], $tailleCheckbox[1])
        $pos[1] += $tailleDecalage
    Next
Next
GUISetState(@SW_SHOW, $gui)

While(1)
    Sleep(100)
WEnd

Func documentation()
    For $i = 0 To UBound($a_installer, 1)-1
        For $j = 1 To UBound($a_installer, 2)-1
            If($a_installer[$i][$j][$C_ID] <= 0) Then ExitLoop
            If _Ischecked($a_installer[$i][$j][0]) then
                MsgBox(64, "Informations sur " & $a_installer[$i][$j][$C_NOM], $a_installer[$i][$j][$C_MSGBOX])
            EndIf
        Next
    Next
EndFunc

Func allcheck()
    Local $state = _Ischecked($checkall) ? $GUI_CHECKED : $GUI_UNCHECKED
    GUICtrlSetState($checkcommun,$GUI_UNCHECKED)
    GUICtrlSetState($checkcommun,$GUI_DISABLE)
    For $i = 0 To UBound($a_installer, 1)-1
        For $j = 1 To UBound($a_installer, 2)-1
            If($a_installer[$i][$j][$C_ID] <= 0) Then ExitLoop
            GUICtrlSetState($a_installer[$i][$j][$C_ID], $state)
        Next
    Next
EndFunc

Func allcommun()
    Local $state = _Ischecked($checkcommun) ? $GUI_CHECKED : $GUI_UNCHECKED
    GUICtrlSetState($checkall,$GUI_DISABLE)
    GUICtrlSetState($checkall,$GUI_UNCHECKED)
    For $i = 0 To UBound($a_installer, 1)-1
        For $j = 1 To UBound($a_installer, 2)-1
            If($a_installer[$i][$j][$C_ID] <= 0) Then ExitLoop
            If($a_installer[$i][$j][$C_COMMUN]) Then
                GUICtrlSetState($a_installer[$i][$j][$C_ID], $state)
            EndIf
        Next
    Next
EndFunc

Func install()
    Local $isRun = False
    For $i = 0 To UBound($a_installer, 1)-1
        For $j = 1 To UBound($a_installer, 2)-1
            If($a_installer[$i][$j][$C_ID] <= 0) Then ExitLoop
            If(_IsChecked($a_installer[$i][$j][$C_ID])) Then
                $isRun = True
                Run( @ScriptDir &"\installation\" & $a_installer[$i][$j][$C_NOMEXE])
                Sleep(1000)
            EndIf
        Next
    Next
    If(Not($isRun)) Then
        MsgBox(0, "Erreur","Vous n'avez rien coché")
    EndIf
EndFunc

Func getTailleByIndex($indice)
    Local $taille = 0
    For $i = 1 To UBound($a_installer, 2)-1
        If(StringLen($a_installer[$indice][$i][$C_NOM]) <= 0) Then ExitLoop
        $taille += 1
    Next
    Return $taille
EndFunc

Func _Ischecked($control)
    Return BitAND(GUICtrlRead($control), $GUI_CHECKED) = $GUI_CHECKED
EndFunc

Func quitter()
   Exit
EndFunc

Merci TommyDDR! Merci Mikell!!!!

Vous m'avez vraiment aidez!! Merci beaucoup!!

TommyDDR,je pense que tu as passé beaucoup de temps donc je savoure ton code!!

AutoIt Français

[R] Décocher une Checkbox

[R] Décocher une Checkbox

Re: [..] Décocher une Checkbox

Re: [..] Décocher une Checkbox

Re: [..] Décocher une Checkbox

Re: [..] Décocher une Checkbox

Re: [..] Décocher une Checkbox