AutoIt Français

Je désespère

...

Arrêtez vos bêtises sur le champ s'il vous plait ^^'.
Reprenez le code que je vous ai fourni et réfléchissez un peu à :
Nous vous disons que CHAQUE exe est différent et vous avez à votre disposition un tableau spécifiant le nom de chaque exe... La logique serait de modifier ce tableau.

Code : Tout sélectionner

If(_IsChecked($a_installer[1][8]["Firefox"])) Then

d'où sort ce "firefox" ?
Vous devriez revoir les bases de la programmation, sans cela, vous risqueriez de venir demander de l'aide pour le béa-bas du langage.

Je connais Autoit depuis 2 semaines, et j'apprend au fur et à mesure, donc je pense pas réellement d'avoir les bonnes bases.

Je suis désolée si ça vous désepère, mais c'est sûr cette partie que j'ai vraiment du mal.
j'essaye de dire que "si on coche la checkbox firefox et qu'on clique sur installer, cela s'installe" (mais apparement c'est pas du tout comme cela) et ainsi de suite pour les autres logiciels.

Bonjour,

Ce code est fonctionnel, mais pas du tout testé avec les programmes proposés (parce que je ne les ai pas, tout simplement ^^). A toi de vérifier, mais tu verras plusieurs choses :
- Ton Enum au début ligne 15 ne me plait pas, une variable dont la valeur n'est pas spécifiquement écrite n'est pas une bonne valeur (un script AutoIt ne se fait pas au petit bonheur la chance ^^)
- Ton tableau a été agrémenté d'un champ supplémentaire juste après le nom du logiciel et avant le boolean True/False
- Ce champ vaut "" (aucun paramètre) partout sauf ligne 52 pour Firefox, où il vaut "-ms"
- ligne 183, j'ai utilisé ShellExecute, car les paramètres d'appel sont explicitement prévus dans un paramètre de la fonction.

Malgré cela, avant toute autre aide, je rejoins les dires de TommyDDR, tu ferais mieux de laisser tout ça de coté, et de former en repartant sur de bonnes bases et avec de bonnes pratiques (en algorithmique et en AutoIt je parle, avec l'excellent tuto disponible dans la bannière en haut à gauche de cette page; vu le reste du code, si il est de toi, tu ne sembles pas avoir trop de souci coté prog au sens large).

A bientôt !

► Afficher le texteCode source corrigé

Code : Tout sélectionner

#RequireAdmin

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <IE.au3>


;~ Opt("MustDeclareVars", 1)  ; À METTRE DANS TOUS VOS SCRIPTS !
Opt("GUIOnEventMode", 1)  ; Activation du mode évenementiel

;Declaration de l'array principale!!!
; Si il y a plus de checkbox, remplacer le 42 par : (nombre de checkbox  + 1)
; Depuis la derniere version d'AutoIt, vous n'êtes plus obligé d'indiquer le nombre de dimension lorsque vous déclarez le contenu explicitement

Global $C_ID=0, $C_NOM=1, $C_NOMEXE=2, $C_PARAMETER=3, $C_COMMUN=4, $C_MSGBOX=5

Global $a_installer =   [   [   ["", "Sécurité",                      "",                                   "", False,  ""], _
                                ["", "Norton Antivirus",                "Norton_Antivirus.exe",             "", True,   "J'aime les licones"], _
                                ["", "Cobian Backup",                   "Cobian_Backup.exe",                "", True,   "J'aime les licones"]], _
                            [   ["", "Multimédia",                     "",                                  "", False,  ""], _
                                ["", "AveIcon2",                        "AveIcon2.exe",                     "", False,  "J'aime les licones"], _
                                ["", "Camstudio",                       "Camstudio.exe",                    "", False,  "J'aime les licones"], _
                                ["", "Codec Camstudio",                 "Codec_Camstudio",                  "", False,  "J'aime les licones"], _
                                ["", "Flash IE",                        "Flash_IE.exe",                     "", True,   "J'aime les licones"], _
                                ["", "Flash Mozilla",                   "Flash_Mozilla.exe",                "", True,   "J'aime les licones"], _
                                ["", "Java",                            "java.exe",                         "", True,   "Java est un langage de programmation et une plate-forme informatique qui ont été créés par Sun Microsystems en 1995. Beaucoup d'applications et de sites Web ne fonctionnent pas si Java n'est pas installé et leur nombre ne cesse de croître chaque jour. Java est rapide, sécurisé et fiable."], _
                                ["", "Photofiltre",                     "Photofiltre.exe",                  "", True,   "J'aime les licones"], _
                                ["", "The Gimp",                        "The_Gimp.exe",                     "", False,  "J'aime les licones"], _
                                ["", "VLC",                             "VLC.exe",                          "", False,  "J'aime les licones"], _
                                ["", "VSO Image Resizer",               "VSo_Image_Resizer.exe",            "", True,   "J'aime les licones"]], _
                            [   ["", "Programmation",                   "",                                 "", False,  ""], _
                                ["", "AutoIt",                          "AutoIt.exe",                       "", False,  "J'adore l'europe, l'europe c'est super, j'adore l'europe, oui c'est vraiment d'enfer"], _
                                ["", "Notepad",                         "NotePad.exe",                      "", False,  "J'aime les licones"]], _
                            [   ["", "Système",                            "",                              "", False,  ""], _
                                ["", "CCleaner",                        "CCleaner.exe",                     "", True,   "CCleaner (abréviation de Crap Cleaner) est un logiciel freeware permettant d'optimiser le fonctionnement d’un ordinateur muni du système d’exploitation Windows et de protéger la vie privée des utilisateurs de l’ordinateur. Il supprime les fichiers et les enregistrements inutiles, ce qui permet à l’ordinateur de fonctionner plus rapidement et libère de l’espace sur le disque dur."], _
                                ["", "Dial A Fix",                      "Dial_A_Fix.exe",                   "", False,  "J'aime les licones"]], _
                            [   ["", "Manipulation de fichiers",        "",                                 "", False,  ""], _
                                ["", "Full Sync",                       "Full_Sync.exe",                    "", False,  "J'aime les licones"], _
                                ["", "Super Copier",                    "Super_Copier.exe",                 "", False,  "J'aime les licones"], _
                                ["", "Lupas Rename",                    "Lupas_Rename.exe",                 "", False,  "J'aime les licones"], _
                                ["", "PC Inspector File Recovery",      "PC_Inspector_File_Recovery.exe",   "", True,   "J'aime les licones"], _
                                ["", "Rep Listing",                     "Rep_Listing.exe",                  "", False,  "J'aime les licones"]], _
                            [   ["", "Scientifique",                    "",                                 "", False,  ""], _
                                ["", "R",                               "R.exe",                            "", False,  "J'aime les licones"], _
                                ["", "SciLab",                          "SciLab.exe",                       "", False,  "J'aime les licones"]], _
                            [   ["", "Bureautique",                     "",                                 "", False,  ""], _
                                ["", "Foxit Reader",                    "Foxit_Reader.exe",                 "", True,   "J'aime les licones"], _
                                ["", "Open Office",                     "Open_Office.exe",                  "", True,   "Open Office est une suite bureautique libre comprenant un traitement de texte, un tableur, un logiciel de présentation et un logiciel de dessin. Cette suite est entièrement gratuite et concurrente directe de Microsoft Office."], _
                                ["", "PDF Creator",                     "PDF_Creator.exe",                  "", True,   "J'aime les licones"], _
                                ["", "Tex Maker",                       "Tex_Maker.exe",                    "", True,   "J'aime les licones"]], _
                            [   ["", "Réseaux",                            "",                              "", False,  ""], _
                                ["", "Firefox",                         "Firefox.exe",                      "-ms", True,   "Firefox est un navigateur Web libre et gratuit, développé et distribué par la Mozilla Foundation avec l'aide de milliers de bénévoles grâce aux méthodes de développement du logiciel libre/open source et à la liberté du code source."], _
                                ["", "IP Scan",                         "IP_Scan.exe",                      "", False,  "J'aime les licones"], _
                                ["", "Magic IP",                        "Magic_IP.exe",                     "", False,  "J'aime les licones"], _
                                ["", "NX",                              "NX.exe",                           "", True,   "J'aime les licones"], _
                                ["", "Putty SSH",                       "Putty_SSH.exe",                    "", False,  "J'aime les licones"], _
                                ["", "Super Scan",                      "Super_Scan.exe",                   "", False,  "J'aime les licones"], _
                                ["", "Thunderbird",                     "Thunderbird.exe",                  "", False,  "J'aime les licones"], _
                                ["", "TightVNC",                        "TightVNC.exe",                     "", False,  "J'aime les licones"], _
                                ["", "Ultr@VNC",                        "UltraVNC.exe",                     "", False,  "J'aime les licones"], _
                                ["", "Win2000 Plain Password",          "Win2000_Plain_Password.exe",       "", False,  "J'aime les licones"], _
                                ["", "Wireshark",                       "WireShark.exe",                    "", True,   "J'aime les licones"], _
                                ["", "XMing",                           "XMing.exe",                        "", False,  "J'aime les licones"], _
                                ["", "XMing Fonts",                     "XMing_fonts.exe",                  "", False,  "J'aime les licones"]], _
                            [   ["", "Utilitaires",                     "",                                 "", False,  ""], _
                                ["", "7Zip",                            "7zip.exe",                         "", True,   "7-Zip est un logiciel de compression de données et d’archivage de fichiers fonctionnant sous Windows développé par le Russe Igor Pavlov. C’est un logiciel libre distribué sous licence LGPL, le code LZMA est dans le domaine public, le code AES est sous licence BSD et le code unRAR est sous licence mixte (LGPL + des restrictions unRAR)."]]]

Global $tailleGui = [751, 666]

$gui = GUICreate(" Selectionner les logiciels à installer ", $tailleGui[0], $tailleGui[1])
GUISetIcon("Data\autorun.ico")
GUISetOnEvent($GUI_EVENT_CLOSE, "quitter") ;On associe l'évenement "Close" (Alt+F4 / Croix rouge / echap / etc) à la fonction quit

$installer = GUICtrlCreateButton(" Installer ", $tailleGui[0]-90, $tailleGui[1]-35, 75, 25, 0) ; Création du bouton "installer"
$quitter = GUICtrlCreateButton(" Quitter ", $tailleGui[0]-175, $tailleGui[1]-35, 75, 25, 0) ; Création du bouton "quitter"
$documentation = GUICtrlCreateButton(" Documentation ", 8, $tailleGui[1]-35, 83, 25, 0) ; Création du bouton "documentation"
$checkall = GUICtrlCreateCheckbox("Tout cocher / Tout décoher", 105, $tailleGui[1]-80, 177, 17)
$checkcommun = GUICtrlCreateCheckbox("Selectionner les logiciels communs", $tailleGui[0]-340, $tailleGui[1]-80, 209, 17)
GUICtrlSetOnEvent($installer, "install")
GUICtrlSetOnEvent($quitter, "quitter")
GUICtrlSetOnEvent($documentation, "documentation")
GUICtrlSetOnEvent($checkall, "allcheck")
GUICtrlSetOnEvent($checkcommun, "allcommun")

Local $pos = [5, 5]
Local $taille = [245, 0]
Local $tailleCheckbox = [100, 17]
Local $tailleDecalage = $tailleCheckbox[1]+15
For $i = 0 To UBound($a_installer, 1)-1
    $taille[1] = getTailleByIndex($i)*$tailleDecalage+15
    If($pos[1] + $taille[1] >= $tailleGui[1]-100) Then
        $pos[0] += $taille[0] + 5
        $pos[1] = 5
    EndIf
    $a_installer[$i][0][$C_ID] = GUICtrlCreateGroup($a_installer[$i][0][$C_NOM], $pos[0], $pos[1], $taille[0], $taille[1])
    $pos[1] += 20
    For $j = 1 To UBound($a_installer, 2)-1
        If(StringLen($a_installer[$i][$j][$C_NOM]) = 0) Then ExitLoop
        $a_installer[$i][$j][$C_ID] = GUICtrlCreateCheckbox($a_installer[$i][$j][$C_NOM], $pos[0]+20, $pos[1], $tailleCheckbox[0], $tailleCheckbox[1])
        $pos[1] += $tailleDecalage
    Next
Next
GUISetState(@SW_SHOW, $gui)

While(1)
    Sleep(100)
WEnd

Func documentation()
   Local $isRun = False
    For $i = 0 To UBound($a_installer, 1)-1
        For $j = 1 To UBound($a_installer, 2)-1
            If($a_installer[$i][$j][$C_ID] <= 0) Then ExitLoop
            If _Ischecked($a_installer[$i][$j][0]) then
               $isRun=True
                MsgBox(64, "Informations sur " & $a_installer[$i][$j][$C_NOM], $a_installer[$i][$j][$C_MSGBOX])
            EndIf
        Next
     Next
         If(Not($isRun)) Then
        MsgBox(16, "Erreur","Vous n'avez rien coché")
    EndIf
EndFunc

Func allcheck()
    Local $state = _Ischecked($checkall) ? $GUI_CHECKED : $GUI_UNCHECKED
   If _IsChecked($checkall) = $GUI_CHECKED Then
      GUICtrlSetState($checkcommun,$GUI_UNCHECKED)
      GUICtrlSetState($checkcommun,$GUI_DISABLE)
      For $i = 0 To UBound($a_installer, 1)-1
        For $j = 1 To UBound($a_installer, 2)-1
            If($a_installer[$i][$j][$C_ID] <= 0) Then ExitLoop
            GUICtrlSetState($a_installer[$i][$j][$C_ID], $state)
         Next
      Next
   Else
     GUICtrlSetState($checkcommun,$GUI_ENABLE)
         GUICtrlSetState($checkcommun,$GUI_UNCHECKED)
         For $i = 0 To UBound($a_installer, 1)-1
            For $j = 1 To UBound($a_installer, 2)-1
               If($a_installer[$i][$j][$C_ID] <= 0) Then ExitLoop
                  GUICtrlSetState($a_installer[$i][$j][$C_ID], $state)
            Next
         Next
      EndIf
EndFunc

Func allcommun()
    Local $state = _Ischecked($checkcommun) ? $GUI_CHECKED : $GUI_UNCHECKED
    Local $i, $j
      If _IsChecked($checkcommun) = $GUI_CHECKED Then
         GUICtrlSetState($checkall,$GUI_DISABLE)
         GUICtrlSetState($checkall,$GUI_UNCHECKED)
         For $i = 0 To UBound($a_installer, 1)-1
            For $j = 1 To UBound($a_installer, 2)-1
               If($a_installer[$i][$j][$C_ID] <= 0) Then ExitLoop
               If($a_installer[$i][$j][$C_COMMUN]) Then
                  GUICtrlSetState($a_installer[$i][$j][$C_ID], $state)
               EndIf
            Next
         Next
      Else
         GUICtrlSetState($checkall,$GUI_ENABLE)
         GUICtrlSetState($checkall,$GUI_UNCHECKED)
         For $i = 0 To UBound($a_installer, 1)-1
            For $j = 1 To UBound($a_installer, 2)-1
               If($a_installer[$i][$j][$C_ID] <= 0) Then ExitLoop
               If($a_installer[$i][$j][$C_COMMUN]) Then
                  GUICtrlSetState($a_installer[$i][$j][$C_ID], $state)
               EndIf
            Next
         Next
      EndIf
EndFunc


Func install()
    Local $isRun = False
    For $i = 0 To UBound($a_installer, 1)-1
        For $j = 1 To UBound($a_installer, 2)-1
            If($a_installer[$i][$j][$C_ID] <= 0) Then ExitLoop
            If(_IsChecked($a_installer[$i][$j][$C_ID])) Then
                $isRun = True
                  ShellExecute(@ScriptDir &"\installation\" & $a_installer[$i][$j][$C_NOMEXE], $a_installer[$i][$j][$C_PARAMETER])
                  Sleep(1000)
            EndIf
        Next
    Next
    If(Not($isRun)) Then
        MsgBox(16, "Erreur","Vous n'avez rien coché")
    EndIf
 EndFunc

Func getTailleByIndex($indice)
    Local $taille = 0
    For $i = 1 To UBound($a_installer, 2)-1
        If(StringLen($a_installer[$indice][$i][$C_NOM]) <= 0) Then ExitLoop
        $taille += 1
    Next
    Return $taille
EndFunc

Func _Ischecked($control)
    Return BitAND(GUICtrlRead($control), $GUI_CHECKED) = $GUI_CHECKED
EndFunc

Func quitter()
   Exit
EndFunc

D'accord!
c'est juste que ce programme est un projet que je dois terminer dans 2 semaines, mais bon, je vais le mettre un peu de coté pour apprendre le B à bas de ce langage.

Plus j'ai testé votre programme(je vous remercie d’ailleurs), il ouvre l'installateur mais il s'installe pas tout seul

@ZDS : Je ne suis pas d'accord avec toi (normal c'est mon code que tu critiques

)
Par défaut, une liste d'enum prendront les valeurs de 0 à x-1 (x étant le nombre de valeurs de l'enum) L'enum sert justement à ne pas devoir se taper 0 1 2 3 4 5 6 7 8 ... à écrire.
Elle permet en plus de pouvoir ajouter un élément au milieu de la liste sans autre changement.
c'est juste un comportement parfait pour nommer les cases d'un tableau.

C bon, ça marche!!

Le problème: c'est juste parce que j'avais une mauvaise version, c'est pour cela qu'il ne voulait pas s'installer.
Comme quoi, c'est en cherchant qu'on finis par trouver son bonheur.

Je vous remercie tous de m'avoir aidé!!

T123x3, tu est proche du but...
Pour l'installation automatique, recherches d'abord si chaque installation est automatisable (avec les sites que j'ai t'ai donné par exemple).
Si tu trouves les paramètres pour une installation, met-les dans le tableau $a_installer (comme l'a fait ZDS avec Firefox, regarde son code).
Par contre, remplace ShellExecute par ShellExecuteWait pour que les installations de se lancent pas toutes en même temps.

Si j'ai un peu de temps, j'essaierai de te donner un coup de main sur les installation automatiques...

C'est bon ça marche!!

J'ai réussi installer Java et Ccleaner mais par contre c'est Firefox, dont j'ai du mal.
Il y a que Firefox qui ouvre l'assistance d'installation, (je pense que c'est un problème de version (j'ai pris la version 29.0.1))

Attention pour Firefox il faut bien faire attention de télécharger le programme d'installation complet, pas le mini-truc qu'on a sur la page d'accueil : http://www.mozilla.org/en-US/firefox/all/

Bon, j'ai pris la version complète hier, ça ne marchait pas et là je reviens ce matin, et ça marche.

Bon je vais pas chercher pourquoi.

Merci encore de m'avoir aidé, c'est vraiment sympas.
Je vais essayer d’améliorer le programme en mettant une barre de progression (un truc dans le genre^^).
Si j'ai besoin d'aide, je vous le dirai!

Merci!!!

Voila j'ai terminée, pour ceux qu'ils veulent le résultat final, le voilà!

Encore merci!!

► Afficher le texte

Code : Tout sélectionner

#RequireAdmin ;permet d'activer un controle de compte d'utilisateur au demarrage

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <IE.au3>


;~ Opt("MustDeclareVars", 1)  ; À METTRE DANS TOUS VOS SCRIPTS !
Opt("GUIOnEventMode", 1)  ; Activation du mode évenementiel

;Declaration de l'array principale!!!
; Si il y a plus de checkbox, remplacer le 42 par : (nombre de checkbox  + 1)
; Depuis la derniere version d'AutoIt, vous n'êtes plus obligé d'indiquer le nombre de dimension lorsque vous déclarez le contenu explicitement

Enum $C_ID, $C_NOM, $C_NOMEXE, $C_PARAMETER, $C_COMMUN, $C_MSGBOX ;les colonnes du tableau $C_ID=Identification, $C-NOM=Nom du logiciel, $C_NOMEXE=Nom du fichier exe, $C_PARAMETER=Parametre d'installation silencieuse, $C_COMMUN=Quand il indique True le logiciel est coché quand on coche "Selectionner les logiciels commun", $C_MSGBOX=Message dans documentation

Global $a_installer =   [   [   ["", "Sécurité",                      "",                                   "", False,  ""], _
                                ["", "Norton Antivirus",                "Norton_Antivirus.exe",             "", True,   ""], _
                                ["", "Cobian Backup",                   "Cobian_Backup.exe",                "", True,   ""]], _
                            [   ["", "Multimédia",                     "",                                  "", False,  ""], _
                                ["", "AveIcon2",                        "AveIcon2.exe",                     "", False,  ""], _
                                ["", "Camstudio",                       "Camstudio.exe",                    "", False,  ""], _
                                ["", "Codec Camstudio",                 "Codec_Camstudio",                  "", False,  ""], _
                                ["", "Flash IE",                        "Flash_IE.exe",                     "", True,   ""], _
                                ["", "Flash Mozilla",                   "Flash_Mozilla.exe",                "", True,   ""], _
                                ["", "Java",                            "java.exe",                         "/s REBOOT=Suppress", True,   "Java est un langage de programmation et une plate-forme informatique qui ont été créés par Sun Microsystems en 1995. Beaucoup d'applications et de sites Web ne fonctionnent pas si Java n'est pas installé et leur nombre ne cesse de croître chaque jour. Java est rapide, sécurisé et fiable."], _
                                ["", "Photofiltre",                     "Photofiltre.exe",                  "", True,   ""], _
                                ["", "The Gimp",                        "The_Gimp.exe",                     "", False,  ""], _
                                ["", "VLC",                             "VLC.exe",                          "", False,  ""], _
                                ["", "VSO Image Resizer",               "VSo_Image_Resizer.exe",            "", True,   ""]], _
                            [   ["", "Programmation",                   "",                                 "", False,  ""], _
                                ["", "AutoIt",                          "AutoIt.exe",                       "", False,  ""], _
                                ["", "Notepad",                         "NotePad.exe",                      "", False,  ""]], _
                            [   ["", "Système",                            "",                              "", False,  ""], _
                                ["", "CCleaner",                        "CCleaner.exe",                     "/S", True,   "CCleaner (abréviation de Crap Cleaner) est un logiciel freeware permettant d'optimiser le fonctionnement d’un ordinateur muni du système d’exploitation Windows et de protéger la vie privée des utilisateurs de l’ordinateur. Il supprime les fichiers et les enregistrements inutiles, ce qui permet à l’ordinateur de fonctionner plus rapidement et libère de l’espace sur le disque dur."], _
                                ["", "Dial A Fix",                      "Dial_A_Fix.exe",                   "", False,  ""]], _
                            [   ["", "Manipulation de fichiers",        "",                                 "", False,  ""], _
                                ["", "Full Sync",                       "Full_Sync.exe",                    "", False,  ""], _
                                ["", "Super Copier",                    "Super_Copier.exe",                 "", False,  ""], _
                                ["", "Lupas Rename",                    "Lupas_Rename.exe",                 "", False,  ""], _
                                ["", "PC Inspector File Recovery",      "PC_Inspector_File_Recovery.exe",   "", True,   ""], _
                                ["", "Rep Listing",                     "Rep_Listing.exe",                  "", False,  ""]], _
                            [   ["", "Scientifique",                    "",                                 "", False,  ""], _
                                ["", "R",                               "R.exe",                            "", False,  ""], _
                                ["", "SciLab",                          "SciLab.exe",                       "", False,  ""]], _
                            [   ["", "Bureautique",                     "",                                 "", False,  ""], _
                                ["", "Foxit Reader",                    "Foxit_Reader.exe",                 "", True,   ""], _
                                ["", "Open Office",                     "Open_Office.exe",                  "", True,   "Open Office est une suite bureautique libre comprenant un traitement de texte, un tableur, un logiciel de présentation et un logiciel de dessin. Cette suite est entièrement gratuite et concurrente directe de Microsoft Office."], _
                                ["", "PDF Creator",                     "PDF_Creator.exe",                  "", True,   ""], _
                                ["", "Tex Maker",                       "Tex_Maker.exe",                    "", True,   ""]], _
                            [   ["", "Réseaux",                            "",                              "", False,  ""], _
                                ["", "IP Scan",                         "IP_Scan.exe",                      "", False,  ""], _
                                ["", "Magic IP",                        "Magic_IP.exe",                     "", False,  ""], _
                                ["", "Mozilla Firefox",                 "Firefox.exe",                      "-ms", True,   "Firefox est un navigateur Web libre et gratuit, développé et distribué par la Mozilla Foundation avec l'aide de milliers de bénévoles grâce aux méthodes de développement du logiciel libre/open source et à la liberté du code source."], _
                                ["", "NX",                              "NX.exe",                           "", True,   ""], _
                                ["", "Putty SSH",                       "Putty_SSH.exe",                    "", False,  ""], _
                                ["", "Super Scan",                      "Super_Scan.exe",                   "", False,  ""], _
                                ["", "Thunderbird",                     "Thunderbird.exe",                  "", False,  ""], _
                                ["", "TightVNC",                        "TightVNC.exe",                     "", False,  ""], _
                                ["", "Ultr@VNC",                        "UltraVNC.exe",                     "", False,  ""], _
                                ["", "Win2000 Plain Password",          "Win2000_Plain_Password.exe",       "", False,  ""], _
                                ["", "Wireshark",                       "WireShark.exe",                    "", True,   ""], _
                                ["", "XMing",                           "XMing.exe",                        "", False,  ""], _
                                ["", "XMing Fonts",                     "XMing_fonts.exe",                  "", False,  ""]], _
                            [   ["", "Utilitaires",                     "",                                 "", False,  ""], _
                                ["", "7Zip",                            "7zip.exe",                         "/S", True,   "7-Zip est un logiciel de compression de données et d’archivage de fichiers fonctionnant sous Windows développé par le Russe Igor Pavlov. C’est un logiciel libre distribué sous licence LGPL, le code LZMA est dans le domaine public, le code AES est sous licence BSD et le code unRAR est sous licence mixte (LGPL + des restrictions unRAR)."]]]

Global $tailleGui = [751, 666]

$gui = GUICreate(" Selectionner les logiciels à installer ", $tailleGui[0], $tailleGui[1]) ;Creation de l'interface graphique
GUISetIcon("Data\autorun.ico")
GUISetOnEvent($GUI_EVENT_CLOSE, "quitter") ;On associe l'évenement "Close" (Alt+F4 / Croix rouge / echap / etc) à la fonction quit

$installer = GUICtrlCreateButton(" Installer ", $tailleGui[0]-90, $tailleGui[1]-35, 75, 25, 0) ; Création du bouton "installer"
$quitter = GUICtrlCreateButton(" Quitter ", $tailleGui[0]-175, $tailleGui[1]-35, 75, 25, 0) ; Création du bouton "quitter"
$documentation = GUICtrlCreateButton(" Documentation ", 8, $tailleGui[1]-35, 83, 25, 0) ; Création du bouton "documentation"
$checkall = GUICtrlCreateCheckbox("Tout cocher / Tout décocher", 105, $tailleGui[1]-80, 177, 17) ;Création de la case à cocher "Tout cocher / Tout décocher"
$checkcommun = GUICtrlCreateCheckbox("Selectionner les logiciels communs", $tailleGui[0]-340, $tailleGui[1]-80, 209, 17) ;Création de la case à cocher "Selectionner les logiciels communs"
GUICtrlSetOnEvent($installer, "install") ;Définit la fonction "install" qui s'applique quand l'utilisateur clique sur le bouton "Installer"
GUICtrlSetOnEvent($quitter, "quitter") ;Définit la fonction "quitter" qui s'applique quand l'utilisateur clique sur le bouton "Quitter"
GUICtrlSetOnEvent($documentation, "documentation") ;Définit la fonction "documentation" qui s'applique quand l'utilisateur clique sur le bouton "Documentation"
GUICtrlSetOnEvent($checkall, "allcheck") ;Définit la fonction "allcheck" qui s'applique quand l'utilisateur clique sur la case à cocher "Tout cocher/ Tout décocher"
GUICtrlSetOnEvent($checkcommun, "allcommun") ;Définit la fonction "allcommun" qui s'applique quand l'utilisateur clique sur la case à cocher "Selectionner les logiciels communs"

Local $pos = [5, 5]
Local $taille = [245, 0]
Local $tailleCheckbox = [100, 17]
Local $tailleDecalage = $tailleCheckbox[1]+15
For $i = 0 To UBound($a_installer, 1)-1
    $taille[1] = getTailleByIndex($i)*$tailleDecalage+15
    If($pos[1] + $taille[1] >= $tailleGui[1]-100) Then
        $pos[0] += $taille[0] + 5
        $pos[1] = 5
    EndIf
    $a_installer[$i][0][$C_ID] = GUICtrlCreateGroup($a_installer[$i][0][$C_NOM], $pos[0], $pos[1], $taille[0], $taille[1])
    $pos[1] += 20
    For $j = 1 To UBound($a_installer, 2)-1
        If(StringLen($a_installer[$i][$j][$C_NOM]) = 0) Then ExitLoop
        $a_installer[$i][$j][$C_ID] = GUICtrlCreateCheckbox($a_installer[$i][$j][$C_NOM], $pos[0]+20, $pos[1], $tailleCheckbox[0], $tailleCheckbox[1])
        $pos[1] += $tailleDecalage
    Next
Next
GUISetState(@SW_SHOW, $gui)

While(1)
    Sleep(100)
WEnd

Func documentation() ;Function documentation qui s'applique quand on clique sur le bouton "Documentation"
   Local $isRun = False ;Création de la variable $isRun dont il est égale à False
    For $i = 0 To UBound($a_installer, 1)-1 ;On met un boucle For, la variable $i=0 et on sort de la boucle si on renvoie la taille de dimensions du tableau à 1.
        For $j = 1 To UBound($a_installer, 2)-1 ;On met un boucle For, la variable $j=1 et on sort de la boucle si on renvoie la taille de dimensions du tableau à 2.
            If($a_installer[$i][$j][$C_ID] <= 0) Then ExitLoop ;Si l'identification d'un logiciel du tableau $a_installer est inferieur à 0 alors on sort de la boucle For.
            If _Ischecked($a_installer[$i][$j][0]) then ;Si une checkbox du tableau $a_installer est cocher alors...
               $isRun=True
                MsgBox(64, "Informations sur " & $a_installer[$i][$j][$C_NOM], $a_installer[$i][$j][$C_MSGBOX]) ;Message indiquant les informations du logiciel
            EndIf ;Fin du IF
        Next ;Fin de la boucle For
     Next;Fin de la boucle For
         If(Not($isRun)) Then ;Si $isRun est egale à False Alors...
        MsgBox(16, "Erreur","Vous n'avez rien coché") ;Message d'erreur indiquant que l'utilisateur n'a rien coché
    EndIf;Fin du If
EndFunc ;Fin de la fonction

Func allcheck() ;Function allcheck qui s'applique quand on clique sur la case à cocher "Tout cocher/Tout decocher"
    Local $state = _Ischecked($checkall) ? $GUI_CHECKED : $GUI_UNCHECKED ;création de la variable $state qui permet de tout cocher et de tout décocher quand on clique sur la case à cocher "checkall"
   If _IsChecked($checkall) = $GUI_CHECKED Then ;Si la case à cocher "Tout cocher/Tout décocher" est cocher alors...
      GUICtrlSetState($checkcommun,$GUI_UNCHECKED) ;la case à cocher "Selectionner les logiciels communs" se décoche
      GUICtrlSetState($checkcommun,$GUI_DISABLE) ;la case à cocher "Selectionner les logiciels communs" se désactive (le checkbox est grisé)
      For $i = 0 To UBound($a_installer, 1)-1 ;On met un boucle For, la variable $i=0 et on sort de la boucle si on renvoie la taille de dimensions du tableau à 1.
        For $j = 1 To UBound($a_installer, 2)-1 ;On met un boucle For, la variable $j=1 et on sort de la boucle si on renvoie la taille de dimensions du tableau à 2.
            If($a_installer[$i][$j][$C_ID] <= 0) Then ExitLoop ;Si l'identification d'un logiciel du tableau $a_installer est inferieur à 0 alors on sort de la boucle For.
               GUICtrlSetState($a_installer[$i][$j][$C_ID], $state) ;Tout les checkbox du tableau $a_installer sont cochés
         Next ;Fin de la boucle For
      Next ;Fin de la boucle For
   Else ;Sinon
      GUICtrlSetState($checkcommun,$GUI_ENABLE) ;la case à cocher "Selectionner les logiciels communs" s'active (le checkbox n'est pas grisé)
      GUICtrlSetState($checkcommun,$GUI_UNCHECKED) ;la case à cocher "Selectionner les logiciels communs" se décoche
      For $i = 0 To UBound($a_installer, 1)-1 ;On met un boucle For, la variable $i=0 et on sort de la boucle si on renvoie la taille de dimensions du tableau à 1.
         For $j = 1 To UBound($a_installer, 2)-1 ;On met un boucle For, la variable $j=1 et on sort de la boucle si on renvoie la taille de dimensions du tableau à 2.
            If($a_installer[$i][$j][$C_ID] <= 0) Then ExitLoop ;Si l'identification d'un logiciel du tableau $a_installer est inferieur à 0 alors on sort de la boucle For.
               GUICtrlSetState($a_installer[$i][$j][$C_ID], $state) ;Tout les checkbox du tableau $a_installer sont décochés
         Next ;Fin de la boucle For
      Next ;Fin de la boucle For
   EndIf ;Fin du If
EndFunc ;Fin de la fonction

Func allcommun() ;Function allcommun qui s'applique quand on clique sur la case à cocher "Selectionner les logiciels communs"
    Local $state = _Ischecked($checkcommun) ? $GUI_CHECKED : $GUI_UNCHECKED ;création de la variable $state qui permet de tout cocher et de tout décocher quand on clique sur la case à cocher "checkcommun"
    Local $i, $j ;Creation de variable $i et $j
      If _IsChecked($checkcommun) = $GUI_CHECKED Then ;Si la case à cocher "Selectionner les logiciels communs" est cocher alors...
         GUICtrlSetState($checkall,$GUI_DISABLE) ;la case à cocher "Tout cocher / Tout décocher" se désactive (le checkbox est grisé)
         GUICtrlSetState($checkall,$GUI_UNCHECKED) ;la case à cocher "Tout cocher / Tout décocher" se décoche
         For $i = 0 To UBound($a_installer, 1)-1 ;On met un boucle For, la variable $i=0 et on sort de la boucle si on renvoie la taille de dimensions du tableau à 1.
            For $j = 1 To UBound($a_installer, 2)-1 ;On met un boucle For, la variable $j=1 et on sort de la boucle si on renvoie la taille de dimensions du tableau à 2.
               If($a_installer[$i][$j][$C_ID] <= 0) Then ExitLoop ;Si l'identification d'un logiciel du tableau $a_installer est inferieur à 0 alors on sort de la boucle For.
               If($a_installer[$i][$j][$C_COMMUN]) Then ;Si les logiciels qui ont comme booléen True Alors...
                  GUICtrlSetState($a_installer[$i][$j][$C_ID], $state) ;les checkbox en communs du tableau $a_installer sont cochés
               EndIf ;Fin du If
            Next ;fin de la boucle For
         Next ;Fin de la boucle For
      Else ;Sinon
         GUICtrlSetState($checkall,$GUI_ENABLE) ;la case à cocher "Tout coché / Tout décocher" s'active (le checkbox n'est pas grisé)
         GUICtrlSetState($checkall,$GUI_UNCHECKED) ;la case à cocher "Tout cocher / Tout décocher" se décoche
         For $i = 0 To UBound($a_installer, 1)-1 ;On met un boucle For, la variable $i=0 et on sort de la boucle si on renvoie la taille de dimensions du tableau à 1.
            For $j = 1 To UBound($a_installer, 2)-1  ;On met un boucle For, la variable $j=1 et on sort de la boucle si on renvoie la taille de dimensions du tableau à 2.
               If($a_installer[$i][$j][$C_ID] <= 0) Then ExitLoop ;Si l'identification d'un logiciel du tableau $a_installer est inferieur à 0 alors on sort de la boucle For.
               If($a_installer[$i][$j][$C_COMMUN]) Then ;Si les logiciels qui ont comme booléen True Alors...
                  GUICtrlSetState($a_installer[$i][$j][$C_ID], $state) ;les checkbox en communs du tableau $a_installer sont décochés
               EndIf ;Fin du If
            Next ;Fin de la boucle For
         Next ;Fin de la boucle For
      EndIf ;Fin du If
EndFunc ;Fin de la fonction


Func install() ;Function install() qui s'applique quand on clique sur le bouton "Installer"
    Local $isRun = False ;création de la variable $isRun dont il est égale à False
    Local $i, $j ;Creation de variable $i et $j
    $label=GUICtrlCreateLabel("Veuillez patientez! Installation en cours!!",$tailleGui[0]-500, $tailleGui[1]-35) ;Création d'une étiquette en indiquant à l'utilisateur de patienter
    For $i = 0 To UBound($a_installer, 1)-1 ;On met un boucle For, la variable $i=0 et on sort de la boucle si on renvoie la taille de dimensions du tableau à 1.
        For $j = 1 To UBound($a_installer, 2)-1 ;On met un boucle For, la variable $j=1 et on sort de la boucle si on renvoie la taille de dimensions du tableau à 2.
            If($a_installer[$i][$j][$C_ID] <= 0) Then ExitLoop ;Si l'identification d'un logiciel du tableau $a_installer est inferieur à 0 alors on sort de la boucle For.

               If(_IsChecked($a_installer[$i][$j][$C_ID])) Then ;Si un checkbox du tableau $a_installer est coché alors...
                  If (FileExists(@ProgramFilesDir & "\" & $a_installer[$i][$j][$C_NOM])) Then
                     $isRun = True
                     MsgBox(16, "Déjà installé", $a_installer[$i][$j][$C_NOM] & " est déjà installé")
                     ExitLoop
                  EndIf

                  $isRun = True
                  ShellExecuteWait(@ScriptDir & "\installation\" & $a_installer[$i][$j][$C_NOMEXE], $a_installer[$i][$j][$C_PARAMETER]) ;L'installateur va chercher dans le dossier "installation" le logiciel coché dans le tableau et prend le parametre d'installation de ce logiciel qui permettra l'installé silencieusement
                  TrayTip("Installation de " & $a_installer[$i][$j][$C_NOM], "Fin de l'installation de " & $a_installer[$i][$j][$C_NOM], 1000) ;Affichage d'une infobulle avec comme titre "Installation de " + le nom du logiciel et comme texte "Fin de l'installation de " + le nom du logiciel pendant 1 seconde
               EndIf ;Fin du If

               If(_IsChecked($a_installer[$i][$j][$C_ID])) Then
                  If($a_installer[$j][$i][$C_ID] = False) Then
                     MsgBox(0,"Fin des installations", "Tout les logiciels sélectionnés ont été installé")
                  EndIf
               EndIf

         Next ;Fin de la boucle For
      Next ;Fin de la boucle For
      GUICtrlSetState($label, $GUI_HIDE)
    If(Not($isRun)) Then  ;Si $isRun est egale à False Alors...
        MsgBox(16, "Erreur","Vous n'avez rien coché") ;Message d'erreur indiquant que l'utilisateur n'a rien coché
    EndIf ;Fin du If
 EndFunc ;Fin de la fonction

Func getTailleByIndex($indice)
    Local $taille = 0
    For $i = 1 To UBound($a_installer, 2)-1
        If(StringLen($a_installer[$indice][$i][$C_NOM]) <= 0) Then ExitLoop
        $taille += 1
    Next
    Return $taille
EndFunc

Func _Ischecked($control)
    Return BitAND(GUICtrlRead($control), $GUI_CHECKED) = $GUI_CHECKED
EndFunc

Func quitter() ;Fonction quitter() qui s'applique quand on clique sur le bouton "Quitter"
   $msgbox=MsgBox(4,"Quitter??","Voulez-vous vraiment quitter???") ;Message qui demande à l'utilisateur si il veut vraiment quitter
   If $msgbox=6 Then ;Si l'utilisateur répond oui (6 correspond à oui et 7 pour non) Alors...
      Exit ;Fermeture de l'application
   EndIf ;Fin du If
EndFunc ;Fin de la fonction

Super.
Maintenant, ce que je te conseille fortement, c'est d'externaliser la liste des différents logiciels (dans un fichier INI par exemple).

Et sans demander d'aide ce coup-ci

Voici une piste : "IniRead" (et ses copines qui l'accompagnent) -> La touche F1 est votre amie

OK je vais essayer ^^

Ah oui, mon tuteur de mon stage a adoré le programme (toujours grâce à vous, merci

) et il m'a demandé si c'était possible que ce programme, on peut le mettre sur un site web avec comme langage html, javascript et php mais je sais pas si c'est vraiment possible.

En fait, il veut faire l'équivalent de Ninite ?

Oui c'est a peu prés ça.

Il veut un site pour que tout le service ait accès plus rapidement possible (un raccourcis sur le bureau)

Bah tu le compile et tu le met dans un réseau local et tu fait un raccourcis sur chaque poste, car faire un site je n'en voit pas bien l’intérêt.

AutoIt Français

[R] Installation de Logiciels

Re: [R] Installation de Logiciels

Re: [R] Installation de Logiciels

Re: [R] Installation de Logiciels

Re: [R] Installation de Logiciels

Re: [R] Installation de Logiciels

Re: [R] Installation de Logiciels

Re: [R] Installation de Logiciels

Re: [R] Installation de Logiciels

Re: [R] Installation de Logiciels

Re: [R] Installation de Logiciels

Re: [R] Installation de Logiciels

Re: [R] Installation de Logiciels

Re: [R] Installation de Logiciels

Re: [R] Installation de Logiciels

Re: [R] Installation de Logiciels

Re: [R] Installation de Logiciels

Re: [R] Installation de Logiciels