AutoIt Français

Code : Tout sélectionner

#include <File.au3>

; 'ãlbértô RødRîgó ' => Chaine écrite dans le fichier
; 'Alberto Rõdrigo'  => Chaine à supprimer

Local $File = "Fichier.txt" ; Nom du fichier à traiter
Local $NameToDelete = 'Alberto Rõdrigo' ; Nom à supprimer du fichier

Local $aFile
_FileReadToArray($File, $aFile) ; Mise en tableau du fichier source
; Si erreur, boite de message puis bye bye.
If @error Then
    MsgBox(16, "Erreur", "Erreur de lecture du fichier de données")
    Exit
EndIf

; Boucle de lecture du tableau pour comparaison
Local $StrTmp
For $i = 1 To UBound($aFile) - 1
    ; Si les deux chaines sont différentes, alors on ajoute l'élément dans une variable, suivit d'un CRLF
    If _NameStringSimplify($NameToDelete) <> _NameStringSimplify($aFile[$i]) Then
        $StrTmp &= $aFile[$i] & @CRLF
    EndIf
Next

; On réouvre le fichier source, mais pour effacement puis écriture
Local $hFile = FileOpen($File, 2)
; Si erreur, boite de message puis bye bye.
If $hFile = -1 Then
    MsgBox(16, "Erreur", "Erreur d'écriture du fichier de données")
    Exit
EndIf
FileWrite($hFile, $StrTmp) ; on écrit le résulta de la comparaison
FileClose($hFile) ; On ferme le fichier puis bye bye ...
Exit

Func _NameStringSimplify($sInput)
    If $sInput = "" Then Return $sInput
    Local $szInput = $sInput

    $szInput = StringLower($szInput) ; Convertit en minuscule
    $szInput = StringRegExpReplace($szInput, '([\x00-\x40])', "") ; Supprime les caractères ASCII 00 à 40
    $szInput = StringRegExpReplace($szInput, '([\x5B-\x60])', "") ; Supprime les caractères ASCII 5B à 60
    $szInput = StringRegExpReplace($szInput, '([\x7B-\xB0])', "") ; Supprime les caractères ASCII 7B à BF
    $szInput = StringRegExpReplace($szInput, '([\xD7\xF7])', "") ; Supprime les caractères ASCII D7 et F7 (× et ÷)
    $szInput = StringRegExpReplace($szInput, '([\xE6])', "ae") ; Remplace æ par ae

    ; Convertit les caractères ASCII spéciaux DF à FF (les caractères E0 à DE étant passé en minuscule)
    Local $aInputChar = StringSplit("àáâãäåçèéêëìíîïðñòóôõöøùúûüýþÿß", "")
    Local $aOutputChar = StringSplit("aaaaaaceeeeiiiidnoooooouuuuybyb", "")
    For $i = 1 To UBound($aInputChar) - 1
        $szInput = StringReplace($szInput, $aInputChar[$i], $aOutputChar[$i])
    Next

    Return $szInput
EndFunc