Page 1 sur 1
[R] Tray Menu Item Persistant
Posté : mar. 04 mars 2014 16:40
par JJJ27
Bonjour, j'utilise un programme autoit qui me permet d'exécuter plusieurs installations à la suite, à partir d'un menu tray comportant plusieurs menus item. Tout fonctionne parfaitement mais mes collègues voudraient que j'améliore le système en faisant en sorte que le menu soit persistant même après avoir cliquer sur un item sans être obligé de cliquer à nouveau sur le system tray, c'est à dire que le menu soit appelé une fois en cliquant sur l'icône en bas à droite puis on clique sur les items et quand la série de clic est finie soit on clique sur un item genre "réduire" ou soit sur exit qui mettra fin au programme lorsque les installations seront finies.
J'ai cherché les options du TrayMenuMode et d'autres et sur les forums mais je ne trouve pas de solutions.
Avez vu une solution ou astuce ?
Merci de vos aides.
Re: [..] Tray Menu Item Persistant
Posté : mar. 04 mars 2014 17:16
par ZDS
Bonjour,
Pourrais tu poster un exemple de code (qu'on ait pas à repartir de zéro) s'il te plait?
Merci, et à bientôt !
PS : En attendant, il y a ce topic sur le site anglophone :
http://www.autoitscript.com/forum/topic ... ia-hotkey/
Re: [..] Tray Menu Item Persistant
Posté : mar. 04 mars 2014 18:03
par JJJ27
Tout simplement en prenant l'exemple de l'aide autoit sur les TrayCreateItem
L'orsque l'on clique sur "préférences" une fenêtre pop avec comme message OSVersion. Ce que mes collègues voudraient c'est que le menu avec les items "préférences", "About" et "Exit" reste affiché, qu'il ne disparaisse pas et que l'on ne soit pas obligé de recliquer sur l'icones du systray pour cliquer sur "exit" par exemple pour quitter le programme.
► Afficher le texte
Code : Tout sélectionner
Opt("TrayMenuMode", 1) ; Default tray menu items (Script Paused/Exit) will not be shown.
Local $prefsitem = TrayCreateItem("Preferences")
TrayCreateItem("")
Local $aboutitem = TrayCreateItem("About")
TrayCreateItem("")
Local $exititem = TrayCreateItem("Exit")
TraySetState()
While 1
Local $msg = TrayGetMsg()
Select
Case $msg = 0
ContinueLoop
Case $msg = $prefsitem
MsgBox(64, "Preferences:", "OS:" & @OSVersion)
Case $msg = $aboutitem
MsgBox(64, "About:", "AutoIt3-Tray-sample.")
Case $msg = $exititem
ExitLoop
EndSelect
WEnd
Exit
Peut être qu'en fait c'est prévu comme ca et que ce n'est pas possible de faire autrement
Re: [..] Tray Menu Item Persistant
Posté : mer. 05 mars 2014 00:08
par jguinch
J'ai cherché un peu, mais je n'ai rien trouvé qui permet de maintenir affiché le menu du Systray...
Par contre, ce qu'il est possible de faire, c'est de passer par un menu contextuel avec GUICtrlCreateContextMenu() et afficher le menu à la position voulue...
J'ai bricolé ça, si tu veux jeter un œil :
► Afficher le texte
Code : Tout sélectionner
#include <TrayConstants.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
Opt("TrayIconHide", 1)
Opt("TrayOnEventMode", 1)
Opt("TrayMenuMode", 1)
TraySetOnEvent($TRAY_EVENT_PRIMARYUP, "_MenuShow")
TraySetOnEvent($TRAY_EVENT_SECONDARYUP, "_MenuShow")
TraySetState()
; ############## Creation d'un fenetre invisible qui permet de creer le menu contextuel ##################
$aDesktopPos = WinGetPos(_WinAPI_GetDesktopWindow() )
$hGUI = GUICreate("", 0, 0, 0, 0, 0, $WS_EX_TOOLWINDOW)
$hForm = GUICreate("", 0, 0, $aDesktopPos[0] - 100, $aDesktopPos[1] - 100, BitOR($WS_CAPTION, $WS_POPUP, $WS_SYSMENU), BitOR($WS_EX_DLGMODALFRAME, $WS_EX_TOPMOST), $hGUI)
; ###########################################################################################################
; Création du menu avec GUICtrlCreateContextMenu + GUICtrlCreateMenuItem au lieu de TrayCreateItem
Local $contextmenu = GUICtrlCreateContextMenu()
Local $HContext = GUICtrlGetHandle($contextmenu)
Local $MenuAction1 = GUICtrlCreateMenuItem("Action 1", $contextmenu)
Local $MenuAction2 = GUICtrlCreateMenuItem("Action 2", $contextmenu)
Local $MenuHide = GUICtrlCreateMenuItem("Masquer le menu", $contextmenu)
GUICtrlCreateMenuItem("", $contextmenu)
Local $MenuExit = GUICtrlCreateMenuItem("Exit", $contextmenu)
Local $x, $y
GUISetState()
While 1
$msg = GUIGetMsg()
Switch $msg
Case $MenuAction1
ConsoleWrite("Clic sur MenuAction1" & @CRLF)
_MenuShow(1) ; On affiche le menu contextuel à la position à laquel il a été affiché lors du clic sur l'icône de systray
Case $MenuAction2
ConsoleWrite("Clic sur MenuAction2" & @CRLF)
_MenuShow(1) ; On affiche le menu contextuel à la position à laquel il a été affiché lors du clic sur l'icône de systray
Case $MenuExit
Exit
EndSwitch
WEnd
Func _MenuShow($iFlag = 0)
If @NumParams = 0 Then
$x = MouseGetPos(0)
$y = MouseGetPos(1)
EndIf
; Le menu contextuel est affiché à la position de la souris
DllCall("user32.dll", "int", "TrackPopupMenuEx", "hwnd", $HContext, "int", 0, "int", $x, "int", $y, "hwnd", $hGUI, "ptr", 0)
EndFunc
Re: [..] Tray Menu Item Persistant
Posté : mer. 05 mars 2014 12:50
par JJJ27
Très bonne idée
Merci beaucoup, je vais à mon tour rebricoler mon script, et voir pour ajouter une coche lorsque un menuitem est cliqué.
Merci jguinch