AutoIt Français

Bonjour à tous. Comme beaucoup d'entre vous bossent avec l'include IE.au3, je poste ici quelques recherches que j'ai pu effectuer sur le sujet. Je mettrai des exemples à la suite en fonction des questions qui se posent sur le forum. Ce post sera tenu propre mais n'hesitez pas à commenter certains exemples si ils ne vous parlent pas !

Bien du courage à ceux qui mettent les mains dans le cambouis

Qu'est ce qu' IE.au3?

IE.au3 est un UDF qui nous permet d'automatiser, de contrôler et d'utiliser IExplore, le celèbre navigateur de Microsoft, aussi appelé Internet Explorer. La version de base utilisée dépend de votre version de windows.
Pour ceux qui se diraient actuellement : "IE c'est de la daube, rien à foutre de ce sujet à la con", sachez seulement qu'IE est le seul programme installé sur tous les ordinateurs sous Windows qui permet d'acceder à internet. Si vous avez besoin d'utiliser une fonctionnalité avancée d'un navigateur dans votre programme et que ce programme va être distribué à grande echelle, c'est vers IE.au3 qu'il faudra vous tourner.
Cependant, si c'est pour votre usage personnel, vous pouvez envisager l'utilisation de FF.au3 qui utilise Firefox et un module externe à installer nommé MozRepl. Suivez le lien suivant : http://autoitscript.fr/forum/viewtopic.php?f=21&t=2296

La première chose à savoir, c'est que Microsoft propose 2 objets bien distincts :

Le premier est l'objet complet, qui permet à peu près de tout faire. A peu de choses près, cela correspond au meme que lorsque vous lancez IExplore.exe manuellement, sauf qu'ici on récupère une variable $oIE qui nous permet de travailler sur cet objet.
Vous pouvez tester le code suivant qui va juste lancer IE puis se fermer.
Code : Tout sélectionner
```
Local $o = ObjCreate("InternetExplorer.Application")
$o.visible = 1
```
Cette version est celle qui est attachée à _IECreate()
Le deuxième est une version minimaliste, mais qui peut être integrée directement dans un programme, ce que ne permet pas le premier.
Code : Tout sélectionner
```
ObjCreate("Shell.Explorer.2")
```
Ce dernier doit être integré dans un programme car il ne peut pas fonctionner en autonomie. On utilise pour cela la fonction GUICtrlCreateObj en Autoit.
Cette version est celle qui est attachée à _IECreateEmbedded()
Vous pouvez alors voir l'aide de cette fonction pour comprendre le fonctionnement de cet objet.
Gardez en mémoire que si cet objet est très utile pour être intégré directement dans une fenêtre de votre cru, pour simuler un navigateur internet par exemple, il ne permet pas de TOUT faire comme le premier, et certaines propriétés vous seront interdites.

N'hesitez pas à visiter les liens qui suivent pour plus d'informations.

Comment acceder à la documentation pour aller plus loin que ce que propose IE.au3?

Reference for Visual Basic Developers WebBrowser: (=ACCUEIL de L'aide MSDN)
http://msdn.microsoft.com/en-us/library ... 85%29.aspx

Reference for Internet Explorer Object : (=_IECreate)
http://msdn.microsoft.com/en-us/library ... 85%29.aspx

Reference for WebBrowser Object : (=_IECreateEmbedded)
http://msdn.microsoft.com/en-us/library ... 85%29.aspx

Reference for Document Object:
http://msdn.microsoft.com/en-us/library ... 85%29.aspx

Reference for A element Object : (<a href=...></a>)
http://msdn.microsoft.com/en-us/library ... 85%29.aspx

Comment obtenir l'adresse URL de ma fenêtre IE active?

Code : Tout sélectionner

_IEPropertyGet($oIE,"locationurl")

Souvenez vous de la fonction _IEPropertyGet qui peut être une mine d'or. L'aide vous sera fort utile !

Comment obtenir les cookies/en définir de nouveaux sur ma page?

Code : Tout sélectionner

If IsObj($oIE) Then $doc = _IEDocGetObj($oIE)
        If IsObj($doc) Then
            $cookies = string($doc.cookie)

Vous obtiendrez une chaine de charactère contenant tous les cookies de la page. A vous de l'analyser avec des RegExp pour obtenir seulement la valeur souhaitée.
Pour définir de nouveaux cookies, veuillez lire le sujet suivant (EN) http://www.autoitscript.com/forum/topic ... ntry873962

Comment capter les evenements qui surviennent sur ma fenêtre IE?

Dans le premier exemple, IE.au3 n'est pas utilisé.

Tout est basé sur les infos que vous pouvez trouver sur MSDN : http://msdn.microsoft.com/en-us/library ... 85%29.aspx

► Afficher le texteIe Events

Code : Tout sélectionner

;#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
; Example script, showing the usage of COM Event functions.
; Requires at least AutoIt beta version 3.1.1.104 !
;
; See also: [url="http://msdn.microsoft.com/workshop/browser/webbrowser/reference/objects/internetexplorer.asp"]http://msdn.microsoft.com/workshop/browser...netexplorer.asp[/url]
dim $odoc

; We use a very simple GUI to show the results of our Events.
$GUIMain=GUICreate            ( "Event Test",      600,500 )
$GUIEdit=GUICtrlCreateEdit    ( "Test Log:" & @CRLF,  10, 20, 580, 400)
GUICtrlSetState($GUIEdit,$GUI_DISABLE)
$GUIProg=GUICtrlCreateProgress  (                      10,  5, 580,  10)
$GUIExit=GUICtrlCreateButton    ( " Close ",          250, 450, 80,  30)
GUISetState ()    ;Show GUI

; We prepare the Internet Explorer as our test subject
$oIE=ObjCreate("InternetExplorer.Application.1")
With $oIE
    .Visible=1
    .Top = (@DesktopHeight-400)/2
    .Height=400     ; Make it a bit smaller than our GUI.
    .Width=600
    .Silent=1         ; Don't show IE's dialog boxes
    $IEWnd=HWnd(.hWnd) ; Remember the Window, in case user decides to close it
EndWith

; We choose for a specific Internet Explorer interface 'DWebBrowserEvents' because the IE is subject
; to modifications by e.g. Visual Studio and Adobe Acrobat Reader. If you have IE-plugins installed,
; AutoIt might not be able to find the correct interface automatically.
$EventObject=ObjEvent($oIE,"IEEvent_","DWebBrowserEvents2")
if @error then
   Msgbox(0,"AutoIt COM Test", _
    "ObjEvent: Can't use event interface 'DWebBrowserEvents'. Error code: " & hex(@error,8))
   exit
endif

; Now starting to load an example Web page.
$URL = "http://www.AutoItScript.com/"
$oIE.Navigate( $URL )
sleep(1000)         ; Give it some time to load the web page

GUISwitch ( $GUIMain ) ; Switch back to our GUI in case IE stealed the focus

; Waiting for user to close the GUI.
While 1
   $msg = GUIGetMsg()
   If $msg = $GUI_EVENT_CLOSE or $msg = $GUIExit Then ExitLoop
Wend

$EventObject.Stop  ; Tell IE we don't want to receive events.
$EventObject=0   ; Kill the Event Object
If WinExists($IEWnd) then $oIE.Quit ; Close IE Window
$oIE=0           ; Remove IE from memory (not really necessary).

GUIDelete ()       ; Remove GUI

exit               ; End of our Demo.

; A few Internet Explorer Event Functions
; See also: [url="http://msdn.microsoft.com/workshop/browser/webbrowser/reference/objects/webbrowser.asp"]http://msdn.microsoft.com/workshop/browser.../webbrowser.asp[/url]

Func IEEvent_BeforeNavigate2($URL, $Flags, $TargetFrameName, $PostData, $Headers, $Cancel)
;   Note: the declaration is different from the one on MSDN.
    GUICtrlSetData ( $GUIEdit, "BeforeNavigate: " & $URL & " Flags: " & $Flags & " tgframe: " & $TargetFrameName & " Postdat: " & $PostData & " Hdrs: " & $Headers & " canc: " & $Cancel  & @CRLF  , "append" )
EndFunc

Func IEEvent_ProgressChange($Progress,$ProgressMax)
    If $ProgressMax > 0 Then
        GUICtrlSetData($GUIProg, ($Progress * 100) / $ProgressMax )
    EndIf
EndFunc

Func IEEvent_StatusTextChange($Text)
    GUICtrlSetData ( $GUIEdit, "IE Status text changed to: " & $Text & @CRLF  , "append" )
EndFunc

Func IEEvent_PropertyChange( $szProperty)
    GUICtrlSetData ( $GUIEdit, "IE Changed the value of the property: " & $szProperty & @CRLF  , "append" )
EndFunc

Func IEEvent_DownloadComplete()
    GUICtrlSetData ( $GUIEdit, "IE has finished a navigation operation" & @CRLF  , "append" )
    $odoc=objcreate("IHtmlDocument2")
    $oDoc= $oIE.document
    $EventDoc=ObjEvent($oDoc,"Document_","HTMLDocumentEvents2")
    GUICtrlSetData ( $GUIEdit, "-->Document cookie : "& $oDoc.cookie & @CRLF  , "append" )
    GUICtrlSetData ( $GUIEdit, "-->Document title : "& $oDoc.title& @CRLF  , "append" )
    GUICtrlSetData ( $GUIEdit, "-->Document referrer : "& $oDoc.referrer& @CRLF  , "append" )
    GUICtrlSetData ( $GUIEdit, "-->Document url : "& $oDoc.url& @CRLF  , "append" )


EndFunc
Func Document_OnMouseOver($e)
; This is an optional event function to catch non-defined events.
; The parameter contains the name of the event being called.
    GUICtrlSetData ( $GUIEdit, "Doc mouseover" & @CRLF  , "append" )
EndFunc

Func Document_OnClick($e)
    GUICtrlSetData ( $GUIEdit, "Doc click : "& $e & @CRLF  , "append" )
EndFunc
Func IEEvent_NavigateComplete($URL)
;   Note: the declaration is different from the one on MSDN.
    GUICtrlSetData ( $GUIEdit, "IE has finished loading URL: " & $URL & @CRLF  , "append" )
EndFunc

Func IEEvent_($EventName)
; This is an optional event function to catch non-defined events.
; The parameter contains the name of the event being called.
    GUICtrlSetData ( $GUIEdit, "Uncatched event: " & $EventName & @CRLF  , "append" )
EndFunc

Comment prévenir/controler la navigation/rafraichissement/fermeture de ma fenêtre IE?
J'ai eu besoin de contrôler la fermeture d'Internet Explorer, en affichant en message à l'utilisateur pour l'informer que si il fait cela, il perdra tout son travail sur mon application. Il n'existe pas à proprement parler d'evenement OnQuit pour Internet Explorer ce qui rend très difficile cette tâche, même si MSDN dit le contraire

Voilà donc une solution retenue sur le forum américain par Dale (toujours lui) qui permet de controler le rafraichissement de la page ou la fermeture d'une fenetre IE grâce à du javascript.

► Afficher le texte

Code : Tout sélectionner

#include <IE.au3>

$oIE = _IECreate()

; Add HTML to blank page
$oBody = _IETagnameGetCollection($oIE, "body", 0)
_IEDocInsertHTML($oBody, "<a href=http://www.autoitscript.com>Navigate to http://www.autoitscript.com</a><p>")
_IEDocInsertHTML($oBody, "<BUTTON id=b1 value='Normal Exit'>Normal Exit</button>&nbsp;")
_IEDocInsertHTML($oBody, "<BUTTON id=b2 value='Safe Exit'> Safe Exit </button>")

; Get references to buttons and setup event handlers
$oButton1 = _IEGetObjById($oIE, "b1")
$oButton2 = _IEGetObjById($oIE, "b2")
$oEvtButton1 = ObjEvent($oButton1, "evtButton_")
$oEvtButton2 = ObjEvent($oButton2, "evtButton_")

; Setup random alert string to appear in popup, add a function to be called when onbeforeunload is triggered.
; This is the "magic" in this example
$sRandom = "MY-ALERT-" & Random(1000000, 9999999, 1) 
IEHeadInsertScript($oIE, "function promptBeforeUnload() { return '" & $sRandom & "'; }")
IEEval($oIE, "window.onbeforeunload = promptBeforeUnload;")

; With this JavaScript injected in the page, any attempt to navigate, refresh or close will
; result in a popup like the following.  The key is adding text to the Return statement of the
; function that is bound to the onbeforeunload event.
;
; The TrapAlert routine called in the idle loop watches for the unique string in the alert ($sRandom),
; quickly covers the alert with a splash screen and presses Cancel to abort the action.
;
; This is not a foolproof method if someone is trying to break out because there is often
; enough of a lag for the user to press OK, but in the right circumstances is very effective.

; ---------------------------------------------------------------
; Are you sure you want to navigate away from this page?
;
; MY-ALERT-2522442
;
; Press OK to continue, or Cancel to stay on the current page.
;
;                                             OK       Cancel
; ---------------------------------------------------------------

While __IEIsObjType($oIE, "browser")
    TrapAlert()
    Sleep(200)
WEnd

; --------------- Functions ---------------
Func TrapAlert()
    If WinExists("", $sRandom) Then
        ControlClick("", $sRandom, "Button2")
        SplashTextOn("Navigation not allowed!", _
            "Use the controls supplied or you will lose all of your work!", -1, -1, -1, -1, 33)
        Sleep(5000)
        SplashOff()
    EndIf
EndFunc

Func evtButton_onclick()
    Local $o_object = @COM_EventObj
    Switch $o_object.value
        Case "Normal Exit"
            $oIE.quit
        Case "Safe Exit"
            ; Remove the function tied to onbeforeunload and defeat the trap so that 
            ; normal navigation, refresh or close can occur
            IEEval($oIE, "window.onbeforeunload = '';")
            $oIE.quit
    EndSwitch
EndFunc

Func IEEval($o_object, $s_eval)
    Return $o_object.document.parentWindow.eval($s_eval)
EndFunc

Func IEHeadInsertScript($o_object, $s_script)
    Local $o_head, $o_element
    $o_head = _IETagNameGetCollection($o_object, "head", 0)
    $o_element = $o_object.document.createElement('script')
    $o_element.type = 'text/javascript'
    $o_element.text = $s_script
    Return $o_head.appendChild($o_element)
EndFunc

Comment savoir si la fenêtre IE répond bien?

Il peut arriver que la fenetre Internet Explorer plante completement. Et alors la, vous l'avez bien dans l'os avec votre automatisation de tâche, car tout va planter lamentablement, et un simple ProcessKill() sur IExplore.exe peut ne pas suffire.
Dans ce cas, je vous invite à utiliser le bout de code suivant, qui detecte si votre fenêtre IE freeze ou non :

Code : Tout sélectionner

If IsObj($oIE) Then
        _IELoadWait($oIE)
        $aerror = 0
        $v_ret = DllCall("user32.dll", "int", "IsHungAppWindow", "hwnd", HWnd($oIE.HWND))
        If @error <> 0 Or $v_ret[0] Then $aerror = 1
    Else
        $aerror = 1
    EndIf

si $aerror = 1, Alors vous pouvez enclencher le plan B : Detruire tous les objets, Fermer IE, et relancer votre automatisation.

Comment forcer la fermeture d'IE?
J'ai précedemment publié un outil qui marche à merveille, mieux même que quand vous faites Ctrl+Alt+Del pour forcer la fermeture d'un programme. Suivez le lien suivant, il contient tous les exemples pour la fermeture d'un process IE :
http://autoitscript.fr/forum/viewtopic.php?f=21&t=3761

Vous pourrez voir dans les exemples du lien précédant qu'il vius faut connaitre le PID du process pour pouvoir forcer sa fermeture.

Si vous voulez forcer la fermeture de la fenêtre IE active mais pas des autres fenetres IE, vous pouvez utiliser la fonction suivante _GetHwndFromPID($PID) qui retourne l'Handle de la fenetre à partir du PID. Ainsi vous pourrez comparer l'Handle de la fenetre active à celle retournée et être certain de fermer le bon IExplore.exe
http://autoitscript.fr/forum/viewtopic.php?f=21&t=5411

Comment supprimer le cache d'IE?
Pour certaines simulations, le cache peut poser problème, par exemple en ne téléchargeant pas certaines informations, et pour un système de Log j'avais besoin d'avoir toujours le même temps de chargement de page en cas de réussite du scénario. Voilà donc une fonction qui vide tout le cache d'IE. Cette fonction a été écrite par Tlem.

► Afficher le texteFunc _EmptyIECache()

Réservé

_IECreateEmbedded est trop limité pour mes besoins, comment faire?

Comme expliqué précedemment, _IECreateEmbedded utilise une version limité d'Internet Explorer, qui ne permet pas de tout faire. Il existe une alternative, mais il vous sera difficile de l'exploiter pleinement sans un niveau suffisant, très peu d'informations étant disponibles à ce sujet.
Cette alternative permet l'utilisation d'une instance d'IE complète, comme si vous utilisiez _IECreate(), tout en l'incorporant à votre fenêtre comme vous le feriez avec ActiveX et _IeCreateEmbedded()

Voilà un code montrant cette alternative: (Plus d'infos ici : http://www.autoitscript.com/forum/topic ... hl__ie+dns)

Code : Tout sélectionner

#Include <WindowsConstants.au3>
#include <WinAPI.au3>
#Include <Constants.au3>
local $pid, $hHandle, $hGUI, $sURL, $xHeight, $xWidth
$sURL = "www.google.com"
$xWidth = 1024
$xHeight = 568
$hGUI = GUICreate("Test", $xWidth, $xHeight)
$oIE = _IECreate2($xWidth, $xHeight, $hGUI)
;Apres cette ligne, vous pouvez utilisez les fonctions _IE comme vous l'auriez fait normalement.

func _IECreate2($xWidth, $xHeight, $hGUI)
$pid = Run(@ProgramFilesDir&"\internet explorer\iexplore.exe -k "&$sURL, "", @SW_HIDE)
Sleep(2000)
$hHandle = _ProcessGetHWnd($pid)
GUISetState(@SW_SHOW, $hGUI)
_WinAPI_SetParent($hHandle, $hGUI)
_WinAPI_MoveWindow($hHandle, 0, 0, $xWidth, $xHeight, True)
_WinAPI_SetWindowLong($hHandle, $GWL_STYLE, $WS_POPUP+$WS_VISIBLE)
Send("{F5}")
EndFunc
Func _ProcessGetHWnd($iPid, $iOption = 1, $sTitle = "", $iTimeout = 2000)
    Local $aReturn[1][1] = [[0]], $aWin, $hTimer = TimerInit()
    While 1
      $aWin = WinList($sTitle)
        For $i = 1 To $aWin[0][0]
            If $iPid = WinGetProcess($aWin[$i][1]) Then
                If $iOption = 1 OR ($iOption = 0 And $aWin[$i][0] <> "") Then
                    Return $aWin[$i][1]
                ElseIf $iOption = 2 Then
                    ReDim $aReturn[UBound($aReturn) + 1][2]
                    $aReturn[0][0] += 1
                    $aReturn[$aReturn[0][0]][0] = $aWin[$i][0]
                    $aReturn[$aReturn[0][0]][1] = $aWin[$i][1]
                EndIf
            EndIf
        Next
        If $iOption = 2 And $aReturn[0][0] > 0 Then Return $aReturn
        If TimerDiff($hTimer) > $iTimeout Then ExitLoop
        Sleep(Opt("WinWaitDelay"))
    WEnd
       SetError(1)
    Return 0
EndFunc  ;==>_ProcessGetHWnd

Do
    Sleep(200)
Until GUIGetMsg() = -3
ProcessClose($pid)

AutoIt Français

[Ex] IE.au3 // Exemples et FAQ

[Ex] IE.au3 // Exemples et FAQ

Re: [Ex] IE.au3 // Exemples et approfondissements

Re: [Ex] IE.au3 // Exemples et approfondissements

Re: [Ex] IE.au3 // Exemples et FAQ

Re: [Ex] IE.au3 // Exemples et FAQ

Re: [Ex] IE.au3 // Exemples et FAQ