Page 1 sur 1
[R] Script ping du réseau.
Posté : mar. 25 mars 2014 17:31
par Fredy76
Bonjour,
Je cherche à faire un script pour mon entreprise,
je dois faire un ping sur 3 adresses IP toutes les 30 minutes, si le ping est négatif un Email d'alerte est envoyer à une personne du service informatique.
(Pour les 30 minutes, je pensais faire une tache planifier).
je ne connais que le langage Batch, et je ne parviens pas à envoyer d'email (le resultat arrive dans un fichier TXT, mais je me complique).
Pouvez vous m'aider?
Merci
Re: [...] Script ping du réseau.
Posté : mer. 26 mars 2014 14:31
par PandiPanda
Bonjour, quel informations voulez vous envoyé par mail?
actuellement j'envoi ceci;
"From" : #user
"titre" : Failure Ping ON 8.8.8.7
"corp" : From: 192.168.1.8 - Username : Pandi
Date[26/03/2014] - Heure[14h28m42s]
j'ai fait ce petit script qui envoi un mail lorsqu'il arrive pas a ping, vous devez simplement remplir, modifié en fonction de votre situation.
- - Local $s_SmtpServer = "smtp.gmail.com" ; ici c'est le smtp du serveur
- Local $s_FromName = "#user" ; votre nom?
- Local $s_FromAddress = "usertest@gmail.com" ; l'adresse qui va envoyé le mail
- Local $s_ToAddress = "user2test@gmail.com" ; celui qui va recevoir
- Local $s_Username = "usertest@gmail.com" ; generalement la meme que l'adresse de base
- Local $s_Password = "usertest" ; votre mot de passe
- Local $IPPort = 465;25 ;465 pour gmail et ssl a 1, sinon laisser a 25 et 0 par défaut
- Local $ssl = 1;0 ; ici a 1 si c'est gmail, sinon 0 generalement
- Local $array[3] = ["8.8.8.8","www.google.be","8.8.8.7"] ; ici les 3 adressses dont vous voulez ping. Le dernier ici provoque une erreur
► Afficher le texte
Code : Tout sélectionner
#cs ----------------------------------------------------------------------------
AutoIt Version : 3.3.8.1
Auteur: Pandi_Panda
Fonction du Script :
#
#ce ----------------------------------------------------------------------------
#include <File.au3>
Local $s_SmtpServer = "smtp.gmail.com"
Local $s_FromName = "#user"
Local $s_FromAddress = "usertest@gmail.com"
Local $s_ToAddress = "user2test@gmail.com"
Local $s_Subject = ""
Local $as_Body = ""
Local $s_AttachFiles = ""
Local $s_CcAddress = ""
Local $s_BccAddress = ""
Local $s_Importance="Normal"
Local $s_Username = "usertest@gmail.com"
Local $s_Password = "usertest"
Local $IPPort = 465;25 ;465 pour gmail et ssl a 1, sinon laisser a 25 et 0 par défaut
Local $ssl = 1;0
Local $array[3] = ["8.8.8.8","www.google.be","8.8.8.7"]
; 8.8.8.7 provoquera erreur pour le test ^^
For $i = 0 To UBound($array)-1
Local $ms = Ping($array[$i])
If @error Then
$as_Body = "From: "&@IPAddress1&" - Username : "&@UserName&@CRLF&"Date["&@MDAY&"/"&@MON&"/"&@YEAR&"] - Heure["&@HOUR&"h"&@MIN&"m"&@SEC&"s]"
$s_Subject = "Failure Ping ON "&$array[$i]
_INetSmtpMailCom($s_SmtpServer,$s_FromName,$s_FromAddress,$s_ToAddress, _
$s_Subject,$as_Body,$s_AttachFiles,$s_CcAddress,$s_BccAddress,$s_Importance,$s_Username,$s_Password,$IPPort,$ssl) ; Envoie e-mail
EndIf
Next
Func _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject = "", $as_Body = "", $s_AttachFiles = "", $s_CcAddress = "", $s_BccAddress = "", $s_Importance="Normal", $s_Username = "", $s_Password = "", $IPPort = 25, $ssl = 0) ; Envoie e-mail
Local $objEmail = ObjCreate("CDO.Message")
$objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
$objEmail.To = $s_ToAddress
If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
If $s_BccAddress <> "" Then $objEmail.Bcc = $s_BccAddress
$objEmail.Subject = $s_Subject
If StringInStr($as_Body, "<") And StringInStr($as_Body, ">") Then
$objEmail.HTMLBody = $as_Body
Else
$objEmail.Textbody = $as_Body & @CRLF
EndIf
If $s_AttachFiles <> "" Then
Local $S_Files2Attach = StringSplit($s_AttachFiles, ";")
For $x = 1 To $S_Files2Attach[0]
$S_Files2Attach[$x] = _PathFull($S_Files2Attach[$x])
ConsoleWrite('@@ Debug(62) : $S_Files2Attach = ' & $S_Files2Attach[$x] & @LF & '>Error code: ' & @error & @LF) ;### Debug Console
If FileExists($S_Files2Attach[$x]) Then
$objEmail.AddAttachment ($S_Files2Attach[$x])
Else
ConsoleWrite('!> File not found to attach: ' & $S_Files2Attach[$x] & @LF)
SetError(1)
Return 0
EndIf
Next
EndIf
$objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
$objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $s_SmtpServer
If Number($IPPort) = 0 then $IPPort = 25
$objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $IPPort
If $s_Username <> "" Then
$objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
$objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") = $s_Username
$objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $s_Password
EndIf
If $ssl Then
$objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
EndIf
$objEmail.Configuration.Fields.Update
$objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "High"
$objEmail.Fields.Update
$objEmail.Send
$objEmail=""
EndFunc
Pour automatiser cette tâche toute les 30 minutes, il vous suffit de l'ajouter dans le planificateur de tâches comme vous l'avez spécifier.
Re: [R] Script ping du réseau.
Posté : mer. 26 mars 2014 18:07
par Fredy76
Merci pour la solution, je vais travailler dessus.
Encore merci
.
Re: [R] Script ping du réseau.
Posté : lun. 31 mars 2014 11:44
par Fredy76
Bonjour,
Je suis entrain de faire des tests et je ne recois pas le mail d'alerte.
Dans votre script, je dois juste changer :
Local $s_SmtpServer = "Nom du serveur SMTP de mon entreprise"
Local $s_FromName = "Un nom"
Local $s_FromAddress = "L'adresse d'envoie"
Local $s_ToAddress = "l'adresse du destinataire"
Local $s_Username = "encore l'adresse d'envoie"
Local $s_Subject = "le sujet"
Local $as_Body = "????????"
Local $s_AttachFiles = "????????"
Local $s_CcAddress = "?????"
Local $s_BccAddress = "?????????"
Local $s_Importance="Haute"
Local $s_Username = "Prenom utilisateur"
Local $s_Password = "usertest"
Local $IPPort = 25 ??????
Local $ssl = 1 ??????
Local $array[3] = ["10.4.20.250"] ( mon adresse Ip pour faire le Test).
je ne touche à rien d'autre dans le script ??
Merci de votre aide.
Frederic
Re: [R] Script ping du réseau.
Posté : lun. 31 mars 2014 12:11
par PandiPanda
Bonjour,
Tout depend de quel type de mail vous avez, personnel (différent d'un public comme hotmail, gmail, ...)?
sur quel port, utilise le ssl, smtp correct ?
Les test sur lesquels j'ai fait sont pour une adresse de type gmail.
Pour gmail, le port a avoir est 465 et le ssl a 1.
Pour un autre il faut se renseigner, comme je l'ai dit généralement c'est 25 pour le port et 0 pour le ssl.
Vous pouvez toucher a tout sur le script :p
Il est juste nécessaire de remplir les variables ci dessous;
Code : Tout sélectionner
- Local $s_SmtpServer = "smtp.gmail.com" ; ici c'est le smtp du serveur
- Local $s_FromName = "#user" ; votre nom?
- Local $s_FromAddress = "usertest@gmail.com" ; l'adresse qui va envoyé le mail
- Local $s_ToAddress = "user2test@gmail.com" ; celui qui va recevoir
- Local $s_Username = "usertest@gmail.com" ; generalement la meme que l'adresse de base
- Local $s_Password = "usertest" ; votre mot de passe
- Local $IPPort = 465;25 ;465 pour gmail et ssl a 1, sinon laisser a 25 et 0 par défaut
- Local $ssl = 1;0 ; ici a 1 si c'est gmail, sinon 0 generalement
- Local $array[3] = ["8.8.8.8","www.google.be","8.8.8.7"] ; ici les 3 adressses dont vous voulez ping. Le dernier ici provoque une erreur
Re: [R] Script ping du réseau.
Posté : lun. 31 mars 2014 17:01
par Fredy76
Re-bonjour,
je crois les SMTP ne fonctionne pas sur mon pc je ne parviens pas a recevoir le mails d'alerte.
Voici comment je configure le script: en piece jointe.
Re: [R] Script ping du réseau.
Posté : mar. 01 avr. 2014 20:48
par Fredy76
Bonjour,
J'ai fais des tests dans mon entreprise et je ne recois pas le mail,
je suis chez moi avec une FREE BOX et je ne recois pas non plus de mail.
Peux tu me donner plus de détails STP ?
Je commence tous juste a travailler dans les scripts.
Merci Frédéric.
(en piece jointe, les variables pour ma free box.)
Re: [R] Script ping du réseau.
Posté : mer. 02 avr. 2014 15:54
par Fredy76
Tous Fonctionne encore MERCI.