AutoIt Français

Bonjour,
J'ais essayé de créer un script , qui copie un dossier donné , à un emplacement quelconque (exemple : Disque local C: , clés USB F: , ect ...) . Et qui le colle vers un dossier donné aussi à un emplacement quelconque . Après beaucoup d'efforts en vain

, j'ai décidé de demander de l'aide .

Merci
PS:(J'ais cherché si la question avait déjà été posée sur le forum , mais je n'ai pas trouvé de réponse à ma question

.)

► Afficher le texte

Code : Tout sélectionner

#include <GuiButton.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=C:\Users\Popipipo\Desktop\Viss Versa  graph.kxf
$Form1_1 = GUICreate("Viss Versa 2.0", 626, 444, 247, 233)
$entrerA = GUICtrlCreateInput("Nom Dossier emmeteur ", 24, 105, 161, 24)
GUICtrlSetFont(-1, 9, 400, 0, "Impact")
$entrerB = GUICtrlCreateInput("Nom Dossier recepteur", 440, 105, 161, 24)
GUICtrlSetFont(-1, 9, 400, 0, "Impact")
$Button2 = GUICtrlCreateButton("Qui sommes nous ?", 440, 384, 169, 41, $WS_GROUP)
GUICtrlSetFont(-1, 9, 400, 0, "Impact")
$Button1 = GUICtrlCreateButton("Copier/Coller", 256, 184, 137, 65, $WS_GROUP)
GUICtrlSetFont(-1, 10, 400, 0, "Impact")
$Label1 = GUICtrlCreateLabel("Dossier émetteur", 48, 72, 113, 23)
GUICtrlSetFont(-1, 11, 400, 0, "Impact")
$Label2 = GUICtrlCreateLabel("Dossier recepteur", 464, 64, 116, 23)
GUICtrlSetFont(-1, 11, 400, 0, "Impact")

GUISetState(@SW_SHOW)






While 1
$nMsg = GUIGetMsg()
    switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $Button1
            $lire_dossier_emetteur = GUICtrlRead ( $entrerA )
            $lire_dossier_recepteur = GUICtrlRead ( $entrerB )

        Global $lire_dossier_emetteur
        Global $lire_dossier_recepteur

            $exist_dossier_emetteur_dans_C = FileExists($lire_dossier_emetteur)
            $exist_dossier_emetteur_dans_D = FileExists("D:\"&$lire_dossier_emetteur&"\")
            $exist_dossier_emetteur_dans_E = FileExists("E:\"&$lire_dossier_emetteur&"\")
            $exist_dossier_emetteur_dans_F = FileExists("F:\"&$lire_dossier_emetteur&"\")
            $exist_dossier_emetteur_dans_G = FileExists("G:\"&$lire_dossier_emetteur&"\")
            $exist_dossier_emetteur_dans_H = FileExists("H:\"&$lire_dossier_emetteur&"\")
            $exist_dossier_emetteur_dans_I = FileExists("I:\"&$lire_dossier_emetteur&"\")

             $exist_dossier_recepteur_dans_C = FileExists($lire_dossier_recepteur)
            $exist_dossier_recepteur_dans_D = FileExists("D:\"&$lire_dossier_recepteur&"\")
            $exist_dossier_recepteur_dans_E = FileExists("E:\"&$lire_dossier_recepteur&"\")
            $exist_dossier_recepteur_dans_F = FileExists("F:\"&$lire_dossier_recepteur&"\")
            $exist_dossier_recepteur_dans_G = FileExists("G:\"&$lire_dossier_recepteur&"\")
            $exist_dossier_recepteur_dans_H = FileExists("H:\"&$lire_dossier_recepteur&"\")
            $exist_dossier_recepteur_dans_I = FileExists("I:\"&$lire_dossier_recepteur&"\")

    If $exist_dossier_emetteur_dans_C = True Then
            $lire_dossier_emetteur = $exist_dossier_emetteur_dans_C
         MsgBox(64,"Espace C:","Le dossier émetteur est dans le disque local C:" )

        ElseIf $exist_dossier_emetteur_dans_D = True Then
            $lire_dossier_emetteur = $exist_dossier_emetteur_dans_D
         MsgBox(64,"Espace D:","Le dossier émetteur est dans le disque local D:" )

        elseIf $exist_dossier_emetteur_dans_E = True Then
              $lire_dossier_emetteur = $exist_dossier_emetteur_dans_E
            MsgBox(64,"Espace E:","Le dossier émetteur est dans le disque local E:" )

        elseIf $exist_dossier_emetteur_dans_F = True Then
             $lire_dossier_emetteur = $exist_dossier_emetteur_dans_F
         MsgBox(64,"Espace F:","Le dossier émetteur est dans le disque local F:" )

        elseIf $exist_dossier_emetteur_dans_G = True Then
              $lire_dossier_emetteur  = $exist_dossier_emetteur_dans_G
         MsgBox(64,"Espace G:","Le dossier émetteur  est dans le disque local G:" )

        elseIf $exist_dossier_emetteur_dans_H = True Then
              $lire_dossier_emetteur  = $exist_dossier_emetteur_dans_H
         MsgBox(64,"Espace H:","Le dossier émetteur est dans le disque local H:" )

        elseIf $exist_dossier_emetteur_dans_I = True Then
             $lire_dossier_emetteur = $exist_dossier_emetteur_dans_I
         MsgBox(64,"Espace I:","Le dossier émetteur est dans le disque local I:" )
       Else
            MsgBox( 64 , "Dossier emetteur absent "," Le Dossier emetteur est absent ")
        EndIf


        If $exist_dossier_recepteur_dans_C = True Then
            $lire_dossier_recepteur =  $exist_dossier_recepteur_dans_C
         MsgBox(64,"Espace C:","Le dossier recepteur est dans le disque local C:" )

        ElseIf $exist_dossier_recepteur_dans_D = True Then
              $lire_dossier_recepteur =  $exist_dossier_recepteur_dans_D
         MsgBox(64,"Espace D:","Le dossier recepteur est dans le disque local D:" )

        elseIf $exist_dossier_recepteur_dans_E = True Then
              $lire_dossier_recepteur =  $exist_dossier_recepteur_dans_E
        MsgBox(64,"Espace E:","Le dossier recepteur  est dans le disque local E:" )

        elseIf $exist_dossier_recepteur_dans_F = True Then
              $lire_dossier_recepteur = $exist_dossier_recepteur_dans_F
         MsgBox(64,"Espace F:","Le dossier recepteur est dans le disque local F:" )

        elseIf $exist_dossier_recepteur_dans_G = True Then
              $lire_dossier_recepteur  = $exist_dossier_recepteur_dans_G
         MsgBox(64,"Espace G:","Le dossier recepteur   est dans le disque local G:" )

        elseIf $exist_dossier_emetteur_dans_H = True Then
              $lire_dossier_recepteur  = $exist_dossier_emetteur_dans_H
         MsgBox(64,"Espace H:","Le dossier recepteur est dans le disque local H:" )

        elseIf $exist_dossier_recepteur_dans_I = True Then
              $lire_dossier_recepteur = $exist_dossier_recepteur_dans_I
         MsgBox(64,"Espace I:","Le dossier recepteur  est dans le disque local I:" )
        Else
            MsgBox( 64 , "Dossier recepteur absent "," Le Dossier recepteur est absent ")
        EndIf


        $test_fin_emetteur = FileExists ($lire_dossier_emetteur )
        $tesgt_fin_recepteur =  FileExists ($lire_dossier_recepteur)

        If $tesgt_fin_recepteur And $test_fin_emetteur = True Then
            FileCopy ( $lire_dossier_emetteur, $lire_dossier_recepteur )
        
                EndIf
    EndSwitch
WEnd[/spoiler]

Popipipo

Bonsoir et bienvenue,

je ne comprends pas tout à fait ton code, mais il y a déjà quelque chose qui me gêne en début de script.
En effet quand tu écris ça :

Code : Tout sélectionner

            $lire_dossier_emetteur = GUICtrlRead ( $entrerA )
            $lire_dossier_recepteur = GUICtrlRead ( $entrerB )

        Global $lire_dossier_emetteur
        Global $lire_dossier_recepteur

tu inverses un peu deux étapes. Pour faire propre on :
- déclare la variable avec son champ d'action : Global $lire_etc...
- on affecte une valeur à la variable : $lire_etc = "dossier"

Ensuite, pour tes tests répétitifs (qui ne sont pas forcément une bonne solution), tu devrais essayer les boucles. Tu fais une boucle qui traite tous les lecteurs possibles et si jamais le dossier est détecté, tu sors de la boucle.
Pareil pour ton dossier récepteur.

Après pour ma part, ces tests ne sont pas réellement utiles puisque à la fin tu cherches directement à savoir s'ils existent tout deux en écrivant :

Code : Tout sélectionner

 $test_fin_emetteur = FileExists ($lire_dossier_emetteur )
        $tesgt_fin_recepteur =  FileExists ($lire_dossier_recepteur

Enfin, je pense que si ton script ne marche pas c'est que dans tes tests, tu écris : " $lire_dossier_emetteur = $exist_dossier_emetteur_dans_I"

Au final, tes variables à la place de contenir les chemins de dossier, elles sont égales soit à 1 soit à 0.

Voici une proposition de code. J'ai essayé de garder tes idées, c'est à dire que l'on puisse voir de quel périphérique ça sort. Seulement j'ai utilisé des tableaux, qui sont très utiles.

► Afficher le texte

Code : Tout sélectionner

#include <GuiButton.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

#Region ### START Koda GUI section ### Form=C:\Users\Popipipo\Desktop\Viss Versa  graph.kxf
$Form1_1 = GUICreate("Viss Versa 2.0", 626, 444, 247, 233)
$entrerA = GUICtrlCreateInput("Nom Dossier emmeteur ", 24, 105, 161, 24)
GUICtrlSetFont(-1, 9, 400, 0, "Impact")
$entrerB = GUICtrlCreateInput("Nom Dossier recepteur", 440, 105, 161, 24)
GUICtrlSetFont(-1, 9, 400, 0, "Impact")
$Button2 = GUICtrlCreateButton("Qui sommes nous ?", 440, 384, 169, 41, $WS_GROUP)
GUICtrlSetFont(-1, 9, 400, 0, "Impact")
$Button1 = GUICtrlCreateButton("Copier/Coller", 256, 184, 137, 65, $WS_GROUP)
GUICtrlSetFont(-1, 10, 400, 0, "Impact")
$Label1 = GUICtrlCreateLabel("Dossier émetteur", 48, 72, 113, 23)
GUICtrlSetFont(-1, 11, 400, 0, "Impact")
$Label2 = GUICtrlCreateLabel("Dossier recepteur", 464, 64, 116, 23)
GUICtrlSetFont(-1, 11, 400, 0, "Impact")

GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            Local $paths[2] = [GUICtrlRead($entrerA),GUICtrlRead($entrerB)], $temp, $firstDrive, $secondDrive
            If FileExists($paths[0]) Then
                $temp = StringSplit($paths[0],"\")
                $firstDrive = $temp[1]
                $temp = StringSplit($paths[1],"\")
                $secondDrive = $temp[1]
                MsgBox(64,"Informations","Copie en cours depuis le périphérique de stockage " & $firstDrive & " vers le périphérique " & $secondDrive)
                If Not FileExists($paths[1]) Then DirCreate($paths[1])
                FileCopy($paths[0],$paths[1])
                MsgBox(64,"Informations","Copie terminée !")
            Else
                MsgBox(16,"Erreur","Le dossier émetteur n'existe pas.")
            EndIf
    EndSwitch
WEnd

Trop de line pour rien, si le but est juste de copier/coller des dossiers alors utilises ça:

► Afficher le texte

Code : Tout sélectionner

#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.3.6.1
 Author:         myName

 Script Function:
    Template AutoIt script.

#ce ----------------------------------------------------------------------------

; Script Start - Add your code below here

#include <GuiButton.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Include <File.au3>
#Include <Array.au3>
#Region ### START Koda GUI section ### Form=C:\Users\Popipipo\Desktop\Viss Versa  graph.kxf
$Form1_1 = GUICreate("Viss Versa 2.0", 700, 444)

$entrerA = GUICtrlCreateInput("Nom Dossier emmeteur ", 24, 105, 161, 24)
GUICtrlSetFont(-1, 9, 400, 0, "Impact")
$browseA = GUICtrlCreateButton("Parcourir",200,105,50,25)

$entrerB = GUICtrlCreateInput("Nom Dossier recepteur", 440, 105, 161, 24)
GUICtrlSetFont(-1, 9, 400, 0, "Impact")
$browseB = GUICtrlCreateButton("Parcourir",610,105,50,25)

$Button2 = GUICtrlCreateButton("Qui sommes nous ?", 440, 384, 169, 41, $WS_GROUP)
GUICtrlSetFont(-1, 9, 400, 0, "Impact")

$Button1 = GUICtrlCreateButton("Copier/Coller", 256, 184, 137, 65, $WS_GROUP)
GUICtrlSetFont(-1, 10, 400, 0, "Impact")

$Label1 = GUICtrlCreateLabel("Dossier émetteur", 48, 72, 113, 23)
GUICtrlSetFont(-1, 11, 400, 0, "Impact")

$Label2 = GUICtrlCreateLabel("Dossier recepteur", 464, 64, 116, 23)
GUICtrlSetFont(-1, 11, 400, 0, "Impact")

GUISetState(@SW_SHOW)






While 1
$nMsg = GUIGetMsg()
    switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        
        ;Parcourir et choisir le dossier à copier
        Case $browseA

            $emetteur = FileSelectFolder("","")
            GUICtrlSetData($entrerA,$emetteur)
        
        ;Parcourir et choisir le dossier destinataire
        Case $browseB

            $recepteur = FileSelectFolder("","")
            GUICtrlSetData($entrerB,$recepteur)
        
        Case $Button1
        
            Dim $drive, $dir, $name, $ext
            ;Extraire le chemin vers le dossier
            $testpath = _PathSplit($emetteur&"\",$drive,$dir,$name,$ext)
            
            ;Récupérer le nom du dossier
            $array = StringSplit($testpath[2],"\")
            
            $i = $array[0]
            
            ;Redéfinition du dossier destinataire en y ajoutant le nom du dossier à copier
            $save_path = $recepteur & "\" & $array[$i-1]
            
            DirCopy($emetteur,$save_path,1)
            
    EndSwitch
WEnd

J'ai mis des commentaires au cas où, mais si t'arrives pas à comprendre mon code je te l'expliquerai. En fait le DirCopy ne prends que le contenu du dossier et non le dossier en entier, c'est pour celà que j'ai fais comme ça.

+1 pour le message plus haut.

FileSelectFolder() permet de gagner en nombres de lignes et puis c'est bien plus ergonomique, intuitif que copier/coller le nom du dossier. Maintenant, rien n'empêche de combiner les deux, ça marche aussi.

Mon message était destiné à l'auteur, j'avais pas vu ton script en fait

du coup on a fait plus ou moins la même chose.

Je vous remercie beaucoup pour votre aide, votre savoir et vos codes . Je comprends où étaient mes erreurs . Et comme partout , la simplicité requière une masse importante de connaissances .

Les connaissances viendront à force de programmer. Une fois que les bases sont là, il ne faut pas avoir peur de se frotter à de nouvelles choses. Tu devrais essayer de familiariser avec les boucles et les tableaux. Ce sont des bébêtes vachement utiles dans certains cas.

Si ton sujet est résolu, remplace la balise [..] par [R] en éditant ton premier message, merci ! Bon courage !

AutoIt Français

[R] Copier/Coller un dossier vers un autre .

[R] Copier/Coller un dossier vers un autre .

Re: [..] Copier/Coller un dossier vers un autre .

Re: [..] Copier/Coller un dossier vers un autre .

Re: [..] Copier/Coller un dossier vers un autre .

Re: [..] Copier/Coller un dossier vers un autre .

Re: [..] Copier/Coller un dossier vers un autre .

Re: [..] Copier/Coller un dossier vers un autre .