AutoIt Français

Code : Tout sélectionner

#include <GDIPlus.au3>
#include <WindowsConstants.au3>

$Gui = SplashImgOn("C:\Documents and Settings\Christelle\Mes documents\Mes images\Nec2.jpg")
Sleep(1000)
SplashImgFondu($Gui, 1000)


Func SplashImgOn($NomImage, $Titre = "")
    Local $Gui = 0
    Local $DimImg[2]
;~  On vérifie que l'image existe
    If($NomImage <> "" And FileExists($NomImage)) Then
;~      On récupère les dimentions de l'image
        $DimImg = DimentionsImages($NomImage)
;~      Création de la fenêtre
        $Gui = GUICreate($Titre, $DimImg[0], $DimImg[1], -1, -1, $WS_POPUPWINDOW)
;~      Création de l'image
        GUICtrlCreatePic($NomImage, 0, 0, $DimImg[0], $DimImg[1])
;~      On applique le début de transparence (à cause du bug)
        WinSetTrans($Gui, "", 254)
;~      On affiche la fenêtre
        GUISetState()
    EndIf
    Return $Gui
EndFunc

Func SplashImgFondu($Gui, $Temps = 1000)
;~  Boucle permettant de changer progressivement la transparence de la fenêtre
    For $i = 254 To 0 Step -1
        WinSetTrans($Gui, "", $i)
        Sleep(Floor($Temps/254))
    Next
    GUIDelete($Gui)
EndFunc

Func DimentionsImages($Image)
;~  Fonction permettant de récupérer les dimentions d'une image jpg / bmp / ... (pas ICO)
    _GDIPlus_Startup()
    Local $Taille[2]
    Local $hImage = _GDIPlus_ImageLoadFromFile($Image)
    $Taille[0] = _GDIPlus_ImageGetWidth($hImage)
    $Taille[1] = _GDIPlus_ImageGetHeight($hImage)
    _GDIPlus_ImageDispose($hImage)
    _GDIPlus_Shutdown()
    Return $Taille
EndFunc