AutoIt Français

Bonjour,

Je n'arrive pas à bloquer mon GUI qui est affiché en plein écran grace à la fonction:

WinSetState($MainGUI, "", @SW_MAXIMIZE)

J'ai trouvé la fonction Func WM_WINDOWPOSCHANGING($hWnd, $iMsg, $wParam, $lParam)
pour empêcher le GUI de ne pas bouger mais ça ne fonctionne pas avec le WinSetState... Lorsque j'essai de bouger mon GUI avec la barre de titre, le GUI se redimensionne avec la valeur de défaut qu'il a été créé...

Ci joint mon code.

► Afficher le texte

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=favicon.ico
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
;==[ Création ]========:   xx/xx/2014
;==[ Auteur ]==========:    
;==[ Service ]=========:    
;==[ Description ]=====:    
;==[ Modification ]====:    Dernière modification le xx/xx/20xx
;==[ Nature modification ]====:
    ;==[xx/xx/20xx: ***********************************]========


;==[Includes]===================================================
#include <File.au3>
#include <Date.au3>
#include <GuiStatusBar.au3>
#include <Timers.au3>
#include <Date.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <GuiListView.au3>
#include <StructureConstants.au3>

Opt("GUIOnEventMode", 1)
$Debug_LV = False ; Check ClassName being passed to ListView functions, set to True and use a handle to another control to see it work

;==[Variables globales & autres]================================
Global $CSVFolder = @ScriptDir & "\csv\"
Global $MainGUI, $ChildGUI, $FileToOpen, $aArrayOfMyFile
Global $hStatus, $aParts[3] = [200, 450, 200], $aGuiPos, $WorkAera
Global $x, $y, $w, $h
Global $ApplicationName = "Modèle vierge", $Version = "Demo", $Author = "DocteurX"

;==[Programme]==================================================

_BuildMainGUI()
GUIRegisterMsg($WM_SIZE, "WM_SIZE")
GUIRegisterMsg($WM_TIMER, "WM_TIMER")
$iTimer = _Timer_SetTimer($MainGUI, 1000)

While GUIGetMsg() <> -3
WEnd


Func _BuildMainGUI()

    $MainGUI = GUICreate($ApplicationName & " Powered By " & $Author & ". Version: " & $Version, 437, 185, -1, -1)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit", $MainGUI)
    WinSetState($MainGUI, "", @SW_MAXIMIZE)
    $hStatus = _GUICtrlStatusBar_Create($MainGUI, -1, "", $SBARS_SIZEGRIP)

    GUIRegisterMsg($WM_WINDOWPOSCHANGING, 'WM_WINDOWPOSCHANGING')
    GUISetState(@SW_SHOW)

    ;==[StatusBar]==============================
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)
    DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", $hStatus, "wstr", 0, "wstr", 0)
    $hIcons = _WinAPI_LoadShell32Icon(265); 233 -> Icon ATTENTION,
    _GUICtrlStatusBar_SetIcon($hStatus, 0, $hIcons)
    $hIcons2 = _WinAPI_LoadShell32Icon(160); 233 -> Icon ATTENTION,
    _GUICtrlStatusBar_SetIcon($hStatus, 1, $hIcons2)
    _GUICtrlStatusBar_SetText($hStatus, "Utilisateur: " & StringUpper(@UserName) & " " & "Poste: " & @ComputerName, 1)

    $size = WinGetClientSize($aGuiPos)  ;Etait $size = WinGetClientSize(hGUI)
    GUISetState(@SW_SHOW)

EndFunc

Func _Exit()
    Exit
EndFunc

Func WM_TIMER($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $ilParam

    Switch _Timer_GetTimerID($iwParam)
        Case $iTimer
            _UpdateStatusBarClock()
        EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_TIMER

Func _UpdateStatusBarClock()
   _GUICtrlStatusBar_SetText($hStatus, @TAB & StringFormat(_NowDate() & " " & "%02d:%02d:%02d", @HOUR, @MIN, @SEC), 0)
EndFunc

Func WM_SIZE($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam, $ilParam
    _GUICtrlStatusBar_Resize($hStatus)
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_SIZE

Func WM_WINDOWPOSCHANGING($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg, $wParam, $lParam
    Local $aWinGetPos = WinGetPos($hWnd)
    If @error  Or $aWinGetPos[0] < -30000 Then Return $GUI_RUNDEFMSG
    Local $tWindowPos = DllStructCreate($tagWINDOWPOS, $lParam)
    DllStructSetData($tWindowPos, 'X', $aWinGetPos[0])
    DllStructSetData($tWindowPos, 'Y', $aWinGetPos[1])
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_WINDOWPOSCHANGING

Vous pouvez éventuellement ne plus passer par le maximise :

► Afficher le textecode

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=favicon.ico
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
;==[ Création ]========:   xx/xx/2014
;==[ Auteur ]==========:
;==[ Service ]=========:
;==[ Description ]=====:
;==[ Modification ]====:    Dernière modification le xx/xx/20xx
;==[ Nature modification ]====:
    ;==[xx/xx/20xx: ***********************************]========


;==[Includes]===================================================
#include <File.au3>
#include <Date.au3>
#include <GuiStatusBar.au3>
#include <Timers.au3>
#include <Date.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <GuiListView.au3>
#include <StructureConstants.au3>

Opt("GUIOnEventMode", 1)
$Debug_LV = False ; Check ClassName being passed to ListView functions, set to True and use a handle to another control to see it work

;==[Variables globales & autres]================================
Global $CSVFolder = @ScriptDir & "\csv\"
Global $MainGUI, $ChildGUI, $FileToOpen, $aArrayOfMyFile
Global $hStatus, $aParts[3] = [200, 450, 200], $aGuiPos, $WorkAera
Global $x, $y, $w, $h
Global $ApplicationName = "Modèle vierge", $Version = "Demo", $Author = "DocteurX"

;==[Programme]==================================================

_BuildMainGUI()
GUIRegisterMsg($WM_SIZE, "WM_SIZE")
GUIRegisterMsg($WM_TIMER, "WM_TIMER")
$iTimer = _Timer_SetTimer($MainGUI, 1000)

While GUIGetMsg() <> -3
WEnd


Func _BuildMainGUI()

    $MainGUI = GUICreate($ApplicationName & " Powered By " & $Author & ". Version: " & $Version, 500, 500, 0, 0)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit", $MainGUI)
;~   WinSetState($MainGUI, "", @SW_MAXIMIZE)
    $hStatus = _GUICtrlStatusBar_Create($MainGUI, -1, "", $SBARS_SIZEGRIP)

    GUIRegisterMsg($WM_WINDOWPOSCHANGING, 'WM_WINDOWPOSCHANGING')
    GUISetState(@SW_SHOW)

    ;==[StatusBar]==============================
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)
    DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", $hStatus, "wstr", 0, "wstr", 0)
    $hIcons = _WinAPI_LoadShell32Icon(265); 233 -> Icon ATTENTION,
    _GUICtrlStatusBar_SetIcon($hStatus, 0, $hIcons)
    $hIcons2 = _WinAPI_LoadShell32Icon(160); 233 -> Icon ATTENTION,
    _GUICtrlStatusBar_SetIcon($hStatus, 1, $hIcons2)
    _GUICtrlStatusBar_SetText($hStatus, "Utilisateur: " & StringUpper(@UserName) & " " & "Poste: " & @ComputerName, 1)

    $size = WinGetClientSize($aGuiPos)  ;Etait $size = WinGetClientSize(hGUI)
    WM_SIZE($MainGUI, 0, 0, 0)
    GUISetState(@SW_SHOW)

EndFunc

Func _Exit()
    Exit
EndFunc

Func WM_TIMER($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $ilParam

    Switch _Timer_GetTimerID($iwParam)
        Case $iTimer
            _UpdateStatusBarClock()
        EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_TIMER

Func _UpdateStatusBarClock()
   _GUICtrlStatusBar_SetText($hStatus, @TAB & StringFormat(_NowDate() & " " & "%02d:%02d:%02d", @HOUR, @MIN, @SEC), 0)
EndFunc

Func WM_SIZE($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam, $ilParam
    WinMove($hWnd, "", 0, 0, @DesktopWidth, @DesktopHeight)
    _GUICtrlStatusBar_Resize($hStatus)
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_SIZE

Func WM_WINDOWPOSCHANGING($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg, $wParam, $lParam
    Local $aWinGetPos = WinGetPos($hWnd)
    If @error  Or $aWinGetPos[0] < -30000 Then Return $GUI_RUNDEFMSG
    Local $tWindowPos = DllStructCreate($tagWINDOWPOS, $lParam)
    DllStructSetData($tWindowPos, 'X', $aWinGetPos[0])
    DllStructSetData($tWindowPos, 'Y', $aWinGetPos[1])
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_WINDOWPOSCHANGING

Mais pourquoi vouloir bloquer un redimentionnement quelles sont vos contraintes ?
(Personnellement lorsque l'on ne me laisse pas ce genre de choix je n'utilise pas le programme ^^)

Bah en fait, c'est que lorsque je réduis ma fenêtre, les contrôles bougent dans tout les "sens" quand on redimensionne le GUI avec la souris.

Il me semble que Opt("GUIResizeMode", $GUI_DOCKALL) permet d'éviter ce genre de désagrément.

$GUI_DOCKALL fixera vos controls, donc une réduction fera disparaitre ceux-ci.

Essayez de regarder du coté de GUICtrlSetResizing et de mettre la bonne valeur pour chaque control, vous arriverez forcément à un résultat qui vous conviendra.

Sinon envoyez votre code avec les contrôls qui vous dérange, je regarderai.

Bonjour, pour empêcher de pouvoir manipuler la gui d'un script j'utilise cette fonction :

Code : Tout sélectionner

#Include <GUIConstantsEx.au3>

;Global Const $WM_SYSCOMMAND = 0x0112
Global Const $SC_MOVE = 0xF010
Global Const $SC_SIZE = 0xF000
Global Const $SC_CLOSE = 0xF060
Global Const $SC_MAXIMIZE = 0xF030
Global Const $SC_MINIMIZE = 0xF020

$gui = GUICreate("")
GUISetState()

GUIRegisterMsg(0x0112, "OnSysCommand")

While GUIGetMsg() <> $GUI_EVENT_CLOSE
WEnd


Func OnSysCommand($hWnd, $Msg, $wParam, $lParam)
    $test = BitAND($wParam, 0xFFF0)
    If $test = 0xF010 Then;OR $test = 0xF020 Then ;a decommanter si on veut ajouter des interdit (reduire...)
    Return False
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc

Bon, je reviens à la charge ^^.

Comme la nuit porte conseil, je me suis dit qu'effectivement pourquoi empecher le déplacement de ma GUI?

Je tiens à remercier tous ceux qui m'ont apporté leur aide pour ma question.

J'ai modifié tout mon code, mais je reste encore "bloqué" avec le resizing... J'ai une scrollbar horizontale et verticale lorsque j'ai beaucoup de données à afficher dans ma ListView.

Si j'ai trop de données, ma ScrollBar horizontal se mélange avec ma StatusBar ( ça fait franchement dégeu..)

Si j'ouvre un fichier csv et que mon gui n'est pas en plein écran, et qu'ensuite j'agrandi mon gui, ma ListView ne rempli pas pas tout mon GUI...

Ci joint mon code complet.... POUR QU'IL FONCTIONNE FAIRE UN FICHIER CSV BIDON

Merci par avance pour votre aide.

► Afficher le texte

Code : Tout sélectionner

;==[ Création ]========:   xx/xx/20xx
;==[ Auteur ]==========:
;==[ Service ]=========:
;==[ Description ]=====:    ************************************
;==[ Modification ]====:    Dernière modification le xx/xx/20xx
;==[ Nature modification ]====:
    ;==[xx/xx/20xx: ***********************************]========

;==[Include]====
#include <GuiStatusBar.au3>
#include <Timers.au3>
#include <Date.au3>
#include <File.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <GuiListView.au3>
#include <GuiMenu.au3>
#include <ListViewConstants.au3>
Opt("GUIOnEventMode", 1)

;==[Variables globales & autres]====
Global $ApplicationName = "Modèle vierge", $Version = "Demo", $Author = "xxxxxxxxxxxxxx"
Global $MainGUI, $hStatus, $aParts[3] = [200, 450, 200], $hMain, $aArrayOfMyFile, $FileToOpen, $hListView=9999
Global Enum $e_idExit, $e_idReadCSVFile
global $x, $y, $w, $h

;==[Programme]====

_Main()

GUIRegisterMsg($WM_SIZE, "WM_SIZE")
GUIRegisterMsg($WM_TIMER, "WM_TIMER")
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
$iTimer = _Timer_SetTimer($MainGUI, 1000)

While GUIGetMsg() <> -3
WEnd

Func _Main()

    $MainGUI = GUICreate($ApplicationName & " Powered By " & $Author & ". Version: " & $Version, 437, 185, -1, -1, $WS_OVERLAPPEDWINDOW)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Quitter", $MainGUI)
    WinSetState($MainGUI, "", @SW_MAXIMIZE)
    $hFile = _GUICtrlMenu_CreateMenu()
    $New= GUICtrlCreateMenuItem("Nouveau" & @TAB & "Ctrl+N", $hFile)
    _GUICtrlMenu_AddMenuItem($hFile, "Fermer l'application", $e_idExit)

    $hEdit = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hEdit, 0, "&Ouvrir fichier *.CSV", $e_idReadCSVFile)
    ; Create Main menu
    $hMain = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_AddMenuItem($hMain, "&Fichier", 0, $hFile)
    _GUICtrlMenu_AddMenuItem($hMain, "&Edition", 0, $hEdit)

    _GUICtrlMenu_SetMenu($MainGUI, $hMain)

    $hStatus = _GUICtrlStatusBar_Create($MainGUI, -1, "", $SBARS_SIZEGRIP)

    ;==[StatusBar]==============================
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)
    DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", $hStatus, "wstr", 0, "wstr", 0)
    $hIcons = _WinAPI_LoadShell32Icon(265); 233 -> Icon ATTENTION,
    _GUICtrlStatusBar_SetIcon($hStatus, 0, $hIcons)
    $hIcons2 = _WinAPI_LoadShell32Icon(160); 233 -> Icon ATTENTION,
    _GUICtrlStatusBar_SetIcon($hStatus, 1, $hIcons2)
    _GUICtrlStatusBar_SetText($hStatus, "Utilisateur: " & StringUpper(@UserName) & " " & "Poste: " & @ComputerName, 1)
    GUISetState(@SW_SHOW)

EndFunc

Func _ReadAndDisplayCSVFile()

    $FileToOpen = _CSVFileToOpen()
    $aArrayOfMyFile = _CSV2Array($FileToOpen)
    _CreateListView()

EndFunc

Func _CreateListView()

    GUICtrlDelete($hListView)
    ;_GUICtrlListView_DeleteAllItems($hListView)
    $NumberOfColumns = UBound($aArrayOfMyFile, 2)
    $FirstLineOfCSVFile = ""

    For $i = 0 to UBound($aArrayOfMyFile, 2)-1   ; nb de colonnes
        $FirstLineOfCSVFile &= $aArrayOfMyFile[0][$i] & "|"
    Next

    $FirstLineOfCSVFile = StringTrimRight($FirstLineOfCSVFile, 1)  ; pour enlever le dernier "|"
    $NumberOfRows = _FileCountLines($FileToOpen)

    ;##########################################################################################################################################
    $SizeOfMainGUI = WinGetClientSize($MainGUI)
    ConsoleWrite($SizeOfMainGUI[0] & " | " & $SizeOfMainGUI[1] & @CRLF )
    $hListView = GUICtrlCreateListView($FirstLineOfCSVFile, 0, 0, $SizeOfMainGUI[0], $SizeOfMainGUI[1] - _GUICtrlStatusBar_GetHeight($hStatus))
    GUICtrlSetBkColor($hListView, $GUI_BKCOLOR_LV_ALTERNATE)
    ;##########################################################################################################################################

    Dim $aItems[$NumberOfRows]
    _GUICtrlListView_BeginUpdate($hListView)

    For $i = 0 To $NumberOfRows - 2
        For $j = 0 to $NumberOfColumns - 1
            $aItems[$i] &= $aArrayOfMyFile[$i+1][$j] & "|"
        Next
        $aItems[$i] = StringTrimRight($aItems[$i], 1)
        GUICtrlCreateListViewItem($aItems[$i], $hListView)
        If Mod($i, 2) <> 0 Then GUICtrlSetBkColor(-1, 0xdddddd)
    Next

    For $c = 0 to $NumberOfColumns - 1
        _GUICtrlListView_SetColumn($hListView, $c, $aArrayOfMyFile[0][$c])
        GUICtrlSendMsg($hListView, $LVM_SETCOLUMNWIDTH, $c, 150)
    Next
    _GUICtrlListView_EndUpdate($hListView)
    My_GUICtrlListView_AutoSizeColumns($hListView)
    GUISetState(@SW_SHOW)

EndFunc

Func _CSVFileToOpen()

    Local $Var = FileOpenDialog("Choisir votre fichier CSV...", @ScriptDir & "\CSV_Files", "Fichier CSV (*.csv)", 1);"C:\temp"
    If @error Then Exit
    Return $var

EndFunc

Func _CSV2Array($hFile, $cSeperator = ";", $bFilterString = True, $iColumnMode = 0)
    Local $s = FileRead($hFile)
    If @error Then Return SetError(1)

    If $cSeperator = Default Then $cSeperator = "auto"
    If Not $cSeperator Then $cSeperator = Opt("GUIDataSeparatorChar")

    ; searching the line-seperator and splitting the lines into an array
    Local $aLines
    If StringInStr($s, @CRLF) Then
        $aLines = StringSplit($s, @CRLF, 1)
    ElseIf StringInStr($s, @CR) Then
        $aLines = StringSplit($s, @CR)
    Else
        $aLines = StringSplit($s, @LF)
    EndIf

    ; searching the delimiter in the first line
    Local $aTMP
    If $cSeperator = "auto" Then
        Local $iMax = 0
        Local $iC[5] = [0, 0, 0, 0, 0]
        Local $sC[5] = [";", ",", @TAB, "|", " "]

        $aTMP = StringRegExp($aLines[1], ";", 3)
        If Not @error Then $iC[0] = UBound($aTMP)
        $aTMP = StringRegExp($aLines[1], ",", 3)
        If Not @error Then $iC[1] = UBound($aTMP)
        $aTMP = StringRegExp($aLines[1], "\t", 3)
        If Not @error Then $iC[2] = UBound($aTMP)
        $aTMP = StringRegExp($aLines[1], "\|", 3)
        If Not @error Then $iC[3] = UBound($aTMP)
        $aTMP = StringRegExp($aLines[1], "[ ]", 3)
        If Not @error Then $iC[4] = UBound($aTMP)

        For $i = 4 To UBound($sC) - 1
            If $iC[$i] > $iMax Then
                $iMax = $iC[$i]
                $cSeperator = $sC[$i]
            EndIf
        Next
    EndIf

    ; creating 2-dim array based on the number of data in the first line
    $aTMP = StringSplit($aLines[1], $cSeperator)
    Local $iCol = $aTMP[0]
    Local $aRet[$aLines[0]][$iCol]

    ; splitting and filling the lines
    For $i = 1 To $aLines[0]
        $aTMP = StringSplit($aLines[$i], $cSeperator)
        If @error Then ContinueLoop
        If $aTMP[0] > $iCol Then
            Switch $iColumnMode
                Case 0
                    Return SetError(2, $i)
                Case 1
                    ReDim $aRet[$aLines[0] - 1][$aTMP[0]]
                Case 2
                    $aTMP[0] = $iCol
                Case Else
                    Return SetError(3)
            EndSwitch
        EndIf
        For $j = 1 To $aTMP[0]
            $aTMP[$j] = StringStripWS($aTMP[$j], 3)

            ; removing leading and trailing " or '
            If $bFilterString Then $aTMP[$j] = StringRegExpReplace($aTMP[$j], '^("|'')(.*?)\1$', '$2')

            $aRet[$i - 1][$j - 1] = $aTMP[$j]
        Next ; /cols
    Next ; /lines

    Return $aRet
EndFunc   ;==>_CSV2Array

Func My_GUICtrlListView_AutoSizeColumns($hListView, $iMini = 30)
    If Not IsHWnd($hListView) Then $hListView = GUICtrlGetHandle($hListView)
    Local $hHeader = _GUICtrlListView_GetHeader($hListView), $iHeader_Width, $iData_Width
    _GUICtrlListView_BeginUpdate($hListView)
    For $iIndex = 0 To _GUICtrlListView_GetColumnCount($hListView) - 1
        If _GUICtrlListView_GetColumnWidth($hListView, $iIndex) = 0 Then ContinueLoop
        _GUICtrlListView_SetColumnWidth($hListView, $iIndex, $LVSCW_AUTOSIZE_USEHEADER)
        $iHeader_Width = _GUICtrlListView_GetColumnWidth($hListView, $iIndex)
        If @OSVersion = "WIN_XP" And $iIndex < _GUICtrlListView_GetColumnCount($hListView) - 1 Then
            If _GUICtrlHeader_GetItemFlags($hHeader, $iIndex) / 2 > 1 Then $iHeader_Width += 30
        EndIf
        _GUICtrlListView_SetColumnWidth($hListView, $iIndex, $LVSCW_AUTOSIZE)
        $iData_Width = _GUICtrlListView_GetColumnWidth($hListView, $iIndex)
        If $iHeader_Width > $iData_Width Then
            _GUICtrlListView_SetColumnWidth($hListView, $iIndex, $iHeader_Width)
        EndIf
        If _GUICtrlListView_GetColumnWidth($hListView, $iIndex) < $iMini Then
            _GUICtrlListView_SetColumnWidth($hListView, $iIndex, $iMini)
        EndIf
    Next
    _GUICtrlListView_EndUpdate($hListView)
EndFunc   ;==>My_GUICtrlListView_AutoSizeColumns

Func _Quitter()
    Exit
EndFunc

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $lParam
    Switch $wParam
        Case $e_idExit
            Exit

        Case $e_idReadCSVFile
            ;MsgBox(64, "", "$e_idReadCSVFile")
            ;_Ini()
            ;_CreateListView()
            _ReadAndDisplayCSVFile()

    EndSwitch
EndFunc   ;==>WM_COMMAND

Func WM_TIMER($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $ilParam

    Switch _Timer_GetTimerID($iwParam)
        Case $iTimer
            _UpdateStatusBarClock()
        EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_TIMER

Func _UpdateStatusBarClock()
   _GUICtrlStatusBar_SetText($hStatus, @TAB & StringFormat(_NowDate() & " " & "%02d:%02d:%02d", @HOUR, @MIN, @SEC), 0)
EndFunc

Func WM_SIZE($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam, $ilParam
    _GUICtrlStatusBar_Resize($hStatus)
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_SIZE

Pouvez vous fournir un csv bidon avec lequel vous reproduisez le problème ?

Bonjour,

Voici le CSV http://www.cjoint.com/14dc/DLfjgWPiclk.htm

Vous n'utilisez pas de resizing pour les controls, pour votre projet je vous conseille de mettre un resizing par défaut égal aux 4 bords pour que la liste s'agrandisse avec le redimensionnement

rajoutez en début de script :

Code : Tout sélectionner

Opt("GUIResizeMode", BitOR($GUI_DOCKLEFT, $GUI_DOCKTOP, $GUI_DOCKRIGHT, $GUI_DOCKBOTTOM))

Si vous avez des controls spécifique, utilisez GUICtrlSetResizing (essayez de jouer avec les valeurs pour voir les effets)

Ok merci beaucoup

Sujet résolu

AutoIt Français

[R] GUI non déplaçable

[R] GUI non déplaçable

Re: [..] GUI non déplaçable

Re: [..] GUI non déplaçable

Re: [..] GUI non déplaçable

Re: [..] GUI non déplaçable

Re: [..] GUI non déplaçable

Re: [..] GUI non déplaçable

Re: [..] GUI non déplaçable

Re: [..] GUI non déplaçable

Re: [..] GUI non déplaçable

Re: [..] GUI non déplaçable