[..] Combobox commencer à taper au clavier

[Bayo]

Bonjour,

Le sujet à peut-être était traiter mais je sais pas quoi taper pour la recherche.

J'ai une combobox avec une liste d'adhérent et j'aimerai que lorsqu'on commence à taper le nom de l'adhérent que ça le tape entierement quand on appuie sur Tab par exemple.

J'essaye avec les différents styles disponibles mais comment mettre un style sans renseigner la hauteur
GUICtrlCreateCombo("", 230, 200, 150,hauteur,style)
si je met rien pour la hauteur, ça met une erreur
si je met des "" ou une valeur je n'ai plus la flêche pour afficher la combobox.
et je ne sais pas si il y a un style pour faire ce que je veux.

Merci

[jguinch]

Il faut que tu recherches avec les termes autocomplétion ou autocomplete.
Pour la hauteur, tu peux mettre -1

[Bayo]

Merci pour la réponse, j'ai trouvé la fonction _GUICtrlComboBox_AutoComplete() mais l'exmple est très compliqué et encore plus pour mon script

en faite je créer un nombre de combobox prédéfini comme ceci :

► Afficher le texte

For $i = 1 To $nbparticipant

                           
                            Assign("classement" & $i, GUICtrlCreateCombo("", 230, $ajoutclassement, 150))
                            GUICtrlSetData(-1, $listeadherents)
                           
                            $ajoutclassement = $ajoutclassement + 40
                        Next

Je ne vois pas comment intégrer tout l'exemple pour chaque combobox j'ai essayer de faire ça

► Afficher le texte

For $i = 1 To $nbparticipant

                           
                            Assign("classement" & $i, GUICtrlCreateCombo("", 230, $ajoutclassement, 150))
                            GUICtrlSetData(-1, $listeadherents)
                            GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
                       
                            $ajoutclassement = $ajoutclassement + 40
                        Next



Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    Local $hWndFrom, $iIDFrom, $iCode, $hWndCombo
    If Not IsHWnd(Eval("classement"&$i)) Then $hWndCombo = GUICtrlGetHandle(Eval("classement"&$i))
    $hWndFrom = $lParam
    $iIDFrom = BitAND($wParam, 0xFFFF) ; Low Word
    $iCode = BitShift($wParam, 16) ; Hi Word
    Switch $hWndFrom
        Case Eval("classement"&$i), $hWndCombo
            Switch $iCode

                Case $CBN_EDITCHANGE ; Sent after the user has taken an action that may have altered the text in the edit control portion of a combo box
                    _DebugPrint("$CBN_EDITCHANGE" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                            "-->Code:" & @TAB & $iCode)
                    _Edit_Changed()
                    ; no return value

            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Func _DebugPrint($s_Text , $sLine = @ScriptLineNumber)
    ConsoleWrite( _
            "!===========================================================" & @CRLF & _
            "+======================================================" & @CRLF & _
            "-->Line(" & StringFormat("%04d", $sLine) & "):" & @TAB & $s_Text  & @CRLF & _
            "+======================================================" & @CRLF)
EndFunc   ;==>_DebugPrint

Func _Edit_Changed()
    _GUICtrlComboBox_AutoComplete(Eval("classement"&$i))
EndFunc   ;==>_Edit_Changed

Je n'ai pas d'erreur mais ça ne marche pas, est-ce que je suis bien parti?

Merci

[jguinch]

Voilà un petit exemple :

► Afficher le texte

Code : Tout sélectionner

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


GUICreate("ComboBox Auto Complete", 400, 296)
$idCombo1 = GUICtrlCreateCombo("", 2, 2, 396, 296)
$hCombo1 = GUICtrlGetHandle($idCombo1)
For $i = 0 To 100 Step 10
    GUICtrlSetData($idCombo1, $i & " participants")
Next

$idCombo2 = GUICtrlCreateCombo("", 2, 50, 396, 296)
$hCombo2 = GUICtrlGetHandle($idCombo2)
For $i = 1 To 10
    GUICtrlSetData($idCombo2, $i & " euro(s)")
Next

GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")


Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()


Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    Local $hWndFrom = $lParam
    Local $iCode = BitShift($wParam, 16)
    
    Switch $hWndFrom
        Case $hCombo1, $hCombo2
            Switch $iCode
                Case $CBN_EDITCHANGE
                    _GUICtrlComboBox_AutoComplete($hWndFrom)
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

 

[Bayo]

Ok merci j'essaye ça, je comprend mon erreur. Au lieu de récupérer l'Handle des combos, j'utilisais leur variable $idcombo1 dans ton exemple. je vais essayer de l'adapter à mes comboboxs dynamiques.

[Bayo]

Bon ben je n'y arrive pas, je ne comprend pas comment l'adapter avec mes combo dynamique

j'en suis là avec ton exemple mais ça ne marche pas

► Afficher le texte

For $i = 1 To $nbparticipant
Assign("classement" & $i, GUICtrlCreateCombo("", 230, $ajoutclassement, 150))
GUICtrlSetData(-1, $listeadherents)
Assign("hclassement" & $i,GUICtrlGetHandle(Eval("classement" & $i)))
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
$ajoutclassement = $ajoutclassement + 40
Next

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
#forceref $hWnd, $iMsg
Local $hWndFrom = $lParam
Local $iCode = BitShift($wParam, 16)
Switch $hWndFrom
Case Eval("hclassement"&$i)
Switch $iCode
Case $CBN_EDITCHANGE
_GUICtrlComboBox_AutoComplete($hWndFrom)
EndSwitch
EndSwitch
Return $GUI_RUNDEFMSG
EndFunc ;==>WM_COMMAND

Eval("hclassement"&$i) fonctionne bien dans la boucle For mais arriver dans la fonction il sont vide mais je ne comprend pas comment mettre le Case avec tout les Handle dynamiquement.

[mikell]

Tu tiens absolument aux combos ? sinon ça c'est pas mal

► Afficher le texte

Code : Tout sélectionner

; http://www.autoitscript.com/forum/topic/158070-autocomplete-input-text/

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <ListBoxConstants.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

Global $aPrenoms[8] = ["Alain", "André", "Albert", "Bernard", "Beatrice", "Antoine", "Charles", "Caroline"]
Global $aNoms[8] = ["Dupont", "David", "Martin", "Morin", "Dubois", "Lagrange", "Laborie", "Legrand"]

Global $hList, $idCurInput, $sCurrInput = "", $hListGUI = -1

$hGUI = GUICreate("Test", 200, 200)
GUICtrlCreateLabel('test avec les lettres "a, b, c" ', 10, 10, 180, 20)
$hInput = GUICtrlCreateInput("", 10, 30, 180, 20)
GUICtrlCreateLabel('test avec les lettres "a, b, c" ', 10, 70, 180, 20)
$hInput2 = GUICtrlCreateInput("", 10, 90, 180, 20)
GUICtrlCreateLabel('test avec les lettres "d, l, m" ', 10, 130, 180, 20)
$hInput3 = GUICtrlCreateInput("", 10, 150, 180, 20)
GUISetState(@SW_SHOW, $hGUI)

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

While 1
  Switch GUIGetMsg()
    Case $GUI_EVENT_CLOSE
        ExitLoop
  EndSwitch
WEnd



Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
   #forceref $hWnd, $Msg, $lParam
    Local $IdFrom = BitAnd($wParam, 0x0000FFFF)
    Local $iCode = BitShift($wParam, 16)
    Switch $IdFrom
       Case $hInput, $hInput2, $hInput3  
          Switch $iCode
            Case $EN_UPDATE
               $idCurInput = $IdFrom
                _Update($idCurInput)
          EndSwitch
       Case $hList
         _Update($idCurInput)
    EndSwitch
   Return $GUI_RUNDEFMSG
EndFunc


Func _Update($_input)
    If GUICtrlRead($_Input) <> $sCurrInput Then 
        $sCurrInput = GUICtrlRead($_Input)
        If $hListGUI <> -1 Then ; List is visible.
             GUIDelete($hListGUI)
             $hListGUI = -1
        EndIf

        Local $_array
        Switch $_input   
            Case $hInput
                 $_array = $aPrenoms
            Case $hInput2
                 $_array = $aPrenoms
            Case $hInput3
                 $_array = $aNoms
        EndSwitch
        $hList = _PopupSelector($hGUI, $hListGUI, $_Input, _CheckInputText($_Input, $_array)) 
    EndIf

    Local $sChosen
    If $hList <> -1 Then $sChosen = GUICtrlRead($hList)
    If $sChosen <> "" Then
       GuiCtrlSetData($_Input, $sChosen)
       $sCurrInput = GUICtrlRead($_Input)
       GUIDelete($hListGUI)
       $hListGUI = -1
    EndIf
EndFunc  ;==>_Update


Func _PopupSelector($hMainGUI, ByRef $hListGUI, $_Input, $sCurr_List)
    Local $hList = -1
    If $sCurr_List = "" Then Return $hList

    Local $pos = ControlGetPos($hMainGUI, "", $_Input)
    $hListGUI = GUICreate("", 280, 160, $pos[0], $pos[1]+$pos[3], $WS_POPUP, _ 
        BitOR($WS_EX_TOOLWINDOW, $WS_EX_TOPMOST, $WS_EX_MDICHILD), $hMainGUI)
    $hList = GUICtrlCreateList("", 0, 0, 280, 150, BitOR(0x00100000, 0x00200000))
    GUICtrlSetData($hList, $sCurr_List)

    StringReplace($sCurr_List, "|", "|")
    Local $iCurrHeight = @extended * GUICtrlSendMsg($hList, $LB_GETITEMHEIGHT, 0, 0) + 10
    WinMove($hListGUI, "", Default, Default, Default, $iCurrHeight)
    GUICtrlSetPos($hList, 0, 0, 150, $iCurrHeight)

    GUISetControlsVisible($hListGUI) ; To Make Control Visible And Window Invisible.
    GUISetState(@SW_SHOWNOACTIVATE, $hListGUI)
    Return $hList
EndFunc   ;==>_PopupSelector


Func _CheckInputText($_Input, $array)
   Local $sPartialData = ""
   Local $aSelected = _GetSelectionPointers($_Input)
    If (IsArray($aSelected)) And ($aSelected[0] <= $aSelected[1]) Then
        $sCurrInput = GUICtrlRead($_Input)
        Local $aSplit = StringSplit(StringLeft($sCurrInput, $aSelected[0]), " ")
        $aSelected[0] -= StringLen($aSplit[$aSplit[0]])
        If $aSplit[$aSplit[0]] <> "" Then
            For $A = 0 To UBound($array)-1
                If StringLeft($array[$A], StringLen($aSplit[$aSplit[0]])) = $aSplit[$aSplit[0]] _ 
                And $array[$A] <> $aSplit[$aSplit[0]] Then
                    $sPartialData &= $array[$A] & "|"
                EndIf
            Next
        EndIf
    EndIf
    Return $sPartialData
EndFunc   ;==>_CheckInputText


Func _GetSelectionPointers($hEdit)
    Local $aReturn[2] = [0, 0]
    Local $aSelected = GUICtrlRecvMsg($hEdit, 0x00B0) ; $EM_GETSEL.
    If IsArray($aSelected) Then
        $aReturn[0] = $aSelected[0]
        $aReturn[1] = $aSelected[1]
    EndIf
    Return $aReturn
EndFunc   ;==>_GetSelectionPointers


Func GUISetControlsVisible($hWnd) ; By Melba23.
    Local $aControlGetPos = 0, $hCreateRect = 0, $hRectRgn = _WinAPI_CreateRectRgn(0, 0, 0, 0)
    Local $iLastControlID = _WinAPI_GetDlgCtrlID(GUICtrlGetHandle(-1))
    For $i = 3 To $iLastControlID
        $aControlGetPos = ControlGetPos($hWnd, '', $i)
        If IsArray($aControlGetPos) = 0 Then ContinueLoop
        $hCreateRect = _WinAPI_CreateRectRgn($aControlGetPos[0], $aControlGetPos[1], _ 
            $aControlGetPos[0] + $aControlGetPos[2], $aControlGetPos[1] + $aControlGetPos[3])
        _WinAPI_CombineRgn($hRectRgn, $hCreateRect, $hRectRgn, 2)
        _WinAPI_DeleteObject($hCreateRect)
    Next
    _WinAPI_SetWindowRgn($hWnd, $hRectRgn, True)
    _WinAPI_DeleteObject($hRectRgn)
EndFunc   ;==>GUISetControlsVisible

 

[Bayo]

Merci.
En effet c'est pas mal aussi, je vais le montrer à ceux de mon club pour voir ce qu'ils préfèrent. et s'ils accrochent sur ça j'essayerai de le faire.
Sinon tu n'a pas de solution pour mes combo dynamique avec autocomplete?

[orax]

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND") n'a pas besoin d'être dans la boucle For/Next. Il faut mettre ça avant, une fois c'est tout.

Code : Tout sélectionner

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    Local $hWndFrom = $lParam
    Local $iCode = BitShift($wParam, 16)
    Switch $hWndFrom
        Case Eval("hclassement" &$i) ; <=== ne peut marcher puisque $i aura toujours la même valeur

[mikell]

Personnellement je suis pas fan de _GUICtrlComboBox_AutoComplete() , tu tapes une lettre et ça envoie le mot mais si tu as plusieurs mots qui commencent par la même lettre c'est la misère
La logique et la souplesse d'utilisation demanderaient plutôt une solution plus "intelligente"

[Bayo]

Oui mikell, ta solution est intéressante mais je me retrouve avec le même problème. Comment faire pour insérer mes Combos dynamiques ou dans ton script des inputs dynamiques dans la Func WM_COMMAND?

[mikell]

Comment faire pour insérer (..) des inputs dynamiques dans la Func WM_COMMAND?

Je comprends pas la question
Dans le code la fonction WM_COMMAND surveille la notification $EN_UPDATE sur les 3 inputs, mais tu peux très bien y rajouter des instructions pour surveiller des évènements sur d'autres controles

[Bayo]

si tu regarde mon code, je génère des combo(ou input) avec des Assign() dans une boucle et je ne vois pas comment après les mettre dynamiquement dans la fonction WM_COMMAND.
Si je pouvais rajouter des paramètres à cette fonction je pourrais indiquer toutes mes boxs mais là je n'y arrive pas.

[mikell]

Ah OK
Personnellement je trouve les Assign casse-gueule et je préfère une array
Voilà le même code avec 3 inputs mais ce nombre peut très bien être défini dans le script
Il faut juste dans les Switch utiliser la syntaxe "Case $var_0 to $var_n"
J'ai pas testé mais avec des assign ça devrait être :
Case Eval("hclassement0") to Eval("hclassement" & $n)

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <ListBoxConstants.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

Global $aPrenoms[8] = ["Alain", "André", "Albert", "Bernard", "Beatrice", "Antoine", "Charles", "Caroline"]
Global $aNoms[8] = ["Dupont", "David", "Martin", "Morin", "Dubois", "Lagrange", "Laborie", "Legrand"]

Global $hList, $idCurInput, $sCurrInput = "", $hListGUI = -1
Global $hInput[3]

$hGUI = GUICreate("Test", 200, 200)
GUICtrlCreateLabel('test avec les lettres "a, b, c" ', 10, 10, 180, 20)
$hInput[0] = GUICtrlCreateInput("", 10, 30, 180, 20)
GUICtrlCreateLabel('test avec les lettres "a, b, c" ', 10, 70, 180, 20)
$hInput[1] = GUICtrlCreateInput("", 10, 90, 180, 20)
GUICtrlCreateLabel('test avec les lettres "d, l, m" ', 10, 130, 180, 20)
$hInput[2] = GUICtrlCreateInput("", 10, 150, 180, 20)
GUISetState(@SW_SHOW, $hGUI)

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

While 1
  Switch GUIGetMsg()
    Case $GUI_EVENT_CLOSE
        ExitLoop
  EndSwitch
WEnd



Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
   #forceref $hWnd, $Msg, $lParam
    Local $IdFrom = BitAnd($wParam, 0x0000FFFF)
    Local $iCode = BitShift($wParam, 16)
    Switch $IdFrom
       Case $hInput[0] to $hInput[2]
          Switch $iCode
            Case $EN_UPDATE
               $idCurInput = $IdFrom
                _Update($idCurInput)
          EndSwitch
       Case $hList
         _Update($idCurInput)
    EndSwitch
   Return $GUI_RUNDEFMSG
EndFunc


Func _Update($_input)
    If GUICtrlRead($_Input) <> $sCurrInput Then
        $sCurrInput = GUICtrlRead($_Input)
        If $hListGUI <> -1 Then ; List is visible.
             GUIDelete($hListGUI)
             $hListGUI = -1
        EndIf

        Local $_array
        Switch $_input  
            Case $hInput[0], $hInput[1]
                 $_array = $aPrenoms
            Case $hInput[2]
                 $_array = $aNoms
        EndSwitch
        $hList = _PopupSelector($hGUI, $hListGUI, $_Input, _CheckInputText($_Input, $_array))
    EndIf

    Local $sChosen
    If $hList <> -1 Then $sChosen = GUICtrlRead($hList)
    If $sChosen <> "" Then
       GuiCtrlSetData($_Input, $sChosen)
       $sCurrInput = GUICtrlRead($_Input)
       GUIDelete($hListGUI)
       $hListGUI = -1
    EndIf
EndFunc  ;==>_Update


Func _PopupSelector($hMainGUI, ByRef $hListGUI, $_Input, $sCurr_List)
    Local $hList = -1
    If $sCurr_List = "" Then Return $hList

    Local $pos = ControlGetPos($hMainGUI, "", $_Input)
    $hListGUI = GUICreate("", 280, 160, $pos[0], $pos[1]+$pos[3], $WS_POPUP, _
        BitOR($WS_EX_TOOLWINDOW, $WS_EX_TOPMOST, $WS_EX_MDICHILD), $hMainGUI)
    $hList = GUICtrlCreateList("", 0, 0, 280, 150, BitOR(0x00100000, 0x00200000))
    GUICtrlSetData($hList, $sCurr_List)

    StringReplace($sCurr_List, "|", "|")
    Local $iCurrHeight = @extended * GUICtrlSendMsg($hList, $LB_GETITEMHEIGHT, 0, 0) + 10
    WinMove($hListGUI, "", Default, Default, Default, $iCurrHeight)
    GUICtrlSetPos($hList, 0, 0, 150, $iCurrHeight)

    GUISetControlsVisible($hListGUI) ; To Make Control Visible And Window Invisible.
    GUISetState(@SW_SHOWNOACTIVATE, $hListGUI)
    Return $hList
EndFunc   ;==>_PopupSelector


Func _CheckInputText($_Input, $array)
   Local $sPartialData = ""
   Local $aSelected = _GetSelectionPointers($_Input)
    If (IsArray($aSelected)) And ($aSelected[0] <= $aSelected[1]) Then
        $sCurrInput = GUICtrlRead($_Input)
        Local $aSplit = StringSplit(StringLeft($sCurrInput, $aSelected[0]), " ")
        $aSelected[0] -= StringLen($aSplit[$aSplit[0]])
        If $aSplit[$aSplit[0]] <> "" Then
            For $A = 0 To UBound($array)-1
                If StringLeft($array[$A], StringLen($aSplit[$aSplit[0]])) = $aSplit[$aSplit[0]] _
                And $array[$A] <> $aSplit[$aSplit[0]] Then
                    $sPartialData &= $array[$A] & "|"
                EndIf
            Next
        EndIf
    EndIf
    Return $sPartialData
EndFunc   ;==>_CheckInputText


Func _GetSelectionPointers($hEdit)
    Local $aReturn[2] = [0, 0]
    Local $aSelected = GUICtrlRecvMsg($hEdit, 0x00B0) ; $EM_GETSEL.
    If IsArray($aSelected) Then
        $aReturn[0] = $aSelected[0]
        $aReturn[1] = $aSelected[1]
    EndIf
    Return $aReturn
EndFunc   ;==>_GetSelectionPointers


Func GUISetControlsVisible($hWnd) ; By Melba23.
    Local $aControlGetPos = 0, $hCreateRect = 0, $hRectRgn = _WinAPI_CreateRectRgn(0, 0, 0, 0)
    Local $iLastControlID = _WinAPI_GetDlgCtrlID(GUICtrlGetHandle(-1))
    For $i = 3 To $iLastControlID
        $aControlGetPos = ControlGetPos($hWnd, '', $i)
        If IsArray($aControlGetPos) = 0 Then ContinueLoop
        $hCreateRect = _WinAPI_CreateRectRgn($aControlGetPos[0], $aControlGetPos[1], _
            $aControlGetPos[0] + $aControlGetPos[2], $aControlGetPos[1] + $aControlGetPos[3])
        _WinAPI_CombineRgn($hRectRgn, $hCreateRect, $hRectRgn, 2)
        _WinAPI_DeleteObject($hCreateRect)
    Next
    _WinAPI_SetWindowRgn($hWnd, $hRectRgn, True)
    _WinAPI_DeleteObject($hRectRgn)
EndFunc   ;==>GUISetControlsVisible

 

[Bayo]

J'ai réussi à adapter ton code au mien, mais j'ai un peu de mal à le suivre. J'ai 1 soucis et un rajout si possible.

Quand je clique sur un nom dans la liste, il ne se met pas dans l'input, la liste reste visible et si je clique sur un autre input et que je tape la même lettre, le nom que j'ai selectionner se met dans cette input. (Exemple : dans le premier input je tape A et je sélectionne Alain, je vais ensuite dans le 2ème Input et je tape A et Alain se met dans cette input)
Je ne vois pas d'où viens l'erreur.

Autre chose: est ce possible de rajouter quand je clique sur les fleche du bas et du haut que je me balade dans la liste et si je fais Entrée ça le met dans l'Input.

Je te met ton code adapter au mien, j'espère que ça va suffire.

► Afficher le texte

Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
#forceref $hWnd, $Msg, $lParam
Local $IdFrom = BitAnd($wParam, 0x0000FFFF)
Local $iCode = BitShift($wParam, 16)
Switch $IdFrom
Case Eval("hclassement0") to Eval("hclassement"&GUICtrlRead($inputnbparticipant))
Switch $iCode
Case $EN_UPDATE
$idCurInput = $IdFrom
_Update($idCurInput)
EndSwitch
Case $hList
_Update($idCurInput)
EndSwitch
Return $GUI_RUNDEFMSG
EndFunc


Func _Update($_Input)
If GUICtrlRead($_Input) <> $sCurrInput Then
$sCurrInput = GUICtrlRead($_Input)
If $hListGUI <> -1 Then ; List is visible.
GUIDelete($hListGUI)
$hListGUI = -1
EndIf

Local $_array
Switch $_Input
Case Eval("hclassement0") to Eval("hclassement"&GUICtrlRead($inputnbparticipant))
$_array = $tableadherent

EndSwitch
$hList = _PopupSelector($creationetape2, $hListGUI, $_Input, _CheckInputText($_Input, $_array))
EndIf

Local $sChosen
If $hList <> -1 Then $sChosen = GUICtrlRead($hList)
If $sChosen <> "" Then
GuiCtrlSetData($_Input, $sChosen)
$sCurrInput = GUICtrlRead($_Input)
GUIDelete($hListGUI)
$hListGUI = -1
EndIf
EndFunc ;==>_Update


Func _PopupSelector($hMainGUI, ByRef $hListGUI, $_Input, $sCurr_List)
Local $hList = -1
If $sCurr_List = "" Then Return $hList

Local $pos = ControlGetPos($hMainGUI, "", $_Input)
$hListGUI = GUICreate("", 280, 160, $pos[0], $pos[1]+$pos[3], $WS_POPUP, _
BitOR($WS_EX_TOOLWINDOW, $WS_EX_TOPMOST, $WS_EX_MDICHILD), $hMainGUI)
$hList = GUICtrlCreateList("", 0, 0, 280, 150, BitOR(0x00100000, 0x00200000))
GUICtrlSetData($hList, $sCurr_List)

StringReplace($sCurr_List, "|", "|")
Local $iCurrHeight = @extended * GUICtrlSendMsg($hList, $LB_GETITEMHEIGHT, 0, 0) + 10
WinMove($hListGUI, "", Default, Default, Default, $iCurrHeight)
GUICtrlSetPos($hList, 0, 0, 150, $iCurrHeight)

GUISetControlsVisible($hListGUI) ; To Make Control Visible And Window Invisible.
GUISetState(@SW_SHOWNOACTIVATE, $hListGUI)
Return $hList
EndFunc ;==>_PopupSelector


Func _CheckInputText($_Input, $array)
Local $sPartialData = ""
Local $aSelected = _GetSelectionPointers($_Input)
If (IsArray($aSelected)) And ($aSelected[0] <= $aSelected[1]) Then
$sCurrInput = GUICtrlRead($_Input)
Local $aSplit = StringSplit(StringLeft($sCurrInput, $aSelected[0]), " ")
$aSelected[0] -= StringLen($aSplit[$aSplit[0]])
If $aSplit[$aSplit[0]] <> "" Then
For $A = 0 To UBound($array)-1
If StringLeft($array[$A], StringLen($aSplit[$aSplit[0]])) = $aSplit[$aSplit[0]] _
And $array[$A] <> $aSplit[$aSplit[0]] Then
$sPartialData &= $array[$A] & "|"
EndIf
Next
EndIf
EndIf
Return $sPartialData
EndFunc ;==>_CheckInputText


Func _GetSelectionPointers($hEdit)
Local $aReturn[2] = [0, 0]
Local $aSelected = GUICtrlRecvMsg($hEdit, 0x00B0) ; $EM_GETSEL.
If IsArray($aSelected) Then
$aReturn[0] = $aSelected[0]
$aReturn[1] = $aSelected[1]
EndIf
Return $aReturn
EndFunc ;==>_GetSelectionPointers


Func GUISetControlsVisible($hWnd) ; By Melba23.
Local $aControlGetPos = 0, $hCreateRect = 0, $hRectRgn = _WinAPI_CreateRectRgn(0, 0, 0, 0)
Local $iLastControlID = _WinAPI_GetDlgCtrlID(GUICtrlGetHandle(-1))
For $i = 3 To $iLastControlID
$aControlGetPos = ControlGetPos($hWnd, '', $i)
If IsArray($aControlGetPos) = 0 Then ContinueLoop
$hCreateRect = _WinAPI_CreateRectRgn($aControlGetPos[0], $aControlGetPos[1], _
$aControlGetPos[0] + $aControlGetPos[2], $aControlGetPos[1] + $aControlGetPos[3])
_WinAPI_CombineRgn($hRectRgn, $hCreateRect, $hRectRgn, 2)
_WinAPI_DeleteObject($hCreateRect)
Next
_WinAPI_SetWindowRgn($hWnd, $hRectRgn, True)
_WinAPI_DeleteObject($hRectRgn)
EndFunc ;==>GUISetControlsVisible

Merci.

[mikell]

Je ne peux rien te dire sur ton code tout simplement parce qu'il n'est pas complet et que je ne peux donc pas le tester
Tout ce que je peux te proposer c'est le code suivant, qui fonctionne avec un nombre prédéterminé d'inputs (dans une array) et avec les touches haut/bas/enter pour la liste

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <ListBoxConstants.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

Global $hList = -1, $idCurInput, $sCurrInput = "", $hListGUI = -1, $iCurrIndex = -1
Global $aPrenoms[8] = ["Alain", "André", "Albert", "Bernard", "Beatrice", "Antoine", "Charles", "Caroline"]

Global $h = 10, $n = 4, $hInput[$n]   ;<<<<<<

$hGUI = GUICreate("Test", 200, $h+($n*60))
For $i = 0 to $n-1
  GUICtrlCreateLabel('test avec les lettres "a, b, c" ', 10, $h+($i*60), 180, 20)
  $hInput[$i] = GUICtrlCreateInput("", 10, $h+20+($i*60), 180, 20)
Next
$hUP = GUICtrlCreateDummy()
$hDOWN = GUICtrlCreateDummy()
$hENTER = GUICtrlCreateDummy()
Dim $AccelKeys[3][2] = [["{UP}", $hUP], ["{DOWN}", $hDOWN], ["{ENTER}", $hENTER]]
GUISetState(@SW_SHOW, $hGUI)

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")


While 1
  Switch GUIGetMsg()
    Case $GUI_EVENT_CLOSE
        ExitLoop
     Case $hUP
          _UpDown("up")
     Case $hDOWN
          _UpDown("down")
    Case $hENTER
         If $hListGUI <> -1 And $iCurrIndex <> -1 Then 
                GuiCtrlSetData($idCurInput, GUICtrlRead($hList))
                GUIDelete($hListGUI)
                $hListGUI = -1
                GUISetAccelerators("", $hGUI)
         EndIf
  EndSwitch
WEnd



Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
  ; #forceref $hWnd, $Msg, $lParam
    Local $IdFrom = BitAnd($wParam, 0x0000FFFF)
    Local $iCode = BitShift($wParam, 16)
    Switch $IdFrom
       Case $hInput[0] to $hInput[$n-1]
          Switch $iCode
            Case $EN_UPDATE
                GUISetAccelerators($AccelKeys)
                $iCurrIndex = -1
                $idCurInput = $IdFrom
                _Update($idCurInput)
          EndSwitch

       Case $hList
         _Update($idCurInput)
    EndSwitch
   Return $GUI_RUNDEFMSG
EndFunc


Func _UpDown($var)
         If $hListGUI <> -1 Then    ; List is visible.
            Local $count = GUICtrlSendMsg($hList, $LB_GETCOUNT, 0, 0)
            If $count = 1 Then 
                GUICtrlSendMsg($hList, $LB_SETCURSEL, 0, 0)
                GuiCtrlSetData($idCurInput, GUICtrlRead($hList))
                GUIDelete($hListGUI)
                $hListGUI = -1
                GUISetAccelerators("", $hGUI)
           Else
                If $var = "up" Then
                    $iCurrIndex =  ($iCurrIndex < 1) ? $count-1 : ($iCurrIndex-1)
                Else   
                    $iCurrIndex =  ($iCurrIndex > $count-2) ? 0 : ($iCurrIndex+1)
                EndIf
                GUICtrlSendMsg($hList, $LB_SETCURSEL, $iCurrIndex, 0)
           EndIf
       Else
           GUISetAccelerators("", $hGUI)
       EndIf
EndFunc


Func _Update($_input)
    If GUICtrlRead($_Input) <> $sCurrInput Then
        $sCurrInput = GUICtrlRead($_Input)
        If $hListGUI <> -1 Then ; List is visible.
             GUIDelete($hListGUI)
             $hListGUI = -1
        EndIf

        Local $_array
        Switch $_input  
           Case $hInput[0] to $hInput[$n-1]
                 $_array = $aPrenoms
        EndSwitch

        $hList = _PopupSelector($hGUI, $hListGUI, $_Input, _CheckInputText($_Input, $_array))
    EndIf

    Local $sChosen
    If $hList <> -1 Then 
       $sChosen = GUICtrlRead($hList)
       If $sChosen <> "" Then
          GuiCtrlSetData($_Input, $sChosen)
          $sCurrInput = GUICtrlRead($_Input)
          GUIDelete($hListGUI)
          $hListGUI = -1
       EndIf
   EndIf

EndFunc  ;==>_Update




Func _PopupSelector($hMainGUI, ByRef $hListGUI, $_Input, $sCurr_List)
    Local $hList = -1
    If $sCurr_List = "" Then Return $hList

    Local $pos = ControlGetPos($hMainGUI, "", $_Input)
    $hListGUI = GUICreate("", 280, 160, $pos[0], $pos[1]+$pos[3], $WS_POPUP, _
        BitOR($WS_EX_TOOLWINDOW, $WS_EX_TOPMOST, $WS_EX_MDICHILD), $hMainGUI)
    $hList = GUICtrlCreateList("", 0, 0, 280, 150, BitOR($LBS_STANDARD, $WS_HSCROLL))
    GUICtrlSetData($hList, $sCurr_List)

    Local $count = GUICtrlSendMsg($hList, $LB_GETCOUNT, 0, 0)
    Local $iCurrHeight = $count * GUICtrlSendMsg($hList, $LB_GETITEMHEIGHT, 0, 0) + 10
    WinMove($hListGUI, "", Default, Default, Default, $iCurrHeight)
    GUICtrlSetPos($hList, 0, 0, 150, $iCurrHeight)

    GUISetControlsVisible($hListGUI) ; To Make Control Visible And Window Invisible.
    GUISetState(@SW_SHOWNOACTIVATE, $hListGUI)
    Return $hList
EndFunc   ;==>_PopupSelector


Func _CheckInputText($_Input, $array)
   Local $sPartialData = ""
   Local $aSelected = _GetSelectionPointers($_Input)
    If (IsArray($aSelected)) And ($aSelected[0] <= $aSelected[1]) Then
        $sCurrInput = GUICtrlRead($_Input)
        Local $aSplit = StringSplit(StringLeft($sCurrInput, $aSelected[0]), " ")
        $aSelected[0] -= StringLen($aSplit[$aSplit[0]])
        If $aSplit[$aSplit[0]] <> "" Then
            For $A = 0 To UBound($array)-1
                If StringLeft($array[$A], StringLen($aSplit[$aSplit[0]])) = $aSplit[$aSplit[0]] _
                And $array[$A] <> $aSplit[$aSplit[0]] Then
                    $sPartialData &= $array[$A] & "|"
                EndIf
            Next
        EndIf
    EndIf
    Return $sPartialData
EndFunc   ;==>_CheckInputText


Func _GetSelectionPointers($hEdit)
    Local $aReturn[2] = [0, 0]
    Local $aSelected = GUICtrlRecvMsg($hEdit, 0x00B0) ; $EM_GETSEL.
    If IsArray($aSelected) Then
        $aReturn[0] = $aSelected[0]
        $aReturn[1] = $aSelected[1]
    EndIf
    Return $aReturn
EndFunc   ;==>_GetSelectionPointers


Func GUISetControlsVisible($hWnd) ; By Melba23.
    Local $aControlGetPos = 0, $hCreateRect = 0, $hRectRgn = _WinAPI_CreateRectRgn(0, 0, 0, 0)
    Local $iLastControlID = _WinAPI_GetDlgCtrlID(GUICtrlGetHandle(-1))
    For $i = 3 To $iLastControlID
        $aControlGetPos = ControlGetPos($hWnd, '', $i)
        If IsArray($aControlGetPos) = 0 Then ContinueLoop
        $hCreateRect = _WinAPI_CreateRectRgn($aControlGetPos[0], $aControlGetPos[1], _
            $aControlGetPos[0] + $aControlGetPos[2], $aControlGetPos[1] + $aControlGetPos[3])
        _WinAPI_CombineRgn($hRectRgn, $hCreateRect, $hRectRgn, 2)
        _WinAPI_DeleteObject($hCreateRect)
    Next
    _WinAPI_SetWindowRgn($hWnd, $hRectRgn, True)
    _WinAPI_DeleteObject($hRectRgn)
EndFunc   ;==>GUISetControlsVisible