[R] Listview_item color dynamique

julie · #1

bonsoir a tous

petit probleme en debut de soiree

pour gerez les changement de couleurs en fonction du changement de place des items dans mon tableaux j'ai fait un petit exemple enfin pour le coup cette partie c'est surtout mikell qui ma beaucoup aider. que je remercie au passage

.

mais voila gros probleme maintenant quand j'y ajoute de la couleur je n'arrive pas a actualiser la couleur en fonction de sa place
Enfaite pour faire simple j'aimerai que quand on deplace un item celui ci garde la couleur qui lui a ete attribuer au debut
hors pour le moment vous pouvez le voir dans l'exemple ci dessous ce n'est pas le cas :/

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <WindowsConstants.au3>
#include <ListviewConstants.au3>
#include <GuiListView.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 537, 241, 284, 165)
$modif_LV = GUICtrlCreateListView("reference|Designation", 8, 12, 461, 214)
$btn_up = GUICtrlCreateButton("plus", 486, 32, 41, 65)
$btn_down = GUICtrlCreateButton("moins", 488, 131, 39, 65)
$itemtab = "article n°"
$bool = true
For $i = 1 To 10
if $bool = true Then
            GUICtrlCreateListViewItem("article n°"&$i & "|" & "desi n°"&$i,$modif_LV)
            GUICtrlSetColor(-1, 0xff0000)
            $bool = False
        Else
            GUICtrlCreateListViewItem("article noir" & "|" & "desi noir",$modif_LV)
            GUICtrlSetColor(-1, 0x000000)
            $bool = True
        EndIf
        Next
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $i_Item = Number(_GUICtrlListView_GetSelectedIndices($modif_LV))
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

            Case $btn_up
                        If $i_Item = 0 Then ContinueLoop ;Or $i_Item = 1
                        _GUICtrlListView_ItemSwap($modif_LV, $i_Item, $i_Item - 1, $btn_up, $btn_down)
                        _GUICtrlListView_SetItemSelected($modif_LV, $i_Item - 1)
                        GUICtrlSetState($modif_LV, $GUI_FOCUS)

                    Case $btn_down
                        If $i_Item = _GUICtrlListView_GetItemCount($modif_LV) - 1 Then ContinueLoop
                        _GUICtrlListView_ItemSwap($modif_LV, $i_Item, $i_Item + 1, $btn_up, $btn_down)
                        _GUICtrlListView_SetItemSelected($modif_LV, $i_Item + 1)
                        GUICtrlSetState($modif_LV, $GUI_FOCUS)

    EndSwitch
WEnd

une idee ?

merci beaucoup

Hugues · #2

Salut, j'ai trouvé ce code sur un forum...

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>
#include <Array.au3>

Global $aList_Array[1]
For $i = 1 To 20
    _ArrayAdd($aList_Array, $i & "-----" & $i & "-----" & $i)
    $aList_Array[0] += 1
Next

; Create dialog
Local $hList_Win = GUICreate("UP/Down ListView", 500, 500, Default, Default, BitOr($WS_POPUPWINDOW, $WS_CAPTION))
    GUISetBkColor(0xCECECE)

; Create list box with no col headers and permit only 1 selection
Local $hListView = GUICtrlCreateListView ("_", 10, 10, 480, 390, $LVS_NOCOLUMNHEADER + $LVS_SINGLESEL, $LVS_EX_FULLROWSELECT )
; Set up alt line colouring
    GUICtrlSetBkColor(-1, $GUI_BKCOLOR_LV_ALTERNATE)
; Set col width
_GUICtrlListView_SetColumnWidth(-1, 0, $LVSCW_AUTOSIZE_USEHEADER)

; Create buttons
Local $hList_Add_Button    = GUICtrlCreateButton("Insert",  170, 410, 80, 30)
Local $hList_Delete_Button  = GUICtrlCreateButton("Delete", 170, 450, 80, 30)
Local $hList_Move_Up_Button   = GUICtrlCreateButton("Move Up",   270, 410, 80, 30)
Local $hList_Move_Down_Button = GUICtrlCreateButton("Move Down", 270, 450, 80, 30)
Local $hList_Cancel_Button  = GUICtrlCreateButton("Cancel", 370, 410, 80, 30)

; Fill listbox, list handles indexed on this dummy
Local $hStart_ID = GUICtrlCreateDummy()

; Fill listbox
; Add placeholders for the list items
    For $i = 1 To 20
        GUICtrlCreateListViewItem($aList_Array[$i], $hListView)
            GUICtrlSetBkColor(-1, 0xCCFFCC)
    Next

; Show dialog
GUISetState(@SW_SHOW, $hList_Win)

While 1

    Local $aMsg = GUIGetMsg(1)

    If $aMsg[1] = $hList_Win Then

        Switch $aMsg[0]
            Case $GUI_EVENT_CLOSE, $hList_Cancel_Button
                Exit
            Case $hList_Add_Button
                List_Item_Insert($aList_Array, $hListView, $hStart_ID)
            Case $hList_Delete_Button
                List_Item_Delete($aList_Array, $hListView, $hStart_ID)
            Case $hList_Move_Up_Button
                List_Item_Up($aList_Array, $hListView, $hStart_ID)
            Case $hList_Move_Down_Button
                List_Item_Down($aList_Array, $hListView, $hStart_ID)
        EndSwitch

    EndIf

Wend

Func List_Item_Insert(ByRef $aList_Array, $hListView, $hStart_ID)

; If list is full, return
If $aList_Array[0] = 20 Then Return

; If list is empty, add first value
If $aList_Array[0] = 0 Then
    $iList_Index = 0
Else
; Get value of listview selection via handle count
    $iList_Index = GUICtrlRead($hListView) - $hStart_ID
; If no selection or out of range assume add to end
    If $iList_Index < 0 Or $iList_Index > $aList_Array[0] Then $iList_Index = $aList_Array[0]
EndIf

; Add tracks to the Playlist
Local $sSelection = InputBox("", "Enter a a value")
If @error Then Return

; Insert in array
_ArrayInsert($aList_Array, $iList_Index + 1, $sSelection)
$aList_Array[0] += 1
; Rewrite list items
For $i = 1 To $aList_Array[0]
    GUICtrlSetData($hStart_ID + $i, $aList_Array[$i])
Next

; Set highlight to inserted item
GUICtrlSetState($hListView, $GUI_FOCUS)
_GUICtrlListView_SetItemSelected ($hListView, $iList_Index)
_GUICtrlListView_EnsureVisible ($hListView, $iList_Index)

EndFunc

; -------

Func List_Item_Delete(ByRef $aList_Array, $hListView, $hStart_ID)

; If list is empty, return
If $aList_Array[0] = 0 Then Return

; Get value of listview selection via handle count
$iList_Index = GUICtrlRead($hListView) - $hStart_ID
; If no selection or out of range
If $iList_Index < 1 Or $iList_Index > $aList_Array[0] Then Return

; Delete from array
_ArrayDelete($aList_Array, $iList_Index)
$aList_Array[0] -= 1

; Rewrite list items
For $i = 1 To $aList_Array[0]
    GUICtrlSetData($hStart_ID + $i, $aList_Array[$i])
Next
; Blank last line
GUICtrlSetData($hStart_ID + $i, "")

; Unselect all items to force selection before next action
_GUICtrlListView_SetItemSelected ($hListView, -1, False)

EndFunc

; -------

Func List_Item_Up(ByRef $aList_Array, $hListView, $hStart_ID)

If $aList_Array[0] < 2 Then Return

; Get value of listview selection via handle count
$iList_Index = GUICtrlRead($hListView) - $hStart_ID
; If already at top or no selection or out of range
If $iList_Index < 2 Or $iList_Index > $aList_Array[0] Then Return

; Swap array elements
_ArraySwap($aList_Array[$iList_Index],  $aList_Array[$iList_Index - 1])

; Rewrite list items
For $i = 1 To $aList_Array[0]
    GUICtrlSetData($hStart_ID + $i, $aList_Array[$i])
Next

; Unselect all items to force selection before next action
_GUICtrlListView_SetItemSelected ($hListView, -1, False)

EndFunc

; -------

Func List_Item_Down(ByRef $aList_Array, $hListView, $hStart_ID)

If $aList_Array[0] < 2 Then Return

; Get value of listview selection via handle count
$iList_Index = GUICtrlRead($hListView) - $hStart_ID
; If already at bottom or no selection or out of range
If $iList_Index < 1 Or $iList_Index > $aList_Array[0] - 1 Then Return

; Swap array elements
_ArraySwap($aList_Array[$iList_Index], $aList_Array[$iList_Index + 1])

; Rewrite list items
For $i = 1 To $aList_Array[0]
    GUICtrlSetData($hStart_ID + $i, $aList_Array[$i])
Next

; Unselect all items to force selection before next action
_GUICtrlListView_SetItemSelected ($hListView, -1, False)

EndFunc

ou bien celui là qui correspondra sûrement plus à tes attentes...

► Afficher le texte

Code : Tout sélectionner

;Demo for _GUICtrlListView_MoveItems() function.
;Just select one (or more) item, and press one of the buttons (Up or Down).

#include <GUIConstants.au3>
#include <WindowsConstants.au3>
#include <ButtonConstants.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <SendMessage.au3>
;

$GUI = GUICreate('Demo for _GUICtrlListView_MoveItems()', 300, 320)

$Up_Button = GUICtrlCreateButton("Up", 20, 20, 24, 24, $BS_ICON)
GUICtrlSetImage(-1, "netcfgx.dll", 1, 0)

$Down_Button = GUICtrlCreateButton("Down", 70, 20, 24, 24, $BS_ICON)
GUICtrlSetImage(-1, "netcfgx.dll", -2, 0)

$ListView = _GUICtrlListView_Create($GUI, "Column1|Column2", 20, 50, 260, 250, _
    BitOR($LVS_SHOWSELALWAYS, $LVS_REPORT), $WS_EX_CLIENTEDGE)

_GUICtrlListView_SetExtendedListViewStyle($ListView, BitOR($LVS_EX_CHECKBOXES, $LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))

$iImage_Size = 14

$hImage = _GUIImageList_Create($iImage_Size, $iImage_Size)

_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($ListView, 0xFF0000, $iImage_Size, $iImage_Size))
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($ListView, 0x00FF00, $iImage_Size, $iImage_Size))
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($ListView, 0x0000FF, $iImage_Size, $iImage_Size))

_GUICtrlListView_SetImageList($ListView, $hImage, 1)

For $i = 0 To 9
    _GUICtrlListView_AddItem($ListView, "Item " & $i+1, Random(0, 2, 1))
    _GUICtrlListView_AddSubItem($ListView, $i, "SubItem " & $i+1, 1, Random(0, 2, 1))
Next

$iRandom_1 = Random(0, 9, 1)
$iRandom_2 = Random(0, 9, 1)

_GUICtrlListView_SetItemChecked($ListView, $iRandom_1, 1)
_GUICtrlListView_SetItemSelected($ListView, $iRandom_1, 1)

_GUICtrlListView_SetItemChecked($ListView, $iRandom_2, 1)
_GUICtrlListView_SetItemSelected($ListView, $iRandom_2, 1)

_SendMessage($ListView, $LVM_SETCOLUMNWIDTH, 0, -1)
_SendMessage($ListView, $LVM_SETCOLUMNWIDTH, 1, -1)

ControlFocus($GUI, "", $ListView)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Up_Button
            _GUICtrlListView_MoveItems($ListView, -1)
            ControlFocus($GUI, "", $ListView)
        Case $Down_Button
            _GUICtrlListView_MoveItems($ListView, 1)
            ControlFocus($GUI, "", $ListView)
    EndSwitch
WEnd

;===============================================================================
; Function Name:    _GUICtrlListView_MoveItems()
; Description:      Moves Up or Down selected item(s) in ListView.
;
; Parameter(s):     $hListView          - ControlID or Handle of ListView control.
;                   $iDirection         - Define in what direction item(s) will move:
;                                           -1 - Move Up.
;                                            1 - Move Down.
;
; Requirement(s):   AutoIt 3.3.0.0
;
; Return Value(s):  On seccess - Move selected item(s) Up/Down and return 1.
;                   On failure - Return "" (empty string) and set @error as following:
;                                                                  1 - No selected item(s).
;                                                                  2 - $iDirection is wrong value (not 1 and not -1).
;                                                                  3 - Item(s) can not be moved, reached last/first item.
;
; Note(s):          * If you select like 15-20 (or more) items, moving them can take a while :( (second or two).
;
; Author(s):        G.Sandler a.k.a CreatoR
;===============================================================================
Func _GUICtrlListView_MoveItems($hListView, $iDirection)
    Local $aSelected_Indices = _GUICtrlListView_GetSelectedIndices($hListView, 1)

    If UBound($aSelected_Indices) < 2 Then Return SetError(1, 0, "")
    If $iDirection <> 1 And $iDirection <> -1 Then Return SetError(2, 0, "")

    Local $iTotal_Items = _GUICtrlListView_GetItemCount($hListView)
    Local $iTotal_Columns = _GUICtrlListView_GetColumnCount($hListView)

    Local $iUbound = UBound($aSelected_Indices)-1, $iNum = 1, $iStep = 1

    Local $iCurrent_Index, $iUpDown_Index, $sCurrent_ItemText, $sUpDown_ItemText
    Local $iCurrent_Index, $iCurrent_CheckedState, $iUpDown_CheckedState
    Local $iImage_Current_Index, $iImage_UpDown_Index

    If ($iDirection = -1 And $aSelected_Indices[1] = 0) Or _
        ($iDirection = 1 And $aSelected_Indices[$iUbound] = $iTotal_Items-1) Then Return SetError(3, 0, "")

    ControlListView($hListView, "", "", "SelectClear")

    If $iDirection = 1 Then
        $iNum = $iUbound
        $iUbound = 1
        $iStep = -1
    EndIf

    For $i = $iNum To $iUbound Step $iStep
        $iCurrent_Index = $aSelected_Indices[$i]
        $iUpDown_Index = $aSelected_Indices[$i]+1
        If $iDirection = -1 Then $iUpDown_Index = $aSelected_Indices[$i]-1

        $iCurrent_CheckedState = _GUICtrlListView_GetItemChecked($hListView, $iCurrent_Index)
        $iUpDown_CheckedState = _GUICtrlListView_GetItemChecked($hListView, $iUpDown_Index)

        _GUICtrlListView_SetItemSelected($hListView, $iUpDown_Index)

        For $j = 0 To $iTotal_Columns-1
            $sCurrent_ItemText = _GUICtrlListView_GetItemText($hListView, $iCurrent_Index, $j)
            $sUpDown_ItemText = _GUICtrlListView_GetItemText($hListView, $iUpDown_Index, $j)

            If _GUICtrlListView_GetImageList($hListView, 1) <> 0 Then
                $iImage_Current_Index = _GUICtrlListView_GetItemImage($hListView, $iCurrent_Index, $j)
                $iImage_UpDown_Index = _GUICtrlListView_GetItemImage($hListView, $iUpDown_Index, $j)

                _GUICtrlListView_SetItemImage($hListView, $iCurrent_Index, $iImage_UpDown_Index, $j)
                _GUICtrlListView_SetItemImage($hListView, $iUpDown_Index, $iImage_Current_Index, $j)
            EndIf

            _GUICtrlListView_SetItemText($hListView, $iUpDown_Index, $sCurrent_ItemText, $j)
            _GUICtrlListView_SetItemText($hListView, $iCurrent_Index, $sUpDown_ItemText, $j)
        Next

        _GUICtrlListView_SetItemChecked($hListView, $iUpDown_Index, $iCurrent_CheckedState)
        _GUICtrlListView_SetItemChecked($hListView, $iCurrent_Index, $iUpDown_CheckedState)

        _GUICtrlListView_SetItemSelected($hListView, $iUpDown_Index, 0)
    Next

    For $i = 1 To UBound($aSelected_Indices)-1
        $iUpDown_Index = $aSelected_Indices[$i]+1
        If $iDirection = -1 Then $iUpDown_Index = $aSelected_Indices[$i]-1
        _GUICtrlListView_SetItemSelected($hListView, $iUpDown_Index)
    Next

    Return 1
EndFunc

#3

Salut Julie.
Elle est où la fonction _GUICtrlListView_ItemSwap ?

julie · #4

heu la voici desole

Code : Tout sélectionner

Func _GUICtrlListView_ItemSwap($hListView, $i_Index, $i_NewIndex, $btn_up, $btn_down)
    GUICtrlSetState($btn_up, $GUI_DISABLE)
    GUICtrlSetState($btn_down, $GUI_DISABLE)
    $i_Index = Number($i_Index)
    $i_NewIndex = Number($i_NewIndex)
    Local $aOrig = _GUICtrlListView_GetItemTextArray($hListView, $i_Index)
    Local $aSwap = _GUICtrlListView_GetItemTextArray($hListView, $i_NewIndex)
    For $i = 1 To UBound($aOrig) - 1
        _GUICtrlListView_SetItemText($hListView, $i_NewIndex, $aOrig[$i], $i - 1)
        _GUICtrlListView_SetItemText($hListView, $i_Index, $aSwap[$i], $i - 1)
    Next
;    _UpdateSections($stockini, $i_Index + 1, $i_NewIndex + 1)
    GUICtrlSetState($btn_up, $GUI_ENABLE)
    GUICtrlSetState($btn_down, $GUI_ENABLE)
EndFunc   ;==>_GUICtrlListView_ItemSwap

julie · #5

merci hugues je regarderai ca de plus pres demain maisa premiere vu ca ne correspond pas vraiment a mes attente je regarderai a dmain merci quand meme

#6

Yo julie

Si tu ne veux pas te lancer dans du code très complexe le meilleur moyen est de te faire une array 2D avec les IDs des items et leur couleur
L'idéal est de gérer ça dans la fonction _GUICtrlListView_ItemSwap

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <WindowsConstants.au3>
#include <ListviewConstants.au3>
#include <GuiListView.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 537, 241, 284, 165)
$modif_LV = GUICtrlCreateListView("reference|Designation", 8, 12, 461, 214)
$btn_up = GUICtrlCreateButton("plus", 486, 32, 41, 65)
$btn_down = GUICtrlCreateButton("moins", 488, 131, 39, 65)
$itemtab = "article n°"
$bool = true
Global $items[10][2]    ;<<<<<<< ze array
For $i = 0 To 9
if $bool = true Then
            $items[$i][0] = GUICtrlCreateListViewItem("article n°"&$i & "|" & "desi n°"&$i,$modif_LV)
            $items[$i][1] = 0xff0000
            GUICtrlSetColor(-1, $items[$i][1])
            $bool = False
        Else
            $items[$i][0] = GUICtrlCreateListViewItem("article noir" & "|" & "desi noir",$modif_LV)
            $items[$i][1] = 0x000000
            GUICtrlSetColor(-1, $items[$i][1])
            $bool = True
        EndIf
        Next
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $i_Item = Number(_GUICtrlListView_GetSelectedIndices($modif_LV))
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

            Case $btn_up
                        If $i_Item = 0 Then ContinueLoop ;Or $i_Item = 1
                        _GUICtrlListView_ItemSwap($items, $i_Item, $i_Item - 1);, $btn_up, $btn_down)
                       _GUICtrlListView_SetItemSelected($modif_LV, $i_Item - 1)
                        GUICtrlSetState($modif_LV, $GUI_FOCUS)

                    Case $btn_down
                        If $i_Item = _GUICtrlListView_GetItemCount($modif_LV) - 1 Then ContinueLoop
                        _GUICtrlListView_ItemSwap($items, $i_Item, $i_Item + 1);, $btn_up, $btn_down)
                        _GUICtrlListView_SetItemSelected($modif_LV, $i_Item + 1)
                        GUICtrlSetState($modif_LV, $GUI_FOCUS)

    EndSwitch
WEnd

Func _GUICtrlListView_ItemSwap(ByRef $items, $i_Index, $i_NewIndex)
  GUICtrlSetState($btn_up, $GUI_DISABLE)
  GUICtrlSetState($btn_down, $GUI_DISABLE)
    $i_Index = Number($i_Index)
    $i_NewIndex = Number($i_NewIndex)

    Local $old_txt = GUICtrlRead($items[$i_Index][0])
    GUICtrlSetData($items[$i_Index][0], GUICtrlRead($items[$i_NewIndex][0]))
    GUICtrlSetData($items[$i_NewIndex][0], $old_txt)

     Local $old_color = $items[$i_NewIndex][1]
     $items[$i_NewIndex][1] = $items[$i_Index][1]
     $items[$i_Index][1] = $old_color
     GUICtrlSetColor($items[$i_NewIndex][0], $items[$i_NewIndex][1])
     GUICtrlSetColor($items[$i_Index][0], $items[$i_Index][1])

;  _UpdateSections($stockini, $i_Index+1, $i_NewIndex+1)
  GUICtrlSetState($btn_up, $GUI_ENABLE)
  GUICtrlSetState($btn_down, $GUI_ENABLE)
EndFunc   ;==>_GUICtrlListView_ItemSwap

NB :
Important : _GUICtrlListView_ItemSwap (que j'ai un peu modifiée en passant) n'intervertit pas les items (qui restent à la même place), elle intervertit leur contenu (le texte change mais pas l'id) donc on fait avec la couleur comme avec le texte
Attention à la correspondance entre index de l'array et index retournés par _GUICtrlListView_GetSelectedIndices

julie · #7

desole de n'avoir pas pu repondre avant

merci beaucoup mikell a premiere vu ca a l'air de focntionner j'ai tenter de l'implanter dans mon script en faisant deux ou trois modif simple mais ducoup ca me decale tout j'ai aussi la possibilite d'ajouter de rajouter des item a mon tableau j'ai donc r'ajouter un redim mais qui ne corrige pas mon probleme ayant actuellement un mal de crane je l'aisse ca pour le moment mais je reviendrai dessu dans la soiree peut etre

en tout cas merci beaucoup mikell une fois de plus .ps ( j'ai arreter de compter combien de fois je t'ai remercier

une bonne centaine

)

#8

En fait il y a un autre moyen, on peut intervenir quand la listview est "repeinte"
ça te met moins la panique dans le script (pas d'enregistrement des couleurs à faire) mais c'est beaucoup plus restrictif parce que la couleur des items est définie en fonction d'un élément de leur texte

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>

$Form1 = GUICreate("Form1", 537, 241, 284, 165)
$modif_LV = GUICtrlCreateListView("reference|Designation", 8, 12, 461, 214)
$btn_up = GUICtrlCreateButton("plus", 486, 32, 41, 65)
$btn_down = GUICtrlCreateButton("moins", 488, 131, 39, 65)
$itemtab = "article n°"
$bool = true
For $i = 1 To 10
if $bool = true Then
            GUICtrlCreateListViewItem("article n°"&$i & "|" & "desi n°"&$i,$modif_LV)
            GUICtrlSetColor(-1, 0xff0000)
            $bool = False
        Else
            GUICtrlCreateListViewItem("article noir" & "|" & "desi noir",$modif_LV)
            GUICtrlSetColor(-1, 0x000000)
            $bool = True
        EndIf
        Next
GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

Global $i_Item

While 1
    $i_Item = Number(_GUICtrlListView_GetSelectedIndices($modif_LV))
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
       Case $btn_up
           If $i_Item = 0 Then ContinueLoop ;Or $i_Item = 1
           _GUICtrlListView_ItemSwap($modif_LV, $i_Item, $i_Item - 1)
           _GUICtrlListView_SetItemSelected($modif_LV, $i_Item - 1)
           GUICtrlSetState($modif_LV, $GUI_FOCUS)
       Case $btn_down
            If $i_Item = _GUICtrlListView_GetItemCount($modif_LV) - 1 Then ContinueLoop
            _GUICtrlListView_ItemSwap($modif_LV, $i_Item, $i_Item + 1)
            _GUICtrlListView_SetItemSelected($modif_LV, $i_Item + 1)
            GUICtrlSetState($modif_LV, $GUI_FOCUS)
    EndSwitch
WEnd


Func _GUICtrlListView_ItemSwap($hListView, $i_Index, $i_NewIndex)
    $i_Index = Number($i_Index)
    $i_NewIndex = Number($i_NewIndex)
    Local $aOrig = _GUICtrlListView_GetItemTextArray($hListView, $i_Index)
    Local $aSwap = _GUICtrlListView_GetItemTextArray($hListView, $i_NewIndex)
    For $i = 1 To UBound($aOrig) - 1
        _GUICtrlListView_SetItemText($hListView, $i_NewIndex, $aOrig[$i], $i - 1)
        _GUICtrlListView_SetItemText($hListView, $i_Index, $aSwap[$i], $i - 1)
    Next
EndFunc   ;==>_GUICtrlListView_ItemSwap


Func WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)
     Local $tNMHDR, $hWndFrom, $iCode
     $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
     $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
     $iCode = DllStructGetData($tNMHDR, "Code")
     $hListView = GuiCtrlGetHandle($modif_LV)

    Switch $hWndFrom
         Case $hListView
             Switch $iCode
               Case $NM_CUSTOMDRAW
                     Local $tCustDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
                     Local $iDrawStage = DllStructGetData($tCustDraw, "dwDrawStage")
                     If $iDrawStage = $CDDS_PREPAINT Then Return $CDRF_NOTIFYITEMDRAW
                     Local $iItem = DllStructGetData($tCustDraw, "dwItemSpec")
                     Local $iColor
                     Local $text = _GUICtrlListView_GetItemText($hListView, $iItem, 1)
                     If StringInStr($text, "noir") Then
                            $iColor = RGB2BGR(0x000000)
                     Else
                            $iColor = RGB2BGR(0xff0000)
                     EndIf
                     DllStructSetData($tCustDraw, "clrText", $iColor)
                     Return $CDRF_NEWFONT
             EndSwitch
     EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func RGB2BGR($iColor)
     Return BitAND(BitShift(String(Binary($iColor)), 8), 0xFFFFFF)
EndFunc   ;==>RGB2BGR()

julie · #9

ce code me corresponderai plus car en realite dans le script dans lequel je vais l'employer

la condition est si la deuxieme colonne de l'article est vide alors color en rouge sinon ...

je test en faisant les modification et je te redis ca tout de suite mais la il y a beaucoup plus de chance que ca colle a mon script

julie · #10

super probleme resolu la deuxieme fonction correspond beaucoup plus a ce que je chercher merci beaucoup de te donner tant de mal mikell

je passe en resolue

AutoIt Français

[R] Listview_item color dynamique

[R] Listview_item color dynamique

Re: [..] Listview_item color dynamique

Re: [..] Listview_item color dynamique

Re: [..] Listview_item color dynamique

Re: [..] Listview_item color dynamique

Re: [..] Listview_item color dynamique

Re: [..] Listview_item color dynamique

Re: [..] Listview_item color dynamique

Re: [..] Listview_item color dynamique

Re: [..] Listview_item color dynamique