AutoIt Français • [R] Déplacer un ou des fichiers sur un executable - Page 2

Page 2 sur 3

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : ven. 24 déc. 2010 16:42

par Tlem

@laddy

C'est bien de poser des questions afin de résoudre vos problèmes, mais la compréhension de votre code serait bien plus enrichissant.

Je vous conseil de lire et de comprendre ceci : http://www.autoitscript.fr/autoit3/docs ... unning.htm
Surtout la partie "Paramètres des lignes de commandes".

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : lun. 03 janv. 2011 17:51

par Laddy

Bonjour

mes meilleurs voeux à tous

Félicitations à Jérome et ZeShrek pour leur passage Force Vert

Bravo !

J'ai tenté de mettre mes extensions dans un fichier ini :

Code : Tout sélectionner


If Not FileExists(@MyDocumentsDir & "\TXT") Then
    DirCreate(@MyDocumentsDir & "\TXT")
EndIf

Global $Exe = '".exe"' &"," &'".msi"' &"," &'".com"' &"," &'".bat"' &"," &'".vbs"' &"," & '".pif"' &"," & '".scr"' &"," & '".vb"' &"," & '".ws"'
Global $TXT = '".txt"' &"," &' ".ini"'
IniWrite(@ScriptDir &"\MoveFile.ini","Programmes", "Valeur", $Exe)
IniWrite(@ScriptDir &"\MoveFile.ini","Texte", "Valeur", $TXT)
Global $Toto = IniRead(@ScriptDir &"\MoveFile.ini","Texte", "Valeur","NotFound")
ConsoleWrite($Toto)

If $CmdLine[0] Then
    For $i = 1 To $CmdLine[0]
        $extension = StringLower(StringRight($CmdLine[$i], 4)) ; on prend l'extension, et on la passe en minuscule
        Switch $extension
            ;Case ".txt", ".ini" ; ca te permet de mettre plusieurs possibilités, séparés par des vircules
                Case $Toto
                FileMove($CmdLine[$i], @MyDocumentsDir & "\TXT", 0)
EndSwitch

    Next
Else
    MsgBox(16, "Information", "Aucun paramètre n'a été transmis.")
EndIf
Exit

J'ai un soucis de lecture avec IniRead , il me tronque les guillements , pourquoi ? j'ai pourtant ajouter des guillements simples et mon fichier ini est correcte.

ConsoleWrite retour :

Code : Tout sélectionner

.txt", ".ini

fichier ini :

Code : Tout sélectionner

[Programmes]
Valeur=".exe",".msi",".com",".bat",".vbs",".pif",".scr",".vb",".ws"
[Texte]
Valeur=".txt", ".ini"

du coup si je fais un
Case $Toto dans mon script les fichiers ne sont pas déplacés.

Merci aux membres qui me répondront.

Laddy

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : lun. 03 janv. 2011 20:15

par zeshrek

Essaye avec ca :

Code : Tout sélectionner

If Not FileExists(@MyDocumentsDir & "\TXT") Then
    DirCreate(@MyDocumentsDir & "\TXT")
EndIf

; Tant qu'a faire on crée aussi le répertoire des executables...
If Not FileExists(@MyDocumentsDir & "\EXECUTABLES") Then
    DirCreate(@MyDocumentsDir & "\EXECUTABLES")
EndIf


;~ Global $Exe = '".exe"' &"," &'".msi"' &"," &'".com"' &"," &'".bat"' &"," &'".vbs"' &"," & '".pif"' &"," & '".scr"' &"," & '".vb"' &"," & '".ws"'
;~ Global $TXT = '".txt"' &"," &' ".ini"'
; on crée les 'banques' d'extentions sous formes de chaines en mettant les extensions a la suite les unes des autres (et on met un point a la fin)
Global $Exe = ".exe.msi.com.bat.vbs.pif.scr.vb.ws."
Global $TXT = ".txt.ini."

; ??? je ne comprend pas a quoi servent les 4 lignes ci dessous ???
IniWrite(@ScriptDir &"\MoveFile.ini","Programmes", "Valeur", $Exe)
IniWrite(@ScriptDir &"\MoveFile.ini","Texte", "Valeur", $TXT)
Global $Toto = IniRead(@ScriptDir &"\MoveFile.ini","Texte", "Valeur","NotFound")
ConsoleWrite($Toto)

If $CmdLine[0] Then
    For $i = 1 To $CmdLine[0]
;~         $extension = StringLower(StringRight($CmdLine[$i], 4)) ; on prend l'extension, et on la passe en minuscule
; la ligne précédente forcait la prise de 4 caracteres, mais là on a des extensions a 2 caracteres seulement, donc il faut trouver autre chose :
        $ext=StringSplit($CmdLine[$i],".") ; on utilise la fonction stringsplit pour découper les noms de fichier au niveau des points
        $extension = "." & $ext[$ext[0]] & "." ; on prend le dernier élément, au cas ou le fichier ait plusieurs points dans son nom, et on l'encadre de points, poir etre sur qu'on trouvera la meme expression dans la 'banque'
        
;~         Switch $extension
;~             ;Case ".txt", ".ini" ; ca te permet de mettre plusieurs possibilités, séparés par des vircules
;~                 Case $Toto
;~                 FileMove($CmdLine[$i], @MyDocumentsDir & "\TXT", 0)
;~          EndSwitch
; switch/case ne convient pas dans ce cas puisqu'on doit rechercher l'extension dans nos 'banques' d'extensions
; on va donc utiliser select/case, qui permet de mettre des expressions a évaluer :
        Select
            case StringInStr($Exe,$extension)<>0 ; si on trouve l'extension dans la banque des exe
                FileMove($CmdLine[$i], @MyDocumentsDir & "\EXECUTABLES", 0)
            case StringInStr($TXT,$extension)<>0 ; si on trouve l'extension dans la banque des txt
                FileMove($CmdLine[$i], @MyDocumentsDir & "\TXT", 0)
        EndSelect
    Next
Else
    MsgBox(16, "Information", "Aucun paramètre n'a été transmis.")
EndIf
Exit

J'ai juste inséré des lignes de commentaire et de code dans ton source pour t'expliquer ma démarche

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : mar. 04 janv. 2011 10:14

par Laddy

Bonjour Zeshrek,

je vais lire attentivement ton code (viens de me réveiller) et je vais essayer de t'expliquer les 4 lignes.

Ces 4 lignes :

Code : Tout sélectionner

IniWrite(@ScriptDir &"\MoveFile.ini","Programmes", "Valeur", $Exe)
IniWrite(@ScriptDir &"\MoveFile.ini","Texte", "Valeur", $TXT)
Global $Toto = IniRead(@ScriptDir &"\MoveFile.ini","Texte", "Valeur","NotFound")
ConsoleWrite($Toto)

Mon but est de créer un fichier de configuration pour pouvoir ajouter via un gui plus tard des extensions non prises en compte actuellement dans mon code.

Je crée le fichier ini nommé MoveFile.ini dans lequel je stockes par section mes extensions (IniWirte)
ce qui me donne le fichier suivant :

Code : Tout sélectionner

[Programmes]
Valeur=".exe",".msi",".com",".bat",".vbs",".pif",".scr",".vb",".ws"
[Texte]
Valeur=".txt", ".ini"

Puis je crée une variable $Toto pour lire les extensions du fichier ini (IniRead) afin de l'exploiter avec le Switch / Case. (Case $Toto)

ConsoleWrite($Toto) m'a permis de vérifier le contenu de ma variable pour l'exploitation du Case et je me suis aperçu qu'il manquait en début et fin les doubles guillemets.
Du coup le glisser déposer ne fonctionne plus, je ne comprend pas pourquoi c'est tronqué.

Est ce que ma méthode n'est pas bonne ?

Laddy

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : mar. 04 janv. 2011 13:06

par zeshrek

sans aller jusqu'a dire que ta méthode n'est pas bonne j'y vois 2 problème.
Tout d'abbord, le plus important et qui conditionne le reste, c'est la facon dont tu vas exploiter les infos qui sont dans le fichier ini que tu crées.
Ton case $Toto ne fonctionnera pas. La preuve :

Code : Tout sélectionner

Global $Exe = '".exe", ".msi", ".com", ".bat", ".vbs", ".pif", ".scr", ".vb", ".ws"'
Global $TXT = '".txt", ".ini"'


Global $Toto = $Exe ; on simule le fait que tu aurais lu le fichier ini et récupéré la chaine correcte


$test = '".msi"' ; on simule le fait que tu aurais traité un fichier msi, donc correspondant a la catégorie exe

Switch $test
    Case $Toto
        MsgBox(0, "", "ca marche")
    case Else
        MsgBox(0, "", "ca marche pas !")
EndSwitch

C'est parceque ton case compare avec la valeur totale de $toto, et ne le traite pas comme si tu avais mis son contenu a la main.

Pour faire ce que tu veux, il faut rechercher dans $toto l'extension du ficheir, c'est pour ca que dans mon exemple j'utilise stringinstr.

Ensuite, la 2eem source de problemes c'est que tu tilises des guillemets, alors que dans les extensions de fichiers il n'y en a pas. Ca veut dire que tu embarques des infos (les guillemets) qui ne servent a rien. Et au passage quand tu lis ton ini, le premier et le dernier de la ligne sont virés.
Dans un ini tu n'as pas besoin de guillemets, et toi même quand tu vas gérer ta liste via ton GUI tu es capable d'identifier les extensions de fichiers par les points, donc pas besoin de guillemets.

Regarde comment fonctionne mon exemple d'hier soir.

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : mar. 04 janv. 2011 13:17

par Laddy

Ok je comprends.

Je pensai bêtement que je pouvais stocker l'équivalent de

Case ".txt", ".ini" ; ca te permet de mettre plusieurs possibilités, séparés par des vircules
dans
Case $Toto en lisant l'information du ini.

Je vais relire ton exemple d'hier soir et voir comment je peux faire pour stocker les informations dans un fichier ini et les extraire car c'est le but.

Merci pour tes explications

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : mar. 04 janv. 2011 13:40

par zeshrek

Pour les stocker tu les mets exactement telles que je les ai mises.
Du coup ton ini ressemblera a ca :

Code : Tout sélectionner

[Programmes]
Valeur=.exe.msi.com.bat.vbs.pif.scr.vb.ws.
[Texte]
Valeur=.txt.ini.

Pas de truc qui sert a rien et qu'on peut oublier au passage (au hazard... tes guillemets

) juste les extensions.

Allez, un indice pour quand tu en seras a ta GUI pour décomposer les valeur et en extraire les extensions individuellement pense a stringsplit()

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : mar. 04 janv. 2011 17:34

par Laddy

Merci zeshrek

J'ai bien avancé , c'est loin d'être terminé mais le glisser déposer des fichiers fonctionnent.
Beaucoup de chose à faire encore.

► Afficher le texteEbauche de code

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=D:\Nconvert\Travaux\Moveiles\moveFiles_256.ico
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#cs
Auteur : Laddy (cheffe de projet)
Co-Dev : Sablier94 - travail sur la Gui
Site : http://batchclipboard.olympe-network.com/
Titre : MoveFile
Version : 1.0

Movefiles permet par un glisser déposer sur l'exécutable d'envoyer les fichiers dans les répertoires définis dans Mes Documents.
Compile le script en exécutable et glisser, déposer des fichiers et dossiers pour les classer.
Transcript batch2au3 de MoveFiles.exe créé par Laddy en 2009.

Merci ZeShrek pour son aide et autoit forum fr

Espace de travail (privé): http://laddy.titanpad.com/3

TODOLIST
- Stocker les extensions dans un fichier ini. [Ok]
- Gérer l'existence du fichier ayant le même nom
- Ajouter le déplacement des dossiers, si un dossier existe le renommer en Nom[0], Nom[1] etc...
- GUI - Ajouter des extensions.


#Region ##Travail sur la Gui

#include <GUIConstants.au3>

Opt("GUIOnEventMode", 1)

#Region ### START Koda GUI section ###
$Configuration = GUICreate("Configuration MoveFiles", 634, 342, 193, 125)
$Options = GUICtrlCreateGroup("Options", 8, 16, 609, 73)
$Copy = GUICtrlCreateRadio("Copier / Coller les fichiers", 48, 48, 169, 17)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
$Move = GUICtrlCreateRadio("Déplacer les fichiers", 256, 48, 177, 17)
GUICtrlSetState(-1, $GUI_CHECKED)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
$GFolders = GUICtrlCreateGroup("Gestion des dossiers", 8, 96, 609, 81)
$GererDossiersTXT = GUICtrlCreateLabel("Gérer les dossiers par défaut :", 24, 130, 183, 20)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
$Gerer = GUICtrlCreateButton("Gérer", 216, 128, 81, 25, 0)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Gext = GUICtrlCreateGroup("Gestions des extensions", 8, 200, 609, 89)
$AjouterTXT = GUICtrlCreateLabel("Ajouter une nouvelle extension :", 32, 232, 191, 20)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
$Extension = GUICtrlCreateInput(".Extension", 240, 232, 89, 21)
$Ajouter = GUICtrlCreateButton("Ajouter", 360, 232, 73, 25, 0)
$Supprimer = GUICtrlCreateButton("Supprimer", 451, 232, 81, 25, 0)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$config = GUICtrlCreateButton("Configurer", 424, 304, 75, 25, $WS_GROUP)
$Quit = GUICtrlCreateButton("Fermer", 512, 304, 75, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
EndIf

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Ajouter
            AjouterExtension()
        Case $supprimer
            Supprimer()
        Case $Gerer
            Gerer()
         Case $Quit
         Exit
EndSwitch
WEnd

Func AjouterExtension()

#Region ### START Koda GUI section ###
$Form2 = GUICreate("MoveFiles : Ajouter une extension", 489, 175, 303, 219)
$DansQuelDossier = GUICtrlCreateLabel("Dans quel dossier déplacer les fichiers de l'extension ajoutée : [nom de l'extension]", 16, 16, 442, 20)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
$dossier = GUICtrlCreateInput("Nom du dossier", 24, 56, 121, 21)
$Valider = GUICtrlCreateButton("Valider", 24, 104, 89, 25, 0)
$Annuler = GUICtrlCreateButton("Annuler", 128, 104, 89, 25, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
$nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Valider
            ExitLoop() ;on sort de la boucle pour ajouter l'extension
        Case $Annuler
            GUIDelete() ;On efface toutes les fenêtres
            ShellExecute(@ScriptFullPath) ;On rouvre le programme
            Exit ;on ferme le programme
EndSwitch
WEnd

;ici, on doit mettre le code pour ajouter l'extension

EndFunc

Func Gerer()
MsgBox(0,"MoveFile","Pas disponible pour le moment")
EndFunc

Func Supprimer()
MsgBox(0,"MoveFile","Pas disponible pour le moment")
EndFunc

#ce

If Not FileExists(@ScriptDir &"\MoveFile.ini") Then
#Region ##Liste variables des extensions
Global $Exe = ".exe.msi.com.bat.vbs.pif.scr.vb.ws."
Global $TXT = ".txt.ini."
Global $DOC = ".doc.docx.odt.rtf.doc.docm.dotx.dotm.docx.wpd.wps.diz.asc.ascii.hz.latex.lit.log.pages.readme.utf8.wpd.wps.yml."
Global $Tab = ".xls.xlsx.xla.xls.xlt.xltm.xltx.xlam.xlsb.xlsm.xlsx.prn.csv."
Global $PPoint = ".pps.ppt.pptx.pptm.pot.potx.potm.pps.ppsx.ppsm."
Global $PDFs = ".pdf."
Global $ZIK = ".mp3.ogg.wma.mid.wav.aif.aiff.aifc.cda.idf.m3u.voc.aac.au.cdr.m4a.mp1.mp2"
Global $Vid = ".mpg.avi.wmv.asf.divx.mkv.mov.mp4.divx.3gp.dpg.evo.fli.flc.flv.ivr.m2v.m4v.mod.movie.mpe.qt.rm .vob.vro."
Global $Net = ".htm.html.css.php.asp.cgi.xml.php3.url.asp.aspx.dhtml.js.jsp.mhtml.rss.xpi."
Global $Autoit = ".au3."
Global $Autohotkey = ".ahk."
Global $SFX = ".zip.rar.7z.CAB.ARJ.LZH.TAR.GZ.BZ2.ACE.UUE.JAR.Z.gz.tgz.000.arc.cbr.ear.efw.lha.mpkg.sea.sfx.uha.yz.z01.zix.zoo.zz."

# EndRegion ## Fin des variables

#Region ## Création fichier INI
IniWrite(@ScriptDir &"\MoveFile.ini","Programmes", "Valeur", $Exe)
IniWrite(@ScriptDir &"\MoveFile.ini","Texte", "Valeur", $TXT)
IniWrite(@ScriptDir &"\MoveFile.ini","Documents", "Valeur", $DOC)
IniWrite(@ScriptDir &"\MoveFile.ini","Tableur", "Valeur", $Tab)
IniWrite(@ScriptDir &"\MoveFile.ini","PowerPoint", "Valeur", $PPoint)
IniWrite(@ScriptDir &"\MoveFile.ini","PDF", "Valeur", $PDFs)
IniWrite(@ScriptDir &"\MoveFile.ini","Music", "Valeur", $ZIK)
IniWrite(@ScriptDir &"\MoveFile.ini","Videos", "Valeur", $Vid)
IniWrite(@ScriptDir &"\MoveFile.ini","Internet", "Valeur", $Net)
IniWrite(@ScriptDir &"\MoveFile.ini","AutoitScript", "Valeur", $Autoit)
IniWrite(@ScriptDir &"\MoveFile.ini","AutohotkeyScript", "Valeur", $Autohotkey)
IniWrite(@ScriptDir &"\MoveFile.ini","Archives", "Valeur", $SFX)
EndIf
# EndRegion

#Region ### Création des Dossiers
If Not FileExists(@MyDocumentsDir & "\TXT") Then
    DirCreate(@MyDocumentsDir & "\TXT")
EndIf

If Not FileExists(@MyDocumentsDir & "\Word") Then
    DirCreate(@MyDocumentsDir & "\Word")
EndIf

If Not FileExists(@MyDocumentsDir & "\Powerpoint") Then
    DirCreate(@MyDocumentsDir & "\Powerpoint")
EndIf

If Not FileExists(@MyDocumentsDir & "\Excel") Then
    DirCreate(@MyDocumentsDir & "\Excel")
EndIf

If Not FileExists(@MyDocumentsDir & "\Ma Musique") Then
    DirCreate(@MyDocumentsDir & "\Ma Musique")
EndIf

If Not FileExists(@MyDocumentsDir & "\Mes Archives") Then
    DirCreate(@MyDocumentsDir & "\Mes Archives")
EndIf

If Not FileExists(@MyDocumentsDir & "\Mes scripts AU3") Then
    DirCreate(@MyDocumentsDir & "\Mes scripts AU3")
EndIf

If Not FileExists(@MyDocumentsDir & "\Mes scripts AUTOHOTKEY") Then
    DirCreate(@MyDocumentsDir & "\Mes scripts AUTOHOTKEY")
EndIf

If Not FileExists(@MyDocumentsDir & "\Mes Images") Then
    DirCreate(@MyDocumentsDir & "\Mes Images")
EndIf

If Not FileExists(@MyDocumentsDir & "\Mes Videos") Then
    DirCreate(@MyDocumentsDir & "\Mes Videos")
EndIf

If Not FileExists(@MyDocumentsDir & "\Internet") Then
    DirCreate(@MyDocumentsDir & "\Internet")
EndIf

If Not FileExists(@MyDocumentsDir & "\Programmes") Then
    DirCreate(@MyDocumentsDir & "\Programes")
EndIf

If Not FileExists(@MyDocumentsDir & "\PDF") Then
    DirCreate(@MyDocumentsDir & "\PDF")
EndIf
# EndRegion ## Fin de création des dossiers



#Region ##Lecture du fichier ini
Global $Executables = IniRead(@ScriptDir &"\MoveFile.ini","Programmes", "Valeur", "NotFound")
Global $Textes = IniRead(@ScriptDir &"\MoveFile.ini","Texte", "Valeur", "NotFound")
Global $Documents = IniRead(@ScriptDir &"\MoveFile.ini","Documents", "Valeur", "NotFound")
Global $Tableurs = IniRead(@ScriptDir &"\MoveFile.ini","Tableur", "Valeur", "NotFound")
Global $Visionneuse = IniRead(@ScriptDir &"\MoveFile.ini","PowerPoint", "Valeur", "NotFound")
Global $Adobe = IniRead(@ScriptDir &"\MoveFile.ini","PDF", "Valeur", "NotFound")
Global $Musik = IniRead(@ScriptDir &"\MoveFile.ini","Music", "Valeur", "NotFound")
Global $Vd = IniRead(@ScriptDir &"\MoveFile.ini","Videos", "Valeur", "NotFound")
Global $Internet = IniRead(@ScriptDir &"\MoveFile.ini","Internet", "Valeur", "NotFound")
Global $AutoItSC = IniRead(@ScriptDir &"\MoveFile.ini","AutoitScript", "Valeur", "NotFound")
Global $AutohotkeySC = IniRead(@ScriptDir &"\MoveFile.ini","AutohotkeyScript", "Valeur", "NotFound")
Global $SFXs = IniRead(@ScriptDir &"\MoveFile.ini","Archives", "Valeur", "NotFound")
# EndRegion

If $CmdLine[0] Then
    For $i = 1 To $CmdLine[0]
        $ext=StringSplit($CmdLine[$i],".") ; on utilise la fonction stringsplit pour découper les noms de fichier au niveau des points
        $extension = "." & $ext[$ext[0]] & "." ; on prend le dernier élément, au cas ou le fichier ait plusieurs points dans son nom, et on l'encadre de points, poir etre sur qu'on trouvera la meme expression dans la 'banque'

            Select
                case StringInStr($Textes,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\TXT", 0)
            case StringInStr($Documents,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\Word", 0) ; par exemple si tu as fait un répertoire pour tes documents Word
            case StringInStr($Tableurs,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\Excel", 0) ; par exemple si tu as fait un répertoire pour tes documents Excel
            case StringInStr($Visionneuse,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\PowerPoint", 0)
            case StringInStr($Adobe,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\PDF", 0)
            case StringInStr($Musik,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\Ma Musique", 0)
            case StringInStr($Vd,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\Mes Videos", 0)
            case StringInStr($Internet,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\Internet", 0)
            case StringInStr($Executables,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\Programmes", 0)
            case StringInStr($AutoItSC,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\Mes scripts AU3", 0)
            case StringInStr($AutohotkeySC,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\Mes scripts AUTOHOTKEY", 0)
            case StringInStr($SFXs,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\Mes Archives", 0)
        EndSelect

    Next
Else
    MsgBox(16, "Information", "Aucun paramètre n'a été transmis.")
EndIf
Exit

Le plus dur je pense va être de lire tout le fichier ini pour vérifier que l'extension y est et si elle n'y est pas lancé la GUI d'ajout.
Pour le moment je vois pas comment m'y prendre mais je cherche ;D

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : mar. 04 janv. 2011 20:45

par zeshrek

Bon, je suis en train de zieuter ton source.
Premier truc que je vois (et qui m'énèèèèèèèèèèèèèèèèèèrve !!!!!) les section # Region xxxx se terminent par # EndRegion, pas par un autre # Region.
Sinon quand on veut les replier pour gagner en lisibilité, bah... on replie tout le script

Edit : 2eme truc que je vois :
Tu devrais modifier la facon dont tu geres ton fichier ini (et par la même, sce qu'il contient)
Perso, plutot que de créer en dur dans le code 1 variable par type de fichier (et en plus comment tu feras quand tu auras ton GUI ou le user pourra créer ses propres catégories ? A moins de faire un script automodifiable qui créera des portions de codes avec les catégories de l'utilisateur...) je ferai bien un petit tableau à 2 dimensions :
$categorie[x][y]
Avec :
x de 1 a n qui incrémente le N° de catégorie de fichier
y = 0 -> Nom de la catégorie, qui devient le nom de section dans le fichier INI)
y = 1 -> Chemin de stockage des fichiersqui devient une valeur de la section dans le fichier ini (parceque apres tout on est pas obligé de stocker les documents dans @MyDocumentsDir, perso, je les stocke sur un NAS, pas en local)
y = 2 -> Les extensions de la catégorie qui devient une seconde valeur de la section dans le fichier ini

Cela te permet de gérer plus simplement tous ce blocs par une simple boucle , par ex plutot que plus de 60 lignes pour la région ### Création des Dossiers :

Code : Tout sélectionner

for $i=1 to $NbSectionsDuFichierIni
    If Not FileExists($categorie[$i][1]) Then DirCreate($categorie[$i][1])
next

Et on peut faire le meme genre de choses dans toutes les sections (ou presque)

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : jeu. 06 janv. 2011 10:20

par Laddy

Bonjour zeshrek,

J'ai édité ma source, et corrigé mon erreur EndRegion

Pour ta solution je vais regarder comment réaliser un tableau deux dimensions je n'ai jamais fait ça.

Si j'ai bien compris tu verrais le fichier ini de cette façon :

Code : Tout sélectionner

[Programmes]
extension=exe.msi.com.bat
Chemin= D:\ ; exemple de délocalisation à la place de @MyDocumentDir

Edit :
J'ai lu cette documentation pour les tableaux 2D : http://www.siteduzero.com/tutoriel-3-22 ... art_228536

Si j'ai bien compris ça devrait donner un truc de ce genre :

Code : Tout sélectionner

$categorie[3][4] = [["", "", "", ""], _
["Programmes", "D:\" ,.exe.msi.com.bat.vbs.pif.scr.vb.ws. , $Executables], _
["Texte", "E:\", .txt.ini. , $Textes], _
["Documents", "@MyDocumentDir",.doc.docx.odt.rtf.doc.docm.dotx.dotm.docx.wpd.wps.diz.asc.ascii.hz.latex.lit.log.pages.readme.utf8.wpd.wps.yml. , $Documents]]

Je suis un peu perdu avec la variable que je dois associer.... est ce une nouvelle variable à définir ? est elle utile ici ?
Là j'ai mis celles du
#Region ##Lecture du fichier ini

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : jeu. 06 janv. 2011 14:06

par zeshrek

Laddy a écrit :Si j'ai bien compris tu verrais le fichier ini de cette façon :
Code : Tout sélectionner
[Programmes]
extension=exe.msi.com.bat
Chemin= D:\ ; exemple de délocalisation à la place de @MyDocumentDir

C'est exactement ca !

Laddy a écrit :Edit :
J'ai lu cette documentation pour les tableaux 2D : http://www.siteduzero.com/tutoriel-3-22 ... art_228536

Si j'ai bien compris ça devrait donner un truc de ce genre :
Code : Tout sélectionner
$categorie[3][4] = [["", "", "", ""], _
["Programmes", "D:\" ,.exe.msi.com.bat.vbs.pif.scr.vb.ws. , $Executables], _
["Texte", "E:\", .txt.ini. , $Textes], _
["Documents", "@MyDocumentDir",.doc.docx.odt.rtf.doc.docm.dotx.dotm.docx.wpd.wps.diz.asc.ascii.hz.latex.lit.log.pages.readme.utf8.wpd.wps.yml. , $Documents]]
Je suis un peu perdu avec la variable que je dois associer.... est ce une nouvelle variable à définir ? est elle utile ici ?
Là j'ai mis celles du
#Region ##Lecture du fichier ini

En fait je préfère plutot faire comme ca (je te l'ai mis dans une fonction, je trouve ca plus propre d'appeler une fonction plutot que d'éxécuter séquenciellement tout le texte) :

► Afficher le texte

Code : Tout sélectionner

#cs
    On a dit Categories[x][y]
    avec
    x : N° de la Categories
    et
    y=0 : titre de la Categories
    y=1 : liste des extensions
    y=2 : chemin de stockage
#ce

Global $categorie[100][100]


_InitCategories()


Func _InitCategories()
    Local $i, $j, $var, $var2

    If Not FileExists(@ScriptDir & "\MoveFile.ini") Then
        $categorie[01][0] = "Executables"
        $categorie[01][1] = ".exe.msi.com.bat.vbs.pif.scr.vb.ws."
        $categorie[01][2] = @MyDocumentsDir & ""

        $categorie[02][0] = "Texte"
        $categorie[02][1] = ".txt.ini."
        $categorie[02][2] = @MyDocumentsDir & ""

        $categorie[03][0] = "Documents"
        $categorie[03][1] = ".doc.docx.odt.rtf.doc.docm.dotx.dotm.docx.wpd.wps.diz.asc.ascii.hz.latex.lit.log.pages.readme.utf8.wpd.wps.yml."
        $categorie[03][2] = @MyDocumentsDir & ""

        $categorie[04][0] = "Tableaux"
        $categorie[04][1] = ".xls.xlsx.xla.xls.xlt.xltm.xltx.xlam.xlsb.xlsm.xlsx.prn.csv."
        $categorie[04][2] = @MyDocumentsDir & ""

        $categorie[05][0] = "Presentations"
        $categorie[05][1] = ".pps.ppt.pptx.pptm.pot.potx.potm.pps.ppsx.ppsm."
        $categorie[05][2] = @MyDocumentsDir & ""

        $categorie[06][0] = "PDF"
        $categorie[06][1] = ".pdf."
        $categorie[06][2] = @MyDocumentsDir & ""

        $categorie[07][0] = "Musique"
        $categorie[07][1] = ".mp3.ogg.wma.mid.wav.aif.aiff.aifc.cda.idf.m3u.voc.aac.au.cdr.m4a.mp1.mp2"
        $categorie[07][2] = @MyDocumentsDir & ""

        $categorie[08][0] = "Videos"
        $categorie[08][1] = ".mpg.avi.wmv.asf.divx.mkv.mov.mp4.divx.3gp.dpg.evo.fli.flc.flv.ivr.m2v.m4v.mod.movie.mpe.qt.rm .vob.vro."
        $categorie[08][2] = @MyDocumentsDir & ""

        $categorie[09][0] = "Internet"
        $categorie[09][1] = ".htm.html.css.php.asp.cgi.xml.php3.url.asp.aspx.dhtml.js.jsp.mhtml.rss.xpi."
        $categorie[09][2] = @MyDocumentsDir & ""

        $categorie[10][0] = "Autoit"
        $categorie[10][1] = ".au3."
        $categorie[10][2] = @MyDocumentsDir & ""

        $categorie[11][0] = "Autohotkey"
        $categorie[11][1] = ".ahk."
        $categorie[11][2] = @MyDocumentsDir & ""

        $categorie[12][0] = "Archives"
        $categorie[12][1] = ".zip.rar.7z.CAB.ARJ.LZH.TAR.GZ.BZ2.ACE.UUE.JAR.Z.gz.tgz.000.arc.cbr.ear.efw.lha.mpkg.sea.sfx.uha.yz.z01.zix.zoo.zz."
        $categorie[12][2] = @MyDocumentsDir & ""

        For $i = 1 To 12
            IniWrite(@ScriptDir & "\MoveFile.ini", $categorie[$i][0], "Extension", $categorie[$i][1])
            IniWrite(@ScriptDir & "\MoveFile.ini", $categorie[$i][0], "Chemin", $categorie[$i][2])
        Next
    Else
        $var = IniReadSectionNames(@ScriptDir & "\MoveFile.ini") ; on lit le fichier ini en stockant dans le tableay $var[] les sections
        If @error Then ; si on tombe sur un os
            MsgBox(4096, "", "y a un bug !") ; on le dit
        Else ; sinon
            For $i = 1 To $var[0] ;  $var[0] contient le nombre de sections
                $categorie[$i][0] = $var[$i] ; $var[1] a $var[...] contient les titres de sections, donc on les mets dans $categorie[x][0]
                $var2 = IniReadSection(@ScriptDir & "\MoveFile.ini", $var[$i]) ; ensuite on lit le contenu de chaque section
                For $j = 1 To $var2[0][0]
                    Switch $var2[$j][0] ; le titre de chaque section est stocké dans var2[...][0]
                        Case "Extension" ; docn si le titre est extension
                            $categorie[$i][1] = $var2[$j][1] ; on met la valeur lue pour extension dans le ini dans $categorie[x][1]
                        Case "Chemin"  ; et si c'est chemin
                            $categorie[$i][2] = $var2[$j][1] ; on met la valeur dans $categorie[x][2]
                    EndSwitch
                Next
            Next
        EndIf
        
        $msg="" ; et pour vérifier
        for $i = 1 to $var[0] ; on parcoure ce qu'on vient de lire
            ConsoleWrite ($categorie[$i][0] & @CRLF) ; on affiche dans la console
            ConsoleWrite ($categorie[$i][1] & @CRLF)
            ConsoleWrite ($categorie[$i][2] & @CRLF)
            ConsoleWrite (@CRLF)
        Next

    EndIf
EndFunc   ;==>_InitCategories

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : jeu. 06 janv. 2011 20:01

par Laddy

Bonsoir
désolé de répondre si tardivement
Woua une belle leçon que je viens de me prendre

Je n'y étais pas de tout.
Je vais lire ton code, et tenter de comprendre la fin que j'ai du mal à saisir.
Je te redonne de mes nouvelles dans quelques jours....

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : jeu. 06 janv. 2011 20:14

par zeshrek

Une lecon ? bah c'était pas le but. Juste un exemple

D'ailleurs, je viens de me rendre compte qu'il y avait un bug.... Je corrige ca de suite

Voilà, c'est fait.
J'ai rajouté une petite boucle a la fin qui te permettra de comprendre comment ca marche en affichant le contenu du fichier ini dans la console.
Bonne lecture

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : jeu. 06 janv. 2011 20:20

par Laddy

Oui je suis une tite débutante et j'ai beaucoup de chose à apprendre.

Pour le moment je suis perdue entre gérer le tableau, créer les dossiers et traiter le glisser déposer.

Peux tu m'expliquer la fin de ton code s'il te plait, je ne saisis pas la fin.

Code : Tout sélectionner

If @error Then
            MsgBox(4096, "", "y a un bug !")
        Else
            For $i = 1 To $var[0]
                $categorie[$i][0] = $var[$i]
                $var2 = IniReadSection(@ScriptDir & "\MoveFile.ini", $var[$i])
                For $j = 1 To $var2[0][0]
                    Switch $var2[$j][0]
                        Case "Extension"
                            $categorie[$i][1] = $var2[$j][1]
                        Case "Chemin"
                            $categorie[$i][2] = $var2[$j][1]
                    EndSwitch
                Next
            Next
        EndIf
        $msg=""
        for $i = 1 to $var[0]
            ConsoleWrite ($categorie[$i][0] & @CRLF)
            ConsoleWrite ($categorie[$i][1] & @CRLF)
            ConsoleWrite ($categorie[$i][2] & @CRLF)
            ConsoleWrite (@CRLF)
        Next

    EndIf

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : jeu. 06 janv. 2011 20:33

par zeshrek

J'ai mis les commentaires dans le code.
Tu vas voir, en fait, c'est tout simple

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : jeu. 06 janv. 2011 20:50

par Laddy

AH oui effectivement c'était simple
merci pour tes commentaires , ta patience, et ton aide.

Laddy

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : ven. 07 janv. 2011 14:40

par Laddy

Coucou
bon j'avance à tatons mais j'avance
J'ai juste ajouter le nom des dossiers dans le chemin pour le fichier ini.
et ajouter la création des dossiers.

► Afficher le texteMaj_v0.2

Code : Tout sélectionner

#cs
    On a dit Categories[x][y]
    avec
    x : N° de la Categories
    et
    y=0 : titre de la Categories
    y=1 : liste des extensions
    y=2 : chemin de stockage
#ce

Global $categorie[100][100]
Global $NbSectionsDuFichierIni

_InitCategories()


Func _InitCategories()
    Local $i, $j, $var, $var2

    If Not FileExists(@ScriptDir & "\MoveFile.ini") Then
        $categorie[01][0] = "Executables"
        $categorie[01][1] = ".exe.msi.com.bat.vbs.pif.scr.vb.ws."
        $categorie[01][2] = @MyDocumentsDir & "\Programmes"

        $categorie[02][0] = "Texte"
        $categorie[02][1] = ".txt.ini."
        $categorie[02][2] = @MyDocumentsDir &"\TXT"

        $categorie[03][0] = "Documents"
        $categorie[03][1] = ".doc.docx.odt.rtf.doc.docm.dotx.dotm.docx.wpd.wps.diz.asc.ascii.hz.latex.lit.log.pages.readme.utf8.wpd.wps.yml."
        $categorie[03][2] = @MyDocumentsDir & "\Word"

        $categorie[04][0] = "Tableaux"
        $categorie[04][1] = ".xls.xlsx.xla.xls.xlt.xltm.xltx.xlam.xlsb.xlsm.xlsx.prn.csv."
        $categorie[04][2] = @MyDocumentsDir & "Excel"

        $categorie[05][0] = "Presentations"
        $categorie[05][1] = ".pps.ppt.pptx.pptm.pot.potx.potm.pps.ppsx.ppsm."
        $categorie[05][2] = @MyDocumentsDir & "\PowerPoint"

        $categorie[06][0] = "PDF"
        $categorie[06][1] = ".pdf."
        $categorie[06][2] = @MyDocumentsDir & "\PDF"

        $categorie[07][0] = "Musique"
        $categorie[07][1] = ".mp3.ogg.wma.mid.wav.aif.aiff.aifc.cda.idf.m3u.voc.aac.au.cdr.m4a.mp1.mp2"
        $categorie[07][2] = @MyDocumentsDir & "\Ma Musique"

        $categorie[08][0] = "Videos"
        $categorie[08][1] = ".mpg.avi.wmv.asf.divx.mkv.mov.mp4.divx.3gp.dpg.evo.fli.flc.flv.ivr.m2v.m4v.mod.movie.mpe.qt.rm .vob.vro."
        $categorie[08][2] = @MyDocumentsDir & "\Mes Videos"

        $categorie[09][0] = "Internet"
        $categorie[09][1] = ".htm.html.css.php.asp.cgi.xml.php3.url.asp.aspx.dhtml.js.jsp.mhtml.rss.xpi."
        $categorie[09][2] = @MyDocumentsDir & "\Internet"

        $categorie[10][0] = "Autoit"
        $categorie[10][1] = ".au3."
        $categorie[10][2] = @MyDocumentsDir & "\Scripts_Autoit"

        $categorie[11][0] = "Autohotkey"
        $categorie[11][1] = ".ahk."
        $categorie[11][2] = @MyDocumentsDir & "\Scripts_Autokotkey"

        $categorie[12][0] = "Archives"
        $categorie[12][1] = ".zip.rar.7z.CAB.ARJ.LZH.TAR.GZ.BZ2.ACE.UUE.JAR.Z.gz.tgz.000.arc.cbr.ear.efw.lha.mpkg.sea.sfx.uha.yz.z01.zix.zoo.zz."
        $categorie[12][2] = @MyDocumentsDir & "\Mes Archives"

        For $i = 1 To 12
            IniWrite(@ScriptDir & "\MoveFile.ini", $categorie[$i][0], "Extension", $categorie[$i][1])
            IniWrite(@ScriptDir & "\MoveFile.ini", $categorie[$i][0], "Chemin", $categorie[$i][2])
        Next
    Else
        $var = IniReadSectionNames(@ScriptDir & "\MoveFile.ini") ; on lit le fichier ini en stockant dans le tableay $var[] les sections
        If @error Then ; si on tombe sur un os
            MsgBox(4096, "", "y a un bug !") ; on le dit
        Else ; sinon
            For $i = 1 To $var[0] ;  $var[0] contient le nombre de sections
                $categorie[$i][0] = $var[$i] ; $var[1] a $var[...] contient les titres de sections, donc on les mets dans $categorie[x][0]
                $var2 = IniReadSection(@ScriptDir & "\MoveFile.ini", $var[$i]) ; ensuite on lit le contenu de chaque section
                For $j = 1 To $var2[0][0]
                    Switch $var2[$j][0] ; le titre de chaque section est stocké dans var2[...][0]
                        Case "Extension" ; docn si le titre est extension
                            $categorie[$i][1] = $var2[$j][1] ; on met la valeur lue pour extension dans le ini dans $categorie[x][1]
                        Case "Chemin"  ; et si c'est chemin
                            $categorie[$i][2] = $var2[$j][1] ; on met la valeur dans $categorie[x][2]
                    EndSwitch
                Next
            Next
        EndIf
       
        $msg="" ; et pour vérifier
        for $i = 1 to $var[0] ; on parcoure ce qu'on vient de lire
            ConsoleWrite ($categorie[$i][0] & @CRLF) ; on affiche dans la console
            ConsoleWrite ($categorie[$i][1] & @CRLF)
            ConsoleWrite ($categorie[$i][2] & @CRLF)
            ConsoleWrite (@CRLF)
        Next
for $i=1 to $var[0]
    If Not FileExists($categorie[$i][2]) Then DirCreate($categorie[$i][2])
    next
    EndIf
EndFunc   ;==>_InitCategories


    
    If $CmdLine[0] Then
    For $i = 1 To $CmdLine[0]
        $ext=StringSplit($CmdLine[$i],".") ; on utilise la fonction stringsplit pour découper les noms de fichier au niveau des points
        $extension = "." & $ext[$ext[0]] & "." ; on prend le dernier élément, au cas ou le fichier ait plusieurs points dans son nom, et on l'encadre de points, poir etre sur qu'on trouvera la meme expression dans la 'banque'

            Select
                case StringInStr($Textes,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\TXT", 0)
            case StringInStr($Documents,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\Word", 0) ; par exemple si tu as fait un répertoire pour tes documents Word
            case StringInStr($Tableurs,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\Excel", 0) ; par exemple si tu as fait un répertoire pour tes documents Excel
            case StringInStr($Visionneuse,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\PowerPoint", 0)
            case StringInStr($Adobe,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\PDF", 0)
            case StringInStr($Musik,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\Ma Musique", 0)
            case StringInStr($Vd,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\Mes Videos", 0)
            case StringInStr($Internet,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\Internet", 0)
            case StringInStr($Executables,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\Programmes", 0)
            case StringInStr($AutoItSC,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\Mes scripts AU3", 0)
            case StringInStr($AutohotkeySC,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\Mes scripts AUTOHOTKEY", 0)
            case StringInStr($SFXs,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\Mes Archives", 0)
        EndSelect

    Next
Else
    MsgBox(16, "Information", "Aucun paramètre n'a été transmis.")
EndIf
Exit

Maintenant j'essaie de comprendre comment lier la lecture du tableau avec le glisser déposer, je soupçonne qu'il faut utiliser la meme technique que dans la fin de ton code qui va réduire les lignes de ce type.

Code : Tout sélectionner

Select
                case StringInStr($Textes,$extension)<>0
                FileMove($CmdLine[$i], @MyDocumentsDir & "\TXT", 0)
EndSelect

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : ven. 07 janv. 2011 14:52

par zeshrek

Tu as tout a fait compris.
Vu que dans la phase d'initialisation on a lu le fichier ini et qu'on a dispatché ce qui nous intéresse dans le tableau $categorie[][], il te faut maintenant utiliser ce tableau.
Vu que cet apres midi je suis charette au boulot je vais te laisser chercher (et puis c'est bien que tu éssayes d'y réfléchir par toi même, sinon, je vais te pondre ton programme, mais ca en t'aura rien apporté).
Je relève les copies ce soir en rentrant a la maison

EDIT : Juste un détail, je viens de parcourir le code que tu as mis.
Pourquoi avoir déclaré $NbSectionsDuFichierIni ?
Soit il faut l'enlever, soit il faut l'utiliser (tu intercales la ligne "$NbSectionsDuFichierIni = $var[0]" entre les lignes 74 et 75, et tu remplaces ensuite tous les $var[0] par $NbSectionsDuFichierIni)

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : ven. 07 janv. 2011 14:54

par Laddy

Je peux donner ma copie en retard ? je ne sais pas si je vais pouvoir pondre un truc dans quelques heures et le week end repos le PC lol.

Oui c'est bien que je cherche et j en fais des tests et des tests pour le moment ça glisse pas lol mais je continue à chercher comment exploiter ce tableau.

J'en suis là

Code : Tout sélectionner

If $CmdLine[0] Then
    For $i = 1 To $CmdLine[0]
        $ext=StringSplit($CmdLine[$i],".") ; on utilise la fonction stringsplit pour découper les noms de fichier au niveau des points
        $extension = "." & $ext[$ext[0]] & "."
$NbSectionsDuFichierIni = IniReadSectionNames(@ScriptDir & "\MoveFile.ini")
For $i = 1 To $NbSectionsDuFichierIni[0]
$NbSectionsDuFichierIni2 = IniReadSection(@ScriptDir & "\MoveFile.ini", $NbSectionsDuFichierIni[$i])
;encore des choses à mettre
Next
Select 
Case
EndSelect
 Next
Else
    MsgBox(16, "Information", "Aucun paramètre n'a été transmis.")
EndIf
Exit

Pas sur que je suis dans le bon mais je prospectes.

Merci Zeshrek

Re: [R] Déplacer un ou des fichiers sur un executable

Posté : sam. 08 janv. 2011 23:34

par zeshrek

Grrrrr !!!!
Je m'en veux. Je suis débordé, mais j'ai pas pu résister....

EDIT : Et le pire c'est que je viens de remettre ca !!! Du coup, là c'est bon, j'y touche plus du weekend (sinon je vais te le finir !!!)
Donc, je t'ai rajouté une petit GUI qui pour l'instant ne fait rien, mais est (éventuellement) destinée a servir a mettre a jour les listes de catégories. Tu y accedes en lancant le fichier directement, sans faire un glisser/déposer dessus.

Edit2 : Bon, j'ai pas tenu plus de qq heures, mais j'ai une excuse... j'avais pas commenté la fonction de la GUI.
Allez hop, cette fois ci j'y touche plus.

Bonne lecture

► Afficher le texte

Code : Tout sélectionner

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <TreeViewConstants.au3>
#include <WindowsConstants.au3>

Opt("MustDeclareVars", 1) ; pour obliger a pré-déclarer les variables (je préfère, mais c'est une question de gout...)

#cs
    On a dit Categories[x][y]
    avec
    x : N° de la Categories
    et
    y=0 : titre de la Categories
    y=1 : liste des extensions
    y=2 : chemin de stockage
#ce

Global $categorie[100][3] ; par défaut on se limite a 100 catégories de fichiers... mais rien n'empeche d'en mettre plus
Global $NbSectionsDuFichierIni

_Main()
Exit

Func _GestionDesCategories()
    Local $TreeView1Items[100][100]
    Local $Form1_1, $TreeView1, $label0, $label1, $label2, $Input0, $Input1, $Input2, $nMsg
    Local $ListeExtensions

    $Form1_1 = GUICreate("Gestion des catégories", 626, 444, 192, 124)
    $TreeView1 = GUICtrlCreateTreeView(8, 8, 177, 425) ; On commence par créer un treeview
    For $i = 1 To $NbSectionsDuFichierIni
        $TreeView1Items[$i][0] = GUICtrlCreateTreeViewItem($categorie[$i][0], $TreeView1) ; dans lequel on commence par mettre en racine les noms de sections
        $ListeExtensions = StringSplit($categorie[$i][1], ".") ; puis on découpe la liste d"extensions
        For $j = 2 To $ListeExtensions[0] - 1
            $TreeView1Items[$i][$j] = GUICtrlCreateTreeViewItem($ListeExtensions[$j], $TreeView1Items[$i][0]) ; qu'on met en sous-ietm de la treeview
        Next
    Next

    $label0 = GUICtrlCreateLabel("Nom de la catégorie", 200, 15, 410, 17)
    $label1 = GUICtrlCreateLabel("Liste des extensions", 200, 70, 410, 17)
    $label2 = GUICtrlCreateLabel("Répertoire de stockage des fichiers", 200, 167, 410, 17)

    $Input0 = GUICtrlCreateInput("", 200, 35, 141, 21)
    $Input1 = GUICtrlCreateInput("", 200, 90, 410, 63)
    $Input2 = GUICtrlCreateInput("", 200, 187, 410, 21)
    GUISetState(@SW_SHOW)

    While 1 ; on attend qu'il se passe qqchose dans la form
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE
                Exit
            Case Else
                For $i = 1 To $NbSectionsDuFichierIni
                    If $nMsg = $TreeView1Items[$i][0] Then ; si l'utilisateur clique sur une des categories dans la treeview
                        GUICtrlSetData($Input0, $categorie[$i][0]) ; on met les valeurs dans les 3 champs de saisie
                        GUICtrlSetData($Input1, StringReplace($categorie[$i][1], ".", " ")) 
                        GUICtrlSetData($Input2, $categorie[$i][2])
                    EndIf
                Next
        EndSwitch
    WEnd
; pour l'instant la GUI fait rien de plus, mais il suffit ensuite de gerer les modifications apportées par l'utilisateur, et éventuellement de les enregistrer
EndFunc   ;==>_GestionDesCategories

Func _InitCategories()
    Local $i, $j, $var, $var2, $msg

    If Not FileExists(@ScriptDir & "\MoveFile.ini") Then
        $categorie[01][0] = "Executables"
        $categorie[01][1] = ".exe.msi.com.bat.vbs.pif.scr.vb.ws."
        $categorie[01][2] = @MyDocumentsDir & "\Programmes"

        $categorie[02][0] = "Texte"
        $categorie[02][1] = ".txt.ini."
        $categorie[02][2] = @MyDocumentsDir & "\TXT"

        $categorie[03][0] = "Documents"
        $categorie[03][1] = ".doc.docx.odt.rtf.doc.docm.dotx.dotm.docx.wpd.wps.diz.asc.ascii.hz.latex.lit.log.pages.readme.utf8.wpd.wps.yml."
        $categorie[03][2] = @MyDocumentsDir & "\Word"

        $categorie[04][0] = "Tableaux"
        $categorie[04][1] = ".xls.xlsx.xla.xls.xlt.xltm.xltx.xlam.xlsb.xlsm.xlsx.prn.csv."
        $categorie[04][2] = @MyDocumentsDir & "Excel"

        $categorie[05][0] = "Presentations"
        $categorie[05][1] = ".pps.ppt.pptx.pptm.pot.potx.potm.pps.ppsx.ppsm."
        $categorie[05][2] = @MyDocumentsDir & "\PowerPoint"

        $categorie[06][0] = "PDF"
        $categorie[06][1] = ".pdf."
        $categorie[06][2] = @MyDocumentsDir & "\PDF"

        $categorie[07][0] = "Musique"
        $categorie[07][1] = ".mp3.ogg.wma.mid.wav.aif.aiff.aifc.cda.idf.m3u.voc.aac.au.cdr.m4a.mp1.mp2"
        $categorie[07][2] = @MyDocumentsDir & "\Ma Musique"

        $categorie[08][0] = "Videos"
        $categorie[08][1] = ".mpg.avi.wmv.asf.divx.mkv.mov.mp4.divx.3gp.dpg.evo.fli.flc.flv.ivr.m2v.m4v.mod.movie.mpe.qt.rm .vob.vro."
        $categorie[08][2] = @MyDocumentsDir & "\Mes Videos"

        $categorie[09][0] = "Internet"
        $categorie[09][1] = ".htm.html.css.php.asp.cgi.xml.php3.url.asp.aspx.dhtml.js.jsp.mhtml.rss.xpi."
        $categorie[09][2] = @MyDocumentsDir & "\Internet"

        $categorie[10][0] = "Autoit"
        $categorie[10][1] = ".au3."
        $categorie[10][2] = @MyDocumentsDir & "\Scripts_Autoit"

        $categorie[11][0] = "Autohotkey"
        $categorie[11][1] = ".ahk."
        $categorie[11][2] = @MyDocumentsDir & "\Scripts_Autokotkey"

        $categorie[12][0] = "Archives"
        $categorie[12][1] = ".zip.rar.7z.CAB.ARJ.LZH.TAR.GZ.BZ2.ACE.UUE.JAR.Z.gz.tgz.000.arc.cbr.ear.efw.lha.mpkg.sea.sfx.uha.yz.z01.zix.zoo.zz."
        $categorie[12][2] = @MyDocumentsDir & "\Mes Archives"

        $NbSectionsDuFichierIni = 12 ; puisqu'on crée par défaut 12 catégories

        _GestionDesCategories()

        For $i = 1 To $NbSectionsDuFichierIni
            IniWrite(@ScriptDir & "\MoveFile.ini", $categorie[$i][0], "Extension", $categorie[$i][1])
            IniWrite(@ScriptDir & "\MoveFile.ini", $categorie[$i][0], "Chemin", $categorie[$i][2])
        Next

    Else
        $var = IniReadSectionNames(@ScriptDir & "\MoveFile.ini") ; on lit le fichier ini en stockant dans le tableay $var[] les sections
        $NbSectionsDuFichierIni = $var[0] ; on initialise le nombre de  sections avec $var[0] qui contient le nombre de sections
        If @error Then ; si on tombe sur un os
            MsgBox(4096, "", "y a un bug !") ; on le dit
        Else ; sinon
            For $i = 1 To $NbSectionsDuFichierIni
                $categorie[$i][0] = $var[$i] ; $var[1] a $var[...] contient les titres de sections, donc on les mets dans $categorie[x][0]
                $var2 = IniReadSection(@ScriptDir & "\MoveFile.ini", $var[$i]) ; ensuite on lit le contenu de chaque section
                For $j = 1 To $var2[0][0]
                    Switch $var2[$j][0] ; le titre de chaque section est stocké dans var2[...][0]
                        Case "Extension" ; docn si le titre est extension
                            $categorie[$i][1] = $var2[$j][1] ; on met la valeur lue pour extension dans le ini dans $categorie[x][1]
                        Case "Chemin" ; et si c'est chemin
                            $categorie[$i][2] = $var2[$j][1] ; on met la valeur dans $categorie[x][2]
                    EndSwitch
                Next
            Next
        EndIf

        $msg = "" ; et pour vérifier
        For $i = 1 To $NbSectionsDuFichierIni ; on parcoure ce qu'on vient de lire
            ConsoleWrite($categorie[$i][0] & @CRLF) ; on affiche dans la console
            ConsoleWrite($categorie[$i][1] & @CRLF)
            ConsoleWrite($categorie[$i][2] & @CRLF)
            ConsoleWrite(@CRLF)
        Next
    EndIf
    ; et maintenant, on vérifie que tous les dossiers existent bien
    For $i = 1 To $NbSectionsDuFichierIni
        If Not FileExists($categorie[$i][2]) Then DirCreate($categorie[$i][2])
    Next

EndFunc   ;==>_InitCategories

Func _Main()
    _InitCategories()

    If $CmdLine[0] Then
        _TraitementDesFichiers()
    Else
;~ MsgBox(16, "Information", "Aucun paramètre n'a été transmis.") ; Plutot que de faire finir le programme, quand on ne lui passe pas de parametres, il pourrait aller sur la GUI de configuration des catégories...
        _GestionDesCategories()
    EndIf
EndFunc   ;==>_Main

Func _TraitementDesFichiers()
    Local $ext, $extension, $trouve
    For $i = 1 To $CmdLine[0]
        $ext = StringSplit($CmdLine[$i], ".") ; on utilise la fonction stringsplit pour découper les noms de fichier au niveau des points
        $extension = "." & $ext[$ext[0]] & "." ; on prend le dernier élément, au cas ou le fichier ait plusieurs points dans son nom, et on l'encadre de points, poir etre sur qu'on trouvera la meme expression dans la 'banque'
        $trouve = False
        For $j = 1 To $NbSectionsDuFichierIni
            If StringInStr($categorie[$j][1], $extension) <> 0 Then
                FileMove($CmdLine[$i], $categorie[$j][2], 0)
                $trouve = True
            EndIf
        Next
        If $trouve = False Then
            MsgBox(0, "Petit probleme", "L'extension " & $ext[$ext[0]] & " du fichier " & $CmdLine[$i] & " est inconue dans le fichier de configuration" & @CRLF & _
                    "Veuillez mettre le fichier de configuration a jour." & @CRLF & @CRLF & _
                    "Ce fichier n'a pas été traité")
            ; il faudra mettre ici un appel a la GUI si l'utilisateur veut créer tout de suite une catégorie...
        EndIf
    Next
EndFunc   ;==>_TraitementDesFichiers