AutoIt Français

Code : Tout sélectionner

$file=@ScriptDir&"\liste_a_chercher"; nom du fichier dans lequel on aura la liste des fichiers à chercher
$serveur="xxxxxx" ; adresse du serveur
$user=InputBox("User","User") ; user
$passwd=InputBox("Passwd","Password de "&$user,"","*") ; password

If $user="" Or $passwd= "" Then Exit 1 ; si l'un des 2 champs est vide on sort

RunWait(@ComSpec&" /c plink.exe -pw "&$passwd&" "&$user&"@"&$serveur&" < find_files.txt",@ScriptDir,@SW_HIDE); On envoie par ssh (plink) les commandes contenues dans find_files.txt;
;;ces commandes sont :
;find /chemin_à_fouiller -name "toto\.txt" > /tmp/liste_a_chercher ; Ceci cherche récursivement les fichiers toto.txt dans le rep /chemin_à_fouiller et écrit le résultat dans /tmp/liste_a_chercher
;logout  ;; on se déconnect de la session SSH
RunWait(@ComSpec&" /c pscp.exe -pw "&$passwd&" "&$user&"@"&$serveur&":/tmp/liste_a_chercher"&" ./",@ScriptDir,@SW_HIDE);on récupère le fichier /tmp/liste_a_chercher du serveur ssh pour le stocker ici même à la racine du script

$hnd=FileOpen($file,0); on va lire ce fichier
If $hnd=-1 Then Exit 2; si échec d'ouverture on sort
$rep_out=@ScriptDir&"\SCP_"&@YEAR&"_"&@MON&"_"&@MDAY&"_"&@HOUR&"_"&@MIN&"_"&@SEC; construction du nom du rep où on va recopier
ConsoleWrite(DirCreate($rep_out)&@CRLF);création du rep (leconsolewrite c'est du debug)
$rep_out='"'&$rep_out&'"';on double quote le nom du répertoire, car les espaces sont des ennemis jurés !
$error=""; variable qui servira à stocker les erreurs de copie, si il y en a
While 1
    $remote=FileReadLine($hnd); on lit ligne par ligne
    If @error=-1 Then ExitLoop; sortie de boucle si fin de fichier
    TrayTip("SCP",$remote,2)
    if(RunWait(@ComSpec&" /c pscp.exe -pw "&$passwd&" "&$user&"@"&$serveur&":"&$remote&" "&$rep_out,@ScriptDir,@SW_HIDE)&@CRLF)<>0 Then ; la commande scp lancée sur le fichier courrant à récupérer
        $error&=$remote&@CRLF;là on est dans un cas d'eerreur on reseigne $error
    EndIf
WEnd
FileClose($hnd); on referme le fichier
If $error<> "" Then
    MsgBox(16,"Erreur","Probleme de copie sur :"&@CRLF&$error)
Else
    MsgBox(0,"Fin","Tout est OK")
EndIf