[Ex] Mettre un Copyright visuel sur une image

[alex1205]

Bonjour.
Nous sommes tous dans l'époque où les internautes volent les images.
Maintenant, avec Copyrighter, vous pourrez choisir vos images et les Copyrighter.
Sans plus, voici le code :

► Afficher le textecode

Code : Tout sélectionner

#include <GDIPlus.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
Dim $img = ""
$Form1 = GUICreate("Copyrighter une image", 399, 121, 192, 124)
$Label1 = GUICtrlCreateLabel("Mon image :", 24, 24, 66, 17)
$Input1 = GUICtrlCreateInput("", 88, 24, 209, 21)
$Button1 = GUICtrlCreateButton("..", 304, 24, 19, 17, $WS_GROUP)
$Label2 = GUICtrlCreateLabel("Mon texte :", 24, 56, 57, 17)
$Input2 = GUICtrlCreateInput("", 88, 56, 257, 21)
$Button2 = GUICtrlCreateButton("Copyrighter", 136, 88, 75, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            $img = FileOpenDialog("Choisir l'image à copyrighter", @MyDocumentsDir, "(*.*)")
             GUICtrlSetData($Input1, $img)
        Case $Button2
            If $img <> '' And GUICtrlRead($Input2) <> "" Then
                $dir = FileSaveDialog("Enregistrer le fichier", @MyDocumentsDir, "(*.png)")
                $societe = Inputbox("Copyrighter", "Quel est le nom de votre société ?")
                _CreateCopyright_Image($img, $dir, GUICtrlRead($Input2) & "© Marque déposée par " & $societe)
                Run('MSPaint.exe ' & @TempDir & '\apercu.png')
                Sleep(10000) ;dix secondes
                $mMsgbox = MsgBox(4, "Copyright", "Cela vous plaît ?")
                If $mMsgbox = 6 Then
                    Msgbox(0, "Copyright", "Voici le chemin de l'image copyrighté :" & $dir)
                Else
                    GUICtrlSetData($Input1, "")
                    GUICtrlSetData($Input2, "")
                EndIf
            Else
                MsgBox(0 + 16 + 524288, "Erreur", "Un ou des champs n'est ou ne sont pas remplis")
            EndIf
    EndSwitch
WEnd

Global $hBitmap, $hImage, $hGraphic, $hFamily, $hFont, $tLayout, $hFormat, $aInfo, $hBrush1, $hBrush2, $iWidth, $iHeight, $hPen
Func _CreateCopyright_Image($img, $dir, $sString)
    _GDIPlus_Startup()
    $hImage = _GDIPlus_ImageLoadFromFile($img)
    $hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage)
    $hFamily = _GDIPlus_FontFamilyCreate("Arial")
    $hFont = _GDIPlus_FontCreate($hFamily, 16, 1)
    $tLayout = _GDIPlus_RectFCreate(0, 0)
    $hFormat = _GDIPlus_StringFormatCreate(2)
    $hBrush1 = _GDIPlus_BrushCreateSolid(0xA2FFFFFF)
    $hBrush2 = _GDIPlus_BrushCreateSolid(0xC4FF0000)
    $hPen = _GDIPlus_PenCreate(0xC4000000, 2)
    $aInfo = _GDIPlus_GraphicsMeasureString($hGraphic, $sString, $hFont, $tLayout, $hFormat)
    $iWidth = DllStructGetData($aInfo[0], "Width")
    $iHeight = DllStructGetData($aInfo[0], "Height")
    _GDIPlus_GraphicsFillRect($hGraphic, 0, 0, $iWidth, $iHeight, $hBrush1)
    _GDIPlus_GraphicsDrawRect($hGraphic, 1, 1, $iWidth, $iHeight, $hPen)
    _GDIPlus_GraphicsDrawStringEx($hGraphic, $sString, $hFont, $aInfo[0], $hFormat, $hBrush2)
    _GDIPlus_ImageSaveToFile($hImage, $dir)
    _GDIPlus_ImageSaveToFile($hImage, @TempDir & '\apercu.png')
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_BrushDispose($hBrush1)
    _GDIPlus_BrushDispose($hBrush2)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_ImageDispose($hImage)
    _GDIPlus_Shutdown()
EndFunc   ;==>_CreateCopyright_Image
 

Si, vous nous faites pas confiance. Regardez le résultat.

► Afficher le texteimage

Et, je rajoute que j'ai pris la partie du copyright de :
AutoIt3\Examples\GUI\Advanced\Emboss.au3
Alors ne me félicitez pas.
Je remercie Ricky qui à repéré les fautes (pas d'orthographe)^^

[cutprod]

Alors la super!!
Félicitation ca peut servir!

[alex1205]

Merci cutprod

[jbnh]

J'adore ! Bravo.

[timmalos]

Ca reste quand même un gros plagiat de l'exemple disponible dans Autoit3 : C:\Program Files\AutoIt3\Examples\GUI\Advanced\Emboss.au3

Donc bravo pour la GUI, mais à part çà le boulot reste très succinct Ca aura au moins le mérite de faire decouvrir cet exemple au plus grand nombre.

[alex1205]

@timmalos : Je sais que c'est du plagiat, mais, je ne suis pas à fond pour faire du GDI+ ou même des DLL
Je me contente de prendre une partie du script et de l'adapter à mon script.

[ricky]

Hello,

pas mal, je connaissais pas Emboss.au3.

Alex : il y a un soucis, manque un endif avant le dernier else et impossible de choisir un dossier :
$img = FileOpenDialog("Choisir l'image à copyrighter", @MyDocumentsDir, "*.*") ne marche pas.
Il y a pas besoin de #include <ScreenCapture.au3> c'est Emboss.au3 qui l'utilise.

[alex1205]

Je ne sais pas comment la réparer pour FileOpenDialog.
EDIT : le #include <ScreenCapture.au3> c'est pour prendre une image sans utiliser FileOpenDialog que ne marche pas.

[SrBelial]

bon, l'exemple peut être utile certes ...
par contre évitez les images de trop grande taille (que ce soit hébergé par le fofo ou par un hébergeur quelconque).
le fait est que pour ceux qui :
* ont une résolution d'écran faible,
* ont une connexion faible débit,
il n'est pas indispensable de leur faire afficher cette image en fullsize ... donc pensez à retailler les photos (un maximum de 800 pixels en largeur donne déjà une bonne taille d'image, en 640 c'est encore mieux (pensez à ceux qui n'ont que 1024 pixels de résolution horizontale sur leurs écrans, cela existe encore !! et encore plus pensez à ceux pour qui cela demande 10 secondes à bande passante pleine pour charger une telle image.)

^__^
sinon à part ça c'est bien, continuez !

[sksbir]

le copyright , c'est le truc rouge marqué verticalement en haut à gauche ?

Ben, la tendance actuellement, c'est le copyright à l'insu du voleur. Par exemple : utilisation de la stéganographie.

le titre mériterait donc une précision : "copyright par dépose d'un tampon sur l'image"

[alex1205]

Oui, c'est le "truc" qu'il y a en haut !
Bon, a part ça, quelqu'un pourrait résoudre le problème du FileOpenDialoge, la ligne où il y a le commentaire.
Merci

[alex1205]

Problème réglé, le FileOpenDialog maque des ( ) pour les extensions.
Voilà. Maintenant, vous pouvez le faire sans aucune erreur