AutoIt Français

Hello !

Je suis au points de finir une "belle" GUI mais il persiste certains "bug".

Pour expliquer rapidement, j'utilise une première GUI qui comporte tous les outils basique d'une fenêtre (fermer, réduire, déplacer) et un grand espace vide. Dans cette espace vide je fais afficher une autre GUI spécifique aux évènements.

Le premier soucie est que j'utilise l'argument "$WS_EX_TOPMOST" pour afficher ma deuxième GUI devant l'autre. Cependant cette fonction va l'afficher vraiment tout devant l'écran. Du coup si on passe une autre fenêtre au dessus de mon interface la deuxième GUI figure encore devant l'écran.

~~Le deuxième soucie est que l'affichage des 2 GUI provoquent 2 vignettes dans la barre des tâches ce qui n'est pas bien pratique lorsqu'on réduit la fenêtre.~~
$WS_EX_TOOLWINDOW

Concernant le code, il est lisible, structuré et vaut le détour ne serait-ce uniquement pour le garder en tant qu'exemple d'application des fonctions que j'utilise. Je suis bien sur ouvert à toute suggestion

Un dernier truc : Le login "bob" va vous permettre d'accéder à la validation du compte

EDIT : MAJ de la GUI
- Insertion de nouvelles balises
- Optimisation du code

Si tu veux imposer un z-order précis à ta gui il te faut utiliser le paramètre $hAfter de _WinAPI_SetWindowPos
J'avais utilisé ça ici

Oulala, merci, je m'étais arrêté de lire la doc dés qu'une solution était possible et du coup j'ai sauté cette histoire de GUI Parent/Enfant

Il y a beaucoup plus simple pour ton problème je pense.
Il suffit d'utiliser le style étendu $WS_EX_MDICHILD pour indiquer à ta fenêtre fille qu'elle est inclue dans la GUI principale. Ainsi, elle se déplacera avec elle et elle gardera le même z-order qu'elle.

► Afficher le texte

Code : Tout sélectionner

#include <IE.au3>
#include <string.au3>
#include <GUIConstants.au3>
#include <GUICtrlSetOnHover.au3>


;===============================User==============================================

$user = False

;===============================GUI==============================================
$width = 470
;########Partie Supérieur########
$Gui_Boss = GUICreate("Leboncoin", $width, 250, (@DesktopWidth - 470) / 2, (@DesktopHeight - 250) / 2,$WS_POPUPWINDOW)
GUIRegisterMsg($WM_MOVE, "MY_WM_MOVE")
GUISetBkColor(0xFFFFEB)

Global $croix = GUICtrlCreatePic(@ScriptDir & "\Leboncoin\croix.jpg", $width - 50, 10,40,40)
Global $moins = GUICtrlCreatePic(@ScriptDir & "\Leboncoin\moins.jpg",$width - 110,20,40,40)
_GUICtrl_SetOnHover($moins, "_Hover_Proc", "_Leave_Hover_Proc")
_GUICtrl_SetOnHover($croix, "_Hover_Proc", "_Leave_Hover_Proc")

GUICtrlCreatePic(@ScriptDir & "\Leboncoin\logo_leboncoin.jpg", 3, 2, 314, 71, -1,$GUI_WS_EX_PARENTDRAG);dimensions de l'image (314*71)
GuiCtrlCreateLabel("", 0, 0, $width, 71, -1, $GUI_WS_EX_PARENTDRAG)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)

;#########Partie Inférieur#######

If $user = False Then

    ;##InputText de l'Email et du MPD##
    $LoginLBC = GUICreate("",470,170,2,73,$WS_POPUP,$WS_EX_MDICHILD, $Gui_Boss)
    GUISetBkColor(0xFFFFEB)
    $txt_titre = GUICtrlCreateLabel("Enregistrez votre compte Leboncoin sur ce Pc",40,30,500,30)
    GUICtrlSetFont(-1, 20, 800, 0, "Myriad Arabic")

    $txt_Email = GUICtrlCreateLabel("Email :",45,70,100,30)
    GUICtrlSetFont(-1, 15, 800, 0, "Myriad Arabic")
    $Email = GUICtrlCreateInput("", 93, 75, 230, 25)
    GUICtrlSetFont(-1, 13)

    $txt_MDP = GUICtrlCreateLabel("Mot de passe :",45,110,100,30)
    GUICtrlSetFont(-1, 15, 800, 0, "Myriad Arabic")
    $Pass = GUICtrlCreateInput("", 143, 115, 180, 25,0x0020) ;0x0020 pour cacher les caractères
    GUICtrlSetFont(-1, 13)

    $validerLogin = GUICtrlCreatePic(@ScriptDir& "\Leboncoin\valider.jpg",350,80,50,50)
    _GUICtrl_SetOnHover(-1, "_Hover_Proc", "_Leave_Hover_Proc", "PrimaryDown_Proc")


    ;##Validation du compte Leboncoin##
    $WaintingLBC = GUICreate("Leboncoin", 470, 170, 2, 73,$WS_POPUP,$WS_EX_MDICHILD, $Gui_Boss)
    GUISetBkColor(0xFFFFEB)

    $oIE = ObjCreate("Shell.Explorer.2")
    $GUIActiveX = GUICtrlCreateObj($oIE, 200, 90, 50, 51)
    $oIE.navigate ("about&#058;blank")
    $oIE.document.body.BGCOLOR = "#FFFFEB"
    $oIE.document.body.background = @ScriptDir & "\Leboncoin\loader.gif"
    $oIE.document.body.scroll = "no"
    $oIE.document.body.style.border = "0px" ;supprime la bordure

    $txt_titre = GUICtrlCreateLabel("Vérification du compte, veuillez patienter...",50,30,400,30)
    GUICtrlSetFont(-1, 20, 800, 0, "Myriad Arabic")


    ;##Erreur de connexion, Mauvais Email ou/et MDP##
    $ErrorLBC = GUICreate("Leboncoin", 470, 170, 2, 73,$WS_POPUP,$WS_EX_MDICHILD, $Gui_Boss)
    GUISetBkColor(0xFFFFEB)

    $txt_titre = GUICtrlCreateLabel("Erreur, identifiant ou mot de passe incorrect.",50,30,500,30)
    GUICtrlSetFont(-1, 20, 800, 0, "Myriad Arabic")

    $ErrorPic = GUICtrlCreatePic(@ScriptDir& "\Leboncoin\error.jpg",200,90,60,60)
    _GUICtrl_SetOnHover($ErrorPic, "_Hover_Proc", "_Leave_Hover_Proc")



    ;##Connexion réussi, compte enregistré##
    $ValidateLBC = GUICreate("Leboncoin", 470, 170, 2, 73,$WS_POPUP,$WS_EX_MDICHILD, $Gui_Boss)
    GUISetBkColor(0xFFFFEB)

    $txt_titre = GUICtrlCreateLabel("Connexion réussi, compte enregistré.",80,30,500,30)
    GUICtrlSetFont(-1, 20, 800, 0, "Myriad Arabic")

    $ValiderPic = GUICtrlCreatePic(@ScriptDir& "\Leboncoin\valider2.jpg",200,90,55,55)
    _GUICtrl_SetOnHover($ValiderPic, "_Hover_Proc", "_Leave_Hover_Proc")



    $PIA = $LoginLBC ;Partie inférieur active (pour MY_WM_MOVE)
Else
    $PIA = ""
EndIf

;================================================================================

GUISetState(@SW_SHOW,$Gui_Boss)
GUISetState(@SW_SHOW,$LoginLBC)
GUISetState(@SW_HIDE,$WaintingLBC)
GUISetState(@SW_HIDE,$ErrorLBC)
GUISetState(@SW_HIDE,$ValidateLBC)


While 1
    $Msg = GUIGetMsg()

    Switch $Msg
        Case $moins
            GUISetState(@SW_MINIMIZE,$Gui_Boss)
        Case $croix
            Exit
        Case $validerLogin
            ToolTip("")
            GuiChange($LoginLBC,$WaintingLBC)

            $oIE = _IECreate("https://compteperso.leboncoin.fr/account/index.html",0,0)
            $oForm = _IEFormGetObjByName($oIE, "loginform")
            $oUser = _IEFormElementGetObjByName($oForm, "st_username")
            _IEFormElementSetValue($oUser, GUICtrlRead($Email))
            $oPass = _IEFormElementGetObjByName($oForm, "st_passwd")
            _IEFormElementSetValue($oPass, GUICtrlRead($pass))
            _IEFormSubmit($oForm)

            Do
                $text = _IEBodyReadText($oIE)
            Until StringInStr($text,"Bienvenue") Or StringInStr($text, "Votre identifiant ou mot de passe est incorrect") or StringInStr($text,"Saisissez un mot de passe")
            _IEQuit($oIE)

            If StringInStr($text,"Bienvenue") Or GUICtrlRead($Email) = "bob" Then
                GuiChange($WaintingLBC,$ValidateLBC)
            Else
                GuiChange($WaintingLBC,$ErrorLBC)
            EndIf
        Case $ErrorPic

            GuiChange($ErrorLBC,$LoginLBC)


    EndSwitch
WEnd

Func GuiChange($Old_GUI,$New_GUI)
    $PIA = $New_GUI ;Partie Inférieur Active
    $aPos = WinGetPos($Gui_Boss)
    WinMove($New_GUI,"",$aPos[0]+1, $aPos[1]+73)
    GUISetState(@SW_HIDE,$Old_GUI)
    GUISetState(@SW_SHOW,$New_GUI)
EndFunc


Func MY_WM_MOVE($hWnd, $Msg, $wParam, $lParam)
    $nNotifyCode = BitShift($wParam, 16)
    $nID = BitAND($wParam, 0x0000FFFF)
    Local $aGui1 = WinGetPos($Gui_Boss)
    If $nID <> 2 And $nNotifyCode = 0 Then WinMove($PIA, "", $aGui1[0]+1, $aGui1[1]+73)
EndFunc   ;==>MY_WM_COMMAND

Func _Hover_Proc($iCtrlID)
    Switch $iCtrlID
        Case $moins
            GUICtrlSetImage($iCtrlID, @ScriptDir & "\Leboncoin\moins_Hover.jpg")
        Case $croix
            GUICtrlSetImage($iCtrlID, @ScriptDir & "\Leboncoin\croix_Hover.jpg")
        Case $validerLogin
            GUICtrlSetImage($iCtrlID, @ScriptDir & "\Leboncoin\valider_Hover.jpg")
            ToolTip("Aucune information concernant votre compte ne sera utilisé autre part que sur cet ordinateur."&@CRLF& _
            "Toutes vos annonces seront stockées sur votre PC, et nul part ailleurs, dans le dossier :"&@CRLF& _
            '"'&@ProgramFilesDir&'\Leboncoin\"')
        Case $ValiderPic
            GUICtrlSetImage($iCtrlID, @ScriptDir & "\Leboncoin\valider2_Hover.jpg")
            ToolTip("Accéder au menu principale")
        Case $ErrorPic
            GUICtrlSetImage($iCtrlID, @ScriptDir & "\Leboncoin\error_Hover.jpg")
            ToolTip("Recommencer")
    EndSwitch
EndFunc   ;==>_Hover_Proc

Func _Leave_Hover_Proc($iCtrlID)
    Switch $iCtrlID
        Case $moins
            GUICtrlSetImage($iCtrlID, @ScriptDir & "\Leboncoin\moins.jpg")
        Case $croix
            GUICtrlSetImage($iCtrlID, @ScriptDir & "\Leboncoin\croix.jpg")
        Case $validerLogin
            GUICtrlSetImage($iCtrlID, @ScriptDir & "\Leboncoin\valider.jpg")
            ToolTip("")
        Case $ValiderPic
            GUICtrlSetImage($iCtrlID, @ScriptDir & "\Leboncoin\valider2.jpg")
            ToolTip("")
        Case $ErrorPic
            GUICtrlSetImage($iCtrlID, @ScriptDir & "\Leboncoin\error.jpg")
            ToolTip("")


    EndSwitch
EndFunc   ;==>_Leave_Hover_Proc

Edit : juste deux remarque par rapport à l'interface :
- c'est sympa

- pense juste à désactiver ton IE embarqué, histoire de ne pas avoir un malin qui pense à faire un clic droit sur l'image... GUICtrlSetState($GUIActiveX, $GUI_DISABLE)

Super merci

J'ai fais un EDIT et tout me semble correcte

AutoIt Français

[R] Superposition 2 GUI & Vignette barre des tâches

[R] Superposition 2 GUI & Vignette barre des tâches

Re: [..] Superposition 2 GUI & Vignette barre des tâches

Re: [..] Superposition 2 GUI & Vignette barre des tâches

Re: [..] Superposition 2 GUI & Vignette barre des tâches

Re: [R] Superposition 2 GUI & Vignette barre des tâches