AutoIt Français

Bonjour,

Existe-t-il un moyen de modifier la couleur d'un item d'une listview lorsque celle-ci est déjà remplie ?
En effectuant des recherches sur le forum, j'ai trouvé des exemples de code pour modifier la couleur du texte d'un item au moment où il est inséré dans la liste, mais après coup je ne trouve pas.
Faut-il retirer l'item et le remettre en modifiant sa couleur ?
(a priori ça me semble un peu lourd comme méthode)

Voici le contexte :
Les items de la listview sont des adresses IP de stations.
Le script effectue des opérations sur chaque station sélectionnée dans la liste.
Quand l'opération se termine sur une station, je souhaite changer la couleur de l'item selon le résultat de l'action. Exemple texte rouge si erreur, texte vert si OK.

Voila, merci d'avance...
Val

Bonjour

je sais pas si c'est possible.

Une autre idée qui est surement plus simple. Tu change l'image de l'item.

Tu créer autant d'icônes que tu veux, pour chaque état.
1 en attente
2 ok
3 erreur

Une autre idée, tu utilises les groupes
1 groupe Fais sans erreur
1 groupe Fais avec erreur

Bien sur tu peux faire les 2, Icônes plus groupes.

_GUICtrlListView_SetItemImage() pour changer l'image

_GUICtrlListView_EnableGroupView() pour activer la vue par groupe
_GUICtrlListView_InsertGroup() pour créer les groupes dans la LV
_GUICtrlListView_SetItemGroupID() pour affecter un item dans un groupe

@val25

Merci de prendre le temps de lire les règles de présentation d'un message.

Pour changer la couleur de fond j'utilise (ça marche aussi quand c'est déjà rempli) :

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
$a_listViewItems[$i] = GUICtrlCreateListViewItem(..., $idListView)
GUICtrlSetBkColor($a_listViewItems[$i], $GUI_BKCOLOR_TRANSPARENT) ; fond transparent
GUICtrlSetBkColor($a_listViewItems[$i], 0xff0000) ; fond rouge

mais j'ai vu qu'il y a d'autres fonctions dans le même genre dans les _GUICtrlListView_...

Merci à tous ceux qui m'ont répondu.
Je suis revenu à d'autre tâches, mais je garde vos propositions sous le coude.
J'ajouterai des commentaires dès que possible pour clôturer le fil.
A bientôt

Bonjour,

Désolé de déterrer ce sujet mais j'ai exactement le même soucis.

Je suis allé du côté de WM_NOTIFY et $NM_CUSTOMDRAW mais impossible de modifier la couleur d'un item de la listview en cliquant dessus par exemple.

Est-ce qu'une solution a été trouvé depuis la création de ce sujet ?

WM_NOTIFY est la bonne piste, voilà un exemple avec dble-clic (adaptable)

► Afficher le texte

Code : Tout sélectionner

#include <WindowsConstants.au3>
#include <GuiConstantsEx.au3>
#include <ListviewConstants.au3>
#include <Array.au3>
Global Const $tagNMHDR = "struct; hwnd hWndFrom;uint_ptr IDFrom;INT Code; endstruct"
Global Const $tagNMITEMACTIVATE = $tagNMHDR & ";int Index;int SubItem;int NewState;int OldState;" & _
         "int Changed;int X;int Y;int lParam;int KeyFlags"

Dim $array[3][3]
$array[0][1] = @Autoitexe
$array[0][2] = FileGetVersion(@Autoitexe)
$array[1][1] = "ligne 2, colonne 1"
$array[1][2] = "ligne 2, colonne 2"
$array[2][1] = "ligne 3, colonne 1"
$array[2][2] = "ligne 3, colonne 2"

$gui = GUICreate("listview items", 420, 180, 100, 200, -1)
$listview = GUICtrlCreateListView("icone|colonne 1|colonne 2 ", 10, 10, 400, 130)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 0, 80)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 1, 200)

Dim $ligne[3]
$ligne[0] = GUICtrlCreateListViewItem("(1)|" &$array[0][1] & "|" & $array[0][2], $listview)
GUICtrlSetImage(-1, @Autoitexe, -1)  
$ligne[1] = GUICtrlCreateListViewItem("(2)|" &$array[1][1] & "|" & $array[1][2], $listview)
GUICtrlSetImage(-1, @SystemDir & "\shell32.dll", -132)
$ligne[2] = GUICtrlCreateListViewItem("(3)|" &$array[2][1] & "|" & $array[2][2], $listview)
GUICtrlSetImage(-1, @SystemDir & "\shell32.dll", -138)
GUISetState()

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    $hWndListView = GUICtrlGetHandle($listView)
    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $NM_DBLCLK 
                         $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                         $index = DllStructGetData($tInfo, "Index")
                         For $i = 0 to 2
                               GuiCtrlSetColor($ligne[$i], 0x000000)
                         Next
                         GuiCtrlSetColor($ligne[$index], 0xff0000)
                         ControlListView($gui, "", $listview, "DeSelect", -1)
           EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Merci beaucoup pour cet exemple.
Malheureusement j'utilise _GUICtrlListView_AddItem et _GUICtrlListView_AddSubItem pour compléter ou mettre à jour la listview et je vois dans votre code que vous récupérez les controlID des items en retour de GUICtrlCreateListViewItem. Ce qui vous permet ensuite de colorer le texte avec GuiCtrlSetColor.

Y a-t-il un moyen pour récupérer les controlID de mes items ?

Edit : Au départ, faute de pouvoir utiliser GuiCtrlSetColor, j'étais parti sur la structure $tagNMCUSTOMDRAW qui permet de modifier les couleurs des items ("clrText" et "clrTextBk") mais je n'ai pas réussi à gérer les messages issus de NM_CUSTOMDRAW.

tatane a écrit :Y a-t-il un moyen pour récupérer les controlID de mes items ?

Non
Mais une gestion de listview peut très bien être faite par GUICtrlCreateListViewItem + GuiCtrlSetData, est-il vraiment nécessaire d'utiliser _GUICtrlListView_AddItem & Co qui ne sont pas du tout pratiques ?

Et bien cela dépend si l'on peut ajouter des icônes/images où l'on souhaite avec la fonction Listview native.
De ce que j'ai pu lire, on peut en ajouter en première colonne via GuiCtrlSetimage mais pas ailleurs ?

Ah mais non

► Afficher le texte

Code : Tout sélectionner

#include <WindowsConstants.au3>
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <Array.au3>

Dim $array[3][3]
$array[0][1] = @Autoitexe
$array[0][2] = FileGetVersion(@Autoitexe)
$array[1][1] = "ligne 2, colonne 1"
$array[1][2] = "ligne 2, colonne 2"
$array[2][1] = "ligne 3, colonne 1"
$array[2][2] = "ligne 3, colonne 2"

$gui = GUICreate("listview items", 420, 180, 100, 200, -1)
$listview = GUICtrlCreateListView("icone|colonne 1|colonne 2 ", 10, 10, 400, 130, -1, $LVS_EX_SUBITEMIMAGES+$LVS_EX_FULLROWSELECT)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 0, 60)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 1, 200)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 2, 130)

$hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @Autoitexe, 0)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 132)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 138)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
_GUICtrlListView_SetImageList($listview, $hImage, 1)

Dim $ligne[3]
$ligne[0] = GUICtrlCreateListViewItem("|" &$array[0][1] & "| ", $listview)
$ligne[1] = GUICtrlCreateListViewItem("|" &$array[1][1] & "|" , $listview)
$ligne[2] = GUICtrlCreateListViewItem("|" &$array[2][1] & "|" , $listview)

_GUICtrlListView_AddSubItem($listview, 0, "(1)", 0, 0)
_GUICtrlListView_AddSubItem($listview, 1, "(2)", 0, 1)
_GUICtrlListView_AddSubItem($listview, 2, "(3)", 0, 2)
_GUICtrlListView_AddSubItem($listview, 0, $array[0][2], 2, 3)
_GUICtrlListView_AddSubItem($listview, 1, $array[1][2], 2, 4)
_GUICtrlListView_AddSubItem($listview, 2, $array[2][2], 2, 5)
GUISetState()

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
   

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    $hWndListView = GUICtrlGetHandle($listView)
    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $NM_DBLCLK
                         $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
; msgbox(0,"", "Index = " & DllStructGetData($tInfo, "Index") &@crlf& _
;       "SubItem = " & DllStructGetData($tInfo, "SubItem") )
                         $index = DllStructGetData($tInfo, "Index")
                         For $i = 0 to 2
                               GuiCtrlSetColor($ligne[$i], 0x000000)
                         Next
                         GuiCtrlSetColor($ligne[$index], 0xff0000)
                         ControlListView($gui, "", $listview, "DeSelect", -1)
           EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

AMHA l'important c'est qu'avec GUICtrlCreateListViewItem tu identifies les items (ID, handle, index) alors qu'avec l'autre machin tu n'as que leurs index ... ce qui te fait une belle jambe si la listview doit évoluer ^^
Après si tu veux gérer la couleur de texte par subitem là en revanche tu peux pas échapper aux joies de NM_CUSTOMDRAW (même si avoir les ids des items peut faciliter la tâche)

Je suis d'accord avec vous, ne récupérer que l'index des items est assez pénible.
En fait je pensais que pour ajouter un subitem par la fonction UDF il fallait au préalable avoir créer l'item avec _GUICtrlListView_AddItem. Des fois je me mettrais des claques...

Voici le bout de code permettant de modifier la couleur de l'item souhaité. Par contre je ne sais pas comment modifier la couleur d'un subitem sans modifier toute la ligne :

Code : Tout sélectionner

        Case $hWndListViewPC
            Switch $iCode
                Case $NM_CUSTOMDRAW ; afin de changer la couleur ou la police du texte des items de la listview
                    If Not _GUICtrlListView_GetViewDetails($hWndFrom) Then Return $GUI_RUNDEFMSG

                    Local $iDrawStage, $tCustDraw
                    $tCustDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $ilParam)
                    $iDrawStage = DllStructGetData($tCustDraw, 'dwDrawStage')
                    $iIndex = DllStructGetData($tCustDraw, 'dwItemSpec')

                    If $iDrawStage = $CDDS_PREPAINT Then Return $CDRF_NOTIFYITEMDRAW

                    If $iDrawStage = $CDDS_ITEMPREPAINT Then
                        If $tab_stock_couleur[$iIndex] <> "" Then ; tableau stockant des couleurs prédéfinies
                            DllStructSetData($tCustDraw, 'clrText', RGB2BGR($tab_stock_couleur[$iIndex]))
                        EndIf
                        Return $CDRF_NOTIFYSUBITEMDRAW
                    EndIf
            EndSwitch

Bon j'ai quelque chose là
On check l'item et le subitem avec le NM_CLICK avant de l'exploiter dans le NM_CUSTOMDRAW
Par facilité parce que j'avais déjà un bout de script ici j'utilise _GUICtrlListView_Create

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>

Global $Array1[6], $click_item = -1, $click_subitem
$Array1[0] = "JPM"
$Array1[1] = "Holger"
$Array1[2] = "Jon"
$Array1[3] = "Larry"
$Array1[4] = "Jeremy"
$Array1[5] = "Valik"

$hGUI = GUICreate("Test", 300, 300)
Global $hListView = _GUICtrlListView_Create($hGUI, "Items|SubItems|", 10, 10, 280, 180, -1, $WS_EX_CLIENTEDGE)
_GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
For $i = 0 To 5
     _GUICtrlListView_AddItem($hListView, "Item :" & $i)
     _GUICtrlListView_AddSubItem($hListView, $i , $Array1[$i], 1)
 Next
GUISetState()

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
    Case $GUI_EVENT_CLOSE
         Exit
EndSwitch
WEnd


Func WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)
     Local $tNMHDR, $hWndFrom, $iCode
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
     $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
     $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom
         Case $hListView
             Switch $iCode
                 Case $NM_CLICK  ; DBLCLK
                     $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                     $click_item = DllStructGetData($tInfo, "Index")
                     $click_subItem = DllStructGetData($tInfo, "SubItem") 
                     ControlListView($hGUI, "", $hListview, "DeSelect", -1)
                     _GUICtrlListView_SetItemFocused($hListView, $click_item, false)
                     _GUICtrlListView_SetTextColor($hListview, 0)

               Case $NM_CUSTOMDRAW
                     Local $tCustDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
                     Local $iDrawStage = DllStructGetData($tCustDraw, "dwDrawStage")
                     If $iDrawStage = $CDDS_PREPAINT Then Return $CDRF_NOTIFYITEMDRAW
                     If $iDrawStage = $CDDS_ITEMPREPAINT Then Return $CDRF_NOTIFYSUBITEMDRAW
                     Local $iSubItem = DllStructGetData($tCustDraw, "iSubItem")
                     Local $iItem = DllStructGetData($tCustDraw, "dwItemSpec")
                     Local $iColor

                     If $iItem = $click_item and $iSubItem = $click_subitem Then
                         If $click_subitem = 0 Then
                              $iColor = RGB2BGR(0x00ff00)
                         ElseIf $click_subitem = 1 Then
                              $iColor = RGB2BGR(0xff0000)
                         EndIf
                    Else
                           $iColor = RGB2BGR(0x000000)
                     EndIf
                     DllStructSetData($tCustDraw, "clrText", $iColor)
                     Return $CDRF_NEWFONT

             EndSwitch
     EndSwitch
    Return $GUI_RUNDEFMSG
 EndFunc   ;==>WM_NOTIFY

Func RGB2BGR($iColor)
     Return BitAND(BitShift(String(Binary($iColor)), 8), 0xFFFFFF)
EndFunc   ;==>RGB2BGR()

Edit
... mais ça marche aussi avec GuiCtrlCreateListview

► Afficher le texte

Code : Tout sélectionner

#include <WindowsConstants.au3>
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <Array.au3>

Global $click_item = -1, $click_subitem
Dim $array[3][3]
$array[0][1] = @Autoitexe
$array[0][2] = FileGetVersion(@Autoitexe)
$array[1][1] = "ligne 2, colonne 1"
$array[1][2] = "ligne 2, colonne 2"
$array[2][1] = "ligne 3, colonne 1"
$array[2][2] = "ligne 3, colonne 2"

$gui = GUICreate("listview items", 420, 180, 100, 200, -1)
$listview = GUICtrlCreateListView("icone|colonne 1|colonne 2 ", 10, 10, 400, 130, -1, $LVS_EX_SUBITEMIMAGES+$LVS_EX_FULLROWSELECT)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 0, 60)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 1, 200)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 2, 130)

$hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @Autoitexe, 0)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 132)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 138)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
_GUICtrlListView_SetImageList($listview, $hImage, 1)

Dim $ligne[3]
$ligne[0] = GUICtrlCreateListViewItem("|" &$array[0][1] & "| ", $listview)
$ligne[1] = GUICtrlCreateListViewItem("|" &$array[1][1] & "|" , $listview)
$ligne[2] = GUICtrlCreateListViewItem("|" &$array[2][1] & "|" , $listview)

_GUICtrlListView_AddSubItem($listview, 0, "(1)", 0, 0)
_GUICtrlListView_AddSubItem($listview, 1, "(2)", 0, 1)
_GUICtrlListView_AddSubItem($listview, 2, "(3)", 0, 2)
_GUICtrlListView_AddSubItem($listview, 0, $array[0][2], 2, 3)
_GUICtrlListView_AddSubItem($listview, 1, $array[1][2], 2, 4)
_GUICtrlListView_AddSubItem($listview, 2, $array[2][2], 2, 5)
GUISetState()

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
   

Func WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)
     Local $tNMHDR, $hWndFrom, $iCode
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
     $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
     $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom
         Case GuiCtrlGetHandle($listView)
             Switch $iCode
                 Case $NM_CLICK  ; DBLCLK
                     $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                     $click_item = DllStructGetData($tInfo, "Index")
                     $click_subItem = DllStructGetData($tInfo, "SubItem") 
                     ControlListView($gUI, "", $listview, "DeSelect", -1)
                     _GUICtrlListView_SetItemFocused($listView, $click_item, false)
                     If $click_item<>-1 Then _GUICtrlListView_SetTextColor($listview, 0)

               Case $NM_CUSTOMDRAW
                     Local $tCustDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
                     Local $iDrawStage = DllStructGetData($tCustDraw, "dwDrawStage")
                     If $iDrawStage = $CDDS_PREPAINT Then Return $CDRF_NOTIFYITEMDRAW
                     If $iDrawStage = $CDDS_ITEMPREPAINT Then Return $CDRF_NOTIFYSUBITEMDRAW
                     Local $iSubItem = DllStructGetData($tCustDraw, "iSubItem")
                     Local $iItem = DllStructGetData($tCustDraw, "dwItemSpec")
                     Local $iColor

                     If $iItem = $click_item and $iSubItem = $click_subitem Then
                         If $click_subitem = 1 Then
                              $iColor = RGB2BGR(0x00ff00)
                         ElseIf $click_subitem = 2 Then
                              $iColor = RGB2BGR(0xff0000)
                         EndIf
                    Else
                           $iColor = 0
                     EndIf
                     DllStructSetData($tCustDraw, "clrText", $iColor)
                     Return $CDRF_NEWFONT

             EndSwitch
     EndSwitch
    Return $GUI_RUNDEFMSG
 EndFunc   ;==>WM_NOTIFY

Func RGB2BGR($iColor)
     Return BitAND(BitShift(String(Binary($iColor)), 8), 0xFFFFFF)
EndFunc   ;==>RGB2BGR()

En un mot : Génial

Par contre je ne comprends pas comment seul le subitem peut changer de couleur ?
La fonction utilisée est toujours la même "DllStructSetData($tCustDraw, "clrText", $iColor)" et on ne précise pas spécialement l'index du subitem ?
Pourquoi ne repaint-il pas toute la ligne ?
De plus vous utilisez $CDRF_NEWFONT comme retour de message, est-ce une obligation ?

Désolé de vous embêter encore mais pouvez-vous m'expliquer en détails le fonctionnement de ce fichu $NM_CUSTOMDRAW ?

Merci par avance.

En fait dans NM_CUSTOMDRAW les notifications sont retournées par étapes, c'est le fait d'avoir retourné CDRF_NOTIFYSUBITEMDRAW à l'étape précédente qui autorise l'action sur les subitems
Et c'est à l'étape suivante qu'on précise l'index du subitem à modifier (le $click_subitem récupéré au NM_CLICK), tu peux le vérifier en modifiant juste cette ligne

Code : Tout sélectionner

If $iItem = $click_item Then [color=#dd0000];;; and $iSubItem = $click_subitem Then[/color]

où là effectivement toute la ligne est repeinte, mais d'une couleur différente selon le subitem cliqué

Quand on a assimilé le concept de fonctionnement, les possibilités deviennent variées
Par exemple pour que l'item garde sa nouvelle couleur il suffit de commenter cette ligne dans le NM_CLICK

Code : Tout sélectionner

; If $click_item<>-1 Then _GUICtrlListView_SetTextColor($listview, 0)

Je renvoie CDRF_NEWFONT pour notifier les modifications mais CDRF_NOTIFYSUBITEMDRAW marche aussi
Pour le fonctionnement en détail voir ici :
http://msdn.microsoft.com/en-us/library ... 85%29.aspx
(surtout en bas de la page) où pour une fois MS explique les choses clairement

Merci beaucoup pour toutes ces précisions.
En effet msdn est assez velu et souvent manque de liens d'explications...
En tout cas grâce à vous je vais pouvoir désormais m'amuser avec Custom Draw.

Oui, par exemple : dans la mesure où on colore les (sub)items sélectionnés, on peut alors avoir envie de se débarrasser de la pollution visuelle que représente le 'highlight' au clic

► Afficher le texte

Code : Tout sélectionner

#include <WindowsConstants.au3>
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

Global $click_item = -1, $click_subitem
Dim $array[3][3]
$array[0][1] = @Autoitexe
$array[0][2] = FileGetVersion(@Autoitexe)
$array[1][1] = "ligne 2, colonne 1"
$array[1][2] = "ligne 2, colonne 2"
$array[2][1] = "ligne 3, colonne 1"
$array[2][2] = "ligne 3, colonne 2"

$gui = GUICreate("listview items", 420, 180, 500, 20, -1)
$listview = GUICtrlCreateListView("icone|colonne 1|colonne 2 ", 10, 10, 400, 130, -1, $LVS_EX_SUBITEMIMAGES+$LVS_EX_FULLROWSELECT)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 0, 60)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 1, 200)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 2, 130)

$hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @Autoitexe, 0)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 132)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 138)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
_GUICtrlListView_SetImageList($listview, $hImage, 1)

Dim $ligne[3]
$ligne[0] = GUICtrlCreateListViewItem("|" &$array[0][1] & "| ", $listview)
$ligne[1] = GUICtrlCreateListViewItem("|" &$array[1][1] & "|" , $listview)
$ligne[2] = GUICtrlCreateListViewItem("|" &$array[2][1] & "|" , $listview)

_GUICtrlListView_AddSubItem($listview, 0, "(1)", 0, 0)
_GUICtrlListView_AddSubItem($listview, 1, "(2)", 0, 1)
_GUICtrlListView_AddSubItem($listview, 2, "(3)", 0, 2)
_GUICtrlListView_AddSubItem($listview, 0, $array[0][2], 2, 3)
_GUICtrlListView_AddSubItem($listview, 1, $array[1][2], 2, 4)
_GUICtrlListView_AddSubItem($listview, 2, $array[2][2], 2, 5)
GUISetState()

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
   

Func WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)
     Local $tNMHDR, $hWndFrom, $iCode
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
     $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
     $iCode = DllStructGetData($tNMHDR, "Code")
     $hListView = GuiCtrlGetHandle($listView)

    Switch $hWndFrom
         Case $hListView
             Switch $iCode
                 Case $NM_CLICK  ; DBLCLK
                     Local $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                     $click_item = DllStructGetData($tInfo, "Index")
                     $click_subItem = DllStructGetData($tInfo, "SubItem") 
                     If $click_item<>-1 Then _GUICtrlListView_SetTextColor($hListView, 0)

               Case $NM_CUSTOMDRAW
                     Local $tCustDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
                     Local $iDrawStage = DllStructGetData($tCustDraw, "dwDrawStage")
                     Local $iSubItem = DllStructGetData($tCustDraw, "iSubItem")
                     Local $iItem = DllStructGetData($tCustDraw, "dwItemSpec")
                     Local $iColor
                     If $iDrawStage = $CDDS_PREPAINT Then Return $CDRF_NOTIFYITEMDRAW
                     If $iDrawStage = $CDDS_ITEMPREPAINT Then 
                          ControlListView($gui, "", $listview, "DeSelect", $iItem)
                         _GUICtrlListView_SetItemFocused($hListView, $iItem, false)
                         Return $CDRF_NOTIFYSUBITEMDRAW
                    EndIf

                     If $iItem = $click_item and $iSubItem = $click_subitem Then
                         If $click_subitem = 1 Then
                              $iColor = RGB2BGR(0x00ff00)
                         ElseIf $click_subitem = 2 Then
                              $iColor = RGB2BGR(0xff0000)
                         EndIf
                    Else
                           $iColor = 0
                     EndIf
                     DllStructSetData($tCustDraw, "clrText", $iColor)
                     Return $CDRF_NEWFONT

             EndSwitch
     EndSwitch
    Return $GUI_RUNDEFMSG
 EndFunc   ;==>WM_NOTIFY

Func RGB2BGR($iColor)
     Return BitAND(BitShift(String(Binary($iColor)), 8), 0xFFFFFF)
EndFunc   ;==>RGB2BGR()

Tiens d'ailleurs en parlant de sélection, est-il possible de changer la couleur du highlight de cette façon ?
Il me semble avoir lu que cela dépendait du thème de Windows et que le seul moyen était de repeindre par dessus via les fonctions _GDIPlus (texte et fond) ?

AutoIt Français

[..] Modifier la couleur d'un item dans une listview

[..] Modifier la couleur d'un item dans une listview

Re: Modifier la couleur d'un item dans une listview déjà remplie

Re: [..] Modifier la couleur d'un item dans une listview

Re: [..] Modifier la couleur d'un item dans une listview

Re: [..] Modifier la couleur d'un item dans une listview

Re: [..] Modifier la couleur d'un item dans une listview

Re: [..] Modifier la couleur d'un item dans une listview

Re: [..] Modifier la couleur d'un item dans une listview

Re: [..] Modifier la couleur d'un item dans une listview

Re: [..] Modifier la couleur d'un item dans une listview

Re: [..] Modifier la couleur d'un item dans une listview

Re: [..] Modifier la couleur d'un item dans une listview

Re: [..] Modifier la couleur d'un item dans une listview

Re: [..] Modifier la couleur d'un item dans une listview

Re: [..] Modifier la couleur d'un item dans une listview

Re: [..] Modifier la couleur d'un item dans une listview

Re: [..] Modifier la couleur d'un item dans une listview

Re: [..] Modifier la couleur d'un item dans une listview