[R] saisie prédictive possible dans Combo ??

[jeanmimigab]

Bonjour à tous(tes)

Je vais essayer d'être claire

J'aimerai savoir si il est possible de faire de la saisie prédictive en saisissant du texte dans un combo.
Le combo ouvre un fichier couleurs.txt contenant pour l'exemple des noms de couleurs classées par ordre alphabétique afin d'en lire le contenu.
le but recherché est qu'en saisissant une lettre dans le combo celui-ci s'ouvre sur les noms commençant par cette lettre (par exp si le saisir "R" le combo s'ouvre en se positionnant sur le premier nom commençant par la lettre "R")
Le but étant qu'avec un longue liste de nom, on ne soit pas obligé de descendre tout en bas du combo avec la molette de la sourie pour sélectionner un nom commençant par "Z".

EDIT: Peux-être qu'il existe tout simplement un paramètre à ajouter à "GUICtrlCreateCombo" ?

voici le script qui me sert de base pour les tests

Merci d'avance

Code: [Tout sélectionner] [Déplier/Replier]

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <File.au3>

;édition couleurs.txt si besoin
$txt = "blanc" & @crlf & "bleu" & @crlf & "rouge"
If not FileExists("couleurs.txt") Then FileWrite("couleurs.txt", $txt)


; déclarations
Local $Fich1
$Fich1 = @ScriptDir&'\couleurs.txt'
$iOpen1 = FileOpen($Fich1,0)
$Read1 = FileRead($Fich1)
$strE = StringReplace(StringStripWS($Read1, 3), @crlf, "|")



;gui
#Region ### START Koda GUI section ### Form=bon de retrait_large.kxf
$Form1 = GUICreate("test saisie prédictive", 500, 200, 30, 10)
GUISetBkColor(0xFFFFFF)
$Combo1 = GUICtrlCreateCombo("", 48, 100, 425, 25, BitOR($GUI_SS_DEFAULT_COMBO, 0))
GUICtrlSetData($Combo1, $strE & "|")
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
GuictrlsetLimit($Combo1,1000)


While 1
$msg = GUIGetMsg()
Select
Case $msg = $GUI_EVENT_CLOSE
Exit
EndSelect
WEnd

GeSHi © Extension Codebox Plus

[jeanmimigab]

J'ai trouvé cela qui est pas mal et permet d'ouvrir le CROLL à l'endroit désiré de la liste, mais ensuite je suis obligé d'ouvrir la liste via le CROLL.
Le top serait que la liste s'ouvre d'elle même (sans cliquer sur la flèche du combo) pour que l'utilisateur visualise les mots qui se trouvent au dessus et en dessous dés qu'il tape une lettre.

Code: [Tout sélectionner] [Déplier/Replier]

$Combo1 = GUICtrlCreateCombo("", 48, 100, 425, 25, BitOR($GUI_SS_DEFAULT_COMBO,$WS_HSCROLL,$WS_BORDER,$WS_CLIPSIBLINGS, 0))

GeSHi © Extension Codebox Plus

[amphase]

Bonsoir,

Pourquoi s'arrêter à la première lettre ?
Peut-être que ça d'une part pour la saisie, et ça d'autre part si la liste est longue seraient des pistes à renifler.

[orax]

La fonction _GUICtrlComboBox_AutoComplete ?

[walkson]

Bonjour,
Comme je suis intéressé par le sujet, je me suis penché sur le problème
Je propose ce code mais je trouve que ça manque de souplesse surtout pour la saisie dans le combo (je n'aime pas du tout le sleep(1000) qui laisse à peine le temps d'écrire 2 lettres !) Si quelqu'un a une solution, je suis preneur
[Edit] je suis un âne ! => https://www.autoitscript.fr/forum/viewtopic.php?t=10770

Code: [Tout sélectionner] [Déplier/Replier]

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <File.au3>
#include <Array.au3>
Global $g_idCombo, $list

Example()

Func Example()
   ; Create GUI
   GUICreate("ComboBox Auto Complete", 400, 296)
   $list = GUICtrlCreateEdit("",3,50,395,245)
   $g_idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
   GUISetState(@SW_SHOW)

   ; Add files
   Global $String
   Global $aFileList = _FileListToArray(@WindowsDir, "*.exe")

   GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

   ; Loop until the user exits.
   Do
   Until GUIGetMsg() = $GUI_EVENT_CLOSE
   GUIDelete()
EndFunc   ;==>Example

Func _Edit_Changed()
   Sleep(1000)
   combo()
   _GUICtrlComboBox_ShowDropDown($g_idCombo, True)
EndFunc   ;==>_Edit_Changed
Func combo()

   $string = ""
   $recherch = GUICtrlRead($g_idCombo)
   $len = StringLen($recherch)
   For $i = 1 To $aFileList[0]
      If StringInStr($aFileList[$i],$recherch,0,1,1,$len) > 0 Then
      $string &= $aFileList[$i] & "|"
      EndIf
   Next
   GUICtrlSetData($g_idCombo, $string,"")

EndFunc


Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
   #forceref $hWnd, $iMsg
   Local $hWndFrom, $iIDFrom, $iCode, $hWndCombo
   If Not IsHWnd($g_idCombo) Then $hWndCombo = GUICtrlGetHandle($g_idCombo)
   $hWndFrom = $lParam
   $iIDFrom = BitAND($wParam, 0xFFFF) ; Low Word
   $iCode = BitShift($wParam, 16) ; Hi Word
   Switch $hWndFrom
      Case $g_idCombo, $hWndCombo
         Switch $iCode
            Case $CBN_CLOSEUP ; Sent when the list box of a combo box has been closed
               GUICtrlSetState ( $list, $GUI_FOCUS )
               _DebugPrint("$CBN_CLOSEUP" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                     "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                     "-->Code:" & @TAB & $iCode )
               ; no return value
            Case $CBN_DBLCLK ; Sent when the user double-clicks a string in the list box of a combo box
               _DebugPrint("$CBN_DBLCLK" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                     "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                     "-->Code:" & @TAB & $iCode)
               ; no return value
            Case $CBN_DROPDOWN ; Sent when the list box of a combo box is about to be made visible
               _DebugPrint("$CBN_DROPDOWN" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                     "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                     "-->Code:" & @TAB & $iCode)
               ; no return value
            Case $CBN_EDITCHANGE ; Sent after the user has taken an action that may have altered the text in the edit control portion of a combo box
               _GUICtrlComboBox_ShowDropDown($g_idCombo, False)
               _DebugPrint("$CBN_EDITCHANGE" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                     "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                     "-->Code:" & @TAB & $iCode)
               _Edit_Changed()
               ; no return value
            Case $CBN_EDITUPDATE ; Sent when the edit control portion of a combo box is about to display altered text
               _DebugPrint("$CBN_EDITUPDATE" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                     "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                     "-->Code:" & @TAB & $iCode)
               ; no return value
            Case $CBN_ERRSPACE ; Sent when a combo box cannot allocate enough memory to meet a specific request
               _DebugPrint("$CBN_ERRSPACE" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                     "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                     "-->Code:" & @TAB & $iCode)
               ; no return value
            Case $CBN_KILLFOCUS ; Sent when a combo box loses the keyboard focus
               $val = GUICtrlRead($g_idCombo)
               _DebugPrint("$CBN_KILLFOCUS" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                     "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                     "-->Code:" & @TAB & $iCode)
               _DebugPrint("=>>>>> " & $val)
               ; no return value
            Case $CBN_SELCHANGE ; Sent when the user changes the current selection in the list box of a combo box
               _DebugPrint("$CBN_SELCHANGE" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                     "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                     "-->Code:" & @TAB & $iCode)
               ; no return value
            Case $CBN_SELENDCANCEL ; Sent when the user selects an item, but then selects another control or closes the dialog box
               _DebugPrint("$CBN_SELENDCANCEL" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                     "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                     "-->Code:" & @TAB & $iCode)
               ; no return value
            Case $CBN_SELENDOK ; Sent when the user selects a list item, or selects an item and then closes the list
               _DebugPrint("$CBN_SELENDOK" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                     "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                     "-->Code:" & @TAB & $iCode)
               ; no return value
            Case $CBN_SETFOCUS ; Sent when a combo box receives the keyboard focus
               GUICtrlSetData($g_idCombo, "")
               _DebugPrint("$CBN_SETFOCUS" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                     "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                     "-->Code:" & @TAB & $iCode)
               ; no return value
         EndSwitch
   EndSwitch
   Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Func _DebugPrint($s_Text , $sLine = @ScriptLineNumber)
   GUICtrlSetData($list, _
         "!===========================================================" & @CRLF & _
         "+======================================================" & @CRLF & _
         "-->Line(" & StringFormat("%04d", $sLine) & "):" & @TAB & $s_Text  & @CRLF & _
         "+======================================================" & @CRLF,1)
EndFunc   ;==>_DebugPrint

GeSHi © Extension Codebox Plus

[orax]

[Edit] je suis un âne ! => https://www.autoitscript.fr/forum/viewtopic.php?t=10770

Je viens de voir l'UDF de matwachich. J'avais trouvé une solution différente. Pour ceux que ça intéresse, voici un exemple :

Code: [Tout sélectionner] [Déplier/Replier]

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <File.au3>
#include <GuiComboBoxEx.au3>
#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idCombo

Example()

Func Example()
   ; Create GUI
   GUICreate("ComboBox Auto Complete", 400, 296)
   $g_idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
   GUISetState(@SW_SHOW)

   ; Add files
   _GUICtrlComboBox_BeginUpdate($g_idCombo)
   _GUICtrlComboBox_AddDir($g_idCombo, @WindowsDir & "\*.*")
   _GUICtrlComboBox_EndUpdate($g_idCombo)

   GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

   ; Loop until the user exits.
   Do
   Until GUIGetMsg() = $GUI_EVENT_CLOSE
   GUIDelete()
EndFunc   ;==>Example

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
   #forceref $hWnd, $iMsg
   Local $hWndFrom, $iIDFrom, $iCode, $hWndCombo
   If Not IsHWnd($g_idCombo) Then $hWndCombo = GUICtrlGetHandle($g_idCombo)
   $hWndFrom = $lParam
   $iIDFrom = BitAND($wParam, 0xFFFF) ; Low Word
   $iCode = BitShift($wParam, 16) ; Hi Word
   Switch $hWndFrom
      Case $g_idCombo, $hWndCombo
         Switch $iCode
            Case $CBN_EDITCHANGE ; Sent after the user has taken an action that may have altered the text in the edit control portion of a combo box
               _DebugPrint("$CBN_EDITCHANGE" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                     "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                     "-->Code:" & @TAB & $iCode)
               ; %=========================%
               Local $iRet = _GUICtrlComboBox_AutoComplete2($hWndCombo)
               If $iRet <> $CB_ERR Then
                  $aRet = _GUICtrlComboBox_GetEditSel($hWndCombo)

                  _GUICtrlComboBox_SetCurSel($hWndCombo, $iRet)
                  _GUICtrlComboBox_ShowDropDown($hWndCombo, True)
                  If __GUICtrlComboBox_IsPressed('08') Then $aRet[0] -= 1 ;backspace pressed
                  _GUICtrlComboBox_SetEditSel($hWndCombo, $aRet[0], StringLen(GUICtrlRead($g_idCombo)))
               EndIf
               ; %=========================%
               ; no return value
         EndSwitch
   EndSwitch
   Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Func _GUICtrlComboBox_AutoComplete2($hWnd)
   Local $iRet = $CB_ERR

   If Not IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($hWnd)

   Local $sEditText = _GUICtrlComboBox_GetEditText($hWnd)
   If StringLen($sEditText) Then
      Local $sInputText
      $iRet = _GUICtrlComboBox_FindString($hWnd, $sEditText)
      If ($iRet <> $CB_ERR) Then
         _GUICtrlComboBox_GetLBText($hWnd, $iRet, $sInputText)
         _GUICtrlComboBox_SetEditText($hWnd, $sInputText)
         _GUICtrlComboBox_SetEditSel($hWnd, StringLen($sEditText), StringLen($sInputText))
      EndIf
   EndIf

   Return $iRet
EndFunc   ;==>_GUICtrlComboBox_AutoComplete2

Func _DebugPrint($s_Text, $sLine = @ScriptLineNumber)
   ConsoleWrite( _
         "!===========================================================" & @CRLF & _
         "+======================================================" & @CRLF & _
         "-->Line(" & StringFormat("%04d", $sLine) & "):" & @TAB & $s_Text & @CRLF & _
         "+======================================================" & @CRLF)
EndFunc   ;==>_DebugPrint

GeSHi © Extension Codebox Plus

On peut valider avec la touche Entrée ou Tabulation.

[jeanmimigab]

Hello les amis,

Que de solutions proposées à explorer

Le script de matwachich proposé par walkson me semble vraiment pas mal, je vois essayer de l'adapter à mon script.

En tout cas merci à tous(tes) pour vos conseils !

@Bientôt

[jeanmimigab]

Bonjours à tous(tes)

@orax, je n'ai pas vu ton message hier car on rédigeait nos messages en même temps

J'hésite entre ton exemple et celui de matwachich car les deux sont intéressant.

Le tient ouvre la liste complète dès que je tape une lettre et cela permet donc de visualiser l'amont et l'aval de la cible ce qui est appréciable lors d'une recherche.

celui de matwachich rassemble tous les résultats commençant par la lettre tapée, mais l’inconvénient et qui l'est impossible de retrouver la liste complète.
En effet quelle que soit la recherche, il faut décocher la case "active" pour retrouver la liste complète.
L’idéal serait qu'en effaçant le contenu du combo, la liste complète soit de nouveau visible en cliquant sur le dérouleur, mais j'ai testé plein de solutions tels que de mettre une condition dans la fonction "_FillFunc" ( genre si le combo est vide retour à l'état initial du combo, mais cela ne fonctionne pas)

Je remet le code de matwachich réduit à un seul combo pour une meilleure lisibilité afin de savoir si quelqu'un(e) trouve une solution.
De mon côté je continu à chercher

Merci d'avance

Code: [Tout sélectionner] [Déplier/Replier]

#NoTrayIcon
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#include "ComboAutoFill.au3"

Local $Fich1
$Fich1 = @ScriptDir&'\couleurs.txt'
$iOpen1 = FileOpen($Fich1,0)
$Read1 = FileRead($Fich1)
Global $__g_aItems1 = StringSplit(StringStripWS($Read1, 3), @crlf, "|")


#Region ### START Koda GUI section ###
$hGUI = GUICreate("Example", 458, 55)
$iCombo1 = GUICtrlCreateCombo("", 80, 16, 201, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL,$WS_VSCROLL))
   GUICtrlSetFont(-1, 12, 400, 0, "Cambria")
$Check1 = GUICtrlCreateCheckbox("Active", 304, 20, 97, 17)
   GUICtrlSetFont(-1, 12, 400, 0, "Cambria")
   GUICtrlSetState(-1, $GUI_CHECKED)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Local $AdvCombo1 = _ComboAutoFill_Create($hGUI, $iCombo1, "_FillFunc")

While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
      Case $GUI_EVENT_CLOSE
         Exit
      Case $Check1
         If GUICtrlRead($Check1) = $GUI_CHECKED Then
            _ComboAutoFill_SetActive($AdvCombo1, 1)
         Else
            _ComboAutoFill_SetActive($AdvCombo1, 0)
         EndIf
   EndSwitch
WEnd

Func _FillFunc($iComboID, $sSearch, $iPartial)
   Local $aItems = Eval('__g_aItems' & $iComboID) ; on selectionne la liste à prendre en compte selon le comboBox
   ; ---
   Local $aRet[1] = [0]
   For $i = 1 To $aItems[0]
      If _
         Not $sSearch Or _ ; Rien à rechercher, donc on prend tout
         ($iPartial And StringInStr($aItems[$i], $sSearch)) Or _ ; recherche partielle
         (Not $iPartial And StringLeft($aItems[$i], StringLen($sSearch)) = $sSearch) _ ; recherche précise (du début de l'item)
      Then
         ReDim $aRet[$aRet[0] + 2]
         $aRet[0] += 1
         $aRet[$aRet[0]] = $aItems[$i]
      EndIf
   Next
   Return $aRet
EndFunc

GeSHi © Extension Codebox Plus

[orax]

L’idéal serait qu'en effaçant le contenu du combo, la liste complète soit de nouveau visible

Dans ComboBoxAutoFill.au3, ligne 126 :

Code: [Tout sélectionner] [Déplier/Replier]

Func __ComboAutoFill_OnChange($iIndex, $sText)
;~    If $sText And __ComboAutoFill_Fill($iIndex, $sText) Then
   If __ComboAutoFill_Fill($iIndex, $sText) Then

GeSHi © Extension Codebox Plus

[jeanmimigab]

Bonsoir orax,

C'est effectivement à mon avis le seul moyen et il est "manuel", je me demande juste si il est possible de faire en sorte que le combo retrouve ses paramètres initiaux lorsque l'on efface son contenu ( car même si la case "active" est cochée, avant de saisir quoi que ce soit dans le combo, la liste complète est disponible. par contre dès que l'on se sert de la saisie prédictive, il n'est plus possible de retrouver cette fameuse liste complète (même si j'efface le contenu du combo).
Si je n'y arrive pas, je conserverai la checkbox car dans le fonctionnement de mon programme je doit impérativement récupérer la liste complète si l’utilisateur ne trouve pas ce qu'il veut en utilisant la saisie prédictive.

En tout cas, merci pour votre aide et vos conseils

bonne soirée

[orax]

J'ai un peu modifié mon message #9 parce que je pense que je n'ai pas été compris.
Le code que j'avais mis est une solution au problème, il faut modifier le fichier ComboBoxAutoFill.au3 (ligne 126).

[jeanmimigab]

holala qu'elle quiche ! je n'avait pas compris qu'il fallait modifier ComboBoxAutoFill.au3, je m'entêtais à modifier mon code

Effectivement cela fonctionne à merveille maintenant

Bonne soirée et encore merci
@++

[jpascal]

Pour ma part j'utilise ceci :
https://www.autoitscript.com/forum/topi ... t-control/

C'est presque parfait.

En effet, si vous testez et que vous tapez rapidement les deux premières lettres, vous verrez que la seconde n'est pas prise en compte. Ce qui peut vite s'avérer pénible.
A moins que ça soit ma façon de programmer mes GUI :
Je suis en mode "GUIOnEventMode"
et j'utilise basiquement :
While 1
Sleep(100)
WEnd