AutoIt Français

Bonjour,

Je crée en ce moment un logiciel qui me permettra de gérer les dépenses faites par moi et mes potes durant les vacances d'étés et de savoir ainsi qui devra combien à qui de manière à ce qu'on ai payé une part égale au final.
J'ai donc crée pour cela un Tab où l'on peut ajouter/supprimer des TabItems en fonction du nombre de personnes participant.
Chaque nouveau TabItem créé vas aussi créer 3 boutons, 1 input et 1 listview.
Pour gérer cet ajout, j'ai stocké chaque control dans un tableau (Il y a donc par exemple $btn_AddEnter[0], list_User[0]...) et ce tableau s'implémente à chaque nouveau TabItem créé.
Mon problème est que je voudrais que lorsque l'on clique sur le $btn_AddEnter[$i] ($i représente le bouton situé dans le TabItem recevant le focus) ça démarre la fonction _addEnter($i) ($i permet de connaitre dans quelle TabItem il faudra ajouter une entrée).
J'ai donc essayé avec un GUICtrlSetOnEvent mais ça ne marche pas.

Si quelqu'un a une solution à me proposer, je suis preneur!
Voici mon script:

► Afficher le texte

Code : Tout sélectionner

#cs ----------------------------------------------------------------------------

 AutoIt Version : 3.3.8.1
 Auteur:         Cyril (Kagami)

 Fonction du Script :
    Permet de calculer l'argent que doit telle personne à telle autre personne.
    Possibilité d'ajout/suppression de personnes
    Possibilité d'ajout/supression d'entrée

#ce ----------------------------------------------------------------------------



;===============================================================================
;                                                                       INCLUDES
;===============================================================================
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <GuiStatusBar.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <GuiTab.au3>
#include <GuiListView.au3>



;===============================================================================
;                                                                      VARIABLES
;===============================================================================
Dim $tab_PanelItem[10]
Dim $btn_AddEnter[10]
Dim $btn_EditEnter[10]
Dim $btn_DeleteEnter[10]
Dim $list_User[10]
Dim $input_MontantTotal[10]
Dim $statusBar_PartEdge[3] = [200, 290, -1]
Dim $statusBar_PartText[3] = [@TAB & "Nom Personne", @TAB & "Monnaie", @TAB & @TAB & ""]
Global $i = 0
Global $focusActuel



;===============================================================================
;                                                                            GUI
;===============================================================================
;===== Main Window =====
Global $window = GUICreate("Control Monnaie", 960, 767)
Global $btn_AddUser = GUICtrlCreateButton("Ajouter une personne", 8, 8, 139, 25)
Global $btn_DeleteUser = GUICtrlCreateButton("Supprimer une personne", 160, 8, 139, 25)
Global $btn_Open = GUICtrlCreateButton("Ouvrir un groupe", 360, 8, 139, 25)
Global $btn_Save = GUICtrlCreateButton("Sauvegarder ce groupe", 512, 8, 139, 25)
Global $btn_Options = GUICtrlCreateButton("Options", 808, 8, 139, 25)
Global $tab_Panel = GUICtrlCreateTab(8, 40, 945, 697, $TCS_MULTILINE)
Global $tab_PanelHome = GUICtrlCreateTabItem("Home")
Global $statusBar = _GUICtrlStatusBar_Create($window, $statusBar_PartEdge, $statusBar_PartText)
GUISetState(@SW_SHOW)



;===============================================================================
;                                                              BOUCLE PRINCIPALE
;===============================================================================
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        ;=== Ajouter une personne ===
        Case $btn_AddUser
            $input_AddUser = InputBox("Ajouter une personne", "Veuillez choisir le nom de la personne à ajouter")
            If @Error = 0 And $input_AddUser <> "" Then
                $i = $i +1
                $tab_PanelItem[$i] = GUICtrlCreateTabItem($input_AddUser)
                    $btn_AddEnter[$i] = GUICtrlCreateButton("Ajouter une entrée", 14, 67, 139, 25)
                    $btn_EditEnter[$i] = GUICtrlCreateButton("Modifier une entrée", 166, 67, 139, 25)
                    $btn_DeleteEnter[$i] = GUICtrlCreateButton("Supprimer une entrée", 318, 67, 139, 25)
                    GUICtrlCreateLabel("Montant total", 472, 72, 66, 17)
                        GUICtrlSetBkColor(-1, 0xFFFFFF)
                    $input_MontantTotal[$i] = GUICtrlCreateInput("0", 544, 68, 73, 21, BitOR($GUI_SS_DEFAULT_INPUT, $ES_RIGHT, $ES_READONLY, $ES_NUMBER))
                    $list_User[$i] = GUICtrlCreateListView("Dépense|Montant", 16, 96, 930, 630)
                        GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 463)
                        GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 463)
                GUICtrlCreateTabItem("")
                _GUICtrlTab_SetCurFocus($tab_Panel, $i)
            EndIf
            GUICtrlSetOnEvent($btn_AddEnter[$i], "_addEnter")

        ;=== Supprimer une personne ===
        Case $btn_DeleteUser
            $focusActuel = _GUICtrlTab_GetCurFocus($tab_Panel)
            If $focusActuel = 0 Then
                MsgBox(48, "Erreur", "Vous ne pouvez pas supprimer l'onglet Home")
            Else
                _GUICtrlTab_DeleteItem($tab_Panel, $focusActuel)
                $i = $i -1
                _GUICtrlTab_SetCurFocus($tab_Panel, $focusActuel -1)
            EndIf

    EndSwitch
WEnd



;===============================================================================
;                                                                      FONCTIONS
;===============================================================================
;=== _addEnter permet d'ajouter une dépense ===
Func _addEnter()
    _createGUIAddEnter()
EndFunc

;=== _createGUIAddEnter permet de créer la fenêtre permettant d'ajouter une dépense ===
Func _createGUIAddEnter()
    ;===== AddEnter Window =====
    Global $w_AddEnter = GUICreate("Ajouter une entrée", 291, 123, -1, -1, BitOR($WS_EX_WINDOWEDGE,$WS_EX_COMPOSITED))
    GUICtrlCreateLabel("Type de la dépense", 8, 8, 98, 17)
    GUICtrlCreateLabel("Montant de la dépense", 8, 35, 113, 17)
    Global $input_AddEnterDep = GUICtrlCreateInput("", 128, 5, 153, 21)
    Global $input_AddEnterMont = GUICtrlCreateInput("0", 128, 32, 153, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_NUMBER))
    Global $updown_AddEnterMont = GUICtrlCreateUpdown($input_AddEnterMont)
    Global $btn_SaveEnter = GUICtrlCreateButton("Enregistrer cette entrée", 56, 64, 163, 25)
    GUISetState(@SW_SHOW)
EndFunc

Voilà, merci à vous.

D'une manière générale, tu ne peux pas utiliser GUIGetMsg() et les SetOnEvent ensemble, il faut choisir un mode ou l'autre
On peut changer de mode en cours de script en intercalant des Opt("GUIOnEventMode", ..) mais faut pas se louper

Tu me conseille de faire comment? Sachant que je n'utilise jamais GUICtrlSetOnEvent, c'est pas une valeur très sur pour moi.
Mais je peux pas faire "Case $btn_AddEnter[$i]" ou quelque chose du genre. Le top serait un Case avec le bouton correspondant au TabItem sur lequel est le focus.
Je sais pas trop comment m'y prendre pour gérer ça :<

Quand tu peux utiliser le onevent, fais-le, c'est plus propre et surtout plus rapide
En gros je ferais comme ça, à toi de compléter

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <GuiStatusBar.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <GuiTab.au3>
#include <GuiListView.au3>

Opt("GUIOnEventMode", 1)  

;===============================================================================
;                                                                      VARIABLES
;===============================================================================
Dim $tab_PanelItem[10]
Dim $btn_AddEnter[10]
Dim $btn_EditEnter[10]
Dim $btn_DeleteEnter[10]
Dim $list_User[10]
Dim $input_MontantTotal[10]
Dim $statusBar_PartEdge[3] = [200, 290, -1]
Dim $statusBar_PartText[3] = [@TAB & "Nom Personne", @TAB & "Monnaie", @TAB & @TAB & ""]
Global $i = 0
Global $focusActuel



;===============================================================================
;                                                                            GUI
;===============================================================================
;===== Main Window =====
Global $window = GUICreate("Control Monnaie", 960, 767)
Global $btn_AddUser = GUICtrlCreateButton("Ajouter une personne", 8, 8, 139, 25)
    GUICtrlSetOnEvent(-1, "_addNewUser")

Global $btn_DeleteUser = GUICtrlCreateButton("Supprimer une personne", 160, 8, 139, 25)
Global $btn_Open = GUICtrlCreateButton("Ouvrir un groupe", 360, 8, 139, 25)
Global $btn_Save = GUICtrlCreateButton("Sauvegarder ce groupe", 512, 8, 139, 25)
Global $btn_Options = GUICtrlCreateButton("Options", 808, 8, 139, 25)
Global $tab_Panel = GUICtrlCreateTab(8, 40, 945, 697, $TCS_MULTILINE)
Global $tab_PanelHome = GUICtrlCreateTabItem("Home")
Global $statusBar = _GUICtrlStatusBar_Create($window, $statusBar_PartEdge, $statusBar_PartText)
GUISetState(@SW_SHOW)

GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")



;===============================================================================
;                                                              BOUCLE PRINCIPALE
;===============================================================================
While 1
 Sleep(10)
#cs
        ;=== Supprimer une personne ===
        Case $btn_DeleteUser
            $focusActuel = _GUICtrlTab_GetCurFocus($tab_Panel)
            If $focusActuel = 0 Then
                MsgBox(48, "Erreur", "Vous ne pouvez pas supprimer l'onglet Home")
            Else
                _GUICtrlTab_DeleteItem($tab_Panel, $focusActuel)
                $i = $i -1
                _GUICtrlTab_SetCurFocus($tab_Panel, $focusActuel -1)
            EndIf
#ce

WEnd




Func _Exit()
    Exit
EndFunc


Func _addNewUser()
           $input_AddUser = InputBox("Ajouter une personne", "Veuillez choisir le nom de la personne à ajouter")
            If @Error = 0 And $input_AddUser <> "" Then
                $i = $i +1
                $tab_PanelItem[$i] = GUICtrlCreateTabItem($input_AddUser)
                    $btn_AddEnter[$i] = GUICtrlCreateButton("Ajouter une entrée", 14, 67, 139, 25)
            GUICtrlSetOnEvent(-1, "_addEnter")
                    $btn_EditEnter[$i] = GUICtrlCreateButton("Modifier une entrée", 166, 67, 139, 25)
                    $btn_DeleteEnter[$i] = GUICtrlCreateButton("Supprimer une entrée", 318, 67, 139, 25)
                    GUICtrlCreateLabel("Montant total", 472, 72, 66, 17)
                        GUICtrlSetBkColor(-1, 0xFFFFFF)
                    $input_MontantTotal[$i] = GUICtrlCreateInput("0", 544, 68, 73, 21, BitOR($GUI_SS_DEFAULT_INPUT, $ES_RIGHT, $ES_READONLY, $ES_NUMBER))
                    $list_User[$i] = GUICtrlCreateListView("Dépense|Montant", 16, 96, 930, 630)
                        GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 463)
                        GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 463)
                GUICtrlCreateTabItem("")
                _GUICtrlTab_SetCurFocus($tab_Panel, $i)
            EndIf
EndFunc




;===============================================================================
;                                                                      FONCTIONS
;===============================================================================
;=== _addEnter permet d'ajouter une dépense ===
Func _addEnter()
    _createGUIAddEnter()
EndFunc

;=== _createGUIAddEnter permet de créer la fenêtre permettant d'ajouter une dépense ===
Func _createGUIAddEnter()
    ;===== AddEnter Window =====
    Global $w_AddEnter = GUICreate("Ajouter une entrée", 291, 123, -1, -1, BitOR($WS_EX_WINDOWEDGE,$WS_EX_COMPOSITED))
    GUICtrlCreateLabel("Type de la dépense", 8, 8, 98, 17)
    GUICtrlCreateLabel("Montant de la dépense", 8, 35, 113, 17)
    Global $input_AddEnterDep = GUICtrlCreateInput("", 128, 5, 153, 21)
    Global $input_AddEnterMont = GUICtrlCreateInput("0", 128, 32, 153, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_NUMBER))
    Global $updown_AddEnterMont = GUICtrlCreateUpdown($input_AddEnterMont)
    Global $btn_SaveEnter = GUICtrlCreateButton("Enregistrer cette entrée", 56, 64, 163, 25)
    GUISetState(@SW_SHOW)
EndFunc

Merci, c'est impeccable

AutoIt Français

[R] GUICtrlSetOnEvent sur tableau de boutons

[R] GUICtrlSetOnEvent sur tableau de boutons

Re: [..] GUICtrlSetOnEvent sur tableau de boutons

Re: [..] GUICtrlSetOnEvent sur tableau de boutons

Re: [..] GUICtrlSetOnEvent sur tableau de boutons

Re: [..] GUICtrlSetOnEvent sur tableau de boutons