[R] ComboBox dynamique

[aulus]

Bonjour,

J'ai découvert, dans les Exemples de scripts du présent forum, un code de matwachich affichant un combo box dynamique. L'exemple proposé montre ce que je souhaiterais obtenir. Ce dernier marche très bien. Toutefois, quand je l'inclus dans mon code, j'ai des problèmes d'affichage :
- un carré blanc s'affiche en haut à gauche de la fenêtre
- les contrôles suivant l'input tenant lieu de combo ne s'affichent pas. Une fois entré le mot cherché et trouvé dans la liste déroulante (ce qui fonctionne parfaitement), le programme plante.

Bien sûr j'ai inséré tout le code dans mon programme, en-têtes et fonctions.

Je vous remercie de m'éclairer sur l'utilisation de ce code.

Le programme de matwachich : http://www.autoitscript.fr/forum/viewto ... =6&t=10742

[xPunKx]

Montre nous ton code ça ne ferait pas de tort

[aulus]

Si mon code avait quelques dizaines de lignes, ce serait possible. Mais mes controles étant perdus dans plus de 15000 lignes, je ne vois pas trop comment faire.

[mikell]

Si on n'a pas même un petit code qui montre et reproduit le problème ça va être difficile de répondre
L'udf de mat crée une gui indépendante pour sa combo (qui n'est pas réellement une combo d'ailleurs ^^)

[aulus]

Matwachich crée une boîte aussitôt après son input et son bouton :

Code : Tout sélectionner

$iCombo1 = _Combo_Init($hGUI, $I_Combo1, '_FillFunc', 10)

... et pourtant, celle-ci ne s'affiche pas. Pourquoi ne s'affiche-t-elle pas ?

Dans mon code, je l'imite au mieux, et cette boîte s'affiche, vide (40 x 40 environ), dans le coin 0,0 de ma fenêtre. Mes contrôles se trouvent dans un Tab...Y aurait-il incompatibilité... ?

D'autre part, son deuxième Input s'affiche bien. Chez moi plus rien ne s'affiche après le premier input.

[mikell]

Il est probable qu'essayer d'intégrer le controle de matwachich à un TabItem soit un problème kafkaïen

[aulus]

Effectivement, j'ai testé les combos hors Tab, et dans cette situation je n'ai pas les deux soucis indiqués ci-dessus. Mais voilà... mes combos sont dans des Tab ! Sniff...

[aulus]

Je tente depuis deuxjours à mettre une GUI dans un TabItem, afin de tirer partie des combos mais... sans succès. Cela est-il faisable ?

[mikell]

Oui... si on veut
Le code qui suit est le mix d'un trouvé sur le forum et de celui de matwachich, il marche ... un peu ... mais il est brouillon et bourré de bugs que je n'ai pas le courage de m'atteler à résoudre
Bon courage avec ce truc et tes 15*10^3 lignes

► Afficher le texte

Code : Tout sélectionner

#include <TreeViewConstants.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <Constants.au3>
#include <ListboxConstants.au3>
#include <GuiListBox.au3>
#include <Array.au3>
Opt("GUIOnEventMode", 1)

Enum $__GUI_CREATE, $__GUI_DELETE, $__GUI_SHOW, $__GUI_HIDE, $__GUI_RESIZE, $__GUI_MOVE

Enum _
    $__gComboBox_iActive, _ ; Si le comboBox est actif ou non
    $__gComboBox_hGui, _ ; La GUI du comboBox
    $__gComboBox_iLB, _ ; Le CtrlID du ListView du comboBox
    $__gComboBox_hLB, _ ; Le Handle ListView du comboBox
    $__gComboBox_hParentGui, _ ; La GUI Parente du comboBox (contenant le input et le bouton)
    $__gComboBox_iIsVisible, _ ; Si le comboBox est affiché ou pas
    $__gComboBox_iInput, _ ; CtrlID du input
    $__gComboBox_hInput, _ ; Handle du input
    $__gComboBox_sFillFunc, _ ; Fonction de remplissage du comboBox
    $__gComboBox_iItemHeight, _ ; Hauteur d'un item
    $__gComboBox_iMaxItems ; Maximum d'items à afficher dans la comboBox

Global $__gComboBox_aArray[1][11] = [[0, "", "", "", "", "", "", "", "", ""]]

; Juste pour les tests
Global $__g_aItems1 = StringSplit("salut,la,compagnie,je,m'appel,matwachich,et,ceci,est,un,test,de,mon,nouveau,comboBox,interactif,et voici enfin un item super long pour voir le comportement du listBox", ",")
Global $__g_aItems2 = StringSplit("Ceci,est,la,2,e,liste,de,valeurs,possibles,pour,le,2,e,comboBox", ",")

;==========================================================================

Global $GUI_Parent, $GUI_ENFANT1, $GUI_ENFANT2, $Tab

_GUI_Parent()

While 1
    Sleep(1000)
WEnd

Func _GUI_Parent()
    Global $GUI_Parent = GUICreate("Parent", 753, 606, -1, -1)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
    Global $Control = GUICtrlCreateTreeView(7, 8, 193, 513, BitOR($GUI_SS_DEFAULT_TREEVIEW,$WS_BORDER))
    Global $Control_0 = GUICtrlCreateTreeViewItem("Test", $Control)
    GUICtrlSetOnEvent(-1, "_GUI_ENFANT1_ON")
    GUISetState(@SW_SHOW, $GUI_Parent)
    _GUI_ENFANT1()
EndFunc

Func _GUI_ENFANT1()
    Global $GUI_ENFANT1 = GUICreate("", 545, 513, 201, 8, BitOr($WS_CHILD,$WS_TABSTOP), -1, $GUI_Parent)
    Global $Tab = GUICtrlCreateTab(7, 0, 520, 514)
    GUICtrlSetOnEvent(-1, "_TAB_Change")
    Global $TabSheet1 = GUICtrlCreateTabItem("TabSheet1")
    GUICtrlSetState(-1,$GUI_SHOW)
    Global $TabSheet2 = GUICtrlCreateTabItem("TabSheet2")
    Global $Checkbox1 = GUICtrlCreateCheckbox("Checkbox1", 96, 48, 97, 17)
    Global $Button1 = GUICtrlCreateButton("Button1", 112, 88, 75, 25)
    GUICtrlCreateTabItem("")
    GUISetState(@SW_HIDE, $GUI_ENFANT1)
    _GUI_ENFANT2()
EndFunc

Func _GUI_ENFANT2()
    Global $GUI_ENFANT2 = GUICreate("", 457, 405, 32, 50, $WS_POPUP, $WS_EX_MDICHILD, $GUI_ENFANT1)
    GUIRegisterMsg($WM_MOVE, "MY_WM_MOVE")
    GUISetBkColor(0x3A6EA5)

$I_Combo1 = GUICtrlCreateInput("", 86, 48, 201, 27)
    GUICtrlSetFont(-1, 12, 400, 0, "Cambria")
$B_Combo1 = GUICtrlCreateButton("", 288, 48, 25, 27)
$iCombo1 = _Combo_Init($GUI_ENFANT2, $I_Combo1, '_FillFunc', 10)
    GUISetState(@SW_HIDE, $GUI_ENFANT2)
EndFunc


Func _TAB_Change()
    If GUICtrlRead($Tab) = 0 Then
        GUISetState(@SW_SHOW, $GUI_ENFANT1)
        GUISetState(@SW_SHOW, $GUI_ENFANT2)
    Else
        GUISetState(@SW_SHOW, $GUI_ENFANT1)
        GUISetState(@SW_HIDE, $GUI_ENFANT2)
    EndIf
EndFunc

Func _GUI_ENFANT1_ON()
    GUISetState(@SW_SHOW, $GUI_ENFANT1)
    GUISetState(@SW_SHOW, $GUI_ENFANT2)
EndFunc

Func _Exit()
    Exit
EndFunc

Func MY_WM_MOVE($hWnd, $Msg, $wParam, $lParam) 
; viewtopic.php?f=3&t=5111&start=0&hilit=Suivi+de+gui
    Local $nNotifyCode, $nID, $hCtrl, $aGui1
    $nNotifyCode = BitShift($wParam, 16)
    $nID = BitAND($wParam, 0x0000FFFF)
    $hCtrl = $lParam
    $aGui1 = WinGetPos($GUI_ENFANT1)
    If $nID <> 2 And $nNotifyCode = 0 Then
        WinMove($GUI_ENFANT2, "", $aGui1[0] + 32, $aGui1[1] + 50)
_WinAPI_SetWindowPos($GUI_ENFANT2, $HWND_TOP, 0, 0, 0, 0, BitOR($SWP_NOMOVE, $SWP_NOSIZE))
    EndIf
EndFunc   ;==>MY_WM_COMMAND


Func _FillFunc($iComboID, $sSearch, $iMax)
    Local $aItems = Eval('__g_aItems' & $iComboID) ; on selectionne la liste à prendre en compte selon le comboBox
    ; ---
    Local $aRet[1] = [0], $extended = 0
    For $i = 1 To $aItems[0]
        If Not $sSearch Or StringInStr($aItems[$i], $sSearch) Then
            ReDim $aRet[$aRet[0] + 2]
            $aRet[0] += 1
            $aRet[$aRet[0]] = $aItems[$i]
        EndIf
        ; ---
        If $aRet[0] >= $iMax Then
            $extended = 1
            ExitLoop
        EndIf
    Next
    Return SetError(0, $extended, $aRet)
EndFunc

; ===============================================================================================================================
; Fonctions de l'UDF

Func _Combo_Init($hGui, $iInputCtrl, $iFillFunc, $iMaxItems = 15)
    ReDim $__gComboBox_aArray[$__gComboBox_aArray[0][0] + 2][11]
    $__gComboBox_aArray[0][0] += 1
    Local $iArrayIndex = $__gComboBox_aArray[0][0]
    ; ---
    $__gComboBox_aArray[$iArrayIndex][$__gComboBox_iActive]     = 1
    $__gComboBox_aArray[$iArrayIndex][$__gComboBox_hParentGui]  = $hGui
    $__gComboBox_aArray[$iArrayIndex][$__gComboBox_iInput]      = $iInputCtrl
    $__gComboBox_aArray[$iArrayIndex][$__gComboBox_hInput]      = GUICtrlGetHandle($iInputCtrl)
    $__gComboBox_aArray[$iArrayIndex][$__gComboBox_sFillFunc]   = $iFillFunc
    $__gComboBox_aArray[$iArrayIndex][$__gComboBox_iMaxItems]   = $iMaxItems
    ; ---
    __GUI_ComboBox($iArrayIndex)
    GUIRegisterMsg(0x0111, '__Combo_WM_COMMAND')
    ; ---
    Return $iArrayIndex
EndFunc

Func _Combo_SetFont($iComboID, $iSize = 8.5, $iWeight = 400, $sName = Default, $iQuality = 2)
    If $iComboID < 1 Or $iComboID > $__gComboBox_aArray[0][0] Then Return SetError(1, 0, 0)
    ; ---
    GUICtrlSetFont($__gComboBox_aArray[$iComboID][$__gComboBox_iLB], $iSize, $iWeight, $sName, $iQuality)
    $__gComboBox_aArray[$iComboID][$__gComboBox_iItemHeight] = _GUICtrlListBox_GetItemHeight($__gComboBox_aArray[$iComboID][$__gComboBox_hLB])
EndFunc

Func _Combo_SetMaxItems($iComboID, $iMaxItems = 15)
    If $iComboID < 1 Or $iComboID > $__gComboBox_aArray[0][0] Then Return SetError(1, 0, 0)
    ; ---
    $__gComboBox_aArray[$iComboID][$__gComboBox_iMaxItems] = $iMaxItems
EndFunc

Func _Combo_ButtonClick($iComboID)
    If $iComboID < 1 Or $iComboID > $__gComboBox_aArray[0][0] Then Return SetError(1, 0, 0)
    ; ---
    If $__gComboBox_aArray[$iComboID][$__gComboBox_iIsVisible] Then
        __GUI_ComboBox($iComboID, $__GUI_HIDE)
    Else
        __Combo_UpdatePositionAndWidth($iComboID)
        __Combo_Fill($iComboID, GUICtrlRead($__gComboBox_aArray[$iComboID][$__gComboBox_iInput]))
        __GUI_ComboBox($iComboID, $__GUI_SHOW)
        ControlFocus($__gComboBox_aArray[$iComboID][$__gComboBox_hParentGui], "", $__gComboBox_aArray[$iComboID][$__gComboBox_iInput])
    EndIf
EndFunc

Func _Combo_SetActive($iComboID, $iActive)
    If $iComboID < 1 Or $iComboID > $__gComboBox_aArray[0][0] Then Return SetError(1, 0, 0)
    ; ---
    $__gComboBox_aArray[$iComboID][$__gComboBox_iActive] = $iActive
    Return 1
EndFunc

Func _Combo_Destroy($iComboID)
    If $iComboID < 1 Or $iComboID > $__gComboBox_aArray[0][0] Then Return SetError(1, 0, 0)
    ; ---
    __GUI_ComboBox($iComboID, $__GUI_DELETE)
    ; ---
    _ArrayDelete($__gComboBox_aArray, $iComboID)
    $__gComboBox_aArray[0][0] -= 1
    ; ---
    Return 1
EndFunc

; ===============================================================================================================================
; Internals

; Adapte la taille et la position au input
Func __Combo_UpdatePositionAndWidth($iComboID)
    Local $aSize = ControlGetPos($__gComboBox_aArray[$iComboID][$__gComboBox_hParentGui], "", $__gComboBox_aArray[$iComboID][$__gComboBox_iInput])
    Local $tPoint = DllStructCreate("int X; int Y")
    DllStructSetData($tPoint, "X", $aSize[0])
    DllStructSetData($tPoint, "Y", $aSize[1])
    _WinAPI_ClientToScreen($__gComboBox_aArray[$iComboID][$__gComboBox_hParentGui], $tPoint)
    ; ---
    __GUI_ComboBox($iComboID, $__GUI_RESIZE, $aSize[2], 100)
    __GUI_ComboBox($iComboID, $__GUI_MOVE, DllStructGetData($tPoint, "X"), DllStructGetData($tPoint, "Y") + $aSize[3])
EndFunc

; Adapte la hauteur au nombre d'items
Func __Combo_UpdateHeight($iComboID, $iItems)
    __GUI_ComboBox($iComboID, $__GUI_RESIZE, Default, ($__gComboBox_aArray[$iComboID][$__gComboBox_iItemHeight] * $iItems) + 4)
EndFunc

; Remplir le LV du comboBox
Func __Combo_Fill($iComboID, $sSearch)
    Local $aData = Call($__gComboBox_aArray[$iComboID][$__gComboBox_sFillFunc], $iComboID, $sSearch, $__gComboBox_aArray[$iComboID][$__gComboBox_iMaxItems])
    Local $iSetMore = @extended
    If Not IsArray($aData) Or $aData[0] = 0 Then Return 0 * _GUICtrlListBox_ResetContent($__gComboBox_aArray[$iComboID][$__gComboBox_hLB])
    ; ---
    If $iSetMore > 1 Then $iSetMore = 1
    If $iSetMore < 0 Then $iSetMore = 0
    ; ---
    __Combo_UpdateHeight($iComboID, $aData[0] + $iSetMore) ; Quand $iSetMore est à 1, on rajoute de la hauteur pour un item de plus qui contiendra "..."
    ; ---
    _GUICtrlListBox_BeginUpdate($__gComboBox_aArray[$iComboID][$__gComboBox_hLB])
    _GUICtrlListBox_ResetContent($__gComboBox_aArray[$iComboID][$__gComboBox_hLB])
    For $i = 1 To $aData[0]
        _GUICtrlListBox_AddString($__gComboBox_aArray[$iComboID][$__gComboBox_hLB], $aData[$i])
    Next
    If $iSetMore Then _GUICtrlListBox_AddString($__gComboBox_aArray[$iComboID][$__gComboBox_hLB], "..." & Chr(0))
    ; ---
    _GUICtrlListBox_EndUpdate($__gComboBox_aArray[$iComboID][$__gComboBox_hLB])
    ; ---
    Return 1
EndFunc

; Remplir le input avec le text de l'item
Func __Combo_SetInput($iComboID)
    Local $sRead = GUICtrlRead($__gComboBox_aArray[$iComboID][$__gComboBox_iLB])
    If Not $sRead Or $sRead = "..." & Chr(0) Then Return 0
    ; ---
    GUICtrlSetData($__gComboBox_aArray[$iComboID][$__gComboBox_iInput], $sRead)
    Return 1
EndFunc

; ===============================================================================================================================
; Internals GUI

Func __Combo_WM_COMMAND($hWnd, $msgID, $wParam, $lParam)
    For $i = 1 To $__gComboBox_aArray[0][0]
        If Not $__gComboBox_aArray[$i][$__gComboBox_iActive] Then ContinueLoop
        ; ---
        If $lParam = $__gComboBox_aArray[$i][$__gComboBox_hInput] Then
            If (BitShift($wParam, 16) <> 768) Then Return "GUI_RUNDEFMSG" ; From GuiOnChangeRegister.au3
            ; ---
            Local $sRead = GUICtrlRead($__gComboBox_aArray[$i][$__gComboBox_iInput])
            If Not $sRead Then
                __GUI_ComboBox($i, $__GUI_HIDE)
            Else
                __Combo_UpdatePositionAndWidth($i)
                ; ---
                If __Combo_Fill($i, $sRead) Then
                    __GUI_ComboBox($i, $__GUI_SHOW)
                Else
                    __GUI_ComboBox($i, $__GUI_HIDE)
                EndIf
                ; ---
                ControlFocus($__gComboBox_aArray[$i][$__gComboBox_hParentGui], "", $__gComboBox_aArray[$i][$__gComboBox_iInput])
            EndIf
            ; ---
            Return "GUI_RUNDEFMSG"
        EndIf
        ; ---
        If $lParam = $__gComboBox_aArray[$i][$__gComboBox_hLB] Then
            If BitShift($wParam, 16) = $LBN_SELCHANGE Then
                If __Combo_SetInput($i) Then __GUI_ComboBox($i, $__GUI_HIDE)
            EndIf
            ; ---
            Return "GUI_RUNDEFMSG"
        EndIf
    Next
    ; ---
    Return "GUI_RUNDEFMSG"
EndFunc

Func __GUI_ComboBox($iArrayIndex, $iFlag = $__GUI_CREATE, $iWidth = Default, $iHeight = Default)
    If $iArrayIndex > $__gComboBox_aArray[0][0] Or $iArrayIndex < 1 Then Return SetError(1, 0, 0)
    ; ---
    Switch $iFlag
        Case $__GUI_CREATE
            ; BitOR($WS_SYSMENU, $WS_POPUP), BitOR($WS_EX_TOPMOST, $WS_EX_WINDOWEDGE, $WS_EX_TOOLWINDOW) anciens flags
            $__gComboBox_aArray[$iArrayIndex][$__gComboBox_hGui] = GUICreate("", 100, 100, -1, -1, $WS_POPUP, BitOR($WS_EX_TOOLWINDOW, $WS_DISABLED, $WS_EX_MDICHILD), $__gComboBox_aArray[$iArrayIndex][$__gComboBox_hParentGui])
            $__gComboBox_aArray[$iArrayIndex][$__gComboBox_iLB] = GUICtrlCreateList("", 0, 0, 100, 100, BitOR($WS_VSCROLL, $LBS_NOINTEGRALHEIGHT))
                GUICtrlSetResizing(-1, 102) ; $GUI_DOCKBORDERS
            $__gComboBox_aArray[$iArrayIndex][$__gComboBox_hLB] = GUICtrlGetHandle(-1)
            ; ---
            $__gComboBox_aArray[$iArrayIndex][$__gComboBox_iItemHeight] = _GUICtrlListBox_GetItemHeight($__gComboBox_aArray[$iArrayIndex][$__gComboBox_hLB])
            ; ---
            $__gComboBox_aArray[$iArrayIndex][$__gComboBox_iIsVisible] = 0
        Case $__GUI_RESIZE
            WinMove($__gComboBox_aArray[$iArrayIndex][$__gComboBox_hGui], "", Default, Default, $iWidth, $iHeight)
        Case $__GUI_MOVE
            WinMove($__gComboBox_aArray[$iArrayIndex][$__gComboBox_hGui], "", $iWidth, $iHeight)
        Case $__GUI_SHOW
            GuiSetState(@SW_SHOW, $__gComboBox_aArray[$iArrayIndex][$__gComboBox_hGui])
            $__gComboBox_aArray[$iArrayIndex][$__gComboBox_iIsVisible] = 1
        Case $__GUI_HIDE
            GuiSetState(@SW_HIDE, $__gComboBox_aArray[$iArrayIndex][$__gComboBox_hGui])
            $__gComboBox_aArray[$iArrayIndex][$__gComboBox_iIsVisible] = 0
        Case $__GUI_DELETE
            GuiDelete($__gComboBox_aArray[$iArrayIndex][$__gComboBox_hGui])
            $__gComboBox_aArray[$iArrayIndex][$__gComboBox_hGui] = 0
    EndSwitch
EndFunc
 

[aulus]

Merci Mikell pour ce travail. Ca fait deux jours que je tente de mixer aussi ces deux codes auxquels m'ont conduit mes recherches sur internet. Tant que je me limite à deux onglets, l'affichage se passe bien mais quand je tente un troisième onglet, plus rien ne va. D'autre part, tant que les deux combos sont dans le même onglet, tout va bien. Quand je les distribue sur deux onglets différents, rien ne va plus. Il est vrai que j'avance en aveugle, par tâtonnements successifs, car je ne comprends goutte au code...

Tout bien réfléchi, vu le nombre d'input et autres combos contenus dans mon programme, je vais abandonner mes TabItem. J'ai aussi des soucis d'affichage concernant les combos (Le rectangle bleu qui les encadre ne disparaît pas entièrement lorsqu'on bascule d'un onglet à l'autre : leurs bases restent affichées). Je vais remplacer les TabItem par des GUI appelées par des boutons alignés à la manière des onglets. Peut-être règlerai-je tout ainsi et que ce ne sera pas trop moche.

[mikell]

C'est franchement une bonne idée, la gestion compliquée du bazar présentait un gros risque de pollution pour le reste du script
D'ailleurs ya pas mal de programmes qui adoptent cette solution, avec un alignement vertical des boutons par exemple

[aulus]

Il reste un souci de taille : au changement de GUI, les valeurs entrées dans les combos des différentes GUI ne sont pas conservées.
J'abandonne ce rêve...