[R] Afficher une page web

[Iste]

Salutations,

J'aimerai un petit script autoit qui affiche une page web (adresse ecrit en dur dans le script) sur tout l'ecran (taille variable) et, mon principal probleme) atribuer a cette fenetre comme "au dessus de tout".
La fenetre en elle meme ne doit pas avoir d'interface, mais ca je dois savoir faire.

Voila, merci d'avance !

Edit : En fait ma demande est un peu mal adroite, en fait je veux simplement lancer une GUI en fullscreen ^^'

[orax]

Code : Tout sélectionner

Global Const $WS_SYSMENU = 0x00080000
Global Const $WS_POPUP = 0x80000000
Global Const $WS_EX_TOOLWINDOW = 0x00000080
Global Const $WS_EX_TOPMOST = 0x00000008

HotKeySet("{Esc}", "Quitter")

$oIE = ObjCreate("Shell.Explorer.2")
$gui = GUICreate("test", @DesktopWidth, @DesktopHeight, 0, 0, BitOR($WS_SYSMENU, $WS_POPUP), BitOR($WS_EX_TOOLWINDOW, $WS_EX_TOPMOST))
$GUIActiveX = GUICtrlCreateObj($oIE, 0, 0, @DesktopWidth, @DesktopHeight)
$oIE.navigate("http://www.autoitscript.fr/")
GUISetState(@SW_SHOW)

While 1
    GUISetState(@SW_RESTORE, $gui) ; pour réafficher la fenêtre au premier plan
    Sleep(250)
WEnd

Func Quitter()
    GUIDelete()
    Exit
EndFunc   ;==>Quitter

J'avais fait comme ça dans un script pour afficher une fenêtre sans bordures mais il y a peut-être une autre solution. Surtout que là, ça ne sera plus au dessus de la barre des tâches si on fait ALT+TAB ou touche "Windows". J'ai donc rajouté un GUISetState(@SW_RESTORE, $gui), je ne vois pas comment faire sinon.

[Iste]

Oui en effet, c'est un probleme que j'attendais.
Enfin, le resultat est exactement ce que je recherchais ^^
merci beaucoup !

edit :
j'ai pas encore chercher mais y'a moyen de suprimer l'assenceur de droite ? (innutile pour ma page)

[Iste]

Le probleme principal n'est en fait pas si résolu que ca.
Des que ma fenetre dépasse les 1420 pixel de large, une bare vertical apparait. ce qui est assez genant..

De plus, j'ai voulu faire disparaitre le mini cadre blanc de 1pixel autour de la fenetre en l'agrandissant de deux pixel et en la reculant d'un pixel... mais devinez ce qu'il se passe quand je demande de la placer au coordonée -1 ? ^^'

Donc voila, si vous avez des solutions... merci d'avance !

[GaRydelaMer]

Bonsoir,

j'ai pas de solution pour la barre de défilement qui pour moi est un contrôle de microsoft il me semble que c'est possible avec des feuilles de styles au niveau du site web lui même.

Pour la position des fenêtres utilise la fonction winmove
WinMove ( "title", "text", x, y [, width [, height[, speed]]] ) voir l'aide.

Code : Tout sélectionner

Global Const $WS_SYSMENU = 0x00080000
Global Const $WS_POPUP = 0x80000000
Global Const $WS_EX_TOOLWINDOW = 0x00000080
Global Const $WS_EX_TOPMOST = 0x00000008

HotKeySet("{Esc}", "Quitter")

$oIE = ObjCreate("Shell.Explorer.2")
$gui = GUICreate("test", @DesktopWidth, @DesktopHeight, 0, 0, BitOR($WS_SYSMENU, $WS_POPUP), BitOR($WS_EX_TOOLWINDOW, $WS_EX_TOPMOST))
$GUIActiveX = GUICtrlCreateObj($oIE, 0, 0, @DesktopWidth, @DesktopHeight)
$oIE.navigate("http://www.autoitscript.fr/")

WinMove($gui, "", -2, -2, @DesktopWidth + 4, @DesktopHeight + 4)

GUISetState(@SW_SHOW)

While 1
    GUISetState(@SW_RESTORE, $gui) ; pour réafficher la fenêtre au premier plan
    Sleep(250)
WEnd

Func Quitter()
    GUIDelete()
    Exit
EndFunc   ;==>Quitter

[orax]

De plus, j'ai voulu faire disparaitre le mini cadre blanc de 1pixel autour de la fenetre en l'agrandissant de deux pixel et en la reculant d'un pixel... mais devinez ce qu'il se passe quand je demande de la placer au coordonée -1 ? ^^'

Ca ne va pas ça ? :

Code : Tout sélectionner

$GUIActiveX = GUICtrlCreateObj($oIE, -1, -1, @DesktopWidth+2, @DesktopHeight+2)
 

[Iste]

Si ! merci beaucoup !

En effet, j'aurai du penser a winmove, mais comme tu me l'as fais remarquer dans ton script, en fait c'est -2 la bonne coordoné ^^' donc pas de probleme...

et orax, bien vu, en donnant les valeurs de l'objet, on peut virer l'ascenseur hors de l'ecran

Le code final (qui marche tres bien chez moi, peut etre pas chez tout le monde)

Code : Tout sélectionner

#NoTrayIcon
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=images.ico
#AutoIt3Wrapper_UseUpx=n
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

Global Const $WS_SYSMENU = 0x00080000
Global Const $WS_POPUP = 0x80000000
Global Const $WS_EX_TOOLWINDOW = 0x00000080
Global Const $WS_EX_TOPMOST = 0x00000008

HotKeySet("{Esc}", "Quitter")

$oIE = ObjCreate("Shell.Explorer.2")
$gui = GUICreate("test", @DesktopWidth+4, @DesktopHeight+4, -2, -2, BitOR($WS_SYSMENU, $WS_POPUP), BitOR($WS_EX_TOOLWINDOW,$WS_EX_TOPMOST))
$GUIActiveX = GUICtrlCreateObj($oIE, 0, 0, @DesktopWidth+21, @DesktopHeight+4)
$oIE.navigate("http://blackle.com/")
GUISetState(@SW_SHOW)

While 1
    GUISetState(@SW_RESTORE, $gui) ; pour réafficher la fenêtre au premier plan
    Sleep(250)
WEnd

Func Quitter()
    GUIDelete()
    Exit
EndFunc   ;==>Quitter