AutoIt Français

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>
#include <WindowsConstants.au3>
#Include <inet.au3>


#Include <_MailFonctions.au3>;Fonctions mails


$Form1_1 = GUICreate("Email Sender", 229, 469, 192, 124)
$SMTP = GUICtrlCreateInput("Serveur SMTP", 24, 16, 153, 21)
$desti = GUICtrlCreateInput("Nom de l'expéditeur", 24, 48, 153, 21)
$Adressed = GUICtrlCreateInput("Email de l'expéditeur", 24, 80, 153, 21)
$Texte = GUICtrlCreateEdit("", 24, 176, 153, 169)
GUICtrlSetData(-1, "Texte")
$MyButton1 = GUICtrlCreateButton("Go", 48, 424, 124, 30, $BS_FLAT)
$adresser = GUICtrlCreateInput("Email du destinataire", 24, 112, 153, 21)
$sujetmess = GUICtrlCreateInput("Sujet du message", 24, 144, 153, 21)
GUISetState(@SW_SHOW)



While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        case $MyButton1
            $s_SmtpServer = GUICtrlRead($SMTP)
            $s_FromName = GUICtrlRead($desti)
            $s_FromAddress = GUICtrlRead($Adressed)
            $s_ToAddress = GUICtrlRead($adresser)
            $s_Subject = GUICtrlRead($sujetmess)
            $as_Body = GUICtrlRead($Texte)
            $s_AttachFiles = ""                                    ; the file you want to attach- leave blank if not needed
            $s_CcAddress = ""                                      ; address for cc - leave blank if not needed
            $s_BccAddress = ""                                     ; address for bcc - leave blank if not needed
            $s_Username = ""                                       ; username for the account used from where the mail gets sent  - Optional (Needed for eg GMail)
            $s_Password = ""                                       ; password for the account used from where the mail gets sent  - Optional (Needed for eg GMail)
            $IPPort = 25                                           ; port used for sending the mail
            $ssl = 0

            Global $oMyRet[2]
            Global $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")
            $rc = _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject, $as_Body, $s_AttachFiles, $s_CcAddress, $s_BccAddress, $s_Username, $s_Password, $IPPort, $ssl)
            If @error Then
            MsgBox(0, "Error sending message", "Error code:" & @error & "  Rc:" & $rc)
            Else
            MsgBox( 0, "Mail Sender", "Mail Sent with success !")
            EndIf

        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd
 

Code : Tout sélectionner

;---------------------
;  Fonctions pour
;   L'envoie de mail
;---------------------
Func _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject = "", $as_Body = "", $s_AttachFiles = "", $s_CcAddress = "", $s_BccAddress = "", $s_Username = "", $s_Password = "",$IPPort=25, $ssl=0)
    $objEmail = ObjCreate("CDO.Message")
    $objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
    $objEmail.To = $s_ToAddress
    Local $i_Error = 0
    Local $i_Error_desciption = ""
    If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
    If $s_BccAddress <> "" Then $objEmail.Bcc = $s_BccAddress
    $objEmail.Subject = $s_Subject
    If StringInStr($as_Body,"<") and StringInStr($as_Body,">") Then
        $objEmail.HTMLBody = $as_Body
    Else
        $objEmail.Textbody = $as_Body & @CRLF
    EndIf
    If $s_AttachFiles <> "" Then
        Local $S_Files2Attach = StringSplit($s_AttachFiles, ";")
        For $x = 1 To $S_Files2Attach[0]
            $S_Files2Attach[$x] = _PathFull ($S_Files2Attach[$x])
            If FileExists($S_Files2Attach[$x]) Then
                $objEmail.AddAttachment ($S_Files2Attach[$x])
            Else
                $i_Error_desciption = $i_Error_desciption & @lf & 'File not found to attach: ' & $S_Files2Attach[$x]
                SetError(1)
                return 0
            EndIf
        Next
    EndIf
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $s_SmtpServer
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $IPPort
;Authenticated SMTP
    If $s_Username <> "" Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") = $s_Username
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $s_Password
    EndIf
    If $Ssl Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
    EndIf
;Update settings
    $objEmail.Configuration.Fields.Update
; Sent the Message
    $objEmail.Send
    if @error then
        SetError(2)
        return $oMyRet[1]
    EndIf
EndFunc ;==>_INetSmtpMailCom
;
;
; Com Error Handler




Func MyErrFunc()
    $HexNumber = Hex($oMyError.number, 8)
    $oMyRet[0] = $HexNumber
    $oMyRet[1] = StringStripWS($oMyError.description,3)
    ConsoleWrite("### COM Error !  Number: " & $HexNumber & "   ScriptLine: " & $oMyError.scriptline & "   Description:" & $oMyRet[1] & @LF)
    SetError(1); something to check for when this function returns
    Return
EndFunc ;==>MyErrFunc
;---------------------
;  Fin Fonctions pour
;   L'envoie de mail
;---------------------