AutoIt Français

Bonjour,

Depuis peu j'ai crée ( avec votre aide ) un lecteur de musique basic..
Vous devez vous dire : " Ah.. encore lui

"
Mais je souhaite en faire un peu plus :
-Avoir comme tout les autre logiciels une barre en haut avec genre Fichier | outils | Affichage | Aide
-Une progress Bar en fonction de la musique ( Je cherche une ressemblance avec d'autre topic )
-Une Boite avec la liste des musique.
Si vous avez d'autre idée assez simple je veux bien que me vous les dites.

Script :

► Afficher le texte

Merci d'avance pour toutes vos réponse

. Cordialement.

recherche tout les mp3 dans le fichiers musique

Code : Tout sélectionner

#include <File.au3>
$monarray = _FileListToArray(@MyDocumentsDir & "/Mes Musiques","*.mp3",1)

après un combo est un bouton jouer devrais suffire pour jouer un des fichiers trouver...

Ou alors, une recherche dans les forums

http://autoitscript.fr/forum/viewtopic.php?f=6&t=7970

locos974 a écrit :Vous devez vous dire : " Ah.. encore lui "

Mais non voyons, cool

locos974 a écrit :-Avoir comme tout les autre logiciels une barre en haut avec genre Fichier | outils | Affichage | Aide

Regarde dans l'aide l'exemple de GUICtrlCreateMenu, c'est exactement ça

locos974 a écrit :-Une progress Bar en fonction de la musique

Ben tu fais une progressbar que tu actualises dans le while en jonglant avec avec _SoundLength et _SoundPos ^^

locos974 a écrit :-Une Boite avec la liste des musique.

Y a des TAS de possibilités, je pencherais pour un ini ou un log (txt) où tu stockes l'adresse des morceaux favoris, avec une combo comme l'a dit moi ou une edit, voire une 2ème gui

EDIT Mince j'ai manqué le post de TT22

TT22 : j'ai déjà regarder de nombreux topic concernant tout ça.. Je cherche mais certains truc ne me vienne pas de regarder. Sinon merci de vos réponse ! j’essaie tout ça d'ici 1heure je vous en tien au courant.

Pour la progressbar elle n'avance pas en fonction de ma musique :

► Afficher le texte

Essaye ça directement dans la boucle While

Code : Tout sélectionner

If $sound Then 
   $percent = Round((_SoundPos($sound, 2)/_SoundLength($sound, 2))*100)
   GuiCtrlSetData($Progress1, $percent)
EndIf

cela ne marche pas :

► Afficher le texte

T'as pas lu mon post ?
Faut pas le mettre sous un "Case $Progress1" qui va le bloquer, faut le sortir du switch et le mettre directement dans la boucle while, juste sous le "While 1" par exemple

Code : Tout sélectionner

While 1

If $sound Then
   $percent = Round((_SoundPos($sound, 2)/_SoundLength($sound, 2))*100)
   GuiCtrlSetData($Progress1, $percent)
EndIf

$nMsg = GUIGetMsg()
Switch $nMsg
    Case ... etc

Même en dessous du "While 1.." ça ne marche pas..

Embêtant..

Bonjour

il faudrait mettre un "if Isarray($sound)"

Puis faire plutôt un appel avec adlibregister toute les secondes au lieu de la continuité du while
Je me suis permis d'aménager un peu le code au niveau des bouton pour les tests :

► Afficher le texte

Code : Tout sélectionner

#region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=/img/sens_interdit.ico
#AutoIt3Wrapper_Res_Description=Lecteur Audio player par GaMeR en Français.
#AutoIt3Wrapper_Res_Language=1036
#endregion ;**** Directives created by AutoIt3Wrapper_GUI ****
;=================================================
;===
;===
;=================================================
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <SliderConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Sound.au3>

;===========================================================================================
;===========================================================================================
$titre = "Média Player Autoit"
Break("enable")

;===========================================================================================
#region ### START Koda GUI section ### Form=
$Form1 = GUICreate($titre, 438, 101, 410, 438)
$Button1 = GUICtrlCreateButton("...", 8, 64, 41, 33, $WS_GROUP)
GUICtrlSetFont(-1, 12, 800, 0, "Comic sans MS")
$Button2 = GUICtrlCreateButton("Play", 56, 64, 49, 33, $WS_GROUP)
GUICtrlSetFont(-1, 11, 800, 0, "Comic sans MS")
GUICtrlSetState(-1,$GUI_DISABLE)
$Button3 = GUICtrlCreateButton("Pause", 112, 64, 49, 33, $WS_GROUP)
GUICtrlSetFont(-1, 11, 800, 0, "Comic sans MS")
GUICtrlSetState(-1,$GUI_DISABLE)
$Button4 = GUICtrlCreateButton("Son Favoris", 352, 8, 81, 25, $WS_GROUP)
GUICtrlSetFont(-1, 10, 800, 0, "Comic sans MS")
$Button5 = GUICtrlCreateButton("Jouer Son", 352, 40, 81, 25, $WS_GROUP)
GUICtrlSetFont(-1, 10, 800, 0, "Comic sans MS")
$Label2 = GUICtrlCreateLabel("Volume :", 224, 72, 53, 25)
GUICtrlSetFont(-1, 10, 800, 0, "Comic sans MS")
$Label3 = GUICtrlCreateLabel("Poids Son :", 8, 40, 178, 25)
$Slider1 = GUICtrlCreateSlider(272, 72, 161, 25)
$Button6 = GUICtrlCreateButton("STOP", 168, 64, 49, 33, $WS_GROUP)
GUICtrlSetFont(-1, 11, 800, 0, "Comic sans MS")
$Progress1 = GUICtrlCreateProgress(8, 8, 334, 17)

GUISetState(@SW_SHOW)
#endregion ### END Koda GUI section ###

;===========================================================================================
;===========================================================================================
$size = ""
$souce = ""
$sound = 0
$vol = 100
$volume = ""
;===========================================================================================
;===========================================================================================

Global $current_length=1
While 1
    $nMsg = GUIGetMsg()

    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Slider1
            SoundSetWaveVolume(GUICtrlRead($Slider1))
        Case $Button1
            $source = FileOpenDialog("Ouvrir:", @DesktopDir & '\', "mp3 (*.mp3)|wav (*.wav)|wma (*.wma)|a52 (*.a52)|acc (*.acc)|ac3 (*.ac3)|ogg (*.ogg)|flac (*.flac)|mp1 (*.mp1)|mp2 (*.mp2)|mp4 (*.mp4)|oga (*.oga)", 9)
            If $source = "" Then
                MsgBox(16, "$titre", "Erreur, aucun son n'a été choisis !")
                ContinueLoop
            EndIf
            If $source <> "" Then
                $size = FileGetSize($source)
                GUICtrlSetData($Label3, "Poids Son : " & $size & " bytes")
            EndIf
            GUICtrlSetState($Button2,$GUI_ENABLE)
            GUICtrlSetState($Button1,$GUI_DISABLE)

        Case $Button2
            If $sound = 0 Then
                $sound = _SoundOpen($source)
                if _SoundPlay($sound) <> 0 Then
                    $current_length=_SoundLength($sound, 2)
                    AdlibRegister("Update_Progress1",1000)
                    GUICtrlSetState($Button2,$GUI_DISABLE)
                    GUICtrlSetState($Button3,$GUI_ENABLE)
                EndIf
            ElseIf _SoundStatus($sound) = "paused" Then
                _SoundResume($sound)
                GUICtrlSetState($Button2,$GUI_DISABLE)
                GUICtrlSetState($Button3,$GUI_ENABLE)
            EndIf


        Case $Button3
            If $sound<> 0 Then
            _SoundPause($sound)
                GUICtrlSetState($Button3,$GUI_DISABLE)
                GUICtrlSetState($Button2,$GUI_ENABLE)
            EndIf


        Case $Button4
            If $source = "" Then MsgBox(16, $titre, "Erreur, aucun son n'a été choisis !")
            If $source <> "" Then
                FileDelete(@ScriptDir & "\fav.txt")
                FileWrite(@ScriptDir & "\fav.txt", $source)
                MsgBox(64, $titre, "Votre son à été marqué comme favoris.")
            EndIf

        Case $Button5
            $source = FileRead(@ScriptDir & "\fav.txt")
            If FileExists(@ScriptDir & "\fav.txt") = 0 Then MsgBox(16, $titre, "Erreur, aucun son n'est définis comme favoris !")
            If FileExists(@ScriptDir & "\fav.txt") = 1 Then
                If FileExists($source) = 0 Then MsgBox(16, $titre, "Erreur, le son définis comme favoris n'existe pas ou plus !")
                If FileExists($source) = 1 Then
                    $sound = 0
                    $sound = $source
                    SoundPlay($sound)
                EndIf
            EndIf
            If $source = "" Then MsgBox(16, $titre, "Erreur, aucun son n'a été choisis !")
            If $source <> "" Then
                $size = FileGetSize($source)
                GUICtrlSetData($Label3, "Poids Son : " & $size & " bytes")

            EndIf
        Case $Button6
            stop_chanson()
        Case $Progress1
            ;AUCUNE FONCTION TROUVABLE..

    EndSwitch
WEnd

Func Update_Progress1()
    local $staus,$position
    If IsArray($sound) Then
        $position=_SoundPos($sound, 2)
        If $position>=$current_length Then
            stop_chanson()
            Return
        EndIf
        $status=_SoundStatus ( $sound )
        Select
            Case $status="playing"
                $percent = Round(($position/$current_length)*100)
                ;ConsoleWrite ($status&" "&$percent&@CRLF)
                GuiCtrlSetData($Progress1, $percent)
            Case $status="stoped"
                stop_chanson()
                Return
            Case Else
                Return
        EndSelect
    EndIf


EndFunc

Func stop_chanson()
    AdlibUnRegister("Update_Progress1")
    $sound=0
    _SoundStop($sound)
    _SoundClose($sound)
    ;GuiCtrlSetData($Progress1, 0)
    GUICtrlSetState($Button1,$GUI_ENABLE)
    GUICtrlSetState($Button2,$GUI_DISABLE)
    GUICtrlSetState($Button3,$GUI_DISABLE)
    GuiCtrlSetData($Progress1, 0)
    $source=""
EndFunc

Chapeau

.. (Le bouton stop ne marche pas par contre.. J'ai cherché l'erreur mais pas trouvé

)
Je ne pensais pas que cela aurait été si dur..
Merci beaucoup.

Faut intervertir ...si tu mets $sound=0 au début, ben ça fera _SoundStop(0) ensuite ... ^^

Code : Tout sélectionner

Func stop_chanson()
    AdlibUnRegister("Update_Progress1")
  [color=#FF0000] ; $sound=0[/color]
    _SoundStop($sound)
    _SoundClose($sound)
   [color=#FF0000] $sound=0[/color]
...etc

Donc ? D'où vient le problème ?

Ben si tu écris la fonction comme ça, le bouton stop devrait marcher

► Afficher le texte

Dite-moi pour cette fonction, je peux le faire pour qu'il recherche tout les musique du disque dur ?

Code : Tout sélectionner

#include <File.au3>
$monarray = _FileListToArray(@MyDocumentsDir & "/Mes Musiques","*.mp3",1)

EDIT : Il faut juste changer la Macro ?

Oui, là il fait la recherche dans :

Code : Tout sélectionner

 @MyDocumentsDir & "/Mes Musiques"

Bonjour,

Moi aussi je travaille sur un lecteur MP3 depuis un bon bout de temps.
J'ai donc une GUI totalement image etc...
Mais je voulais savoir un petit quelque chose et je ne pense pas qu'il y ai besoin de recréer un sujet pour cela :S
Truc tout bête sur lequel je bloque:
Je voudrais afficher le titre de la chanson et juste le titre.
J'ai essayé avec des fonctions telles que FileGetLongName ou FileGetShortName, j'ai regardé dans l'aide, fait une recherche sur le forum mais rien, je m'adresse donc à vous.

En gros, ce que je voudrais, c'est récupérer le nom de ma chanson et uniquement le nom à travers une variable $Name (donc sans le chemin ni l'extension si possible).
Pour choisir la chanson, j'ai utilisé ceci:
$Name = FileOpenDialog("Veuillez ouvrir une musique", @DesktopDir & '', "mp3 (*.mp3)")

Merci de votre aide

Argh... avec StringRegExp ça serait mieux, sûrement

Code : Tout sélectionner

$Name = FileOpenDialog("Veuillez ouvrir une musique", @DesktopDir & '', "mp3 (*.mp3)")
$split = StringSplit($Name , "\")

msgbox(0,"", StringTrimRight($split[$split[0]], 4))

Essayez alors

Code : Tout sélectionner

$Name=StringRegExpReplace($Name,".+\\",""))

après le FileOpenDialog

PS: dslé pour l'erreur du stop, reliquat d'un debug ...

AutoIt Français

[R] Lecteur de Musique.

[R] Lecteur de Musique.

Re: [..] Lecteur de Musique.

Re: [..] Lecteur de Musique.

Re: [..] Lecteur de Musique.

Re: [..] Lecteur de Musique.

Re: [..] Lecteur de Musique.

Re: [..] Lecteur de Musique.

Re: [..] Lecteur de Musique.

Re: [..] Lecteur de Musique.

Re: [..] Lecteur de Musique.

Re: [..] Lecteur de Musique.

Re: [..] Lecteur de Musique.

Re: [..] Lecteur de Musique.

Re: [..] Lecteur de Musique.

Re: [..] Lecteur de Musique.

Re: [..] Lecteur de Musique.

Re: [..] Lecteur de Musique.

Re: [..] Lecteur de Musique.

Re: [..] Lecteur de Musique.

Re: [..] Lecteur de Musique.