AutoIt Français

Bonjour je fais acutellement un système qui télécharge automatiquement des new.Cependant j'aimerais avoir 2 progressbar: la 1ere indiquant la progression du téléchargement actuel et la seconde l'état de téléchargement total.

Pour cela j'ai donc fais ceci

► Afficher le texte

Code : Tout sélectionner

        Local $size = 0 ,$_FileSize = 0
        Local $s_ReleaseNum = IniRead($s_DatFile_Local, 'INI', 'nb_file', 'Erreur de lecture')
        Local $s_ReleaseTaille = IniRead($s_DatFile_Local, 'INI', 'taille', 'Erreur de lecture')
        Local $s_ReleaseAdr = IniRead($s_DatFile_Local, 'INI', 'adresse', 'Erreur de lecture')
        Local $s_ReleaseIni = IniRead($s_DatFile_Local, 'INI', 'new_ini', 'Erreur de lecture')

        for $i = 0 to $s_ReleaseNum ;boucle qui télécharge chaque fichier

            $_perc_total = Round ( ( 100 * $_FileSize ) / $s_ReleaseTaille ) ; on calcule le pourcentage
            $_perc_total = _Min ( _Max ( 1, $_perc_total ), 100 )
            $downloaded_Perc += $_perc_total ;%de dl total reprend la valeur de la taille du précédent fichier renvoyé par InetGetSize

            ;On lis les infos dans les ini
            $s_ReleaseFile = IniRead($s_DatFile_Local, 'INI', 'file'&$i, 'Erreur de lecture')
            $_FileSize = InetGetSize($s_ReleaseAdr&$s_ReleaseFile)
            $_Download = InetGet($s_ReleaseAdr&$s_ReleaseFile,@ScriptDir&"\Resource\"&$s_ReleaseFile,1,1)
            $to_real_name = IniRead($s_DatFile_Local, 'INI', 'real_name'&$i, 'Erreur de lecture')

            Local $_InfoData
                Do ;Boucle tant que le Dl est pas fini
                    Sleep ( 50 )
                    $_InfoData = InetGetInfo ( $_Download )
                    If Not @error Then;si on télécharge
                        $_InetGet = $_InfoData[0];on récupère le nb d'octect téléchargé
                        $_DownloadPercent = Round ( ( 100 * $_InetGet ) / $_FileSize ) ;calcul du pourcentage total
                        $_DownloadPercent = _Min ( _Max ( 1, $_DownloadPercent ), 100 )
                        GUICtrlSetData ( $ProgressBar_1file, $_DownloadPercent );on fais avancé la progressbar du fichier en cour

                        $_DownloadPercent_all = Round ( ( 100 * $_InetGet ) / $s_ReleaseTaille ) ;on calcul le pourcentage de dl par rapport au poid total
                        $_DownloadPercent_all = _Min ( _Max ( 1, $_DownloadPercent_all ), 100 )
                        GUICtrlSetData ( $ProgressBar_allfile, $downloaded_Perc + $_DownloadPercent_all) ; on fais progressé des pourcentage que représente les fichier précent + notre pourcentage
                    EndIf
                Until $_InfoData[2] = True

            GUICtrlSetData ( $ProgressBar_1file, 100 ) ; on met a 100 normalement sa y ai déja mais bon ^^
            FileDelete(@ScriptDir&"\Resource\"&$to_real_name) ;on manage le fichier
            FileCopy(@ScriptDir&"\Resource\"&$s_ReleaseFile,@ScriptDir&"\Resource\"&$to_real_name,1)
            FileDelete(@ScriptDir&"\Resource\"&$s_ReleaseFile)

        Next

En gros dans la boucle for qui parcours chaque fichier je recup et j'addition a mon total, la taille du précédent , puis je le converti en pourcentage.
Apres dans la boucle do(ce fini quand le téléchargement est fini) j'update la progress bar en faisais la valeur des pourcentage déjà effectuer + la valeur du pourcentage du téléchargement courant. Logiquement a la fin du dl la taille téléchargé équivaut à la taille retourné par InetGetSize.
La boucle recommence dans le for n'ayant pas changer la valeur de ma variable de stockage de InetGetSize je l'additionne à mon total etc....
Cependant la barre représentant le total arrive avant celle du dessus ce qui n'est pas normal ^^'

PS: je me suis dis que j'indiquais peut être une mauvaise taille dans le ini mais voici ce que j'utilise pour déterminer la taille

► Afficher le texte

Merci d'avance pour votre aide car la je ne comprend pas pourquoi j'ai ce petit problème :/

Vous vous compliquez bien la tâche !!!

Puisque vous connaissez le nombre de fichier dès le départ, utilisez la barre de progression totale sur le nombre de fichier et non sur une taille totale que vous ne connaissez pas d'entrée de jeu.

Mais si je le fais ainsi la barre total sera sur le nombre de fichier et non sur la taille pour prendre un exemple j'ai des fichiers de quelques ko dans mes maj et des fichiers de plusieurs centaines de mb des fois ^^'

De plus je connais la taille total car les fichiers sont sur mon serveur. Comme je le dis j'ai fais le script du dessous pour connaitre la taille d'un répertoire. Après je n'ai plus qu'a le mettre dans mon ini dans "taille" => Local $s_ReleaseTaille = IniRead($s_DatFile_Local, 'INI', 'taille', 'Erreur de lecture')

Si pour la progressbar 1 tu fais le % téléchargé/total pour chaque fichier successivement, alors pour la 2 tu peux concaténer ces quantités téléchargées pour calculer le % avec la taille de l'ensemble des fichiers
Regarde la fonction InetGetX de matwachich, elle est super-bien faite et te renvoie dans une petite fonction Callback() toutes les infos dont tu as besoin
Un exemple assez complet ici
http://www.autoitscript.fr/forum/viewto ... 806#p68806

Je n'ai pas compris la réelle différence qu'il a avec mon script.
le seul changement que j'ai vu c'est qu'au lieu d'avoir la taille par InetGetSize ça sera les donnés reçu par les socket?

Serait il possible d'avoir les fichiers INI avec des valeurs par défaut de manière à effectuer quelques tests ?
Sinon j'ai du mal a comprendre ton premier calcul :

Code : Tout sélectionner

$_perc_total = Round ( ( 100 * $_FileSize ) / $s_ReleaseTaille )

Peut importe la valeur de $s_ReleaseTaille tu obtiendra toujours 0 puisque 0/(x>0) = 0 !!!
Autant faire :

Code : Tout sélectionner

$_perc_total =0

J'en déduis donc que tes calculs sont faux

Cependant, j'ai commencé à faire une analyse commenté de ton code, mais sans les INI cela devient un peu plus complexe et je ne peux pas poursuivre.
Mon code -> http://pastebin.com/E6m7quiK

Je te conseil de le coller dans un éditeur de code il sera bien plus que lisible

Sh4dows,

Sh4dows a écrit :Sinon j'ai du mal a comprendre ton premier calcul :
Code : Tout sélectionner
$_perc_total = Round ( ( 100 * $_FileSize ) / $s_ReleaseTaille )
 
Peut importe la valeur de $s_ReleaseTaille tu obtiendra toujours 0 puisque 0/(x>0) = 0 !!!

Comment un nombre entier > 0 multiplié par 100 (100 * $FileSize) peut-il être égal à zéro ?

@Tlem en regardant son code vous auriez remarqué que $FileSize valait aussi 0

Première ligne :

Code : Tout sélectionner

Local $size = 0 ,$_FileSize = 0

Donc un ~~nombre entier~~ 0 multiplié par 100 donne bien 0 chez moi

Ensuite la division est complètement inutile derrière puisque le résultat restera la même !

Initialisation de variable

Code : Tout sélectionner

$_FileSize = 0
...
For $i = 0 to $s_ReleaseNum
    $_perc_total = Round ( ( 100 * $_FileSize ) / $s_ReleaseTaille )
    ...
    $_FileSize = InetGetSize($s_ReleaseAdr&$s_ReleaseFile)
    ...
Next

mikell a écrit :

Code : Tout sélectionner

$_FileSize = 0
...
For $i = 0 to $s_ReleaseNum
    $_perc_total = Round ( ( 100 * $_FileSize ) / $s_ReleaseTaille )
    ...
    $_FileSize = InetGetSize($s_ReleaseAdr&$s_ReleaseFile)
    ...
Next

+1

T'as vraiment du mal avec les boucles For toi...

Code : Tout sélectionner

$_FileSize = 0
For $i = 1 to 5
    $_perc_total = Round ( ( 100 * $_FileSize ) / 1000 )
    $_FileSize += $i*100
    Msgbox(0,"", $_perc_total)
Next

~~Qui ? moi ? du mal avec les boucles for ?~~
J'ai compris

Je retourne me couché ça vaut mieux

Désolé pour le retard voici la structure de mon ini(pour avoir la taille j'utilise le script que j'ai donné au dessus dans le 1er post, de plus j'ai essayé de mettre la taille cumulé des truc téléchargé retourné par inetgetsize et toujours le même problème :/)

Code : Tout sélectionner

[INI]
nb_file=2
taille=1000
adresse=http://monsite.com/monRépertoire/maMaj/
new_ini=http://monsite.com/monRépertoire/maMaj/Version.ini
file1=1.txt
real_name1=#onB}Z+yYKddN
file2=2.txt
real_name2=%.UWaee!Zyeo`AE5.$a!!k

up....

Si vous avez besoin de plus d'information dites le moi ^^'

Up...

Je pense recoder tout le système donc si vous pouvez me donner un exemple pour faire ceci( de préférence sans ini en gros en allant sur l'index récupéré le nombre de fichier dans le dossier et faire un InetFileGetSize sur chaque fichier. Je pense que c'est possible donc mon problème c'est bien de faire 2 barre de téléchargement)

Bonsoir, je propose une idée :

si vous connaissez exactement la taille des fichiers à télécharger, car comme vous l'avez dit, ils 'agit de votre serveur. Pourquoi ne pas envoyer tout simplement une requête au serveur qui dans ce cas là, renverrait la taille total des fichiers.

Le calcul du pourcentage devrait s'effectuer sans encombres, j'me trompe ?

Au risque de paraître lourd je redis que la fonction InetGetX de matwachich est un excellent plan, dans la mesure où elle fournit toutes les données nécessaires et surtout permet une interruption/reprise du (des) téléchargement(s)
Exemple complet avec les 2 progressbar :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)

; fichiers à télécharger
Global $url = "http://www.autoitscript.com/autoit3/files/archive/autoit/"
Dim $files[6] = ["autoit-docs-v3.3.2.0-src.exe", "autoit-docs-v3.3.4.0-src.exe",  _
    "autoit-docs-v3.3.6.0-src.exe", "autoit-docs-v3.3.6.1-src.exe",  _
    "autoit-docs-v3.3.8.0-src.exe", "autoit-docs-v3.3.8.1-src.exe"]

Global $destDir = @DesktopDir
Global $old = 0, $progressbarPart, $progressbarTot, $run = 1, $t , $p, $nt

GUICreate("My GUI Progressbar", 260, 120, -1, 200)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
$infolabel = GuiCtrlCreateLabel("Fichier :", 20, 5, 250, 20)
$progressbarPart = GUICtrlCreateProgress(10, 20, 200, 20, $PBS_SMOOTH)
$label0 = GuiCtrlCreateLabel("", 210, 23, 25, 20, 2)
GuiCtrlCreateLabel("%", 240, 23, 10, 20)
GuiCtrlCreateLabel("Total :", 20, 45, 50, 20)
$progressbarTot = GUICtrlCreateProgress(10, 60, 200, 20, $PBS_SMOOTH)
$label = GuiCtrlCreateLabel("", 210, 63, 25, 20, 2)
GuiCtrlCreateLabel("%", 240, 63, 10, 20)
$start = GUICtrlCreateButton("Start", 40, 90, 60, 20)
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlSetOnEvent(-1, "_Demarrage")
 $stop = GUICtrlCreateButton("Interrompre", 120, 90, 80, 20)
GUICtrlSetState(-1, $GUI_DISABLE)
GUISetState()

; calcul des tailles de fichier et vérification en cas de téléchargement interrompu
$totalSize = 0
Dim $filesize[6]    ; stocke les tailles
For $i = 0 to 5
    $filesize[$i] = InetGetSize($url & $files[$i])
    $totalSize += $filesize[$i]
Next
For $i = 0 to 5
If FileExists($destDir & "\" & $files[$i]) Then
 If Round($filesize[$i]) = Round(FileGetSize($destDir & "\" & $files[$i])) Then
    $nt += ($filesize[$i]/$totalSize)*100
 EndIf
EndIf
Next
GUICtrlSetState($start, $GUI_ENABLE)
GUICtrlSetState($stop, $GUI_ENABLE)

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

While 1
  Sleep(10)
Wend

;====================================


Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
  #forceref $hWnd, $Msg, $lParam
  Switch BitAND($wParam, 0x0000FFFF)
    Case $stop
        If BitShift($wParam, 16)=0 Then _Interruption()
 EndSwitch
  Return 'GUI_RUNDEFMSG'
EndFunc  


Func _callBack($i, $partSize)
    $p = ($i/$partSize)*100
    $t = ($i/$totalSize)*100
    If $old <> $p Then  
        GUICtrlSetData($progressbarPart, Round($p)) 
        GUICtrlSetData($label0, Round($p)) 
        GUICtrlSetData($progressbarTot, Round($nt+$t))  
        GUICtrlSetData($label, Round( $nt+$t))
    EndIf  
   $old = $p
    If Not $run Then Return -1
EndFunc


Func _Demarrage()
For $i = 0 to 5
    $Nurl = _Url_To_Host($url & $files[$i])
    GUICtrlSetData($infolabel, $files[$i])
        $ret = _InetGetX($Nurl[0], $Nurl[1], $destDir & "\" & $files[$i], -1, 0, "_callBack")
    If $ret = 1 And not @error Then
        $nt += (@extended/$totalSize)*100
    ;   GUICtrlSetData($label0, "0")
        GUICtrlSetData($label, Ceiling($nt))
        Continueloop
    EndIf
Next
   Msgbox(0,"", "Terminé !")
    Exit
EndFunc

Func _Interruption()
    If MsgBox(36, "Confirmation", "Interrompre le téléchargement?") = 6 Then $run = 0
EndFunc

Func _Url_To_Host($url)
Local $ret[2]
$url = StringReplace($url, 'http://', '')
$ret[0] = StringLeft($url, StringInStr($url, '/') - 1)
$ret[1] = StringTrimLeft($url, StringInStr($url, '/'))
Return $ret
EndFunc

Func _Exit()
Exit
EndFunc

; # FUNCTION # ================================================================================================
; Name...........:  _InetGetX
; Description....:  Téléchager un fichier, fonction reprendre prise en charge
;
; Parameters.....:  - $sHost = Le server (ex: "www.site.fr", "http://mon_site.hebergeur.com/")
;                   - $sRessource = Le fichier à télécharger (ex: "/dossier/fichier.exe", "dossier/fichier.txt")
;                   - $sFile = Le chemin du fichier local (destination)
;                   - $iStartByte = Le position (en octet) d'ou commencer/reprendre le téléchargement
;                       (DEFAULT: 0 = Depuis le début)
;                       Si = -1, le téléchargement reprend depuis la taille du fichier en local
;                   - $bForce = Forcer le téléchargement même si la taille du fichier ne peut être récupérer
;                       (DEFAULT: 0)
;                       (Si = 1, Aucune vérification ne sera faite à la fin du téléchargement)
;                       Voir Return values
;                   - $sCallBack = Fonction call-back de forme:
;                       Func _callBack($iDownloaded, $iTotalSize)
;                       Si la fonction callback retourn -1, le téléchargement est interrompu
;                       (DEFAULT: "" => Aucun call-back)
;                   - $iTimeOut = Time-out (en secondes) PS: temps maximum sans recevoir de données du serveur
;                       (DEFAULT: 5)
;                   - $sAgent = User-Agent (Header HTTP)
;                       (DEFAULT: "AutoItMacro")
;
; Return values..:  - $bForce = 0
;                       - Ret = 0, @error = 1 => Echec InetGetSize
;                       - Ret = 1, @error = 2 => taille fichier local = Taille fichier distant (@extended = Taille)
;                       - Ret = 1, @error = 0 => Succes, @extended = Total télécharge (octets)
;                           (PS: Ici, @extended = FileGetSize("Fichier télécharger"))
;                       - Ret = 0, @error = 7 => Echec, @extended = Total télécharge (octets)
;                   - $bForce = 1
;                       - Ret = -1, @error = 0 => La fonction s'est bien terminé, mais impossible de vérifier le téléchargement
;
;                   - Ret = 0:
;                       - @error = -x => Vérifiez le paramètre N° x
;                       - @error = 3 => Impossible de se connecter
;                       - @error = 4 => Impossible d'envoyer la requête HTTP
;                       - @error = 5 => Timed-out (@extended = Total télécharger (octets))
;                       - @error = 6 => Impossible d'ouvrir le fichier destination
;
; Author.........:  Matwachich, Inspired from HTTP.au3 by Greg "Overload" Laabs
; Remarks........:  - La fonction reprend très bien un téléchargement (sans corruption du fichier) si on a
;                       killer le processus AutoIt.exe, aussi bien que si il y a un problème de connection
;                   - La meilleur méthode est de lancer cette fonction avec $iStartByte = -1, comme cela,
;                       Elle récupère la taille du fichier destination et continue automatiquement à
;                       partire de cette taille.
;   Exemple:
;       Voir entête de l'UDF
; ===========================================================================================================
Func _InetGetX($sHost, $sRessource, $sFile, $iStartByte = 0, $bForce = 0, $sCallBack = "", $iTimeOut = 5, $sAgent = "AutoItMacro")
    ; Checking parameters
    If String($sHost) <> $sHost Or $sHost = "" Then Return SetError(-1, 0, 0)
    If String($sRessource) <> $sRessource Or $sRessource = "" Then Return SetError(-2, 0, 0)
    If String($sFile) <> $sFile Or $sFile = "" Then Return SetError(-3, 0, 0)
    If Number($iStartByte) <> $iStartByte Then Return SetError(-4, 0, 0)
    If Number($bForce) <> $bForce Then Return SetError(-5, 0, 0)
    If String($sCallBack) <> $sCallBack Then Return SetError(-6, 0, 0)
    If Number($iTimeOut) <> $iTimeOut Or $iTimeOut = 0 Then Return SetError(-7, 0, 0)
    If String($sAgent) <> $sAgent Or $sAgent = "" Then Return SetError(-8, 0, 0)
    $iTimeOut = $iTimeOut * 1000

    If StringRight($sHost, 1) = "/" Then $sHost = StringTrimRight($sHost, 1)
    If StringLeft($sHost, 7) = "http://" Then $sHost = StringTrimLeft($sHost, 7)
    If StringLeft($sRessource, 1) <> "/" Then $sRessource = "/" & $sRessource

    Local $iFileSize = FileGetSize($sFile)
    If $iStartByte < 0 Then $iStartByte = $iFileSize

    ; Getting ressource size
    Local $iSize = 0x10 ; just random value
    If Not $bForce Then
        $iSize = InetGetSize("http://" & $sHost & $sRessource, 1)
        ConsoleWrite("URL: " & "http://" & $sHost & $sRessource & @LF)
        ConsoleWrite("Size: " & $iSize & @CRLF)
        If @error Then Return SetError(1, @error, 0)
        ; If Local FileSize = Remote FileSize Then cancel download
        If $iSize = $iFileSize Then Return SetError(2, $iFileSize, 1)
    EndIf

    ; Connecting to Server
    TCPStartup()
    Local $ip = TCPNameToIP($sHost)
    Local $socket = TCPConnect($ip, 80)
    If $socket <= 0 Then Return SetError(3, @error, 0) ; Could not connect XXX

    ; Creating command string
    Local $command = "GET " & $sRessource & " HTTP/1.1" & @CRLF
    $command &= "Host: " & $sHost & @CRLF
    $command &= "User-Agent: " & $sAgent & @CRLF
    If $iStartByte > 0 Then $command &= "Range: bytes=" & $iStartByte & "-" & @CRLF
    $command &= "Connection: close" & @CRLF & @CRLF
    ;ConsoleWrite($command & @CRLF)

    ; Sending command string
    Local $bytessent = TCPSend($socket, $command)
    If $bytessent = 0 Then
        ;FileClose($hFile)
        ;FileDelete($sFile)
        TCPCloseSocket($socket)
        TCPShutdown()
        Return SetError(4, @error, 0) ; Could not send request XXX
    EndIf

    ; Receiving and writing
    Local $hFile, $openFlag = 1, $bBinary = 0, $bStripLastCRLF = 0
    Local $recv, $crlfPos, $split, $writing = 0, $iFirst = 1
    Local $timer = TimerInit()
    ; Pour ne pas fausser la fonction call-back si c'est une reprise de téléchargement
    Local $iTotalDwn = $iStartByte

    While 1
        $recv = TCPRecv($socket, 4096) ; On recoit un paquet de données
        If @error Then ExitLoop ; $socket n'est plus valide (déconnecté)
        If Not $recv Then ; Pas de données
            ; Test time-out
            If TimerDiff($timer) >= $iTimeOut Then
                FileClose($hFile)
                TCPCloseSocket($socket)
                TCPShutdown()
                Return SetError(5, $iTotalDwn, 0) ; Timed out XXX
            EndIf
            ContinueLoop ; => continuer la boucle
        EndIf

        $timer = TimerInit() ; Si des données sont reçues, on réinitialise le timer

        ; Si on recoit des données binaires, on les convertie en String
        If IsBinary($recv) Then
            $recv = BinaryToString($recv)
            ; Si c'est le premier paquet de données, on règle le flag d'ouverture du fichier
            ; et on met $bBinary à 1
            If $iFirst Then
                $openFlag = 17
                $bBinary = 1
            EndIf
        EndIf

        ; Si c'est le premier paquet de données, on ouvre le fichier et on met $iFirst à 0
        If $iFirst Then
            $hFile = FileOpen($sFile, $openFlag)
            If $hFile = -1 Then Return SetError(6, @error, 0) ; File creation failed XXX
            FileSetAttrib($sFile, "+H")
            $iFirst = 0
        EndIf

        ; Si on est pas en train d'ecrire (CaD, on est au premier paquet), On passe les headers de la réponse HTTP:
        If Not $writing Then
            $split = StringSplit($recv, @CRLF, 1)
            If StringInStr($recv, 2) <> @CRLF Then $bStripLastCRLF = 1 ; Because the loop (*) inserts a @CRLF
                                                                       ; at the end of reconstructed $recv string
            $recv = ""
            For $i = 1 To $split[0]
                If $split[$i] = "" And Not $writing Then
                    $writing = 1
                    ContinueLoop
                EndIf
                If $writing Then
                    $recv &= $split[$i] & @CRLF ; Loop (*)
                EndIf
            Next
            If $bStripLastCRLF Then $recv = StringTrimRight($recv, 2) ; Trims the last @CRLF inserted by the loop (*)
        EndIf

        ; Ici, on ecrit les données dans le fichier
        If $writing Then
            If $bBinary Then
                $recv = Binary($recv)
                $iTotalDwn += BinaryLen($recv)
            Else
                $iTotalDwn += StringLen($recv)
            EndIf
            FileWrite($hFile, $recv)
            ; Appel de la fonction call-back
            If $sCallBack <> "" Then
                If Call($sCallBack, $iTotalDwn, $iSize) = -1 Then
            TCPCloseSocket($socket)
            Exitloop
        EndIf
            EndIf
        EndIf
    Wend
    FileClose($hFile)
    FilesetAttrib($sFile, "-H")

    ; Verifications
    $iFileSize = FileGetSize($sFile)
    If Not $bForce Then
        If $iFileSize = $iSize Then
            Return SetError(0, $iTotalDwn, 1)
        Else
            return setError(7, $iTotalDwn, 0) ; Download failed XXX
        EndIf
    Else ; If $bForce Then we don't check file size
        Return SetError(0, $iTotalDwn, -1)
    EndIf

EndFunc

@Mikell => Au risque de paraître lourd
Mikell exactement ce que je voulais donc je t'en voudrais pas d'être un gros chat

blacksoul305 a écrit : si vous connaissez exactement la taille des fichiers à télécharger, car comme vous l'avez dit, ils 'agit de votre serveur. Pourquoi ne pas envoyer tout simplement une requête au serveur qui dans ce cas là, renverrait la taille total des fichiers.

Il s'agit d'un serveur Xamp donc à ce que je sache il n'existe pas de requête comme ceci par contre ce que je peux faire c'est un script php qui va me retourné la taille à téléchargé puis je récup cette valeur avec un _inetgetsource

Oui, enfin je pensais à une fonction personnalisée que vous auriez au préalablement créé qui retournerait la taille totale. Mais vous avez trouvé votre solution donc c'est parfait !

Bonne continuation !

Par contre j'ai une petite question je vois que celui-ci supporte l’arrêt et le redémarrage du téléchargement.Ce basant sur le nombre de byte contenu en local.

Mais prenons cette exemple.
Contenu MAJ 1 =>
sur le serveur => 1.txt a téléchargé en local => 1.txt
sur le serveur => 2.txt a téléchargé en local => 2.txt
Contenu MAJ 2 =>
sur le serveur => 1.txt a téléchargé en local => 1.txt
sur le serveur => 2.txt a téléchargé en local => 2.txt

Que va t'il ce passé dans le cas ou les fichiers locaux ont les mêmes noms et destination?
Comment le script détecte que c'est bien les deux mêmes fichiers?
Pour cela je pense ajouter une fonction MD5 a l'udf
(j'ai un script php qui me donne le nombre de fichier/le hash md5 de chaque fichier/ la taille de chaque fichier/ le total de la taille / le nombre total de fichier)

► Afficher le texteCodé en 3min a 1h du mat donc possibilité de non optimisation >.<

AutoIt Français

[R] Double barre téléchargement

[R] Double barre téléchargement

Re: [..] Double barre téléchargement

Re: [..] Double barre téléchargement

Re: [..] Double barre téléchargement

Re: [..] Double barre téléchargement

Re: [..] Double barre téléchargement

Re: [..] Double barre téléchargement

Re: [..] Double barre téléchargement

Re: [..] Double barre téléchargement

Re: [..] Double barre téléchargement

Re: [..] Double barre téléchargement

Re: [..] Double barre téléchargement

Re: [..] Double barre téléchargement

Re: [..] Double barre téléchargement

Re: [..] Double barre téléchargement

Re: [..] Double barre téléchargement

Re: [..] Double barre téléchargement

Re: [..] Double barre téléchargement

Re: [..] Double barre téléchargement

Re: [..] Double barre téléchargement