AutoIt Français

Bonjour à tous,

je dispose d'une gui avec une image au milieu créé à partir de la fonction guictrlcreatepic()

Au dessus du cadre il y a une combo box, contentant, disons trois choix.

En fonction du choix, l'image du logo doit changer.

Hors, lorsque je change de logo, la taille du cadre de l'image s'agrandie au fur et à mesure.

Ce qui serait souhaitable, c'est que la taille ne varie pas, quelle que soit le choix.

J'ai vu sur le forum un certain nombre de possibilité, dont certaine passant par gdi plus.

voici ma gui :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#Include <GuiComboBox.au3>
#include <ComboConstants.au3>
#include <file.au3>
#include <EditConstants.au3>
#include <GuiEdit.au3>
#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <GUIListBox.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <array.au3>


Global $base_logo = @ScriptDir & "\logo_base.jpg"

#Region ### choix du client
$Gui_choix_client = GUICreate("Choix du client", 522, 194, -1, -1)
GUISetBkColor(0xA6CAF0)
GUICtrlCreateGroup("Choisir la société", 5, 8, 508, 73, $BS_CENTER)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Cmb_choix_client = GUICtrlCreateCombo("", 13, 34, 488, 25)
GUICtrlSetFont(-1, 14, 400, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Cancel_gui_client = GUICtrlCreateButton("Annuler", 5, 160, 250, 25, $WS_GROUP)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
$Next_Gui_Client = GUICtrlCreateButton("Suivant", 265, 160, 250, 25, $WS_GROUP)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
$logo_society_client = GUICtrlCreatePic($base_logo, 160, 88, 204, 60, BitOR($SS_NOTIFY,$WS_GROUP,$WS_CLIPSIBLINGS), $WS_EX_CLIENTEDGE)
GUISetState(@SW_SHOW)
Dim $Gui_choix_client_AccelTable[2][2] = [["{ESC}", $Cancel_gui_client],["{ENTER}", $Next_Gui_Client]]
GUISetAccelerators($Gui_choix_client_AccelTable)
#EndRegion ### END Koda GUI section ###

Global $client_name; Lire la combobox client

Global $logo_society ; emplacement du logo par defaut.

_initial_folder_client_read()

_Guiintro_choix_clients()

Func _Guiintro_choix_clients()

GUISetState(@SW_SHOW, $Gui_choix_client)

    While 1
        $nMsg = GUIGetMsg(1)
        Select

            Case $nMsg[0] = $GUI_EVENT_CLOSE And $nMsg[1] = $Gui_choix_client
                Exit

            Case $nMsg[0] = $Cancel_gui_client And $nMsg[1] = $Gui_choix_client
                Exit

            Case $nMsg[0] = $Cmb_choix_client And $nMsg[1] = $Gui_choix_client
                If GUICtrlRead($Cmb_choix_client) = "(Aucun)" Then
                    Sleep(50)
                Else

                _changelogo()

                EndIf

        EndSelect
    WEnd

EndFunc
#endregion

Func _initial_folder_client_read()

Dim $list_folder_client = _FileListToArray(@ScriptDir & "\", "*", 2)

GUISetState(@SW_SHOW, $Gui_choix_client)

GUICtrlSetData($Cmb_choix_client, "")
GUICtrlSetData($Cmb_choix_client, "(aucun)", "(aucun)")

For $list = 1 To $list_folder_client[0]
    GUICtrlSetData($Cmb_choix_client, $list_folder_client[$list])
Next

EndFunc

func _changelogo()

$logo_society = @ScriptDir & "\" & GUICtrlRead($Cmb_choix_client) & "\logo.jpg" ; emplacement du logo par defaut.

If Not FileExists($logo_society) Then

GUICtrlSetImage($logo_society_client, $base_logo)

ElseIf FileExists($logo_society) Then

GUICtrlSetImage($logo_society_client, $logo_society)


EndIf

EndFunc

logos.zip: (94.63 Kio) Téléchargé 254 fois

Est il possible de proceder à une taille uniforme de maniere simple ?

Je voudrais savoir s'il y a un moyen de fixer cette taille, sans avoir à retoucher chaque logos avec un editeur d'images.

En vous remerciant par avance pour vos réponses.

Bonjour,

Je me suis heurté au même souci il y a quelques temps, et je n'ai pas le code sous la main; en attendant que je le retrouve, voici un correctif pour le moins "bourrin" : on efface l'image et on recommence !

► Afficher le texteCorrection

Code : Tout sélectionner

#include <ButtonConstants.au3>
#Include <GuiComboBox.au3>
#include <ComboConstants.au3>
#include <file.au3>
#include <EditConstants.au3>
#include <GuiEdit.au3>
#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <GUIListBox.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <array.au3>



; création des chemins d'acces temporaires

Global $base_logo = @ScriptDir & "\logo_base.jpg"
; declaration du fichier temporaire (dossier dans lequel les fichiers ini sont enregistrés

#Region ### choix du client
$Gui_choix_client = GUICreate("Choix du client", 522, 194, -1, -1)
GUISetBkColor(0xA6CAF0)
GUICtrlCreateGroup("Choisir la société", 5, 8, 508, 73, $BS_CENTER)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Cmb_choix_client = GUICtrlCreateCombo("", 13, 34, 488, 25)
GUICtrlSetFont(-1, 14, 400, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Cancel_gui_client = GUICtrlCreateButton("Annuler", 5, 160, 250, 25, $WS_GROUP)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
$Next_Gui_Client = GUICtrlCreateButton("Suivant", 265, 160, 250, 25, $WS_GROUP)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
Global $logo_society_client_POSITION[4] = [160, 88, 204, 60]
Global $logo_society_client = GUICtrlCreatePic($base_logo, _
    $logo_society_client_POSITION[0], $logo_society_client_POSITION[1], $logo_society_client_POSITION[2], $logo_society_client_POSITION[3], _
    BitOR($SS_NOTIFY,$WS_GROUP,$WS_CLIPSIBLINGS), $WS_EX_CLIENTEDGE)
GUISetState(@SW_SHOW)
Dim $Gui_choix_client_AccelTable[2][2] = [["{ESC}", $Cancel_gui_client],["{ENTER}", $Next_Gui_Client]]
GUISetAccelerators($Gui_choix_client_AccelTable)
#EndRegion ### END Koda GUI section ###

Global $client_name; Lire la combobox client

Global $logo_society ; emplacement du logo par defaut.

_initial_folder_client_read()

_Guiintro_choix_clients()



Func _Guiintro_choix_clients()

GUISetState(@SW_SHOW, $Gui_choix_client)

    While 1
        $nMsg = GUIGetMsg(1)
        Select

            Case $nMsg[0] = $GUI_EVENT_CLOSE And $nMsg[1] = $Gui_choix_client
                Exit

            Case $nMsg[0] = $Cancel_gui_client And $nMsg[1] = $Gui_choix_client
                Exit

            Case $nMsg[0] = $Cmb_choix_client And $nMsg[1] = $Gui_choix_client
                If GUICtrlRead($Cmb_choix_client) = "(Aucun)" Then
                    Sleep(50)
                Else

                _changelogo()

                EndIf

        EndSelect
    WEnd

EndFunc
#endregion

Func _initial_folder_client_read()

    Dim $list_folder_client = _FileListToArray(@ScriptDir & "\", "*", 2)

    GUISetState(@SW_SHOW, $Gui_choix_client)

    GUICtrlSetData($Cmb_choix_client, "")
    GUICtrlSetData($Cmb_choix_client, "(aucun)", "(aucun)")

    For $list = 1 To $list_folder_client[0]
        GUICtrlSetData($Cmb_choix_client, $list_folder_client[$list])
    Next

EndFunc

func _changelogo()
    $client_name = GUICtrlRead($Cmb_choix_client); Lire la combobox client
    $logo_society = @ScriptDir & "\" & GUICtrlRead($Cmb_choix_client) & "\logo.jpg" ; emplacement du logo par defaut.
    If Not FileExists($logo_society) Then $logo_society = $base_logo
    Global $logo_society_client_POSITION[4] = [160, 88, 204, 60]
    ; Methode bourrine :
    GUICtrlDelete($logo_society_client)
    $logo_society_client = GUICtrlCreatePic($logo_society, _
        $logo_society_client_POSITION[0], $logo_society_client_POSITION[1], $logo_society_client_POSITION[2], $logo_society_client_POSITION[3], _
        BitOR($SS_NOTIFY,$WS_GROUP,$WS_CLIPSIBLINGS), $WS_EX_CLIENTEDGE)
EndFunc

A bientôt !

La solution me semble pas mal.

je vais la tester.

Merci encore.

Bonjour,

Cela fonctionne très bien , et , je le confirme , la methode est sauvage.

Du coup, j'ai essayé plusieurs approches en utilisant guictrlsetpos et guictrlsetlimit, on en revient au résultat du debut, à savoir une incrementation de la taille de l'image ( je serai curieux d'en connaitre la cause d'ailleurs)

C'est dommage, je pensait que la methode était plus simple.

Je laisse le sujet ouvert 3 jours de plus, si cela ne dérange pas les modérateurs, au cas ou une personne aurait une autre idée.

Quoi qu'il en soit, je remercie ZDS pour son astuce.

je vais l'utiliser pour mon code final.

Bizarrement il semble que ce soit le $WS_EX_CLIENTEDGE qui perturbe

avec cette ligne modifiée

Code : Tout sélectionner

$logo_society_client = GUICtrlCreatePic($base_logo, 160, 88, 204, 60, BitOR($SS_NOTIFY, $WS_GROUP,$WS_CLIPSIBLINGS))

plus de problème

Si vous voulez conserver le look "$WS_EX_CLIENTEDGE", vous pouvez tricher en plaçant une label sous l'image, votre gui devient :

Code : Tout sélectionner

#Region ### choix du client
$Gui_choix_client = GUICreate("Choix du client", 522, 194, -1, -1, -1, $WS_EX_LAYERED+$WS_EX_COMPOSITED)  ; <== attention, nouveau style
GUISetBkColor(0xA6CAF0)
GUICtrlCreateGroup("Choisir la société", 5, 8, 508, 73, $BS_CENTER)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Cmb_choix_client = GUICtrlCreateCombo("", 13, 34, 488, 25)
GUICtrlSetFont(-1, 14, 400, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Cancel_gui_client = GUICtrlCreateButton("Annuler", 5, 160, 250, 25, $WS_GROUP)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
$Next_Gui_Client = GUICtrlCreateButton("Suivant", 265, 160, 250, 25, $WS_GROUP)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
      ;on triche ici
GUICtrlCreateLabel ("", 158, 86, 208, 64, -1, $WS_EX_CLIENTEDGE)  ; <== le cadre fait 2 pixels 
$logo_society_client = GUICtrlCreatePic($base_logo, 160, 88, 204, 60, BitOR($SS_NOTIFY, $WS_GROUP,$WS_CLIPSIBLINGS))
GuiCtrlSetState(-1, $GUI_ONTOP)

GUISetState(@SW_SHOW)

bonjour, bonjour ...

Désolé pour le retard.

J'avais (presque) oublié mon post

.

Je vais jongler entre les deux solution.

Je passe le sujet en clos.

Je remercie mikel et zds pour leur aide.

Je ressors ce vieux post parce que ayant été confronté au même problème, j'ai ENFIN la BONNE réponse

Code : Tout sélectionner

GUICtrlCreatePic($base_logo, 160, 88, 204, 60, BitOR([color=#FF0000]$SS_CENTERIMAGE[/color],$SS_NOTIFY,$WS_GROUP,$WS_CLIPSIBLINGS), $WS_EX_CLIENTEDGE)

Oufff...

mikell a écrit :Je ressors ce vieux post parce que ayant été confronté au même problème, j'ai ENFIN la BONNE réponse
Code : Tout sélectionner
GUICtrlCreatePic($base_logo, 160, 88, 204, 60, BitOR([color=#FF0000]$SS_CENTERIMAGE[/color],$SS_NOTIFY,$WS_GROUP,$WS_CLIPSIBLINGS), $WS_EX_CLIENTEDGE)
Oufff...

Avec BeauCoup de retard, Merci Mikell

AutoIt Français

[R] Problème de cadrage image (logo)

[R] Problème de cadrage image (logo)

Re: [..]probleme de cadrage image (logo)

Re: [..]probleme de cadrage image (logo)

Re: [..] Problème de cadrage image (logo)

Re: [..] Problème de cadrage image (logo)

Re: [..] Problème de cadrage image (logo)

Re: [R] Problème de cadrage image (logo)

Re: [R] Problème de cadrage image (logo)