[R] Problème Label variable

[karl789]

Bonjour, alors voici mon problème,
Je voudrai faire un petit scritp avec plein de petit fonction mais une, me pose problème.
Je fait en sort que le label se modifi en fonction du resultat mais le problème est que j'arrive a inserré correctement 2 variable mais pas la troisième.

En gros je vodrais les même fonction en rajoutant que si rien est écris qu'il ne me lance pas la suite et qu'il écrive veuillez taper ip

je pense a un truc comme cela : "if $ip = ("") then Guictrlcreatelabel ( "veuillez taper ip")"

mais sa ne fonction pas.

Je copie le code merci d'avance

PS : Je suis débutant dans ce language alors si vous voyez d'autre petit problème n'hésiter pas a me les faire remarquer

► Afficher le texte

#include <GUIConstants.au3>
#include <GUIConstantsEx.au3>
#include <IE.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>


Opt("TrayIconHide", 1)


; Création de la fenètre---------------------------------------------------

$GUI = GUICreate ("Projet distance", 500, 300, -1, -1) ; Creation de la fenetre

$Group1 = GUICtrlCreateGroup ( "Saisir information", 10, 10, 280, 150) ; Création de l'encradré avec un titre

$Label1 = GUICtrlCreateLabel("Adresse IP :", 20, 35, 120, 15) ; Crétion d'une écriture appelé Label
$saisir_ip = GUICtrlCreateCombo("", 20, 50, 120, 25) ; création d'un petit menu déroulant

$Label2 = GUICtrlCreateLabel("Domaine\Login :", 20, 90, 120, 20)
$saisir_login = GUICtrlCreateInput("", 20, 105, 120, 20) ; Création d'une posibilété d'inscription

$Label3 = GUICtrlCreateLabel("Password :", 160, 90, 120, 20)
$saisir_mdp = GUICtrlCreateInput("", 160, 105, 120, 20, 0x0020) ; pour crypter le texte rajout de 0x0020 a la fin

$Bouton_ping = GUICtrlCreateButton("Ping",160, 50, 120, 20)


GUISetState(@SW_SHOW)

;----------------------------------------------------------------------------


While 1
$projet = GUIGetMsg()
Switch $projet

Case $GUI_EVENT_CLOSE
Exit

Case $Bouton_ping
Ping_pc()

EndSwitch
WEnd



Func Ping_pc()
Global $ip = GUICtrlRead($saisir_ip)
Local $var = Ping( $ip, 250)

If $ip = ("") Then GUICtrlCreateLabel(" Veuillez taper l'ip", 180, 30, 80, 15)


EndIf


If $var Then
$label_res2 = GUICtrlCreateLabel(" PING OK", 180, 30, 80, 15) ; le label dit ok
GUICtrlSetBkColor(-1, 0x00ff00) ; VERT
Sleep (2000)
GUICtrlDelete ($label_res2)

Else ; Si le ping n'est pas OK alors
$label_res2 = GUICtrlCreateLabel(" PING FAIL", 180, 30, 80, 15) ; le label dit fail
GUICtrlSetBkColor(-1, 0xFF0000)
Sleep (2000) ; ROUGE
GUICtrlDelete ($label_res2)
Endif

EndFunc

[Chokolaa]

Essaye en créant le label vide a l'endroit que tu veux et de faire un Guictrlsetdata au lieu d'un Guicreatelabel

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstants.au3>
#include <GUIConstantsEx.au3>
#include <IE.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>


Opt("TrayIconHide", 1)


; Création de la fenètre---------------------------------------------------

$GUI = GUICreate ("Projet distance", 500, 300, -1, -1) ; Creation de la fenetre

$Group1 = GUICtrlCreateGroup ( "Saisir information", 10, 10, 280, 150) ; Création de l'encradré avec un titre

$Label1 = GUICtrlCreateLabel("Adresse IP :", 20, 35, 120, 15) ; Crétion d'une écriture appelé Label
$saisir_ip = GUICtrlCreateCombo("", 20, 50, 120, 25) ; création d'un petit menu déroulant

$Label2 = GUICtrlCreateLabel("Domaine\Login :", 20, 90, 120, 20)
$saisir_login = GUICtrlCreateInput("", 20, 105, 120, 20) ; Création d'une posibilété d'inscription

$Label3 = GUICtrlCreateLabel("Password :", 160, 90, 120, 20)
$saisir_mdp = GUICtrlCreateInput("", 160, 105, 120, 20, 0x0020) ; pour crypter le texte rajout de 0x0020 a la fin

$Bouton_ping = GUICtrlCreateButton("Ping",160, 50, 120, 20)

$label = GUICtrlCreateLabel("", 180, 30, 80, 15)

GUISetState(@SW_SHOW)

;----------------------------------------------------------------------------


While 1
$projet = GUIGetMsg()
Switch $projet

Case $GUI_EVENT_CLOSE
Exit

Case $Bouton_ping
Ping_pc()

EndSwitch
WEnd



Func Ping_pc()
Global $ip = GUICtrlRead($saisir_ip)
Local $var = Ping( $ip, 250)

If $ip = ("") Then GUICtrlSetData($label," Veuillez taper l'ip")


EndIf


If $var Then
$label_res2 = GUICtrlSetData($label," PING OK") ; le label dit ok
GUICtrlSetBkColor(-1, 0x00ff00) ; VERT
Sleep (2000)
GUICtrlDelete ($label_res2)

Else ; Si le ping n'est pas OK alors
$label_res2 = GUICtrlSetData($label," PING FAIL") ; le label dit fail
GUICtrlSetBkColor(-1, 0xFF0000)
Sleep (2000)     ; ROUGE
GUICtrlDelete ($label_res2)
Endif

EndFunc

[karl789]

merci pour cette réponse mais ça ne réssoud pas mon problème j'ai trouvé une solutin alternative en rajoutant une fonction ( vérified() ) pas très beau mais ça fonctionne. Si quelqu'un vois d'autre petit défaut n'hésité pas a me le faire savoir ...
Merci beaucoup pour cette aide

► Afficher le texte

#include <GUIConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>


Opt("TrayIconHide", 1)


; Création de la fenètre---------------------------------------------------

$GUI = GUICreate ("Projet distance", 500, 300, -1, -1) ; Creation de la fenetre

$Group1 = GUICtrlCreateGroup ( "Saisir information", 10, 10, 280, 150) ; Création de l'encradré avec un titre

$Label1 = GUICtrlCreateLabel("Adresse IP :", 20, 35, 120, 15) ; Crétion d'une écriture appelé Label
$saisir_ip = GUICtrlCreateCombo("", 20, 50, 120, 25) ; création d'un petit menu déroulant

$Label2 = GUICtrlCreateLabel("Domaine\Login :", 20, 90, 120, 20)
$saisir_login = GUICtrlCreateInput("", 20, 105, 120, 20) ; Création d'une posibilété d'inscription

$Label3 = GUICtrlCreateLabel("Password :", 160, 90, 120, 20)
$saisir_mdp = GUICtrlCreateInput("", 160, 105, 120, 20, 0x0020) ; pour crypter le texte rajout de 0x0020 a la fin

$Bouton_ping = GUICtrlCreateButton("Ping",160, 50, 120, 20)


GUISetState(@SW_SHOW)

;----------------------------------------------------------------------------


While 1
$projet = GUIGetMsg()
Switch $projet

Case $GUI_EVENT_CLOSE
Exit

Case $Bouton_ping
Verified()

EndSwitch
WEnd

Func Verified()
Global $ip = GUICtrlRead($saisir_ip)
$cestbon = True

If $ip = "" Then
$label_res = GUICtrlCreateLabel("Veuillez taper l'ip", 180, 30, 80, 15)
Sleep (4000)
GUICtrlDelete ($label_res)
$cestbon = False
EndIf

If $cestbon = True Then Ping_pc()


EndFunc

Func Ping_pc()

$var = Ping( $ip, 250)


If $var Then
$label_res = GUICtrlCreateLabel(" PING OK", 180, 30, 80, 15) ; le label dit ok
GUICtrlSetBkColor(-1, 0x00ff00) ; VERT
Sleep (4000)
GUICtrlDelete ($label_res)

Else ; Si le ping n'est pas OK alors
$label_res = GUICtrlCreateLabel(" PING FAIL", 180, 30, 80, 15) ; le label dit fail
GUICtrlSetBkColor(-1, 0xFF0000)
Sleep (4000) ; ROUGE
GUICtrlDelete ($label_res)
Endif

EndFunc

[matwachich]

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>
#include <StaticConstants.au3>



Opt("TrayIconHide", 1)


; Création de la fenètre---------------------------------------------------

$GUI = GUICreate("Projet distance", 500, 300, -1, -1) ; Creation de la fenetre

$Group1 = GUICtrlCreateGroup("Saisir information", 10, 10, 280, 150) ; Création de l'encradré avec un titre

$Label1 = GUICtrlCreateLabel("Adresse IP :", 20, 35, 120, 15) ; Crétion d'une écriture appelé Label
$saisir_ip = GUICtrlCreateCombo("", 20, 50, 120, 25) ; création d'un petit menu déroulant

$Label2 = GUICtrlCreateLabel("Domaine\Login :", 20, 90, 120, 20)
$saisir_login = GUICtrlCreateInput("", 20, 105, 120, 20) ; Création d'une posibilété d'inscription

$Label3 = GUICtrlCreateLabel("Password :", 160, 90, 120, 20)
$saisir_mdp = GUICtrlCreateInput("", 160, 105, 120, 20, 0x0020) ; pour crypter le texte rajout de 0x0020 a la fin

$Bouton_ping = GUICtrlCreateButton("Ping", 160, 50, 120, 20)

; Pas besoin de re-créer à chaque fois le label
$label_res = GUICtrlCreateLabel("", 180, 30, 80, 15, $GUI_SS_DEFAULT_LABEL + $SS_CENTER)

GUISetState(@SW_SHOW)

;----------------------------------------------------------------------------


While 1
    $projet = GUIGetMsg()
    Switch $projet

        Case $GUI_EVENT_CLOSE
            Exit

        Case $Bouton_ping
            Ping_pc()

    EndSwitch
WEnd

Func Ping_pc()
    Local $ip = GuiCtrlRead($saisir_ip)
    If Not _Verifier_adresse_ip($ip) Then Return MsgBox(16, "Attention", "Vous devez entrer une addresse IP valide")
    ; ---
    If Ping($ip, 250) Then
        _Set_Label(True)
    Else
        _Set_Label(False)
    EndIf
EndFunc   ;==>Ping_pc

; ##############################################################

Func _Set_Label($iStatus)
    If $iStatus Then
        GuiCtrlSetData($label_res, "PING OK")
        GUICtrlSetBkColor($label_res, 0x00FF00)
    Else
        GuiCtrlSetData($label_res, "PING FAIL")
        GUICtrlSetBkColor($label_res, 0xFF0000)
    EndIf
    ; ---
    ; j'utilise cette fonction pour ne pas faire freezer la GUI (voyez la documentation)
    AdLibRegister("_Reinit_Label", 4000) ; ###
EndFunc

Func _Reinit_Label()
    GuiCtrlSetData($label_res, "")
    GUICtrlSetBkColor($label_res, $GUI_BKCOLOR_TRANSPARENT)
    ; ---
    AdlibUnRegister("_Reinit_Label") ; ###
EndFunc

; ##############################################################

Func _Verifier_adresse_ip($ip)
    $ip = StringSplit($ip, ".")
    If $ip[0] <> 4 Then Return False
    ; ---
    For $i = 1 To $ip[0]
        If Not $ip[$i] Or Int($ip[$i]) < 0 Or Int($ip[$i]) > 255 Then Return False
    Next
    ; ---
    Return True
EndFunc

[karl789]

Merci pour cette corretion il y plein de fonction que je ne connaissais pas. Je teste dés ce soir et je vous tiens au courant, j'espère pouvoir mettre un petit. [R]

[karl789]

Je viens de tester et nikel c'est exactement ce que voulais et avec le fait que l'adresse soit obligatoirement en 0.0.0.0 grand merci à toi matwachich .
Je met de suite le petit [R]

[matwachich]

A votre service!

[Tlem]

Je met de suite le petit [R]

2 heures après, toujours pas de [R] dans le titre de votre premier message !!!
Un oubli ?

[karl789]

Je met de suite le petit [R]

2 heures après, toujours pas de [R] dans le titre de votre premier message !!!
Un oubli ?

Effectivement je suis repartie sur mon autoit pour rajouter les fonctions qui vont suivre et j'ai complétement zapper. lool.
Mais ce petit oubli est réparer.
Merci beaucoup pour vos aide.